lisp/tutorial.el

   1 ;;; tutorial.el --- tutorial for Emacs
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: help, internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Code for running the Emacs tutorial.
  28
  29 ;;; History:
  30
  31 ;; File was created 2006-09.
  32
  33 ;;; Code:
  34
  35 (require 'help-mode) ;; for function help-buffer
  36
  37 (defface tutorial-warning-face
  38   '((t :inherit font-lock-warning-face))
  39   "Face used to highlight warnings in the tutorial."
  40   :group 'help)
  41
  42 (defvar tutorial--point-before-chkeys 0
  43   "Point before display of key changes.")
  44 (make-variable-buffer-local 'tutorial--point-before-chkeys)
  45
  46 (defvar tutorial--point-after-chkeys 0
  47   "Point after display of key changes.")
  48 (make-variable-buffer-local 'tutorial--point-after-chkeys)
  49
  50 (defvar tutorial--lang nil
  51   "Tutorial language.")
  52 (make-variable-buffer-local 'tutorial--lang)
  53
  54 (defun tutorial--describe-nonstandard-key (value)
  55   "Give more information about a changed key binding.
  56 This is used in `help-with-tutorial'.  The information includes
  57 the key sequence that no longer has a default binding, the
  58 default binding and the current binding.  It also tells in what
  59 keymap the new binding has been done and how to access the
  60 function in the default binding from the keyboard.
  61
  62 For `cua-mode' key bindings that try to combine CUA key bindings
  63 with default Emacs bindings information about this is shown.
  64
  65 VALUE should have either of these formats:
  66
  67   \(cua-mode)
  68   \(current-binding KEY-FUN DEF-FUN KEY WHERE)
  69
  70 Where
  71   KEY         is a key sequence whose standard binding has been changed
  72   KEY-FUN     is the actual binding for KEY
  73   DEF-FUN     is the standard binding of KEY
  74   WHERE       is a text describing the key sequences to which DEF-FUN is
  75               bound now (or, if it is remapped, a key sequence
  76               for the function it is remapped to)"
  77   (with-output-to-temp-buffer (help-buffer)
  78     (help-setup-xref (list #'tutorial--describe-nonstandard-key value)
  79                      (interactive-p))
  80     (with-current-buffer (help-buffer)
  81       (insert
  82        "Your Emacs customizations override the default binding for this key:"
  83        "\n\n")
  84       (let ((inhibit-read-only t))
  85         (cond
  86          ((eq (car value) 'cua-mode)
  87           (insert
  88            "CUA mode is enabled.
  89
  90 When CUA mode is enabled, you can use C-z, C-x, C-c, and C-v to
  91 undo, cut, copy, and paste in addition to the normal Emacs
  92 bindings.  The C-x and C-c keys only do cut and copy when the
  93 region is active, so in most cases, they do not conflict with the
  94 normal function of these prefix keys.
  95
  96 If you really need to perform a command which starts with one of
  97 the prefix keys even when the region is active, you have three
  98 options:
  99 - press the prefix key twice very quickly (within 0.2 seconds),
 100 - press the prefix key and the following key within 0.2 seconds, or
 101 - use the SHIFT key with the prefix key, i.e. C-S-x or C-S-c."))
 102          ((eq (car value) 'current-binding)
 103           (let ((cb    (nth 1 value))
 104                 (db    (nth 2 value))
 105                 (key   (nth 3 value))
 106                 (where (nth 4 value))
 107                 map
 108                 (maps (current-active-maps))
 109                 mapsym)
 110             ;; Look at the currently active keymaps and try to find
 111             ;; first the keymap where the current binding occurs:
 112             (while maps
 113               (let* ((m (car maps))
 114                      (mb (lookup-key m key t)))
 115                 (setq maps (cdr maps))
 116                 (when (eq mb cb)
 117                   (setq map m)
 118                   (setq maps nil))))
 119             ;; Now, if a keymap was found we must found the symbol
 120             ;; name for it to display to the user.  This can not
 121             ;; always be found since all keymaps does not have a
 122             ;; symbol pointing to them, but here they should have
 123             ;; that:
 124             (when map
 125               (mapatoms (lambda (s)
 126                           (and
 127                            ;; If not already found
 128                            (not mapsym)
 129                            ;; and if s is a keymap
 130                            (and (boundp s)
 131                                 (keymapp (symbol-value s)))
 132                            ;; and not the local symbol map
 133                            (not (eq s 'map))
 134                            ;; and the value of s is map
 135                            (eq map (symbol-value s))
 136                            ;; then save this value in mapsym
 137                            (setq mapsym s)))))
 138             (insert "The default Emacs binding for the key "
 139                     (key-description key)
 140                     " is the command `")
 141             (insert (format "%s" db))
 142             (insert "'.  "
 143                     "However, your customizations have rebound it to the command `")
 144             (insert (format "%s" cb))
 145             (insert "'.")
 146             (when mapsym
 147               (insert "  (For the more advanced user:"
 148                       " This binding is in the keymap `"
 149                       (format "%s" mapsym)
 150                       "'.)"))
 151             (if (string= where "")
 152                 (unless (keymapp db)
 153                   (insert "\n\nYou can use M-x "
 154                           (format "%s" db)
 155                           " RET instead."))
 156               (insert "\n\nWith your current key bindings"
 157                       " you can use "
 158                       (if (string-equal "the menus" where)
 159                           ""
 160                         "the key ")
 161                       where
 162                       " to get the function `"
 163                       (format "%s" db)
 164                       "'.")))
 165           (fill-region (point-min) (point)))))
 166       (print-help-return-message))))
 167
 168 (defun tutorial--sort-keys (left right)
 169   "Sort predicate for use with `tutorial--default-keys'.
 170 This is a predicate function to `sort'.
 171
 172 The sorting is for presentation purpose only and is done on the
 173 key sequence.
 174
 175 LEFT and RIGHT are the elements to compare."
 176   (let ((x (append (cadr left)  nil))
 177         (y (append (cadr right) nil)))
 178     ;; Skip the front part of the key sequences if they are equal:
 179     (while (and x y
 180                 (listp x) (listp y)
 181                 (equal (car x) (car y)))
 182       (setq x (cdr x))
 183       (setq y (cdr y)))
 184     ;; Try to make a comparision that is useful for presentation (this
 185     ;; could be made nicer perhaps):
 186     (let ((cx (car x))
 187           (cy (car y)))
 188       ;;(message "x=%s, y=%s;;;; cx=%s, cy=%s" x y cx cy)
 189       (cond
 190        ;; Lists? Then call this again
 191        ((and cx cy
 192              (listp cx)
 193              (listp cy))
 194         (tutorial--sort-keys cx cy))
 195        ;; Are both numbers? Then just compare them
 196        ((and (wholenump cx)
 197              (wholenump cy))
 198         (> cx cy))
 199        ;; Is one of them a number? Let that be bigger then.
 200        ((wholenump cx)
 201         t)
 202        ((wholenump cy)
 203         nil)
 204        ;; Are both symbols? Compare the names then.
 205        ((and (symbolp cx)
 206              (symbolp cy))
 207         (string< (symbol-name cy)
 208                  (symbol-name cx)))))))
 209
 210 (defconst tutorial--default-keys
 211   ;; On window system, `suspend-emacs' is replaced in the default
 212   ;; keymap
 213   (let* ((suspend-emacs (if window-system
 214                             'iconify-or-deiconify-frame
 215                           'suspend-emacs))
 216          (default-keys
 217            `((ESC-prefix [27])
 218              (Control-X-prefix [?\C-x])
 219              (mode-specific-command-prefix [?\C-c])
 220              (save-buffers-kill-emacs [?\C-x ?\C-c])
 221
 222              ;; * SUMMARY
 223              (scroll-up [?\C-v])
 224              (scroll-down [?\M-v])
 225              (recenter [?\C-l])
 226
 227              ;; * BASIC CURSOR CONTROL
 228              (forward-char [?\C-f])
 229              (backward-char [?\C-b])
 230              (forward-word [?\M-f])
 231              (backward-word [?\M-b])
 232              (next-line [?\C-n])
 233              (previous-line [?\C-p])
 234              (move-beginning-of-line [?\C-a])
 235              (move-end-of-line [?\C-e])
 236              (backward-sentence [?\M-a])
 237              (forward-sentence [?\M-e])
 238              (newline "\r")
 239              (beginning-of-buffer [?\M-<])
 240              (end-of-buffer [?\M->])
 241              (universal-argument [?\C-u])
 242
 243              ;; * WHEN EMACS IS HUNG
 244              (keyboard-quit [?\C-g])
 245
 246              ;; * DISABLED COMMANDS
 247              (downcase-region [?\C-x ?\C-l])
 248
 249              ;; * WINDOWS
 250              (delete-other-windows [?\C-x ?1])
 251              ;; C-u 0 C-l
 252              ;; Type CONTROL-h k CONTROL-f.
 253
 254              ;; * INSERTING AND DELETING
 255              ;; C-u 8 * to insert ********.
 256              (delete-backward-char "\d")
 257              (delete-char [?\C-d])
 258              (backward-kill-word [?\M-\d])
 259              (kill-word [?\M-d])
 260              (kill-line [?\C-k])
 261              (kill-sentence [?\M-k])
 262              (set-mark-command [?\C-@])
 263              (set-mark-command [?\C- ])
 264              (kill-region [?\C-w])
 265              (yank [?\C-y])
 266              (yank-pop [?\M-y])
 267
 268              ;; * UNDO
 269              (advertised-undo [?\C-x ?u])
 270              (advertised-undo [?\C-x ?u])
 271
 272              ;; * FILES
 273              (find-file [?\C-x ?\C-f])
 274              (save-buffer [?\C-x ?\C-s])
 275
 276              ;; * BUFFERS
 277              (list-buffers [?\C-x ?\C-b])
 278              (switch-to-buffer [?\C-x ?b])
 279              (save-some-buffers [?\C-x ?s])
 280
 281              ;; * EXTENDING THE COMMAND SET
 282              ;; C-x     Character eXtend.  Followed by one character.
 283              (execute-extended-command [?\M-x])
 284              ;; C-x C-f         Find file
 285              ;; C-x C-s         Save file
 286              ;; C-x s           Save some buffers
 287              ;; C-x C-b         List buffers
 288              ;; C-x b           Switch buffer
 289              ;; C-x C-c         Quit Emacs
 290              ;; C-x 1           Delete all but one window
 291              ;; C-x u           Undo
 292
 293              ;; * MODE LINE
 294              (describe-mode [?\C-h ?m])
 295              (set-fill-column [?\C-x ?f])
 296              (fill-paragraph [?\M-q])
 297
 298              ;; * SEARCHING
 299              (isearch-forward [?\C-s])
 300              (isearch-backward [?\C-r])
 301
 302              ;; * MULTIPLE WINDOWS
 303              (split-window-vertically [?\C-x ?2])
 304              (scroll-other-window [?\C-\M-v])
 305              (other-window [?\C-x ?o])
 306              (find-file-other-window [?\C-x ?4 ?\C-f])
 307
 308              ;; * RECURSIVE EDITING LEVELS
 309              (keyboard-escape-quit [27 27 27])
 310
 311              ;; * GETTING MORE HELP
 312              ;; The most basic HELP feature is C-h c
 313              (describe-key-briefly [?\C-h ?c])
 314              (describe-key [?\C-h ?k])
 315
 316              ;; * MORE FEATURES
 317              ;; F10
 318
 319              ;; * CONCLUSION
 320              ;;(iconify-or-deiconify-frame [?\C-z])
 321              (,suspend-emacs [?\C-z]))))
 322     (sort default-keys 'tutorial--sort-keys))
 323   "Default Emacs key bindings that the tutorial depends on.")
 324
 325 (defun tutorial--detailed-help (button)
 326   "Give detailed help about changed keys."
 327   (with-output-to-temp-buffer (help-buffer)
 328     (help-setup-xref (list #'tutorial--detailed-help button)
 329                      (interactive-p))
 330     (with-current-buffer (help-buffer)
 331       (let* ((tutorial-buffer  (button-get button 'tutorial-buffer))
 332              (explain-key-desc (button-get button 'explain-key-desc))
 333              (changed-keys (with-current-buffer tutorial-buffer
 334                              (save-excursion
 335                                (goto-char (point-min))
 336                                (tutorial--find-changed-keys
 337                                 tutorial--default-keys)))))
 338         (when changed-keys
 339           (insert
 340            "The following key bindings used in the tutorial have been changed
 341 from the Emacs default:\n\n" )
 342           (let ((frm "   %-14s %-27s %-16s\n"))
 343             (insert (format frm
 344                             "Standard Key" "Command" "In Your Emacs")))
 345           (dolist (tk changed-keys)
 346             (let* ((def-fun     (nth 1 tk))
 347                    (key         (nth 0 tk))
 348                    (def-fun-txt (nth 2 tk))
 349                    (where       (nth 3 tk))
 350                    (remark      (nth 4 tk))
 351                    (rem-fun (command-remapping def-fun))
 352                    (key-txt (key-description key))
 353                    (key-fun (with-current-buffer tutorial-buffer (key-binding key)))
 354                    tot-len)
 355               (unless (eq def-fun key-fun)
 356                 ;; Insert key binding description:
 357                 (when (string= key-txt explain-key-desc)
 358                   (put-text-property 0 (length key-txt)
 359                                      'face 'tutorial-warning-face key-txt))
 360                 (insert "   " key-txt " ")
 361                 (indent-to 18)
 362                 ;; Insert a link describing the old binding:
 363                 (insert-button def-fun-txt
 364                                'value def-fun
 365                                'action
 366                                (lambda (button) (interactive)
 367                                  (describe-function
 368                                   (button-get button 'value)))
 369                                'follow-link t)
 370                 (indent-to 45)
 371                 (when (listp where)
 372                   (setq where "list"))
 373                 ;; Tell where the old binding is now:
 374                 (insert (format " %-16s "
 375                                 (if (string= "" where)
 376                                     (format "M-x %s" def-fun-txt)
 377                                   where)))
 378                 ;; Insert a link with more information, for example
 379                 ;; current binding and keymap or information about
 380                 ;; cua-mode replacements:
 381                 (insert-button (car remark)
 382                                'action
 383                                (lambda (b) (interactive)
 384                                  (let ((value (button-get b 'value)))
 385                                    (tutorial--describe-nonstandard-key value)))
 386                                'value (cdr remark)
 387                                'follow-link t)
 388                 (insert "\n")))))
 389
 390         (insert "
 391 It is OK to change key bindings, but changed bindings do not
 392 correspond to what the tutorial says.\n\n")
 393         (print-help-return-message)))))
 394
 395 (defun tutorial--find-changed-keys (default-keys)
 396   "Find the key bindings used in the tutorial that have changed.
 397 Return a list with elements of the form
 398
 399   '(KEY DEF-FUN DEF-FUN-TXT WHERE REMARK QUIET)
 400
 401 where
 402
 403   KEY         is a key sequence whose standard binding has been changed
 404   DEF-FUN     is the standard binding of KEY
 405   DEF-FUN-TXT is a short descriptive text for DEF-FUN
 406   WHERE       is a text describing the key sequences to which DEF-FUN is
 407               bound now (or, if it is remapped, a key sequence
 408               for the function it is remapped to)
 409   REMARK      is a list with info about rebinding.  It has either of
 410               these formats:
 411
 412                 \(TEXT cua-mode)
 413                 \(TEXT current-binding KEY-FUN DEF-FUN KEY WHERE)
 414
 415               Here TEXT is a link text to show to the user.  The
 416               rest of the list is used to show information when
 417               the user clicks the link.
 418
 419               KEY-FUN is the actual binding for KEY.
 420   QUIET       is t if this changed keybinding should be handled quietly.
 421               This is used by `tutorial--display-changes'."
 422   (let (changed-keys remark)
 423     ;; Look up the bindings in a Fundamental mode buffer
 424     ;; so we do not get fooled by some other major mode.
 425     (with-temp-buffer
 426       (fundamental-mode)
 427       (dolist (kdf default-keys)
 428         ;; The variables below corresponds to those with the same names
 429         ;; described in the doc string.
 430         (let* ((key     (nth 1 kdf))
 431                (def-fun (nth 0 kdf))
 432                (def-fun-txt (format "%s" def-fun))
 433                (rem-fun (command-remapping def-fun))
 434                ;; Handle prefix definitions specially
 435                ;; so that a mode that rebinds some subcommands
 436                ;; won't make it appear that the whole prefix is gone.
 437                (key-fun (if (eq def-fun 'ESC-prefix)
 438                             (lookup-key global-map [27])
 439                           (if (eq def-fun 'Control-X-prefix)
 440                               (lookup-key global-map [24])
 441                             (key-binding key))))
 442                (where (where-is-internal (if rem-fun rem-fun def-fun))))
 443
 444           (if where
 445               (progn
 446                 (setq where (key-description (car where)))
 447                 (when (and (< 10 (length where))
 448                            (string= (substring where 0 (length "<menu-bar>"))
 449                                     "<menu-bar>"))
 450                   (setq where "the menus")))
 451             (setq where ""))
 452           (setq remark nil)
 453           (unless
 454               (cond ((eq key-fun def-fun)
 455                      ;; No rebinding, return t
 456                      t)
 457                     ((and key-fun
 458                           (eq key-fun (command-remapping def-fun)))
 459                      ;; Just a remapping, return t
 460                      t)
 461                     ;; cua-mode specials:
 462                     ((and cua-mode
 463                           (or (and
 464                                (equal key [?\C-v])
 465                                (eq key-fun 'cua-paste))
 466                               (and
 467                                (equal key [?\C-z])
 468                                (eq key-fun 'undo))))
 469                      (setq remark (list "cua-mode, more info" 'cua-mode))
 470                      nil)
 471                     ((and cua-mode
 472                           (or (and (eq def-fun 'ESC-prefix)
 473                                    (equal key-fun
 474                                           `(keymap
 475                                             (118 . cua-repeat-replace-region)))
 476                                    (setq def-fun-txt "\"ESC prefix\""))
 477                               (and (eq def-fun 'mode-specific-command-prefix)
 478                                    (equal key-fun
 479                                           '(keymap
 480                                             (timeout . copy-region-as-kill)))
 481                                    (setq def-fun-txt "\"C-c prefix\""))
 482                               (and (eq def-fun 'Control-X-prefix)
 483                                    (equal key-fun
 484                                           '(keymap (timeout . kill-region)))
 485                                    (setq def-fun-txt "\"C-x prefix\""))))
 486                      (setq remark (list "cua-mode replacement" 'cua-mode))
 487                      (setq where "Same key")
 488                      nil)
 489                     ;; viper-mode specials:
 490                     ((and (boundp 'viper-mode-string)
 491                           (boundp 'viper-current-state)
 492                           (eq viper-current-state 'vi-state)
 493                           (or (and (eq def-fun 'isearch-forward)
 494                                    (eq key-fun 'viper-isearch-forward))
 495                               (and (eq def-fun 'isearch-backward)
 496                                    (eq key-fun 'viper-isearch-backward))))
 497                      ;; These bindings works as the default bindings,
 498                      ;; return t
 499                      t)
 500                     ((when normal-erase-is-backspace
 501                        (or (and (equal key [C-delete])
 502                                 (equal key-fun 'kill-word))
 503                            (and (equal key [C-backspace])
 504                                 (equal key-fun 'backward-kill-word))))
 505                      ;; This is the strange handling of C-delete and
 506                      ;; C-backspace, return t
 507                      t)
 508                     (t
 509                      ;; This key has indeed been rebound. Put information
 510                      ;; in `remark' and return nil
 511                      (setq remark
 512                            (list "more info" 'current-binding
 513                                  key-fun def-fun key where))
 514                      nil))
 515             (add-to-list 'changed-keys
 516                          (list key def-fun def-fun-txt where remark nil))))))
 517     changed-keys))
 518
 519 (defun tutorial--key-description (key)
 520   (let ((desc (key-description key)))
 521     (cond ((string= "ESC" desc) "<ESC>")
 522           ((string= "RET" desc) "<Return>")
 523           ((string= "DEL" desc) "<Delback>")
 524           (t desc))))
 525
 526 (defun tutorial--display-changes ()
 527   "Display changes to some default key bindings.
 528 If some of the default key bindings that the tutorial depends on
 529 have been changed then display the changes in the tutorial buffer
 530 with some explanatory links."
 531   (let* ((changed-keys (tutorial--find-changed-keys
 532                         tutorial--default-keys))
 533          ;; Alist of element (DESC . CK) where DESC is the
 534          ;; key-description of a changed key and CK is the
 535          ;; corresponding element in `changed-keys'.
 536          (changed-keys-alist
 537           (mapcar (lambda (ck) (cons (tutorial--key-description (car ck)) ck))
 538                   changed-keys))
 539          changed-key
 540          (start (point))
 541          (case-fold-search nil)
 542          (keybindings-regexp
 543           (concat "[[:space:]]\\("
 544                   (mapconcat (lambda (kdf) (regexp-quote
 545                                             (tutorial--key-description
 546                                              (nth 1 kdf))))
 547                              tutorial--default-keys
 548                              "\\|")
 549                   "\\)[[:punct:][:space:]]")))
 550     ;; Need the custom button face for viper buttons:
 551     (if (boundp 'viper-mode-string) (require 'cus-edit))
 552
 553     (if (or changed-keys (boundp 'viper-mode-string))
 554         (let ((head  (get-lang-string tutorial--lang 'tut-chgdhead))
 555               (head2 (get-lang-string tutorial--lang 'tut-chgdhead2)))
 556           (when (and head head2)
 557             (goto-char tutorial--point-before-chkeys)
 558             (insert head " [")
 559             (insert-button head2 'tutorial-buffer (current-buffer)
 560                            'action 'tutorial--detailed-help
 561                            'follow-link t 'face 'link)
 562             (insert "]\n\n")
 563             (add-text-properties tutorial--point-before-chkeys (point)
 564                                  '(tutorial-remark remark
 565                                    face tutorial-warning-face
 566                                    read-only t)))))
 567
 568     ;; Scan the tutorial for all key sequences.
 569     (goto-char (point-min))
 570     (while (re-search-forward keybindings-regexp (point-max) t)
 571       ;; Then highlight each rebound key sequence.
 572       ;; This avoids issuing a warning for, e.g., C-x C-b if C-b is rebound.
 573       (setq changed-key (assoc (match-string 1) changed-keys-alist))
 574       (and changed-key
 575            (not (get-text-property (match-beginning 1) 'tutorial-remark))
 576            (let* ((desc    (car changed-key))
 577                   (ck      (cdr changed-key))
 578                   (key     (nth 0 ck))
 579                   (def-fun (nth 1 ck))
 580                   (where   (nth 3 ck))
 581                   s1 s2 help-string)
 582              (unless (string= where "Same key")
 583                (when (string= where "")
 584                  (setq where (format "M-x %s" def-fun)))
 585                (setq tutorial--point-after-chkeys (point-marker)
 586                      s1 (get-lang-string tutorial--lang 'tut-chgdkey)
 587                      s2 (get-lang-string tutorial--lang 'tut-chgdkey2)
 588                      help-string (and s1 s2 (format s1 desc where)))
 589                (add-text-properties (match-beginning 1) (match-end 1)
 590                                     '(face tutorial-warning-face
 591                                       tutorial-remark key-sequence))
 592                (if help-string
 593                    (if (nth 5 ck)
 594                        ;; Put help string in the tooltip.
 595                        (put-text-property (match-beginning 1) (match-end 1)
 596                                           'help-echo help-string)
 597                      ;; Put help string in the buffer.
 598                      (save-excursion
 599                        (setcar (nthcdr 5 ck) t)
 600                        (forward-line)
 601                        ;; Two or more changed keys were on the same line.
 602                        (while (eq (get-text-property (point) 'tutorial-remark)
 603                                   'remark)
 604                          (forward-line))
 605                        (setq start (point))
 606                        (insert "** " help-string " [")
 607                        (insert-button s2 'tutorial-buffer (current-buffer)
 608                                       'action 'tutorial--detailed-help
 609                                       'explain-key-desc desc 'follow-link t
 610                                       'face 'link)
 611                        (insert "] **\n")
 612                        (add-text-properties start (point)
 613                                             '(tutorial-remark remark
 614                                               rear-nonsticky t
 615                                               face tutorial-warning-face
 616                                               read-only t)))))))))))
 617
 618 (defun tutorial--saved-dir ()
 619   "Directory to which tutorials are saved."
 620   (expand-file-name "tutorial"
 621                     (if (eq system-type 'ms-dos) "~/_emacs.d/" "~/.emacs.d/")))
 622
 623 (defun tutorial--saved-file ()
 624   "File name in which to save tutorials."
 625   (let ((file-name tutorial--lang)
 626         (ext (file-name-extension tutorial--lang)))
 627     (when (or (not ext)
 628               (string= ext ""))
 629       (setq file-name (concat file-name ".tut")))
 630     (expand-file-name file-name (tutorial--saved-dir))))
 631
 632 (defun tutorial--remove-remarks ()
 633   "Remove the remark lines that was added to the tutorial buffer."
 634   (save-excursion
 635     (goto-char (point-min))
 636     (let (prop-start
 637           prop-end
 638           prop-val)
 639       ;; Catch the case when we already are on a remark line
 640       (while (if (get-text-property (point) 'tutorial-remark)
 641                  (setq prop-start (point))
 642                (setq prop-start (next-single-property-change (point) 'tutorial-remark)))
 643         (setq prop-end (next-single-property-change prop-start 'tutorial-remark))
 644         (setq prop-val (get-text-property prop-start 'tutorial-remark))
 645         (unless prop-end
 646           (setq prop-end (point-max)))
 647         (goto-char prop-end)
 648         (unless (eq prop-val 'key-sequence)
 649           (delete-region prop-start prop-end))))))
 650
 651 (defun tutorial--save-tutorial ()
 652   "Save the tutorial buffer.
 653 This saves the part of the tutorial before and after the area
 654 showing changed keys.  It also saves the point position and the
 655 position where the display of changed bindings was inserted."
 656   ;; This runs in a hook so protect it:
 657   (condition-case err
 658       (if (y-or-n-p "Save your position in the tutorial? ")
 659           (tutorial--save-tutorial-to (tutorial--saved-file))
 660         (message "Tutorial position not saved"))
 661     (error (message "Error saving tutorial state: %s"
 662                     (error-message-string err)))))
 663
 664 (defun tutorial--save-tutorial-to (saved-file)
 665   "Save the tutorial buffer to SAVED-FILE.
 666 See `tutorial--save-tutorial' for more information."
 667   ;; Anything to save?
 668   (when (or (buffer-modified-p)
 669             (< 1 (point)))
 670     (let ((tutorial-dir (tutorial--saved-dir))
 671           save-err)
 672       ;; The tutorial is saved in a subdirectory in the user home
 673       ;; directory. Create this subdirectory first.
 674       (unless (file-directory-p tutorial-dir)
 675         (condition-case err
 676             (make-directory tutorial-dir nil)
 677           (error (setq save-err t)
 678                  (warn "Could not create directory %s: %s" tutorial-dir
 679                        (error-message-string err)))))
 680       ;; Make sure we have that directory.
 681       (if (file-directory-p tutorial-dir)
 682           (let ((tut-point (if (= 0 tutorial--point-after-chkeys)
 683                                ;; No info about changed keys is
 684                                ;; displayed.
 685                                (point)
 686                              (if (< (point) tutorial--point-after-chkeys)
 687                                  (- (point))
 688                                (- (point) tutorial--point-after-chkeys))))
 689                 (old-point (point))
 690                 ;; Use a special undo list so that we easily can undo
 691                 ;; the changes we make to the tutorial buffer.  This is
 692                 ;; currently not needed since we now delete the buffer
 693                 ;; after saving, but kept for possible future use of
 694                 ;; this function.
 695                 buffer-undo-list
 696                 (inhibit-read-only t))
 697             ;; Delete the area displaying info about changed keys.
 698             ;;             (when (< 0 tutorial--point-after-chkeys)
 699             ;;               (delete-region tutorial--point-before-chkeys
 700             ;;                              tutorial--point-after-chkeys))
 701             ;; Delete the remarks:
 702             (tutorial--remove-remarks)
 703             ;; Put the value of point first in the buffer so it will
 704             ;; be saved with the tutorial.
 705             (goto-char (point-min))
 706             (insert (number-to-string tut-point)
 707                     "\n"
 708                     (number-to-string (marker-position
 709                                        tutorial--point-before-chkeys))
 710                     "\n")
 711             (condition-case err
 712                 (write-region nil nil saved-file)
 713               (error (setq save-err t)
 714                      (warn "Could not save tutorial to %s: %s"
 715                            saved-file
 716                            (error-message-string err))))
 717             ;; An error is raised here?? Is this a bug?
 718             (condition-case err
 719                 (undo-only)
 720               (error nil))
 721             ;; Restore point
 722             (goto-char old-point)
 723             (if save-err
 724                 (message "Could not save tutorial state.")
 725               (message "Saved tutorial state.")))
 726         (message "Can't save tutorial: %s is not a directory"
 727                  tutorial-dir)))))
 728
 729
 730 ;;;###autoload
 731 (defun help-with-tutorial (&optional arg dont-ask-for-revert)
 732   "Select the Emacs learn-by-doing tutorial.
 733 If there is a tutorial version written in the language
 734 of the selected language environment, that version is used.
 735 If there's no tutorial in that language, `TUTORIAL' is selected.
 736 With ARG, you are asked to choose which language.
 737 If DONT-ASK-FOR-REVERT is non-nil the buffer is reverted without
 738 any question when restarting the tutorial.
 739
 740 If any of the standard Emacs key bindings that are used in the
 741 tutorial have been changed then an explanatory note about this is
 742 shown in the beginning of the tutorial buffer.
 743
 744 When the tutorial buffer is killed the content and the point
 745 position in the buffer is saved so that the tutorial may be
 746 resumed later."
 747   (interactive "P")
 748   (if (boundp 'viper-current-state)
 749       (let ((prompt1
 750              "You can not run the Emacs tutorial directly because you have \
 751 enabled Viper.")
 752             (prompt2 "\nThere is however a Viper tutorial you can run instead.
 753 Run the Viper tutorial? "))
 754         (if (fboundp 'viper-tutorial)
 755             (if (y-or-n-p (concat prompt1 prompt2))
 756                 (progn (message "")
 757                        (funcall 'viper-tutorial 0))
 758               (message "Tutorial aborted by user"))
 759           (message prompt1)))
 760     (let* ((lang (if arg
 761                      (let ((minibuffer-setup-hook minibuffer-setup-hook))
 762                        (add-hook 'minibuffer-setup-hook
 763                                  'minibuffer-completion-help)
 764                        (read-language-name 'tutorial "Language: " "English"))
 765                    (if (get-language-info current-language-environment 'tutorial)
 766                        current-language-environment
 767                      "English")))
 768            (filename (get-language-info lang 'tutorial))
 769            ;; Choose a buffer name including the language so that
 770            ;; several languages can be tested simultaneously:
 771            (tut-buf-name (concat "TUTORIAL (" lang ")"))
 772            (old-tut-buf (get-buffer tut-buf-name))
 773            (old-tut-win (when old-tut-buf (get-buffer-window old-tut-buf t)))
 774            (old-tut-is-ok (when old-tut-buf
 775                             (not (buffer-modified-p old-tut-buf))))
 776            old-tut-file
 777            (old-tut-point 1))
 778       (setq tutorial--point-after-chkeys (point-min))
 779       ;; Try to display the tutorial buffer before asking to revert it.
 780       ;; If the tutorial buffer is shown in some window make sure it is
 781       ;; selected and displayed:
 782       (if old-tut-win
 783           (raise-frame
 784            (window-frame
 785             (select-window (get-buffer-window old-tut-buf t))))
 786         ;; Else, is there an old tutorial buffer? Then display it:
 787         (when old-tut-buf
 788           (switch-to-buffer old-tut-buf)))
 789       ;; Use whole frame for tutorial
 790       (delete-other-windows)
 791       ;; If the tutorial buffer has been changed then ask if it should
 792       ;; be reverted:
 793       (when (and old-tut-buf
 794                  (not old-tut-is-ok))
 795         (setq old-tut-is-ok
 796               (if dont-ask-for-revert
 797                   nil
 798                 (not (y-or-n-p
 799                       "You have changed the Tutorial buffer.  Revert it? ")))))
 800       ;; (Re)build the tutorial buffer if it is not ok
 801       (unless old-tut-is-ok
 802         (switch-to-buffer (get-buffer-create tut-buf-name))
 803         (unless old-tut-buf (text-mode))
 804         (unless lang (error "Variable lang is nil"))
 805         (setq tutorial--lang lang)
 806         (setq old-tut-file (file-exists-p (tutorial--saved-file)))
 807         (let ((inhibit-read-only t))
 808           (erase-buffer))
 809         (message "Preparing tutorial ...") (sit-for 0)
 810
 811         ;; Do not associate the tutorial buffer with a file. Instead use
 812         ;; a hook to save it when the buffer is killed.
 813         (setq buffer-auto-save-file-name nil)
 814         (add-hook 'kill-buffer-hook 'tutorial--save-tutorial nil t)
 815
 816         ;; Insert the tutorial. First offer to resume last tutorial
 817         ;; editing session.
 818         (when dont-ask-for-revert
 819           (setq old-tut-file nil))
 820         (when old-tut-file
 821           (setq old-tut-file
 822                 (y-or-n-p "Resume your last saved tutorial? ")))
 823         (if old-tut-file
 824             (progn
 825               (insert-file-contents (tutorial--saved-file))
 826               (goto-char (point-min))
 827               (setq old-tut-point
 828                     (string-to-number
 829                      (buffer-substring-no-properties
 830                       (line-beginning-position) (line-end-position))))
 831               (forward-line)
 832               (setq tutorial--point-before-chkeys
 833                     (string-to-number
 834                      (buffer-substring-no-properties
 835                       (line-beginning-position) (line-end-position))))
 836               (forward-line)
 837               (delete-region (point-min) (point))
 838               (goto-char tutorial--point-before-chkeys)
 839               (setq tutorial--point-before-chkeys (point-marker)))
 840           (insert-file-contents (expand-file-name filename data-directory))
 841           (forward-line)
 842           (setq tutorial--point-before-chkeys (point-marker)))
 843
 844         (tutorial--display-changes)
 845
 846         ;; Clear message:
 847         (unless dont-ask-for-revert
 848           (message "") (sit-for 0))
 849
 850
 851         (if old-tut-file
 852             ;; Just move to old point in saved tutorial.
 853             (let ((old-point
 854                    (if (> 0 old-tut-point)
 855                        (- old-tut-point)
 856                      (+ old-tut-point tutorial--point-after-chkeys))))
 857               (when (< old-point 1)
 858                 (setq old-point 1))
 859               (goto-char old-point))
 860           (goto-char (point-min))
 861           (search-forward "\n<<")
 862           (beginning-of-line)
 863           ;; Convert the <<...>> line to the proper [...] line,
 864           ;; or just delete the <<...>> line if a [...] line follows.
 865           (cond ((save-excursion
 866                    (forward-line 1)
 867                    (looking-at "\\["))
 868                  (delete-region (point) (progn (forward-line 1) (point))))
 869                 ((looking-at "<<Blank lines inserted.*>>")
 870                  (replace-match "[Middle of page left blank for didactic purposes.   Text continues below]"))
 871                 (t
 872                  (looking-at "<<")
 873                  (replace-match "[")
 874                  (search-forward ">>")
 875                  (replace-match "]")))
 876           (beginning-of-line)
 877           (let ((n (- (window-height (selected-window))
 878                       (count-lines (point-min) (point))
 879                       6)))
 880             (if (< n 8)
 881                 (progn
 882                   ;; For a short gap, we don't need the [...] line,
 883                   ;; so delete it.
 884                   (delete-region (point) (progn (end-of-line) (point)))
 885                   (newline n))
 886               ;; Some people get confused by the large gap.
 887               (newline (/ n 2))
 888
 889               ;; Skip the [...] line (don't delete it).
 890               (forward-line 1)
 891               (newline (- n (/ n 2)))))
 892           (goto-char (point-min)))
 893         (setq buffer-undo-list nil)
 894         (set-buffer-modified-p nil)))))
 895
 896
 897 ;; Below is some attempt to handle language specific strings. These
 898 ;; are currently only used in the tutorial.
 899
 900 (defconst lang-strings
 901   '(("English" .
 902      ((tut-chgdkey . "%s has been rebound, but you can use %s instead")
 903       (tut-chgdkey2 . "More")
 904       (tut-chgdhead . "
 905  NOTICE: The main purpose of the Emacs tutorial is to teach you
 906  the most important standard Emacs commands (key bindings).
 907  However, your Emacs has been customized by changing some of
 908  these basic editing commands, so it doesn't correspond to the
 909  tutorial.  We have inserted colored notices where the altered
 910  commands have been introduced.")
 911       (tut-chgdhead2 . "More"))))
 912   "Language specific strings for Emacs.
 913 This is an association list with the keys equal to the strings
 914 that can be returned by `read-language-name'.  The elements in
 915 the list are themselves association lists with keys that are
 916 string ids and values that are the language specific strings.
 917
 918 See `get-lang-string' for more information.")
 919
 920 (defun get-lang-string (lang stringid &optional no-eng-fallback)
 921   "Get a language specific string for Emacs.
 922 In certain places Emacs can replace a string shown to the user with
 923 a language specific string.  This function retrieves such strings.
 924
 925 LANG is the language specification.  It should be one of those
 926 strings that can be returned by `read-language-name'.  STRINGID
 927 is a symbol that specifies the string to retrieve.
 928
 929 If no string is found for STRINGID in the chosen language then
 930 the English string is returned unless NO-ENG-FALLBACK is non-nil.
 931
 932 See `lang-strings' for more information.
 933
 934 Currently this feature is only used in `help-with-tutorial'."
 935   (let ((my-lang-strings (assoc lang lang-strings))
 936         (found-string))
 937     (when my-lang-strings
 938       (let ((entry (assoc stringid (cdr my-lang-strings))))
 939         (when entry
 940           (setq found-string (cdr entry)))))
 941     ;; Fallback to English strings
 942     (unless (or found-string
 943                 no-eng-fallback)
 944       (setq found-string (get-lang-string "English" stringid t)))
 945     found-string))
 946
 947 ;;(get-lang-string "English" 'tut-chgdkey)
 948
 949 (provide 'tutorial)
 950
 951 ;; arch-tag: c8e80aef-c3bb-4ffb-8af6-22171bf0c100
 952 ;;; tutorial.el ends here