lisp/lpr.el

   1 ;;; lpr.el --- print Emacs buffer on line printer
   2
   3 ;; Copyright (C) 1985, 1988, 1992, 1994, 2001-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Commands to send the region or a buffer to your printer.  Entry points
  27 ;; are `lpr-buffer', `print-buffer', `lpr-region', or `print-region'; option
  28 ;; variables include `printer-name', `lpr-switches' and `lpr-command'.
  29
  30 ;;; Code:
  31
  32 ;;;###autoload
  33 (defvar lpr-windows-system
  34   (memq system-type '(ms-dos windows-nt)))
  35
  36 ;;;###autoload
  37 (defvar lpr-lp-system
  38   (memq system-type '(usg-unix-v hpux irix)))
  39
  40
  41 (defgroup lpr nil
  42   "Print Emacs buffer on line printer."
  43   :group 'wp)
  44
  45
  46 ;;;###autoload
  47 (defcustom printer-name
  48   (and (eq system-type 'ms-dos) "PRN")
  49   "The name of a local printer to which data is sent for printing.
  50 \(Note that PostScript files are sent to `ps-printer-name', which see.\)
  51
  52 On Unix-like systems, a string value should be a name understood by
  53 lpr's -P option; otherwise the value should be nil.
  54
  55 On MS-DOS and MS-Windows systems, a string value is taken as the name of
  56 a printer device or port, provided `lpr-command' is set to \"\".
  57 Typical non-default settings would be \"LPT1\" to \"LPT3\" for parallel
  58 printers, or \"COM1\" to \"COM4\" or \"AUX\" for serial printers, or
  59 \"//hostname/printer\" for a shared network printer.  You can also set
  60 it to the name of a file, in which case the output gets appended to that
  61 file.  If you want to discard the printed output, set this to \"NUL\"."
  62   :type '(choice :menu-tag "Printer Name"
  63                  :tag "Printer Name"
  64                  (const :tag "Default" nil)
  65                  ;; could use string but then we lose completion for files.
  66                  (file :tag "Name"))
  67   :group 'lpr)
  68
  69 ;;;###autoload
  70 (defcustom lpr-switches nil
  71   "List of strings to pass as extra options for the printer program.
  72 It is recommended to set `printer-name' instead of including an explicit
  73 switch on this list.
  74 See `lpr-command'."
  75   :type '(repeat (string :tag "Argument"))
  76   :group 'lpr)
  77
  78 (defcustom lpr-add-switches (memq system-type '(berkeley-unix gnu/linux))
  79   "Non-nil means construct `-T' and `-J' options for the printer program.
  80 These are made assuming that the program is `lpr';
  81 if you are using some other incompatible printer program,
  82 this variable should be nil."
  83   :type 'boolean
  84   :group 'lpr)
  85
  86 (defcustom lpr-printer-switch
  87   (if lpr-lp-system
  88       "-d "
  89     "-P")
  90   "Printer switch, that is, something like \"-P\", \"-d \", \"/D:\", etc.
  91 This switch is used in conjunction with `printer-name'."
  92   :type '(choice :menu-tag "Printer Name Switch"
  93                  :tag "Printer Name Switch"
  94                  (const :tag "None" nil)
  95                  (string :tag "Printer Switch"))
  96   :group 'lpr)
  97
  98 ;;;###autoload
  99 (defcustom lpr-command
 100  (purecopy
 101   (cond
 102    (lpr-windows-system
 103     "")
 104    (lpr-lp-system
 105     "lp")
 106    (t
 107     "lpr")))
 108   "Name of program for printing a file.
 109
 110 On MS-DOS and MS-Windows systems, if the value is an empty string then
 111 Emacs will write directly to the printer port named by `printer-name'.
 112 The programs `print' and `nprint' (the standard print programs on
 113 Windows NT and Novell Netware respectively) are handled specially, using
 114 `printer-name' as the destination for output; any other program is
 115 treated like `lpr' except that an explicit filename is given as the last
 116 argument."
 117   :type 'string
 118   :group 'lpr)
 119
 120 ;; Default is nil, because that enables us to use pr -f
 121 ;; which is more reliable than pr with no args, which is what lpr -p does.
 122 (defcustom lpr-headers-switches nil
 123   "List of strings of options to request page headings in the printer program.
 124 If nil, we run `lpr-page-header-program' to make page headings
 125 and print the result."
 126   :type '(repeat (string :tag "Argument"))
 127   :group 'lpr)
 128
 129 (defcustom print-region-function nil
 130   "Function to call to print the region on a printer.
 131 See definition of `print-region-1' for calling conventions."
 132   :type '(choice (const nil) function)
 133   :group 'lpr)
 134
 135 (defcustom lpr-page-header-program "pr"
 136   "Name of program for adding page headers to a file."
 137   :type 'string
 138   :group 'lpr)
 139
 140 ;; Berkeley systems support -F, and GNU pr supports both -f and -F,
 141 ;; So it looks like -F is a better default.
 142 (defcustom lpr-page-header-switches '("-h" "%s" "-F")
 143   "List of strings to use as options for the page-header-generating program.
 144 If `%s' appears in any of the strings, it is substituted by the page title.
 145 Note that for correct quoting, `%s' should normally be a separate element.
 146 The variable `lpr-page-header-program' specifies the program to use."
 147   :type '(repeat string)
 148   :group 'lpr)
 149
 150 ;;;###autoload
 151 (defun lpr-buffer ()
 152   "Print buffer contents without pagination or page headers.
 153 See the variables `lpr-switches' and `lpr-command'
 154 for customization of the printer command."
 155   (interactive
 156    (unless (y-or-n-p "Send current buffer to default printer? ")
 157      (error "Cancelled")))
 158   (print-region-1 (point-min) (point-max) lpr-switches nil))
 159
 160 ;;;###autoload
 161 (defun print-buffer ()
 162   "Paginate and print buffer contents.
 163
 164 The variable `lpr-headers-switches' controls how to paginate.
 165 If it is nil (the default), we run the `pr' program (or whatever program
 166 `lpr-page-header-program' specifies) to paginate.
 167 `lpr-page-header-switches' specifies the switches for that program.
 168
 169 Otherwise, the switches in `lpr-headers-switches' are used
 170 in the print command itself; we expect them to request pagination.
 171
 172 See the variables `lpr-switches' and `lpr-command'
 173 for further customization of the printer command."
 174   (interactive
 175    (unless (y-or-n-p "Send current buffer to default printer? ")
 176      (error "Cancelled")))
 177   (print-region-1 (point-min) (point-max) lpr-switches t))
 178
 179 ;;;###autoload
 180 (defun lpr-region (start end)
 181   "Print region contents without pagination or page headers.
 182 See the variables `lpr-switches' and `lpr-command'
 183 for customization of the printer command."
 184   (interactive
 185    (if (y-or-n-p "Send selected text to default printer? ")
 186        (list (region-beginning) (region-end))
 187      (error "Cancelled")))
 188   (print-region-1 start end lpr-switches nil))
 189
 190 ;;;###autoload
 191 (defun print-region (start end)
 192   "Paginate and print the region contents.
 193
 194 The variable `lpr-headers-switches' controls how to paginate.
 195 If it is nil (the default), we run the `pr' program (or whatever program
 196 `lpr-page-header-program' specifies) to paginate.
 197 `lpr-page-header-switches' specifies the switches for that program.
 198
 199 Otherwise, the switches in `lpr-headers-switches' are used
 200 in the print command itself; we expect them to request pagination.
 201
 202 See the variables `lpr-switches' and `lpr-command'
 203 for further customization of the printer command."
 204   (interactive
 205    (if (y-or-n-p "Send selected text to default printer? ")
 206        (list (region-beginning) (region-end))
 207      (error "Cancelled")))
 208   (print-region-1 start end lpr-switches t))
 209
 210 (defun print-region-1 (start end switches page-headers)
 211   ;; On some MIPS system, having a space in the job name
 212   ;; crashes the printer demon.  But using dashes looks ugly
 213   ;; and it seems to annoying to do for that MIPS system.
 214   (let ((name  (concat (buffer-name) " Emacs buffer"))
 215         (title (concat (buffer-name) " Emacs buffer"))
 216         ;; Make pipes use the same coding system as
 217         ;; writing the buffer to a file would.
 218         (coding-system-for-write (or coding-system-for-write
 219                                      buffer-file-coding-system))
 220         (coding-system-for-read  (or coding-system-for-read
 221                                      buffer-file-coding-system))
 222         (width tab-width)
 223         nswitches
 224         switch-string)
 225     (save-excursion
 226       (and page-headers lpr-headers-switches
 227            ;; It's possible to use an lpr option to get page headers.
 228            (setq switches (append (if (stringp lpr-headers-switches)
 229                                       (list lpr-headers-switches)
 230                                     lpr-headers-switches)
 231                                   switches)))
 232       (setq nswitches     (lpr-flatten-list
 233                            (mapcar 'lpr-eval-switch ; Dynamic evaluation
 234                                    switches))
 235             switch-string (if switches
 236                               (concat " with options "
 237                                       (mapconcat 'identity switches " "))
 238                             ""))
 239       (message "Spooling%s..." switch-string)
 240       (if (/= tab-width 8)
 241           (let ((new-coords (print-region-new-buffer start end)))
 242             (setq start     (car new-coords)
 243                   end       (cdr new-coords)
 244                   tab-width width)
 245             (save-excursion
 246               (goto-char end)
 247               (setq end (point-marker)))
 248             (untabify (point-min) (point-max))))
 249       (if page-headers
 250           (if lpr-headers-switches
 251               ;; We handled this above by modifying SWITCHES.
 252               nil
 253             ;; Run a separate program to get page headers.
 254             (let ((new-coords (print-region-new-buffer start end)))
 255               (apply 'call-process-region (car new-coords) (cdr new-coords)
 256                      lpr-page-header-program t t nil
 257                      (mapcar (lambda (e) (format e title))
 258                              lpr-page-header-switches)))
 259             (setq start (point-min)
 260                   end   (point-max))))
 261       (apply (or print-region-function 'call-process-region)
 262              (nconc (list start end lpr-command
 263                           nil nil nil)
 264                     (and lpr-add-switches
 265                          (list "-J" name))
 266                     ;; These belong in pr if we are using that.
 267                     (and lpr-add-switches lpr-headers-switches
 268                          (list "-T" title))
 269                     (and (stringp printer-name)
 270                          (list (concat lpr-printer-switch
 271                                        printer-name)))
 272                     nswitches))
 273       (if (markerp end)
 274           (set-marker end nil))
 275       (message "Spooling%s...done" switch-string))))
 276
 277 ;; This function copies the text between start and end
 278 ;; into a new buffer, makes that buffer current.
 279 ;; It returns the new range to print from the new current buffer
 280 ;; as (START . END).
 281
 282 (defun print-region-new-buffer (ostart oend)
 283   (if (string= (buffer-name) " *spool temp*")
 284       (cons ostart oend)
 285     (let ((oldbuf (current-buffer)))
 286       (set-buffer (get-buffer-create " *spool temp*"))
 287       (widen)
 288       (erase-buffer)
 289       (insert-buffer-substring oldbuf ostart oend)
 290       (cons (point-min) (point-max)))))
 291
 292 (defun printify-region (begin end)
 293   "Replace nonprinting characters in region with printable representations.
 294 The printable representations use ^ (for ASCII control characters) or hex.
 295 The characters tab, linefeed, space, return and formfeed are not affected."
 296   (interactive "r")
 297   (save-excursion
 298     (save-restriction
 299       (narrow-to-region begin end)
 300       (goto-char (point-min))
 301       (let (c)
 302         (while (re-search-forward "[\^@-\^h\^k\^n-\^_\177-\377]" nil t)
 303           (setq c (preceding-char))
 304           (delete-char -1)
 305           (insert (if (< c ?\s)
 306                       (format "\\^%c" (+ c ?@))
 307                     (format "\\%02x" c))))))))
 308
 309 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 310 ;; Functions hacked from `ps-print' package.
 311
 312 ;; Dynamic evaluation
 313 (defun lpr-eval-switch (arg)
 314   (cond ((stringp arg) arg)
 315         ((functionp arg) (apply arg nil))
 316         ((symbolp arg) (symbol-value arg))
 317         ((consp arg) (apply (car arg) (cdr arg)))
 318         (t nil)))
 319
 320 ;; `lpr-flatten-list' is defined here (copied from "message.el" and
 321 ;; enhanced to handle dotted pairs as well) until we can get some
 322 ;; sensible autoloads, or `flatten-list' gets put somewhere decent.
 323
 324 ;; (lpr-flatten-list '((a . b) c (d . e) (f g h) i . j))
 325 ;; => (a b c d e f g h i j)
 326
 327 (defun lpr-flatten-list (&rest list)
 328   (lpr-flatten-list-1 list))
 329
 330 (defun lpr-flatten-list-1 (list)
 331   (cond
 332    ((null list) (list))
 333    ((consp list)
 334     (append (lpr-flatten-list-1 (car list))
 335             (lpr-flatten-list-1 (cdr list))))
 336    (t (list list))))
 337
 338 (provide 'lpr)
 339
 340 ;;; lpr.el ends here