lisp/timer.el

   1 ;;; timer.el --- run a function with args at some time in future.
   2
   3 ;; Copyright (C) 1996 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package gives you the capability to run Emacs Lisp commands at
  27 ;; specified times in the future, either as one-shots or periodically.
  28
  29 ;;; Code:
  30
  31 ;; Layout of a timer vector:
  32 ;; [triggered-p high-seconds low-seconds usecs repeat-delay
  33 ;;  function args idle-delay]
  34
  35 (defun timer-create ()
  36   "Create a timer object."
  37   (let ((timer (make-vector 8 nil)))
  38     (aset timer 0 t)
  39     timer))
  40
  41 (defun timerp (object)
  42   "Return t if OBJECT is a timer."
  43   (and (vectorp object) (= (length object) 8)))
  44
  45 (defun timer-set-time (timer time &optional delta)
  46   "Set the trigger time of TIMER to TIME.
  47 TIME must be in the internal format returned by, e.g., `current-time'.
  48 If optional third argument DELTA is a non-zero integer, make the timer
  49 fire repeatedly that many seconds apart."
  50   (or (timerp timer)
  51       (error "Invalid timer"))
  52   (aset timer 1 (car time))
  53   (aset timer 2 (if (consp (cdr time)) (car (cdr time)) (cdr time)))
  54   (aset timer 3 (or (and (consp (cdr time)) (consp (cdr (cdr time)))
  55                          (nth 2 time))
  56                     0))
  57   (aset timer 4 (and (numberp delta) (> delta 0) delta))
  58   timer)
  59
  60 (defun timer-set-idle-time (timer secs &optional repeat)
  61   "Set the trigger idle time of TIMER to SECS.
  62 If optional third argument REPEAT is non-nil, make the timer
  63 fire each time Emacs is idle for that many seconds."
  64   (or (timerp timer)
  65       (error "Invalid timer"))
  66   (aset timer 1 0)
  67   (aset timer 2 0)
  68   (aset timer 3 0)
  69   (timer-inc-time timer secs)
  70   (aset timer 4 repeat)
  71   timer)
  72
  73 (defun timer-next-integral-multiple-of-time (time secs)
  74   "Yield the next value after TIME that is an integral multiple of SECS.
  75 More precisely, the next value, after TIME, that is an integral multiple
  76 of SECS seconds since the epoch.  SECS may be a fraction."
  77   (let ((time-base (ash 1 16)))
  78     (if (fboundp 'atan)
  79         ;; Use floating point, taking care to not lose precision.
  80         (let* ((float-time-base (float time-base))
  81                (million 1000000.0)
  82                (time-usec (+ (* million
  83                                 (+ (* float-time-base (nth 0 time))
  84                                    (nth 1 time)))
  85                              (nth 2 time)))
  86                (secs-usec (* million secs))
  87                (mod-usec (mod time-usec secs-usec))
  88                (next-usec (+ (- time-usec mod-usec) secs-usec))
  89                (time-base-million (* float-time-base million)))
  90           (list (floor next-usec time-base-million)
  91                 (floor (mod next-usec time-base-million) million)
  92                 (floor (mod next-usec million))))
  93       ;; Floating point is not supported.
  94       ;; Use integer arithmetic, avoiding overflow if possible.
  95       (let* ((mod-sec (mod (+ (* (mod time-base secs)
  96                                  (mod (nth 0 time) secs))
  97                               (nth 1 time))
  98                            secs))
  99              (next-1-sec (+ (- (nth 1 time) mod-sec) secs)))
 100         (list (+ (nth 0 time) (floor next-1-sec time-base))
 101               (mod next-1-sec time-base)
 102               0)))))
 103
 104 (defun timer-relative-time (time secs &optional usecs)
 105   "Advance TIME by SECS seconds and optionally USECS microseconds.
 106 SECS may be a fraction."
 107   (let ((high (car time))
 108         (low (if (consp (cdr time)) (nth 1 time) (cdr time)))
 109         (micro (if (numberp (car-safe (cdr-safe (cdr time))))
 110                    (nth 2 time)
 111                  0)))
 112     ;; Add
 113     (if usecs (setq micro (+ micro usecs)))
 114     (if (floatp secs)
 115         (setq micro (+ micro (floor (* 1000000 (- secs (floor secs)))))))
 116     (setq low (+ low (floor secs)))
 117
 118     ;; Normalize
 119     (setq low (+ low (/ micro 1000000)))
 120     (setq micro (mod micro 1000000))
 121     (setq high (+ high (/ low 65536)))
 122     (setq low (logand low 65535))
 123
 124     (list high low (and (/= micro 0) micro))))
 125
 126 (defun timer-inc-time (timer secs &optional usecs)
 127   "Increment the time set in TIMER by SECS seconds and USECS microseconds.
 128 SECS may be a fraction."
 129   (let ((time (timer-relative-time
 130                (list (aref timer 1) (aref timer 2) (aref timer 3))
 131                secs
 132                usecs)))
 133     (aset timer 1 (nth 0 time))
 134     (aset timer 2 (nth 1 time))
 135     (aset timer 3 (or (nth 2 time) 0))))
 136
 137 (defun timer-set-time-with-usecs (timer time usecs &optional delta)
 138   "Set the trigger time of TIMER to TIME.
 139 TIME must be in the internal format returned by, e.g., `current-time'.
 140 If optional third argument DELTA is a non-zero integer, make the timer
 141 fire repeatedly that many seconds apart."
 142   (or (timerp timer)
 143       (error "Invalid timer"))
 144   (aset timer 1 (car time))
 145   (aset timer 2 (if (consp (cdr time)) (car (cdr time)) (cdr time)))
 146   (aset timer 3 usecs)
 147   (aset timer 4 (and (numberp delta) (> delta 0) delta))
 148   timer)
 149
 150 (defun timer-set-function (timer function &optional args)
 151   "Make TIMER call FUNCTION with optional ARGS when triggering."
 152   (or (timerp timer)
 153       (error "Invalid timer"))
 154   (aset timer 5 function)
 155   (aset timer 6 args)
 156   timer)
 157 \f
 158 (defun timer-activate (timer)
 159   "Put TIMER on the list of active timers."
 160   (if (and (timerp timer)
 161            (integerp (aref timer 1))
 162            (integerp (aref timer 2))
 163            (integerp (aref timer 3))
 164            (aref timer 5))
 165       (let ((timers timer-list)
 166             last)
 167         ;; Skip all timers to trigger before the new one.
 168         (while (and timers
 169                     (or (> (aref timer 1) (aref (car timers) 1))
 170                         (and (= (aref timer 1) (aref (car timers) 1))
 171                              (> (aref timer 2) (aref (car timers) 2)))
 172                         (and (= (aref timer 1) (aref (car timers) 1))
 173                              (= (aref timer 2) (aref (car timers) 2))
 174                              (> (aref timer 3) (aref (car timers) 3)))))
 175           (setq last timers
 176                 timers (cdr timers)))
 177         ;; Insert new timer after last which possibly means in front of queue.
 178         (if last
 179             (setcdr last (cons timer timers))
 180           (setq timer-list (cons timer timers)))
 181         (aset timer 0 nil)
 182         (aset timer 7 nil)
 183         nil)
 184     (error "Invalid or uninitialized timer")))
 185
 186 (defun timer-activate-when-idle (timer)
 187   "Arrange to activate TIMER whenever Emacs is next idle."
 188   (if (and (timerp timer)
 189            (integerp (aref timer 1))
 190            (integerp (aref timer 2))
 191            (integerp (aref timer 3))
 192            (aref timer 5))
 193       (let ((timers timer-idle-list)
 194             last)
 195         ;; Skip all timers to trigger before the new one.
 196         (while (and timers
 197                     (or (> (aref timer 1) (aref (car timers) 1))
 198                         (and (= (aref timer 1) (aref (car timers) 1))
 199                              (> (aref timer 2) (aref (car timers) 2)))
 200                         (and (= (aref timer 1) (aref (car timers) 1))
 201                              (= (aref timer 2) (aref (car timers) 2))
 202                              (> (aref timer 3) (aref (car timers) 3)))))
 203           (setq last timers
 204                 timers (cdr timers)))
 205         ;; Insert new timer after last which possibly means in front of queue.
 206         (if last
 207             (setcdr last (cons timer timers))
 208           (setq timer-idle-list (cons timer timers)))
 209         (aset timer 0 t)
 210         (aset timer 7 t)
 211         nil)
 212     (error "Invalid or uninitialized timer")))
 213
 214 ;;;###autoload
 215 (defalias 'disable-timeout 'cancel-timer)
 216 ;;;###autoload
 217 (defun cancel-timer (timer)
 218   "Remove TIMER from the list of active timers."
 219   (or (timerp timer)
 220       (error "Invalid timer"))
 221   (setq timer-list (delq timer timer-list))
 222   (setq timer-idle-list (delq timer timer-idle-list))
 223   nil)
 224
 225 ;;;###autoload
 226 (defun cancel-function-timers (function)
 227   "Cancel all timers scheduled by `run-at-time' which would run FUNCTION."
 228   (interactive "aCancel timers of function: ")
 229   (let ((tail timer-list))
 230     (while tail
 231       (if (eq (aref (car tail) 5) function)
 232           (setq timer-list (delq (car tail) timer-list)))
 233       (setq tail (cdr tail))))
 234   (let ((tail timer-idle-list))
 235     (while tail
 236       (if (eq (aref (car tail) 5) function)
 237           (setq timer-idle-list (delq (car tail) timer-idle-list)))
 238       (setq tail (cdr tail)))))
 239 \f
 240 ;; Record the last few events, for debugging.
 241 (defvar timer-event-last-2 nil)
 242 (defvar timer-event-last-1 nil)
 243 (defvar timer-event-last nil)
 244
 245 (defvar timer-max-repeats 10
 246   "*Maximum number of times to repeat a timer, if real time jumps.")
 247
 248 (defun timer-until (timer time)
 249   "Calculate number of seconds from when TIMER will run, until TIME.
 250 TIMER is a timer, and stands for the time when its next repeat is scheduled.
 251 TIME is a time-list."
 252   (let ((high (- (car time) (aref timer 1)))
 253         (low (- (nth 1 time) (aref timer 2))))
 254     (+ low (* high 65536))))
 255
 256 (defun timer-event-handler (timer)
 257   "Call the handler for the timer TIMER.
 258 This function is called, by name, directly by the C code."
 259   (setq timer-event-last-2 timer-event-last-1)
 260   (setq timer-event-last-1 timer-event-last)
 261   (setq timer-event-last timer)
 262   (let ((inhibit-quit t))
 263     (if (timerp timer)
 264         (progn
 265           ;; Delete from queue.
 266           (cancel-timer timer)
 267           ;; Re-schedule if requested.
 268           (if (aref timer 4)
 269               (if (aref timer 7)
 270                   (timer-activate-when-idle timer)
 271                 (timer-inc-time timer (aref timer 4) 0)
 272                 ;; If real time has jumped forward,
 273                 ;; perhaps because Emacs was suspended for a long time,
 274                 ;; limit how many times things get repeated.
 275                 (if (and (numberp timer-max-repeats)
 276                          (< 0 (timer-until timer (current-time))))
 277                     (let ((repeats (/ (timer-until timer (current-time))
 278                                       (aref timer 4))))
 279                       (if (> repeats timer-max-repeats)
 280                           (timer-inc-time timer (* (aref timer 4) repeats)))))
 281                 (timer-activate timer)))
 282           ;; Run handler.
 283           ;; We do this after rescheduling so that the handler function
 284           ;; can cancel its own timer successfully with cancel-timer.
 285           (condition-case nil
 286               (apply (aref timer 5) (aref timer 6))
 287             (error nil)))
 288       (error "Bogus timer event"))))
 289
 290 ;; This function is incompatible with the one in levents.el.
 291 (defun timeout-event-p (event)
 292   "Non-nil if EVENT is a timeout event."
 293   (and (listp event) (eq (car event) 'timer-event)))
 294 \f
 295 ;;;###autoload
 296 (defun run-at-time (time repeat function &rest args)
 297   "Perform an action at time TIME.
 298 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 299 TIME should be a string like \"11:23pm\", nil meaning now, a number of seconds
 300 from now, a value from `current-time', or t (with non-nil REPEAT)
 301 meaning the next integral multiple of REPEAT.
 302 REPEAT may be an integer or floating point number.
 303 The action is to call FUNCTION with arguments ARGS.
 304
 305 This function returns a timer object which you can use in `cancel-timer'."
 306   (interactive "sRun at time: \nNRepeat interval: \naFunction: ")
 307
 308   (or (null repeat)
 309       (and (numberp repeat) (< 0 repeat))
 310       (error "Invalid repetition interval"))
 311
 312   ;; Special case: nil means "now" and is useful when repeating.
 313   (if (null time)
 314       (setq time (current-time)))
 315
 316   ;; Special case: t means the next integral multiple of REPEAT.
 317   (if (and (eq time t) repeat)
 318       (setq time (timer-next-integral-multiple-of-time (current-time) repeat)))
 319
 320   ;; Handle numbers as relative times in seconds.
 321   (if (numberp time)
 322       (setq time (timer-relative-time (current-time) time)))
 323
 324   ;; Handle relative times like "2 hours and 35 minutes"
 325   (if (stringp time)
 326       (let ((secs (timer-duration time)))
 327         (if secs
 328             (setq time (timer-relative-time (current-time) secs)))))
 329
 330   ;; Handle "11:23pm" and the like.  Interpret it as meaning today
 331   ;; which admittedly is rather stupid if we have passed that time
 332   ;; already.  (Though only Emacs hackers hack Emacs at that time.)
 333   (if (stringp time)
 334       (progn
 335         (require 'diary-lib)
 336         (let ((hhmm (diary-entry-time time))
 337               (now (decode-time)))
 338           (if (>= hhmm 0)
 339               (setq time
 340                     (encode-time 0 (% hhmm 100) (/ hhmm 100) (nth 3 now)
 341                                  (nth 4 now) (nth 5 now) (nth 8 now)))))))
 342
 343   (or (consp time)
 344       (error "Invalid time format"))
 345
 346   (let ((timer (timer-create)))
 347     (timer-set-time timer time repeat)
 348     (timer-set-function timer function args)
 349     (timer-activate timer)
 350     timer))
 351
 352 ;;;###autoload
 353 (defun run-with-timer (secs repeat function &rest args)
 354   "Perform an action after a delay of SECS seconds.
 355 Repeat the action every REPEAT seconds, if REPEAT is non-nil.
 356 SECS and REPEAT may be integers or floating point numbers.
 357 The action is to call FUNCTION with arguments ARGS.
 358
 359 This function returns a timer object which you can use in `cancel-timer'."
 360   (interactive "sRun after delay (seconds): \nNRepeat interval: \naFunction: ")
 361   (apply 'run-at-time secs repeat function args))
 362
 363 ;;;###autoload
 364 (defun add-timeout (secs function object &optional repeat)
 365   "Add a timer to run SECS seconds from now, to call FUNCTION on OBJECT.
 366 If REPEAT is non-nil, repeat the timer every REPEAT seconds.
 367 This function is for compatibility; see also `run-with-timer'."
 368   (run-with-timer secs repeat function object))
 369
 370 ;;;###autoload
 371 (defun run-with-idle-timer (secs repeat function &rest args)
 372   "Perform an action the next time Emacs is idle for SECS seconds.
 373 If REPEAT is non-nil, do this each time Emacs is idle for SECS seconds.
 374 SECS may be an integer or a floating point number.
 375 The action is to call FUNCTION with arguments ARGS.
 376
 377 This function returns a timer object which you can use in `cancel-timer'."
 378   (interactive
 379    (list (read-from-minibuffer "Run after idle (seconds): " nil nil t)
 380          (y-or-n-p "Repeat each time Emacs is idle? ")
 381          (intern (completing-read "Function: " obarray 'fboundp t))))
 382   (let ((timer (timer-create)))
 383     (timer-set-function timer function args)
 384     (timer-set-idle-time timer secs repeat)
 385     (timer-activate-when-idle timer)
 386     timer))
 387 \f
 388 (defun with-timeout-handler (tag)
 389   (throw tag 'timeout))
 390
 391 ;;;###autoload (put 'with-timeout 'lisp-indent-function 1)
 392
 393 ;;;###autoload
 394 (defmacro with-timeout (list &rest body)
 395   "Run BODY, but if it doesn't finish in SECONDS seconds, give up.
 396 If we give up, we run the TIMEOUT-FORMS and return the value of the last one.
 397 The call should look like:
 398  (with-timeout (SECONDS TIMEOUT-FORMS...) BODY...)
 399 The timeout is checked whenever Emacs waits for some kind of external
 400 event \(such as keyboard input, input from subprocesses, or a certain time);
 401 if the program loops without waiting in any way, the timeout will not
 402 be detected."
 403   (let ((seconds (car list))
 404         (timeout-forms (cdr list)))
 405     `(let ((with-timeout-tag (cons nil nil))
 406            with-timeout-value with-timeout-timer)
 407        (if (catch with-timeout-tag
 408              (progn
 409                (setq with-timeout-timer
 410                      (run-with-timer ,seconds nil
 411                                       'with-timeout-handler
 412                                       with-timeout-tag))
 413                (setq with-timeout-value (progn . ,body))
 414                nil))
 415            (progn . ,timeout-forms)
 416          (cancel-timer with-timeout-timer)
 417          with-timeout-value))))
 418
 419 (defun y-or-n-p-with-timeout (prompt seconds default-value)
 420   "Like (y-or-n-p PROMPT), with a timeout.
 421 If the user does not answer after SECONDS seconds, return DEFAULT-VALUE."
 422   (with-timeout (seconds default-value)
 423     (y-or-n-p prompt)))
 424 \f
 425 (defvar timer-duration-words
 426   (list (cons "microsec" 0.000001)
 427         (cons "microsecond" 0.000001)
 428         (cons "millisec" 0.001)
 429         (cons "millisecond" 0.001)
 430         (cons "sec" 1)
 431         (cons "second" 1)
 432         (cons "min" 60)
 433         (cons "minute" 60)
 434         (cons "hour" (* 60 60))
 435         (cons "day" (* 24 60 60))
 436         (cons "week" (* 7 24 60 60))
 437         (cons "fortnight" (* 14 24 60 60))
 438         (cons "month" (* 30 24 60 60))    ; Approximation
 439         (cons "year" (* 365.25 24 60 60)) ; Approximation
 440         )
 441   "Alist mapping temporal words to durations in seconds")
 442
 443 (defun timer-duration (string)
 444   "Return number of seconds specified by STRING, or nil if parsing fails."
 445   (let ((secs 0)
 446         (start 0)
 447         (case-fold-search t))
 448     (while (string-match
 449             "[ \t]*\\([0-9.]+\\)?[ \t]*\\([a-z]+[a-rt-z]\\)s?[ \t]*"
 450             string start)
 451       (let ((count (if (match-beginning 1)
 452                        (string-to-number (match-string 1 string))
 453                      1))
 454             (itemsize (cdr (assoc (match-string 2 string)
 455                                   timer-duration-words))))
 456         (if itemsize
 457             (setq start (match-end 0)
 458                   secs (+ secs (* count itemsize)))
 459           (setq secs nil
 460                 start (length string)))))
 461     (if (= start (length string))
 462         secs
 463       (if (string-match "\\`[0-9.]+\\'" string)
 464           (string-to-number string)))))
 465 \f
 466 (provide 'timer)
 467
 468 ;;; timer.el ends here