lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;; Copyright (C) 1993-1994, 2000-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; For those who are annoyed by the mouse pointer obscuring text,
  26 ;; this mode moves the mouse pointer - either just a little out of
  27 ;; the way, or all the way to the corner of the frame.
  28 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  29 ;; To set up permanently, put the following in your .emacs:
  30 ;;
  31 ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate))
  32 ;;
  33 ;; Other legitimate alternatives include
  34 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  35 ;; They do somewhat different things.
  36 ;; See the documentation for function `mouse-avoidance-mode' for
  37 ;; details of the different modes.
  38 ;;
  39 ;; For added silliness, make the animatee animate...
  40 ;; put something similar to the following into your .emacs:
  41 ;;
  42 ;; (if (eq window-system 'x)
  43 ;;     (mouse-avoidance-set-pointer-shape
  44 ;;           (eval (nth (random 4)
  45 ;;                      '(x-pointer-man x-pointer-spider
  46 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  47 ;;
  48 ;; For completely random pointer shape, replace the setq above with:
  49 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  50 ;;
  51 ;; Bugs / Warnings / To-Do:
  52 ;;
  53 ;; - Using this code does slow Emacs down.  "banish" mode shouldn't
  54 ;;   be too bad, and on my workstation even "animate" is reasonable.
  55 ;;
  56 ;; - It ought to find out where any overlapping frames are and avoid them,
  57 ;;   rather than always raising the frame.
  58
  59 ;; Credits:
  60 ;; This code was helped by all those who contributed suggestions,
  61 ;;   fixes, and additions
  62 ;; Joe Harrington (and his advisor), for the original inspiration.
  63 ;; Ken Manheimer, for dreaming up the Protean mode.
  64 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  65 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  66 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  67
  68 ;;; Code:
  69
  70 (provide 'avoid)
  71
  72 (defgroup avoid nil
  73   "Make mouse pointer stay out of the way of editing."
  74   :prefix "mouse-avoidance-"
  75   :group 'mouse)
  76
  77 ;;;###autoload
  78 (defcustom mouse-avoidance-mode nil
  79   "Activate mouse avoidance mode.
  80 See function `mouse-avoidance-mode' for possible values.
  81 Setting this variable directly does not take effect;
  82 use either \\[customize] or the function `mouse-avoidance-mode'."
  83   :set (lambda (symbol value)
  84          ;; 'none below prevents toggling when value is nil.
  85          (mouse-avoidance-mode (or value 'none)))
  86   :initialize 'custom-initialize-default
  87   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  88                  (const animate) (const exile) (const proteus)
  89                  )
  90   :group 'avoid
  91   :require 'avoid
  92   :version "20.3")
  93
  94
  95 (defcustom mouse-avoidance-nudge-dist 15
  96   "Average distance that mouse will be moved when approached by cursor.
  97 Only applies in Mouse-Avoidance mode `jump' and its derivatives.
  98 For best results make this larger than `mouse-avoidance-threshold'."
  99   :type 'integer
 100   :group 'avoid)
 101
 102 (defcustom mouse-avoidance-nudge-var 10
 103   "Variability of `mouse-avoidance-nudge-dist' (which see)."
 104   :type 'integer
 105   :group 'avoid)
 106
 107 (defcustom mouse-avoidance-animation-delay .01
 108   "Delay between animation steps, in seconds."
 109   :type 'number
 110   :group 'avoid)
 111
 112 (defcustom mouse-avoidance-threshold 5
 113   "Mouse-pointer's flight distance.
 114 If the cursor gets closer than this, the mouse pointer will move away.
 115 Only applies in mouse-avoidance-modes `animate' and `jump'."
 116   :type 'integer
 117   :group 'avoid)
 118
 119 ;; Internal variables
 120 (defvar mouse-avoidance-state nil)
 121 (defvar mouse-avoidance-pointer-shapes nil)
 122 (defvar mouse-avoidance-n-pointer-shapes 0)
 123 (defvar mouse-avoidance-old-pointer-shape nil)
 124 (defvar mouse-avoidance-animating-pointer nil)
 125
 126 ;; This timer is used to run something when Emacs is idle.
 127 (defvar mouse-avoidance-timer nil)
 128
 129 ;;; Functions:
 130
 131 (defsubst mouse-avoidance-set-pointer-shape (shape)
 132   "Set the shape of the mouse pointer to SHAPE."
 133   (when (boundp 'x-pointer-shape)
 134     (setq x-pointer-shape shape)
 135     (set-mouse-color nil)))
 136
 137 (defun mouse-avoidance-point-position ()
 138   "Return the position of point as (FRAME X . Y).
 139 Analogous to `mouse-position'."
 140   (let ((edges (window-inside-edges))
 141         (x-y (posn-x-y (posn-at-point))))
 142     (cons (selected-frame)
 143           (cons (+ (car edges)
 144                    (/ (car x-y) (frame-char-width)))
 145                 (+ (car (cdr edges))
 146                    (/ (cdr x-y) (frame-char-height)))))))
 147
 148 ;(defun mouse-avoidance-point-position-test ()
 149 ;  (interactive)
 150 ;  (message (format "point=%s mouse=%s"
 151 ;                  (cdr (mouse-avoidance-point-position))
 152 ;                  (cdr (mouse-position)))))
 153
 154 (defun mouse-avoidance-set-mouse-position (pos)
 155   ;; Carefully set mouse position to given position (X . Y)
 156   ;; Ideally, should check if X,Y is in the current frame, and if not,
 157   ;; leave the mouse where it was.  However, this is currently
 158   ;; difficult to do, so we just raise the frame to avoid frame switches.
 159   ;; Returns t if it moved the mouse.
 160   (let ((f (selected-frame)))
 161     (raise-frame f)
 162     (set-mouse-position f (car pos) (cdr pos))
 163     t))
 164
 165 (defun mouse-avoidance-too-close-p (mouse)
 166   "Return t if mouse pointer and point cursor are too close.
 167 MOUSE is the current mouse position as returned by `mouse-position'.
 168 Acceptable distance is defined by `mouse-avoidance-threshold'."
 169   (let* ((frame (car mouse))
 170          (mouse-y (cdr (cdr mouse)))
 171          (tool-bar-lines (frame-parameter nil 'tool-bar-lines)))
 172     (or tool-bar-lines
 173         (setq tool-bar-lines 0))
 174     (if (and mouse-y (< mouse-y tool-bar-lines))
 175         nil
 176       (let ((point (mouse-avoidance-point-position))
 177             (mouse-x (car (cdr mouse))))
 178         (and (eq frame (car point))
 179              (not (null mouse-x))
 180              (< (abs (- mouse-x (car (cdr point))))
 181                 mouse-avoidance-threshold)
 182              (< (abs (- mouse-y (cdr (cdr point))))
 183                 mouse-avoidance-threshold))))))
 184
 185 (defun mouse-avoidance-banish-destination ()
 186   "The position to which Mouse-Avoidance mode `banish' moves the mouse.
 187 You can redefine this if you want the mouse banished to a different corner."
 188   (let* ((pos (window-edges)))
 189     (cons (- (nth 2 pos) 2)
 190           (nth 1 pos))))
 191
 192 (defun mouse-avoidance-banish-mouse ()
 193   ;; Put the mouse pointer in the upper-right corner of the current frame.
 194   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 195
 196 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 197   ;; Decide how far to move in either dimension.
 198   ;; Args are the CURRENT location, the desired DELTA for
 199   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 200   ;; in distance allowed, and the MIN and MAX possible window positions.
 201   ;; Returns something as close to DELTA as possible within the constraints.
 202   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 203         (R1                  (+ (- dist)    var ))
 204         (L2                  (+    dist  (- var)))
 205         (R2 (min (- max cur) (+    dist     var))))
 206     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 207     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 208     (cond ((and L1 (< delta L1)) L1)
 209           ((and R1 (< delta R1)) delta)
 210           ((and R1 (< delta 0)) R1)
 211           ((and L2 (< delta L2)) L2)
 212           ((and R2 (< delta R2)) delta)
 213           (R2)
 214           ((or R1 L2))
 215           (t 0))))
 216
 217 (defun mouse-avoidance-nudge-mouse ()
 218   ;; Push the mouse a little way away, possibly animating the move.
 219   ;; For these modes, state keeps track of the total offset that we've
 220   ;; accumulated, and tries to keep it close to zero.
 221   (let* ((cur (mouse-position))
 222          (cur-frame (car cur))
 223          (cur-pos (cdr cur))
 224          (pos (window-edges))
 225          (wleft (pop pos))
 226          (wtop (pop pos))
 227          (wright (pop pos))
 228          (wbot (pop pos))
 229          (deltax (mouse-avoidance-delta
 230                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 231                                    (car mouse-avoidance-state))
 232                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 233                   wleft (1- wright)))
 234          (deltay (mouse-avoidance-delta
 235                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 236                                    (cdr mouse-avoidance-state))
 237                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 238                   wtop (1- wbot))))
 239     (setq mouse-avoidance-state
 240           (cons (+ (car mouse-avoidance-state) deltax)
 241                 (+ (cdr mouse-avoidance-state) deltay)))
 242     (if (or (eq mouse-avoidance-mode 'animate)
 243             (eq mouse-avoidance-mode 'proteus))
 244         (let ((i 0.0)
 245               (incr (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 246           (setq mouse-avoidance-animating-pointer t)
 247           (while (<= i 1)
 248             (mouse-avoidance-set-mouse-position
 249              (cons (+ (car cur-pos) (round (* i deltax)))
 250                    (+ (cdr cur-pos) (round (* i deltay)))))
 251             (setq i (+ i incr))
 252             (if (eq mouse-avoidance-mode 'proteus)
 253                 (mouse-avoidance-set-pointer-shape
 254                  (mouse-avoidance-random-shape)))
 255             (sit-for mouse-avoidance-animation-delay))
 256           (setq mouse-avoidance-animating-pointer nil))
 257       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 258                                                 (+ (cdr (cdr cur)) deltay))))))
 259
 260 (defun mouse-avoidance-random-shape ()
 261   "Return a random cursor shape.
 262 This assumes that any variable whose name begins with x-pointer- and
 263 has an integer value is a valid cursor shape.  You might want to
 264 redefine this function to suit your own tastes."
 265   (if (null mouse-avoidance-pointer-shapes)
 266       (progn
 267         (setq mouse-avoidance-pointer-shapes
 268               (mapcar (lambda (x) (symbol-value (intern x)))
 269                       (all-completions "x-pointer-" obarray
 270                                        (lambda (x)
 271                                           (and (boundp x)
 272                                                (integerp (symbol-value x)))))))
 273         (setq mouse-avoidance-n-pointer-shapes
 274               (length mouse-avoidance-pointer-shapes))))
 275   (nth (random mouse-avoidance-n-pointer-shapes)
 276        mouse-avoidance-pointer-shapes))
 277
 278 (defun mouse-avoidance-ignore-p ()
 279   (let ((mp (mouse-position)))
 280     (or (not (frame-pointer-visible-p)) ; The pointer is hidden
 281         executing-kbd-macro            ; don't check inside macro
 282         (null (cadr mp))               ; don't move unless in an Emacs frame
 283         (not (eq (car mp) (selected-frame)))
 284         ;; Don't do anything if last event was a mouse event.
 285         ;; FIXME: this code fails in the case where the mouse was moved
 286         ;; since the last key-press but without generating any event.
 287         (and (consp last-input-event)
 288              (symbolp (car last-input-event))
 289              (let ((modifiers (event-modifiers (car last-input-event))))
 290                (or (memq (car last-input-event)
 291                          '(mouse-movement scroll-bar-movement
 292                            select-window switch-frame))
 293                    (memq 'click modifiers)
 294                    (memq 'double modifiers)
 295                    (memq 'triple modifiers)
 296                    (memq 'drag modifiers)
 297                    (memq 'down modifiers)))))))
 298
 299 (defun mouse-avoidance-banish ()
 300   (if (not (mouse-avoidance-ignore-p))
 301       (mouse-avoidance-banish-mouse)))
 302
 303 (defun mouse-avoidance-exile ()
 304   ;; For exile mode, the state is nil when the mouse is in its normal
 305   ;; position, and set to the old mouse-position when the mouse is in exile.
 306   (if (not (mouse-avoidance-ignore-p))
 307       (let ((mp (mouse-position)))
 308         (cond ((and (not mouse-avoidance-state)
 309                     (mouse-avoidance-too-close-p mp))
 310                (setq mouse-avoidance-state mp)
 311                (mouse-avoidance-banish-mouse))
 312               ((and mouse-avoidance-state
 313                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 314                (if (and (eq (car mp) (selected-frame))
 315                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 316                    (mouse-avoidance-set-mouse-position
 317                     ;; move back only if user has not moved mouse
 318                     (cdr mouse-avoidance-state)))
 319                ;; but clear state anyway, to be ready for another move
 320                (setq mouse-avoidance-state nil))))))
 321
 322 (defun mouse-avoidance-fancy ()
 323   ;; Used for the "fancy" modes, ie jump et al.
 324   (if (and (not mouse-avoidance-animating-pointer)
 325            (not (mouse-avoidance-ignore-p))
 326            (mouse-avoidance-too-close-p (mouse-position)))
 327       (let ((old-pos (mouse-position)))
 328         (mouse-avoidance-nudge-mouse)
 329         (if (not (eq (selected-frame) (car old-pos)))
 330             ;; This should never happen.
 331             (apply 'set-mouse-position old-pos)))))
 332
 333 ;;;###autoload
 334 (defun mouse-avoidance-mode (&optional mode)
 335   "Set cursor avoidance mode to MODE.
 336 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 337 `cat-and-mouse', `proteus', or `none'.
 338
 339 If MODE is nil, toggle mouse avoidance between `none' and `banish'
 340 modes.  Positive numbers and symbols other than the above are treated
 341 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 342
 343 Effects of the different modes:
 344  * banish: Move the mouse to the upper-right corner on any keypress.
 345  * exile: Move the mouse to the corner only if the cursor gets too close,
 346      and allow it to return once the cursor is out of the way.
 347  * jump: If the cursor gets too close to the mouse, displace the mouse
 348      a random distance & direction.
 349  * animate: As `jump', but shows steps along the way for illusion of motion.
 350  * cat-and-mouse: Same as `animate'.
 351  * proteus: As `animate', but changes the shape of the mouse pointer too.
 352
 353 Whenever the mouse is moved, the frame is also raised.
 354
 355 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 356 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 357 definition of \"random distance\".)"
 358   (interactive
 359    (list (intern (completing-read
 360                   "Select cursor avoidance technique (SPACE for list): "
 361                   '(("banish") ("exile") ("jump") ("animate")
 362                     ("cat-and-mouse") ("proteus") ("none"))
 363                   nil t))))
 364   (if (eq mode 'cat-and-mouse)
 365       (setq mode 'animate))
 366   (if mouse-avoidance-timer
 367       (cancel-timer mouse-avoidance-timer))
 368   (setq mouse-avoidance-timer nil)
 369
 370   ;; Restore pointer shape if necessary
 371   (if (eq mouse-avoidance-mode 'proteus)
 372       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 373
 374   ;; Do additional setup depending on version of mode requested
 375   (cond ((eq mode 'none)
 376          (setq mouse-avoidance-mode nil))
 377         ((or (eq mode 'jump)
 378              (eq mode 'animate)
 379              (eq mode 'proteus))
 380          (setq mouse-avoidance-timer
 381                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy))
 382          (setq mouse-avoidance-mode mode
 383                mouse-avoidance-state (cons 0 0)
 384                mouse-avoidance-old-pointer-shape
 385                (and (boundp 'x-pointer-shape) x-pointer-shape)))
 386         ((eq mode 'exile)
 387          (setq mouse-avoidance-timer
 388                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile))
 389          (setq mouse-avoidance-mode mode
 390                mouse-avoidance-state nil))
 391         ((or (eq mode 'banish)
 392              (eq mode t)
 393              (and (null mode) (null mouse-avoidance-mode))
 394              (and mode (> (prefix-numeric-value mode) 0)))
 395          (setq mouse-avoidance-timer
 396                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish))
 397          (setq mouse-avoidance-mode 'banish))
 398         (t (setq mouse-avoidance-mode nil)))
 399   (force-mode-line-update))
 400
 401 ;; Most people who use avoid mode leave it on all the time, so it's not
 402 ;; very informative to announce it in the mode line.
 403 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 404 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 405 ;;                               minor-mode-alist)))
 406
 407 ;; Needed for custom.
 408 (if mouse-avoidance-mode
 409     (mouse-avoidance-mode mouse-avoidance-mode))
 410
 411 ;;; avoid.el ends here