lisp/linum.el

   1 ;;; linum.el --- display line numbers in the left margin
   2
   3 ;; Copyright (C) 2008-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Markus Triska <markus.triska@gmx.at>
   6 ;; Maintainer: FSF
   7 ;; Keywords: convenience
   8 ;; Version: 0.9x
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Display line numbers for the current buffer.
  28 ;;
  29 ;; Toggle display of line numbers with M-x linum-mode.  To enable
  30 ;; line numbering in all buffers, use M-x global-linum-mode.
  31
  32 ;;; Code:
  33
  34 (defconst linum-version "0.9x")
  35
  36 (defvar linum-overlays nil "Overlays used in this buffer.")
  37 (defvar linum-available nil "Overlays available for reuse.")
  38 (defvar linum-before-numbering-hook nil
  39   "Functions run in each buffer before line numbering starts.")
  40
  41 (mapc #'make-variable-buffer-local '(linum-overlays linum-available))
  42
  43 (defgroup linum nil
  44   "Show line numbers in the left margin."
  45   :group 'convenience)
  46
  47 ;;;###autoload
  48 (defcustom linum-format 'dynamic
  49   "Format used to display line numbers.
  50 Either a format string like \"%7d\", `dynamic' to adapt the width
  51 as needed, or a function that is called with a line number as its
  52 argument and should evaluate to a string to be shown on that line.
  53 See also `linum-before-numbering-hook'."
  54   :group 'linum
  55   :type 'sexp)
  56
  57 (defface linum
  58   '((t :inherit (shadow default)))
  59   "Face for displaying line numbers in the display margin."
  60   :group 'linum)
  61
  62 (defcustom linum-eager t
  63   "Whether line numbers should be updated after each command.
  64 The conservative setting `nil' might miss some buffer changes,
  65 and you have to scroll or press \\[recenter-top-bottom] to update the numbers."
  66   :group 'linum
  67   :type 'boolean)
  68
  69 (defcustom linum-delay nil
  70   "Delay updates to give Emacs a chance for other changes."
  71   :group 'linum
  72   :type 'boolean)
  73
  74 ;;;###autoload
  75 (define-minor-mode linum-mode
  76   "Toggle display of line numbers in the left margin."
  77   :lighter ""                           ; for desktop.el
  78   (if linum-mode
  79       (progn
  80         (if linum-eager
  81             (add-hook 'post-command-hook (if linum-delay
  82                                              'linum-schedule
  83                                            'linum-update-current) nil t)
  84           (add-hook 'after-change-functions 'linum-after-change nil t))
  85         (add-hook 'window-scroll-functions 'linum-after-scroll nil t)
  86         ;; Using both window-size-change-functions and
  87         ;; window-configuration-change-hook seems redundant. --Stef
  88         ;; (add-hook 'window-size-change-functions 'linum-after-size nil t)
  89         (add-hook 'change-major-mode-hook 'linum-delete-overlays nil t)
  90         (add-hook 'window-configuration-change-hook
  91                   ;; FIXME: If the buffer is shown in N windows, this
  92                   ;; will be called N times rather than once.  We should use
  93                   ;; something like linum-update-window instead.
  94                   'linum-update-current nil t)
  95         (linum-update-current))
  96     (remove-hook 'post-command-hook 'linum-update-current t)
  97     (remove-hook 'post-command-hook 'linum-schedule t)
  98     ;; (remove-hook 'window-size-change-functions 'linum-after-size t)
  99     (remove-hook 'window-scroll-functions 'linum-after-scroll t)
 100     (remove-hook 'after-change-functions 'linum-after-change t)
 101     (remove-hook 'window-configuration-change-hook 'linum-update-current t)
 102     (remove-hook 'change-major-mode-hook 'linum-delete-overlays t)
 103     (linum-delete-overlays)))
 104
 105 ;;;###autoload
 106 (define-globalized-minor-mode global-linum-mode linum-mode linum-on)
 107
 108 (defun linum-on ()
 109   (unless (minibufferp)
 110     (linum-mode 1)))
 111
 112 (defun linum-delete-overlays ()
 113   "Delete all overlays displaying line numbers for this buffer."
 114   (mapc #'delete-overlay linum-overlays)
 115   (setq linum-overlays nil)
 116   (dolist (w (get-buffer-window-list (current-buffer) nil t))
 117     (set-window-margins w 0 (cdr (window-margins w)))))
 118
 119 (defun linum-update-current ()
 120   "Update line numbers for the current buffer."
 121   (linum-update (current-buffer)))
 122
 123 (defun linum-update (buffer)
 124   "Update line numbers for all windows displaying BUFFER."
 125   (with-current-buffer buffer
 126     (when linum-mode
 127       (setq linum-available linum-overlays)
 128       (setq linum-overlays nil)
 129       (save-excursion
 130         (mapc #'linum-update-window
 131               (get-buffer-window-list buffer nil 'visible)))
 132       (mapc #'delete-overlay linum-available)
 133       (setq linum-available nil))))
 134
 135 (defun linum-update-window (win)
 136   "Update line numbers for the portion visible in window WIN."
 137   (goto-char (window-start win))
 138   (let ((line (line-number-at-pos))
 139         (limit (window-end win t))
 140         (fmt (cond ((stringp linum-format) linum-format)
 141                    ((eq linum-format 'dynamic)
 142                     (let ((w (length (number-to-string
 143                                       (count-lines (point-min) (point-max))))))
 144                       (concat "%" (number-to-string w) "d")))))
 145         (width 0))
 146     (run-hooks 'linum-before-numbering-hook)
 147     ;; Create an overlay (or reuse an existing one) for each
 148     ;; line visible in this window, if necessary.
 149     (while (and (not (eobp)) (<= (point) limit))
 150       (let* ((str (if fmt
 151                       (propertize (format fmt line) 'face 'linum)
 152                     (funcall linum-format line)))
 153              (visited (catch 'visited
 154                         (dolist (o (overlays-in (point) (point)))
 155                           (when (equal-including-properties
 156                                  (overlay-get o 'linum-str) str)
 157                             (unless (memq o linum-overlays)
 158                               (push o linum-overlays))
 159                             (setq linum-available (delq o linum-available))
 160                             (throw 'visited t))))))
 161         (setq width (max width (length str)))
 162         (unless visited
 163           (let ((ov (if (null linum-available)
 164                         (make-overlay (point) (point))
 165                       (move-overlay (pop linum-available) (point) (point)))))
 166             (push ov linum-overlays)
 167             (overlay-put ov 'before-string
 168                          (propertize " " 'display `((margin left-margin) ,str)))
 169             (overlay-put ov 'linum-str str))))
 170       ;; Text may contain those nasty intangible properties, but that
 171       ;; shouldn't prevent us from counting those lines.
 172       (let ((inhibit-point-motion-hooks t))
 173         (forward-line))
 174       (setq line (1+ line)))
 175     (set-window-margins win width (cdr (window-margins win)))))
 176
 177 (defun linum-after-change (beg end len)
 178   ;; update overlays on deletions, and after newlines are inserted
 179   (when (or (= beg end)
 180             (= end (point-max))
 181             (string-match-p "\n" (buffer-substring-no-properties beg end)))
 182     (linum-update-current)))
 183
 184 (defun linum-after-scroll (win start)
 185   (linum-update (window-buffer win)))
 186
 187 ;; (defun linum-after-size (frame)
 188 ;;   (linum-after-config))
 189
 190 (defun linum-schedule ()
 191   ;; schedule an update; the delay gives Emacs a chance for display changes
 192   (run-with-idle-timer 0 nil #'linum-update-current))
 193
 194 ;; (defun linum-after-config ()
 195 ;;   (walk-windows (lambda (w) (linum-update (window-buffer w))) nil 'visible))
 196
 197 (defun linum-unload-function ()
 198   "Unload the Linum library."
 199   (global-linum-mode -1)
 200   ;; continue standard unloading
 201   nil)
 202
 203 (provide 'linum)
 204
 205 ;;; linum.el ends here