lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Code:
  27
  28 (provide 'timezone)
  29
  30 (defvar timezone-world-timezones
  31   '(("PST" .  -800)
  32     ("PDT" .  -700)
  33     ("MST" .  -700)
  34     ("MDT" .  -600)
  35     ("CST" .  -600)
  36     ("CDT" .  -500)
  37     ("EST" .  -500)
  38     ("EDT" .  -400)
  39     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  40     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  41     ("UT"  .  +000)
  42     ("GMT" .  +000)
  43     ("BST" .  +100)
  44     ("MET" .  +100)
  45     ("EET" .  +200)
  46     ("JST" .  +900)
  47     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  48     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  49     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  50     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  51     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  52     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  53     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  54     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  55   "*Time differentials of timezone from GMT in +-HHMM form.
  56 This list is obsolescent, and is present only for backwards compatibility,
  57 because time zone names are ambiguous in practice.
  58 Use `current-time-zone' instead.")
  59
  60 (defvar timezone-months-assoc
  61   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  62     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  63     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  64     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  65   "Alist of first three letters of a month and its numerical representation.")
  66
  67 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  68   "Convert DATE to an arpanet standard date.
  69 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  70 if nil, GMT is assumed.
  71 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  72 if nil, the local time zone is assumed."
  73   (let ((new (timezone-fix-time date local timezone)))
  74     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  75                              (timezone-make-time-string
  76                               (aref new 3) (aref new 4) (aref new 5))
  77                              (aref new 6))
  78     ))
  79
  80 (defun timezone-make-date-sortable (date &optional local timezone)
  81   "Convert DATE to a sortable date string.
  82 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  83 if nil, GMT is assumed.
  84 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  85 if nil, the local time zone is assumed."
  86   (let ((new (timezone-fix-time date local timezone)))
  87     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  88                                  (timezone-make-time-string
  89                                   (aref new 3) (aref new 4) (aref new 5)))
  90     ))
  91
  92 \f
  93 ;;
  94 ;; Parsers and Constructors of Date and Time
  95 ;;
  96
  97 (defun timezone-make-arpa-date (year month day time &optional timezone)
  98   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  99 Optional argument TIMEZONE specifies a time zone."
 100   (let ((zone
 101          (if (listp timezone)
 102              (let* ((m (timezone-zone-to-minute timezone))
 103                     (absm (if (< m 0) (- m) m)))
 104                (format "%c%02d%02d"
 105                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 106            timezone)))
 107     (format "%02d %s %04d %s %s"
 108             day
 109             (capitalize (car (rassq month timezone-months-assoc)))
 110             year
 111             time
 112             zone)))
 113
 114 (defun timezone-make-sortable-date (year month day time)
 115   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 116   (format "%4d%02d%02d%s"
 117           year month day time))
 118
 119 (defun timezone-make-time-string (hour minute second)
 120   "Make time string from HOUR, MINUTE, and SECOND."
 121   (format "%02d:%02d:%02d" hour minute second))
 122
 123 (defun timezone-parse-date (date)
 124   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 125 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 126 Understands the following styles:
 127  (1) 14 Apr 89 03:20[:12] [GMT]
 128  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 129  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 130  (4) 6 May 1992 1641-JST (Wednesday)
 131  (5) 22-AUG-1993 10:59:12.82
 132  (6) Thu, 11 Apr 16:17:12 91 [MET]
 133  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 134  (8) 1996-06-24 21:13:12 [GMT]
 135  (9) 1996-06-24 21:13-ZONE"
 136  ;; Get rid of any text properties.
 137   (and (stringp date)
 138        (or (text-properties-at 0 date)
 139            (next-property-change 0 date))
 140        (setq date (copy-sequence date))
 141        (set-text-properties 0 (length date) nil date))
 142   (let ((date (or date ""))
 143         (year nil)
 144         (month nil)
 145         (day nil)
 146         (time nil)
 147         (zone nil))                     ;This may be nil.
 148     (cond ((string-match
 149             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 150            ;; Styles: (1) and (2) with timezone and buggy timezone
 151            ;; This is most common in mail and news,
 152            ;; so it is worth trying first.
 153            (setq year 3 month 2 day 1 time 4 zone 5))
 154           ((string-match
 155             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 156            ;; Styles: (1) and (2) without timezone
 157            (setq year 3 month 2 day 1 time 4 zone nil))
 158           ((string-match
 159             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 160            ;; Styles: (6) and (7) without timezone
 161            (setq year 6 month 3 day 2 time 4 zone nil))
 162           ((string-match
 163             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 164            ;; Styles: (6) and (7) with timezone and buggy timezone
 165            (setq year 6 month 3 day 2 time 4 zone 7))
 166           ((string-match
 167             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 168            ;; Styles: (3) without timezone
 169            (setq year 4 month 1 day 2 time 3 zone nil))
 170           ((string-match
 171             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 172            ;; Styles: (3) with timezone
 173            (setq year 5 month 1 day 2 time 3 zone 4))
 174           ((string-match
 175             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 176            ;; Styles: (4) with timezone
 177            (setq year 3 month 2 day 1 time 4 zone 5))
 178           ((string-match
 179             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 180            ;; Styles: (5) without timezone.
 181            (setq year 3 month 2 day 1 time 4 zone nil))
 182           ((string-match
 183             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 184            ;; Styles: (8) with timezone.
 185            (setq year 1 month 2 day 3 time 4 zone 5))
 186           ((string-match
 187             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+\\)[ \t]*\\([-+a-zA-Z0-9:]+\\)" date)
 188            ;; Styles: (8) with timezone with a colon in it.
 189            (setq year 1 month 2 day 3 time 4 zone 5))
 190           ((string-match
 191             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 192            ;; Styles: (8) without timezone.
 193            (setq year 1 month 2 day 3 time 4 zone nil))
 194           )
 195     (if year
 196         (progn
 197           (setq year
 198                 (substring date (match-beginning year) (match-end year)))
 199           ;; It is now Dec 1992.  8 years before the end of the World.
 200           (if (= (length year) 1)
 201               (setq year (concat "190" (substring year -1 nil)))
 202             (if (< (length year) 4)
 203                 (setq year (concat "19" (substring year -2 nil)))))
 204           (setq month
 205                 (if (= (aref date (+ (match-beginning month) 2)) ?-)
 206                     ;; Handle numeric months, spanning exactly two digits.
 207                     (substring date
 208                                (match-beginning month)
 209                                (+ (match-beginning month) 2))
 210                   (let* ((string (substring date
 211                                             (match-beginning month)
 212                                             (+ (match-beginning month) 3)))
 213                          (monthnum
 214                           (cdr (assoc (upcase string) timezone-months-assoc))))
 215                     (if monthnum
 216                         (int-to-string monthnum)
 217                       nil))))
 218           (setq day
 219                 (substring date (match-beginning day) (match-end day)))
 220           (setq time
 221                 (substring date (match-beginning time) (match-end time)))))
 222     (if zone
 223         (setq zone
 224               (substring date (match-beginning zone) (match-end zone))))
 225     ;; Return a vector.
 226     (if (and year month)
 227         (vector year month day time zone)
 228       (vector "0" "0" "0" "0" nil))
 229     ))
 230
 231 (defun timezone-parse-time (time)
 232   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 233 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 234   (let ((time (or time ""))
 235         (hour nil)
 236         (minute nil)
 237         (second nil))
 238     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 239            ;; HH:MM:SS
 240            (setq hour 1 minute 2 second 3))
 241           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 242            ;; HH:MM
 243            (setq hour 1 minute 2 second nil))
 244           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 245            ;; HHMMSS
 246            (setq hour 1 minute 2 second 3))
 247           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 248            ;; HHMM
 249            (setq hour 1 minute 2 second nil))
 250           )
 251     ;; Return [hour minute second]
 252     (vector
 253      (if hour
 254          (substring time (match-beginning hour) (match-end hour)) "0")
 255      (if minute
 256          (substring time (match-beginning minute) (match-end minute)) "0")
 257      (if second
 258          (substring time (match-beginning second) (match-end second)) "0"))
 259     ))
 260
 261 \f
 262 ;; Miscellaneous
 263
 264 (defun timezone-zone-to-minute (timezone)
 265   "Translate TIMEZONE to an integer minute offset from GMT.
 266 TIMEZONE can be a cons cell containing the output of current-time-zone,
 267 or an integer of the form +-HHMM, or a time zone name."
 268   (cond
 269      ((consp timezone)
 270       (/ (car timezone) 60))
 271      (timezone
 272       (progn
 273         (setq timezone
 274               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 275                   ;; +900
 276                   timezone))
 277         (if (stringp timezone)
 278             (setq timezone (string-to-int timezone)))
 279         ;; Taking account of minute in timezone.
 280         ;; HHMM -> MM
 281         (let* ((abszone (abs timezone))
 282                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 283           (if (< timezone 0) (- minutes) minutes))))
 284      (t 0)))
 285
 286 (defun timezone-time-from-absolute (date seconds)
 287   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 288 Return a list suitable as an argument to current-time-zone,
 289 or nil if the date cannot be thus represented.
 290 DATE is the number of days elapsed since the (imaginary)
 291 Gregorian date Sunday, December 31, 1 BC."
 292   (let* ((current-time-origin 719163)
 293             ;; (timezone-absolute-from-gregorian 1 1 1970)
 294          (days (- date current-time-origin))
 295          (seconds-per-day (float 86400))
 296          (seconds (+ seconds (* days seconds-per-day)))
 297          (current-time-arithmetic-base (float 65536))
 298          (hi (floor (/ seconds current-time-arithmetic-base)))
 299          (hibase (* hi current-time-arithmetic-base))
 300          (lo (floor (- seconds hibase))))
 301      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 302           (cons hi lo))))
 303
 304 (defun timezone-time-zone-from-absolute (date seconds)
 305   "Compute the local time zone for DATE at time SECONDS after midnight.
 306 Return a list in the same format as current-time-zone's result,
 307 or nil if the local time zone could not be computed.
 308 DATE is the number of days elapsed since the (imaginary)
 309 Gregorian date Sunday, December 31, 1 BC."
 310    (and (fboundp 'current-time-zone)
 311         (let ((utc-time (timezone-time-from-absolute date seconds)))
 312           (and utc-time
 313                (let ((zone (current-time-zone utc-time)))
 314                  (and (car zone) zone))))))
 315
 316 (defun timezone-fix-time (date local timezone)
 317   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 318 If LOCAL is nil, it is assumed to be GMT.
 319 If TIMEZONE is nil, use the local time zone."
 320   (let* ((date   (timezone-parse-date date))
 321          (year   (string-to-int (aref date 0)))
 322          (year   (cond ((< year 50)
 323                         (+ year 2000))
 324                        ((< year 100)
 325                         (+ year 1900))
 326                        (t year)))
 327          (month  (string-to-int (aref date 1)))
 328          (day    (string-to-int (aref date 2)))
 329          (time   (timezone-parse-time (aref date 3)))
 330          (hour   (string-to-int (aref time 0)))
 331          (minute (string-to-int (aref time 1)))
 332          (second (string-to-int (aref time 2)))
 333          (local  (or (aref date 4) local)) ;Use original if defined
 334          (timezone
 335           (or timezone
 336               (timezone-time-zone-from-absolute
 337                (timezone-absolute-from-gregorian month day year)
 338                (+ second (* 60 (+ minute (* 60 hour)))))))
 339          (diff   (- (timezone-zone-to-minute timezone)
 340                     (timezone-zone-to-minute local)))
 341          (minute (+ minute diff))
 342          (hour-fix (floor minute 60)))
 343     (setq hour (+ hour hour-fix))
 344     (setq minute (- minute (* 60 hour-fix)))
 345     ;; HOUR may be larger than 24 or smaller than 0.
 346     (cond ((<= 24 hour)                 ;24 -> 00
 347            (setq hour (- hour 24))
 348            (setq day  (1+ day))
 349            (if (< (timezone-last-day-of-month month year) day)
 350                (progn
 351                  (setq month (1+ month))
 352                  (setq day 1)
 353                  (if (< 12 month)
 354                      (progn
 355                        (setq month 1)
 356                        (setq year (1+ year))
 357                        ))
 358                  )))
 359           ((> 0 hour)
 360            (setq hour (+ hour 24))
 361            (setq day  (1- day))
 362            (if (> 1 day)
 363                (progn
 364                  (setq month (1- month))
 365                  (if (> 1 month)
 366                      (progn
 367                        (setq month 12)
 368                        (setq year (1- year))
 369                        ))
 370                  (setq day (timezone-last-day-of-month month year))
 371                  )))
 372           )
 373     (vector year month day hour minute second timezone)))
 374
 375 ;; Partly copied from Calendar program by Edward M. Reingold.
 376 ;; Thanks a lot.
 377
 378 (defun timezone-last-day-of-month (month year)
 379   "The last day in MONTH during YEAR."
 380   (if (and (= month 2) (timezone-leap-year-p year))
 381       29
 382     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 383
 384 (defun timezone-leap-year-p (year)
 385   "Returns t if YEAR is a Gregorian leap year."
 386   (or (and (zerop  (% year 4))
 387            (not (zerop (% year 100))))
 388       (zerop (% year 400))))
 389
 390 (defun timezone-day-number (month day year)
 391   "Return the day number within the year of the date month/day/year."
 392   (let ((day-of-year (+ day (* 31 (1- month)))))
 393     (if (> month 2)
 394         (progn
 395           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 396           (if (timezone-leap-year-p year)
 397               (setq day-of-year (1+ day-of-year)))))
 398     day-of-year))
 399
 400 (defun timezone-absolute-from-gregorian (month day year)
 401   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 402 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 403   (+ (timezone-day-number month day year);; Days this year
 404      (* 365 (1- year));;        + Days in prior years
 405      (/ (1- year) 4);;          + Julian leap years
 406      (- (/ (1- year) 100));;    - century years
 407      (/ (1- year) 400)));;      + Gregorian leap years
 408
 409 ;;; timezone.el ends here