lisp/desktop.el

   1 ;;; desktop.el --- save partial status of Emacs when killed
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@diku.dk>
   7 ;; Keywords: convenience
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Save the Desktop, i.e.,
  30 ;;      - some global variables
  31 ;;      - the list of buffers with associated files.  For each buffer also
  32 ;;              - the major mode
  33 ;;              - the default directory
  34 ;;              - the point
  35 ;;              - the mark & mark-active
  36 ;;              - buffer-read-only
  37 ;;              - some local variables
  38
  39 ;; To use this, use customize to turn on desktop-save-mode or add the
  40 ;; following line somewhere in your .emacs file:
  41 ;;
  42 ;;      (desktop-save-mode 1)
  43 ;;
  44 ;; For further usage information, look at the section
  45 ;; "Saving Emacs Sessions" in the GNU Emacs Manual.
  46
  47 ;; When the desktop module is loaded, the function `desktop-kill' is
  48 ;; added to the `kill-emacs-hook'.  This function is responsible for
  49 ;; saving the desktop when Emacs is killed.  Furthermore an anonymous
  50 ;; function is added to the `after-init-hook'.  This function is
  51 ;; responsible for loading the desktop when Emacs is started.
  52
  53 ;; Special handling.
  54 ;; -----------------
  55 ;; Variables `desktop-buffer-mode-handlers' and `desktop-minor-mode-handlers'
  56 ;; are supplied to handle special major and minor modes respectively.
  57 ;; `desktop-buffer-mode-handlers' is an alist of major mode specific functions
  58 ;; to restore a desktop buffer.  Elements must have the form
  59 ;;
  60 ;;    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
  61 ;;
  62 ;; Functions listed are called by `desktop-create-buffer' when `desktop-read'
  63 ;; evaluates the desktop file.  Buffers with a major mode not specified here,
  64 ;; are restored by the default handler `desktop-restore-file-buffer'.
  65 ;; `desktop-minor-mode-handlers' is an alist of functions to restore
  66 ;; non-standard minor modes.  Elements must have the form
  67 ;;
  68 ;;    (MINOR-MODE . RESTORE-FUNCTION).
  69 ;;
  70 ;; Functions are called by `desktop-create-buffer' to restore minor modes.
  71 ;; Minor modes not specified here, are restored by the standard minor mode
  72 ;; function.  If you write a module that defines a major or minor mode that
  73 ;; needs a special handler, then place code like
  74
  75 ;;    (defun foo-restore-desktop-buffer
  76 ;;    ...
  77 ;;    (add-to-list 'desktop-buffer-mode-handlers
  78 ;;                 '(foo-mode . foo-restore-desktop-buffer))
  79
  80 ;; or
  81
  82 ;;    (defun bar-desktop-restore
  83 ;;    ...
  84 ;;    (add-to-list 'desktop-minor-mode-handlers
  85 ;;                 '(bar-mode . bar-desktop-restore))
  86
  87 ;; in the module itself, and make shure that the mode function is
  88 ;; autoloaded.  See the docstrings of `desktop-buffer-mode-handlers' and
  89 ;; `desktop-minor-mode-handlers' for more info.
  90
  91 ;; Minor modes.
  92 ;; ------------
  93 ;; Conventional minor modes (see node "Minor Mode Conventions" in the elisp
  94 ;; manual) are handled in the following way:
  95 ;; When `desktop-save' saves the state of a buffer to the desktop file, it
  96 ;; saves as `desktop-minor-modes' the list of names of those variables in
  97 ;; `minor-mode-alist' that have a non-nil value.
  98 ;; When `desktop-create' restores the buffer, each of the symbols in
  99 ;; `desktop-minor-modes' is called as function with parameter 1.
 100 ;; The variables `desktop-minor-mode-table' and `desktop-minor-mode-handlers'
 101 ;; are used to handle non-conventional minor modes.  `desktop-save' uses
 102 ;; `desktop-minor-mode-table' to map minor mode variables to minor mode
 103 ;; functions before writing `desktop-minor-modes'.  If a minor mode has a
 104 ;; variable name that is different form its function name, an entry
 105
 106 ;;    (NAME RESTORE-FUNCTION)
 107
 108 ;; should be added to `desktop-minor-mode-table'.  If a minor mode should not
 109 ;; be restored, RESTORE-FUNCTION should be set to nil.  `desktop-create' uses
 110 ;; `desktop-minor-mode-handlers' to lookup minor modes that needs a restore
 111 ;; function different from the usual minor mode function.
 112 ;; ---------------------------------------------------------------------------
 113
 114 ;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
 115 ;; in your home directory is used for that.  Saving global default values
 116 ;; for buffers is an example of misuse.
 117
 118 ;; PLEASE NOTE: The kill ring can be saved as specified by the variable
 119 ;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
 120 ;; things you did not mean to keep.  Use M-x desktop-clear RET.
 121
 122 ;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
 123 ;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
 124 ;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
 125 ;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
 126 ;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
 127 ;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
 128 ;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
 129 ;; ---------------------------------------------------------------------------
 130 ;; TODO:
 131 ;;
 132 ;; Save window configuration.
 133 ;; Recognize more minor modes.
 134 ;; Save mark rings.
 135
 136 ;;; Code:
 137
 138 (defvar uniquify-managed)
 139
 140 (defvar desktop-file-version "206"
 141   "Version number of desktop file format.
 142 Written into the desktop file and used at desktop read to provide
 143 backward compatibility.")
 144
 145 ;; ----------------------------------------------------------------------------
 146 ;; USER OPTIONS -- settings you might want to play with.
 147 ;; ----------------------------------------------------------------------------
 148
 149 (defgroup desktop nil
 150   "Save status of Emacs when you exit."
 151   :group 'frames)
 152
 153 ;;;###autoload
 154 (define-minor-mode desktop-save-mode
 155   "Toggle desktop saving mode.
 156 With numeric ARG, turn desktop saving on if ARG is positive, off
 157 otherwise.  If desktop saving is turned on, the state of Emacs is
 158 saved from one session to another.  See variable `desktop-save'
 159 and function `desktop-read' for details."
 160   :global t
 161   :group 'desktop)
 162
 163 ;; Maintained for backward compatibility
 164 (define-obsolete-variable-alias 'desktop-enable
 165                                 'desktop-save-mode "22.1")
 166
 167 (defun desktop-save-mode-off ()
 168   "Disable `desktop-save-mode'.  Provided for use in hooks."
 169   (desktop-save-mode 0))
 170
 171 (defcustom desktop-save 'ask-if-new
 172   "*Specifies whether the desktop should be saved when it is killed.
 173 A desktop is killed when the user changes desktop or quits Emacs.
 174 Possible values are:
 175    t             -- always save.
 176    ask           -- always ask.
 177    ask-if-new    -- ask if no desktop file exists, otherwise just save.
 178    ask-if-exists -- ask if desktop file exists, otherwise don't save.
 179    if-exists     -- save if desktop file exists, otherwise don't save.
 180    nil           -- never save.
 181 The desktop is never saved when `desktop-save-mode' is nil.
 182 The variables `desktop-dirname' and `desktop-base-file-name'
 183 determine where the desktop is saved."
 184   :type
 185   '(choice
 186     (const :tag "Always save" t)
 187     (const :tag "Always ask" ask)
 188     (const :tag "Ask if desktop file is new, else do save" ask-if-new)
 189     (const :tag "Ask if desktop file exists, else don't save" ask-if-exists)
 190     (const :tag "Save if desktop file exists, else don't" if-exists)
 191     (const :tag "Never save" nil))
 192   :group 'desktop
 193   :version "22.1")
 194
 195 (defcustom desktop-load-locked-desktop 'ask
 196   "Specifies whether the desktop should be loaded if locked.
 197 Possible values are:
 198    t    -- load anyway.
 199    nil  -- don't load.
 200    ask  -- ask the user.
 201 If the value is nil, or `ask' and the user chooses not to load the desktop,
 202 the normal hook `desktop-not-loaded-hook' is run."
 203   :type
 204   '(choice
 205     (const :tag "Load anyway" t)
 206     (const :tag "Don't load" nil)
 207     (const :tag "Ask the user" ask))
 208   :group 'desktop
 209   :version "22.2")
 210
 211 (defcustom desktop-base-file-name
 212   (convert-standard-filename ".emacs.desktop")
 213   "Name of file for Emacs desktop, excluding the directory part."
 214   :type 'file
 215   :group 'desktop)
 216 (define-obsolete-variable-alias 'desktop-basefilename
 217                                 'desktop-base-file-name "22.1")
 218
 219 (defcustom desktop-base-lock-name
 220   (convert-standard-filename ".emacs.desktop.lock")
 221   "Name of lock file for Emacs desktop, excluding the directory part."
 222   :type 'file
 223   :group 'desktop
 224   :version "22.2")
 225
 226 (defcustom desktop-path '("." "~")
 227   "List of directories to search for the desktop file.
 228 The base name of the file is specified in `desktop-base-file-name'."
 229   :type '(repeat directory)
 230   :group 'desktop
 231   :version "22.1")
 232
 233 (defcustom desktop-missing-file-warning nil
 234   "If non-nil, offer to recreate the buffer of a deleted file.
 235 Also pause for a moment to display message about errors signaled in
 236 `desktop-buffer-mode-handlers'.
 237
 238 If nil, just print error messages in the message buffer."
 239   :type 'boolean
 240   :group 'desktop
 241   :version "22.1")
 242
 243 (defcustom desktop-no-desktop-file-hook nil
 244   "Normal hook run when `desktop-read' can't find a desktop file.
 245 Run in the directory in which the desktop file was sought.
 246 May be used to show a dired buffer."
 247   :type 'hook
 248   :group 'desktop
 249   :version "22.1")
 250
 251 (defcustom desktop-not-loaded-hook nil
 252   "Normal hook run when the user declines to re-use a desktop file.
 253 Run in the directory in which the desktop file was found.
 254 May be used to deal with accidental multiple Emacs jobs."
 255   :type 'hook
 256   :group 'desktop
 257   :options '(desktop-save-mode-off save-buffers-kill-emacs)
 258   :version "22.2")
 259
 260 (defcustom desktop-after-read-hook nil
 261   "Normal hook run after a successful `desktop-read'.
 262 May be used to show a buffer list."
 263   :type 'hook
 264   :group 'desktop
 265   :options '(list-buffers)
 266   :version "22.1")
 267
 268 (defcustom desktop-save-hook nil
 269   "Normal hook run before the desktop is saved in a desktop file.
 270 Run with the desktop buffer current with only the header present.
 271 May be used to add to the desktop code or to truncate history lists,
 272 for example."
 273   :type 'hook
 274   :group 'desktop)
 275
 276 (defcustom desktop-globals-to-save
 277   '(desktop-missing-file-warning
 278     tags-file-name
 279     tags-table-list
 280     search-ring
 281     regexp-search-ring
 282     register-alist)
 283   "List of global variables saved by `desktop-save'.
 284 An element may be variable name (a symbol) or a cons cell of the form
 285 \(VAR . MAX-SIZE), which means to truncate VAR's value to at most
 286 MAX-SIZE elements (if the value is a list) before saving the value.
 287 Feature: Saving `kill-ring' implies saving `kill-ring-yank-pointer'."
 288   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 289   :group 'desktop)
 290
 291 (defcustom desktop-globals-to-clear
 292   '(kill-ring
 293     kill-ring-yank-pointer
 294     search-ring
 295     search-ring-yank-pointer
 296     regexp-search-ring
 297     regexp-search-ring-yank-pointer)
 298   "List of global variables that `desktop-clear' will clear.
 299 An element may be variable name (a symbol) or a cons cell of the form
 300 \(VAR . FORM).  Symbols are set to nil and for cons cells VAR is set
 301 to the value obtained by evaluating FORM."
 302   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 303   :group 'desktop
 304   :version "22.1")
 305
 306 (defcustom desktop-clear-preserve-buffers
 307   '("\\*scratch\\*" "\\*Messages\\*" "\\*server\\*" "\\*tramp/.+\\*")
 308   "*List of buffers that `desktop-clear' should not delete.
 309 Each element is a regular expression.  Buffers with a name matched by any of
 310 these won't be deleted."
 311   :type '(repeat string)
 312   :group 'desktop)
 313
 314 ;;;###autoload
 315 (defcustom desktop-locals-to-save
 316   '(desktop-locals-to-save  ; Itself!  Think it over.
 317     truncate-lines
 318     case-fold-search
 319     case-replace
 320     fill-column
 321     overwrite-mode
 322     change-log-default-name
 323     line-number-mode
 324     column-number-mode
 325     size-indication-mode
 326     buffer-file-coding-system
 327     indent-tabs-mode
 328     tab-width
 329     indicate-buffer-boundaries
 330     indicate-empty-lines
 331     show-trailing-whitespace)
 332   "List of local variables to save for each buffer.
 333 The variables are saved only when they really are local.  Conventional minor
 334 modes are restored automatically; they should not be listed here."
 335   :type '(repeat symbol)
 336   :group 'desktop)
 337
 338 ;; We skip .log files because they are normally temporary.
 339 ;;         (ftp) files because they require passwords and whatnot.
 340 (defcustom desktop-buffers-not-to-save
 341   "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\)$"
 342   "Regexp identifying buffers that are to be excluded from saving."
 343   :type 'regexp
 344   :group 'desktop)
 345
 346 ;; Skip tramp and ange-ftp files
 347 (defcustom desktop-files-not-to-save
 348   "^/[^/:]*:"
 349   "Regexp identifying files whose buffers are to be excluded from saving."
 350   :type 'regexp
 351   :group 'desktop)
 352
 353 ;; We skip TAGS files to save time (tags-file-name is saved instead).
 354 (defcustom desktop-modes-not-to-save
 355   '(tags-table-mode)
 356   "List of major modes whose buffers should not be saved."
 357   :type '(repeat symbol)
 358   :group 'desktop)
 359
 360 (defcustom desktop-file-name-format 'absolute
 361   "*Format in which desktop file names should be saved.
 362 Possible values are:
 363    absolute -- Absolute file name.
 364    tilde    -- Relative to ~.
 365    local    -- Relative to directory of desktop file."
 366   :type '(choice (const absolute) (const tilde) (const local))
 367   :group 'desktop
 368   :version "22.1")
 369
 370 (defcustom desktop-restore-eager t
 371   "Number of buffers to restore immediately.
 372 Remaining buffers are restored lazily (when Emacs is idle).
 373 If value is t, all buffers are restored immediately."
 374   :type '(choice (const t) integer)
 375   :group 'desktop
 376   :version "22.1")
 377
 378 (defcustom desktop-lazy-verbose t
 379   "Verbose reporting of lazily created buffers."
 380   :type 'boolean
 381   :group 'desktop
 382   :version "22.1")
 383
 384 (defcustom desktop-lazy-idle-delay 5
 385   "Idle delay before starting to create buffers.
 386 See `desktop-restore-eager'."
 387   :type 'integer
 388   :group 'desktop
 389   :version "22.1")
 390
 391 ;;;###autoload
 392 (defvar desktop-save-buffer nil
 393   "When non-nil, save buffer status in desktop file.
 394 This variable becomes buffer local when set.
 395
 396 If the value is a function, it is called by `desktop-save' with argument
 397 DESKTOP-DIRNAME to obtain auxiliary information to save in the desktop
 398 file along with the state of the buffer for which it was called.
 399
 400 When file names are returned, they should be formatted using the call
 401 \"(desktop-file-name FILE-NAME DESKTOP-DIRNAME)\".
 402
 403 Later, when `desktop-read' evaluates the desktop file, auxiliary information
 404 is passed as the argument DESKTOP-BUFFER-MISC to functions in
 405 `desktop-buffer-mode-handlers'.")
 406 (make-variable-buffer-local 'desktop-save-buffer)
 407 (make-obsolete-variable 'desktop-buffer-modes-to-save
 408                         'desktop-save-buffer "22.1")
 409 (make-obsolete-variable 'desktop-buffer-misc-functions
 410                         'desktop-save-buffer "22.1")
 411
 412 ;;;###autoload
 413 (defvar desktop-buffer-mode-handlers
 414   nil
 415   "Alist of major mode specific functions to restore a desktop buffer.
 416 Functions listed are called by `desktop-create-buffer' when `desktop-read'
 417 evaluates the desktop file.  List elements must have the form
 418
 419    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
 420
 421 Buffers with a major mode not specified here, are restored by the default
 422 handler `desktop-restore-file-buffer'.
 423
 424 Handlers are called with argument list
 425
 426    (DESKTOP-BUFFER-FILE-NAME DESKTOP-BUFFER-NAME DESKTOP-BUFFER-MISC)
 427
 428 Furthermore, they may use the following variables:
 429
 430    desktop-file-version
 431    desktop-buffer-major-mode
 432    desktop-buffer-minor-modes
 433    desktop-buffer-point
 434    desktop-buffer-mark
 435    desktop-buffer-read-only
 436    desktop-buffer-locals
 437
 438 If a handler returns a buffer, then the saved mode settings
 439 and variable values for that buffer are copied into it.
 440
 441 Modules that define a major mode that needs a special handler should contain
 442 code like
 443
 444    (defun foo-restore-desktop-buffer
 445    ...
 446    (add-to-list 'desktop-buffer-mode-handlers
 447                 '(foo-mode . foo-restore-desktop-buffer))
 448
 449 Furthermore the major mode function must be autoloaded.")
 450
 451 ;;;###autoload
 452 (put 'desktop-buffer-mode-handlers 'risky-local-variable t)
 453 (make-obsolete-variable 'desktop-buffer-handlers
 454                         'desktop-buffer-mode-handlers "22.1")
 455
 456 (defcustom desktop-minor-mode-table
 457   '((auto-fill-function auto-fill-mode)
 458     (vc-mode nil)
 459     (vc-dired-mode nil))
 460   "Table mapping minor mode variables to minor mode functions.
 461 Each entry has the form (NAME RESTORE-FUNCTION).
 462 NAME is the name of the buffer-local variable indicating that the minor
 463 mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
 464 RESTORE-FUNCTION nil means don't try to restore the minor mode.
 465 Only minor modes for which the name of the buffer-local variable
 466 and the name of the minor mode function are different have to be added to
 467 this table.  See also `desktop-minor-mode-handlers'."
 468   :type 'sexp
 469   :group 'desktop)
 470
 471 ;;;###autoload
 472 (defvar desktop-minor-mode-handlers
 473   nil
 474   "Alist of functions to restore non-standard minor modes.
 475 Functions are called by `desktop-create-buffer' to restore minor modes.
 476 List elements must have the form
 477
 478    (MINOR-MODE . RESTORE-FUNCTION).
 479
 480 Minor modes not specified here, are restored by the standard minor mode
 481 function.
 482
 483 Handlers are called with argument list
 484
 485    (DESKTOP-BUFFER-LOCALS)
 486
 487 Furthermore, they may use the following variables:
 488
 489    desktop-file-version
 490    desktop-buffer-file-name
 491    desktop-buffer-name
 492    desktop-buffer-major-mode
 493    desktop-buffer-minor-modes
 494    desktop-buffer-point
 495    desktop-buffer-mark
 496    desktop-buffer-read-only
 497    desktop-buffer-misc
 498
 499 When a handler is called, the buffer has been created and the major mode has
 500 been set, but local variables listed in desktop-buffer-locals has not yet been
 501 created and set.
 502
 503 Modules that define a minor mode that needs a special handler should contain
 504 code like
 505
 506    (defun foo-desktop-restore
 507    ...
 508    (add-to-list 'desktop-minor-mode-handlers
 509                 '(foo-mode . foo-desktop-restore))
 510
 511 Furthermore the minor mode function must be autoloaded.
 512
 513 See also `desktop-minor-mode-table'.")
 514
 515 ;;;###autoload
 516 (put 'desktop-minor-mode-handlers 'risky-local-variable t)
 517
 518 ;; ----------------------------------------------------------------------------
 519 (defvar desktop-dirname nil
 520   "The directory in which the desktop file should be saved.")
 521
 522 (defun desktop-full-file-name (&optional dirname)
 523   "Return the full name of the desktop file in DIRNAME.
 524 DIRNAME omitted or nil means use `desktop-dirname'."
 525   (expand-file-name desktop-base-file-name (or dirname desktop-dirname)))
 526
 527 (defun desktop-full-lock-name (&optional dirname)
 528   "Return the full name of the desktop lock file in DIRNAME.
 529 DIRNAME omitted or nil means use `desktop-dirname'."
 530   (expand-file-name desktop-base-lock-name (or dirname desktop-dirname)))
 531
 532 (defconst desktop-header
 533 ";; --------------------------------------------------------------------------
 534 ;; Desktop File for Emacs
 535 ;; --------------------------------------------------------------------------
 536 " "*Header to place in Desktop file.")
 537
 538 (defvar desktop-delay-hook nil
 539   "Hooks run after all buffers are loaded; intended for internal use.")
 540
 541 ;; ----------------------------------------------------------------------------
 542 ;; Desktop file conflict detection
 543 (defvar desktop-file-modtime nil
 544   "When the desktop file was last modified to the knowledge of this Emacs.
 545 Used to detect desktop file conflicts.")
 546
 547 (defun desktop-owner (&optional dirname)
 548   "Return the PID of the Emacs process that owns the desktop file in DIRNAME.
 549 Return nil if no desktop file found or no Emacs process is using it.
 550 DIRNAME omitted or nil means use `desktop-dirname'."
 551   (let (owner)
 552     (and (file-exists-p (desktop-full-lock-name dirname))
 553          (condition-case nil
 554              (with-temp-buffer
 555                (insert-file-contents-literally (desktop-full-lock-name dirname))
 556                (goto-char (point-min))
 557                (setq owner (read (current-buffer)))
 558                (integerp owner))
 559            (error nil))
 560          owner)))
 561
 562 (defun desktop-claim-lock (&optional dirname)
 563   "Record this Emacs process as the owner of the desktop file in DIRNAME.
 564 DIRNAME omitted or nil means use `desktop-dirname'."
 565   (write-region (number-to-string (emacs-pid)) nil
 566                 (desktop-full-lock-name dirname)))
 567
 568 (defun desktop-release-lock (&optional dirname)
 569   "Remove the lock file for the desktop in DIRNAME.
 570 DIRNAME omitted or nil means use `desktop-dirname'."
 571   (let ((file (desktop-full-lock-name dirname)))
 572     (when (file-exists-p file) (delete-file file))))
 573
 574 ;; ----------------------------------------------------------------------------
 575 (defun desktop-truncate (list n)
 576   "Truncate LIST to at most N elements destructively."
 577   (let ((here (nthcdr (1- n) list)))
 578     (when (consp here)
 579       (setcdr here nil))))
 580
 581 ;; ----------------------------------------------------------------------------
 582 ;;;###autoload
 583 (defun desktop-clear ()
 584   "Empty the Desktop.
 585 This kills all buffers except for internal ones and those with names matched by
 586 a regular expression in the list `desktop-clear-preserve-buffers'.
 587 Furthermore, it clears the variables listed in `desktop-globals-to-clear'."
 588   (interactive)
 589   (desktop-lazy-abort)
 590   (dolist (var desktop-globals-to-clear)
 591     (if (symbolp var)
 592         (eval `(setq-default ,var nil))
 593       (eval `(setq-default ,(car var) ,(cdr var)))))
 594   (let ((buffers (buffer-list))
 595         (preserve-regexp (concat "^\\("
 596                                  (mapconcat (lambda (regexp)
 597                                               (concat "\\(" regexp "\\)"))
 598                                             desktop-clear-preserve-buffers
 599                                             "\\|")
 600                                  "\\)$")))
 601     (while buffers
 602       (let ((bufname (buffer-name (car buffers))))
 603          (or
 604            (null bufname)
 605            (string-match preserve-regexp bufname)
 606            ;; Don't kill buffers made for internal purposes.
 607            (and (not (equal bufname "")) (eq (aref bufname 0) ?\s))
 608            (kill-buffer (car buffers))))
 609       (setq buffers (cdr buffers))))
 610   (delete-other-windows))
 611
 612 ;; ----------------------------------------------------------------------------
 613 (add-hook 'kill-emacs-hook 'desktop-kill)
 614
 615 (defun desktop-kill ()
 616   "If `desktop-save-mode' is non-nil, do what `desktop-save' says to do.
 617 If the desktop should be saved and `desktop-dirname'
 618 is nil, ask the user where to save the desktop."
 619   (when (and desktop-save-mode
 620              (let ((exists (file-exists-p (desktop-full-file-name))))
 621                (or (eq desktop-save t)
 622                    (and exists (memq desktop-save '(ask-if-new if-exists)))
 623                    (and
 624                     (or (memq desktop-save '(ask ask-if-new))
 625                         (and exists (eq desktop-save 'ask-if-exists)))
 626                     (y-or-n-p "Save desktop? ")))))
 627     (unless desktop-dirname
 628       (setq desktop-dirname
 629             (file-name-as-directory
 630              (expand-file-name
 631               (read-directory-name "Directory for desktop file: " nil nil t)))))
 632     (condition-case err
 633         (desktop-save desktop-dirname t)
 634       (file-error
 635        (unless (yes-or-no-p "Error while saving the desktop.  Ignore? ")
 636          (signal (car err) (cdr err))))))
 637   ;; If we own it, we don't anymore.
 638   (when (eq (emacs-pid) (desktop-owner)) (desktop-release-lock)))
 639
 640 ;; ----------------------------------------------------------------------------
 641 (defun desktop-list* (&rest args)
 642   (if (null (cdr args))
 643       (car args)
 644     (setq args (nreverse args))
 645     (let ((value (cons (nth 1 args) (car args))))
 646       (setq args (cdr (cdr args)))
 647       (while args
 648         (setq value (cons (car args) value))
 649         (setq args (cdr args)))
 650       value)))
 651
 652 ;; ----------------------------------------------------------------------------
 653 (defun desktop-buffer-info (buffer)
 654   (set-buffer buffer)
 655   (list
 656    ;; basic information
 657    (desktop-file-name (buffer-file-name) desktop-dirname)
 658    (if (bound-and-true-p uniquify-managed)
 659        (uniquify-item-base (car uniquify-managed))
 660      (buffer-name))
 661    major-mode
 662    ;; minor modes
 663    (let (ret)
 664      (mapc
 665       #'(lambda (minor-mode)
 666           (and (boundp minor-mode)
 667                (symbol-value minor-mode)
 668                (let* ((special (assq minor-mode desktop-minor-mode-table))
 669                       (value (cond (special (cadr special))
 670                                    ((functionp minor-mode) minor-mode))))
 671                  (when value (add-to-list 'ret value)))))
 672       (mapcar #'car minor-mode-alist))
 673      ret)
 674    ;; point and mark, and read-only status
 675    (point)
 676    (list (mark t) mark-active)
 677    buffer-read-only
 678    ;; auxiliary information
 679    (when (functionp desktop-save-buffer)
 680      (funcall desktop-save-buffer desktop-dirname))
 681    ;; local variables
 682    (let ((locals desktop-locals-to-save)
 683          (loclist (buffer-local-variables))
 684          (ll))
 685      (while locals
 686        (let ((here (assq (car locals) loclist)))
 687          (if here
 688              (setq ll (cons here ll))
 689            (when (member (car locals) loclist)
 690              (setq ll (cons (car locals) ll)))))
 691        (setq locals (cdr locals)))
 692      ll)))
 693
 694 ;; ----------------------------------------------------------------------------
 695 (defun desktop-internal-v2s (value)
 696   "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
 697 TXT is a string that when read and evaluated yields value.
 698 QUOTE may be `may' (value may be quoted),
 699 `must' (values must be quoted), or nil (value may not be quoted)."
 700   (cond
 701     ((or (numberp value) (null value) (eq t value) (keywordp value))
 702      (cons 'may (prin1-to-string value)))
 703     ((stringp value)
 704      (let ((copy (copy-sequence value)))
 705        (set-text-properties 0 (length copy) nil copy)
 706        ;; Get rid of text properties because we cannot read them
 707        (cons 'may (prin1-to-string copy))))
 708     ((symbolp value)
 709      (cons 'must (prin1-to-string value)))
 710     ((vectorp value)
 711      (let* ((special nil)
 712             (pass1 (mapcar
 713                     (lambda (el)
 714                       (let ((res (desktop-internal-v2s el)))
 715                         (if (null (car res))
 716                             (setq special t))
 717                         res))
 718                     value)))
 719        (if special
 720            (cons nil (concat "(vector "
 721                              (mapconcat (lambda (el)
 722                                           (if (eq (car el) 'must)
 723                                               (concat "'" (cdr el))
 724                                             (cdr el)))
 725                                         pass1
 726                                         " ")
 727                              ")"))
 728          (cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
 729     ((consp value)
 730      (let ((p value)
 731            newlist
 732            use-list*
 733            anynil)
 734        (while (consp p)
 735          (let ((q.txt (desktop-internal-v2s (car p))))
 736            (or anynil (setq anynil (null (car q.txt))))
 737            (setq newlist (cons q.txt newlist)))
 738          (setq p (cdr p)))
 739        (if p
 740            (let ((last (desktop-internal-v2s p)))
 741              (or anynil (setq anynil (null (car last))))
 742              (or anynil
 743                  (setq newlist (cons '(must . ".") newlist)))
 744              (setq use-list* t)
 745              (setq newlist (cons last newlist))))
 746        (setq newlist (nreverse newlist))
 747        (if anynil
 748            (cons nil
 749                  (concat (if use-list* "(desktop-list* "  "(list ")
 750                          (mapconcat (lambda (el)
 751                                       (if (eq (car el) 'must)
 752                                           (concat "'" (cdr el))
 753                                         (cdr el)))
 754                                     newlist
 755                                     " ")
 756                          ")"))
 757          (cons 'must
 758                (concat "(" (mapconcat 'cdr newlist " ") ")")))))
 759     ((subrp value)
 760      (cons nil (concat "(symbol-function '"
 761                        (substring (prin1-to-string value) 7 -1)
 762                        ")")))
 763     ((markerp value)
 764      (let ((pos (prin1-to-string (marker-position value)))
 765            (buf (prin1-to-string (buffer-name (marker-buffer value)))))
 766        (cons nil (concat "(let ((mk (make-marker)))"
 767                          " (add-hook 'desktop-delay-hook"
 768                          " (list 'lambda '() (list 'set-marker mk "
 769                          pos " (get-buffer " buf ")))) mk)"))))
 770     (t                                   ; save as text
 771      (cons 'may "\"Unprintable entity\""))))
 772
 773 ;; ----------------------------------------------------------------------------
 774 (defun desktop-value-to-string (value)
 775   "Convert VALUE to a string that when read evaluates to the same value.
 776 Not all types of values are supported."
 777   (let* ((print-escape-newlines t)
 778          (float-output-format nil)
 779          (quote.txt (desktop-internal-v2s value))
 780          (quote (car quote.txt))
 781          (txt (cdr quote.txt)))
 782     (if (eq quote 'must)
 783         (concat "'" txt)
 784       txt)))
 785
 786 ;; ----------------------------------------------------------------------------
 787 (defun desktop-outvar (varspec)
 788   "Output a setq statement for variable VAR to the desktop file.
 789 The argument VARSPEC may be the variable name VAR (a symbol),
 790 or a cons cell of the form (VAR . MAX-SIZE),
 791 which means to truncate VAR's value to at most MAX-SIZE elements
 792 \(if the value is a list) before saving the value."
 793   (let (var size)
 794     (if (consp varspec)
 795         (setq var (car varspec) size (cdr varspec))
 796       (setq var varspec))
 797     (when (boundp var)
 798       (when (and (integerp size)
 799                  (> size 0)
 800                  (listp (eval var)))
 801         (desktop-truncate (eval var) size))
 802       (insert "(setq "
 803               (symbol-name var)
 804               " "
 805               (desktop-value-to-string (symbol-value var))
 806               ")\n"))))
 807
 808 ;; ----------------------------------------------------------------------------
 809 (defun desktop-save-buffer-p (filename bufname mode &rest dummy)
 810   "Return t if buffer should have its state saved in the desktop file.
 811 FILENAME is the visited file name, BUFNAME is the buffer name, and
 812 MODE is the major mode.
 813 \n\(fn FILENAME BUFNAME MODE)"
 814   (let ((case-fold-search nil))
 815     (and (not (string-match desktop-buffers-not-to-save bufname))
 816          (not (memq mode desktop-modes-not-to-save))
 817          (or (and filename
 818                   (not (string-match desktop-files-not-to-save filename)))
 819              (and (eq mode 'dired-mode)
 820                   (with-current-buffer bufname
 821                     (not (string-match desktop-files-not-to-save
 822                                        default-directory))))
 823              (and (null filename)
 824                   (with-current-buffer bufname desktop-save-buffer))))))
 825
 826 ;; ----------------------------------------------------------------------------
 827 (defun desktop-file-name (filename dirname)
 828   "Convert FILENAME to format specified in `desktop-file-name-format'.
 829 DIRNAME must be the directory in which the desktop file will be saved."
 830   (cond
 831     ((not filename) nil)
 832     ((eq desktop-file-name-format 'tilde)
 833      (let ((relative-name (file-relative-name (expand-file-name filename) "~")))
 834        (cond
 835          ((file-name-absolute-p relative-name) relative-name)
 836          ((string= "./" relative-name) "~/")
 837          ((string= "." relative-name) "~")
 838          (t (concat "~/" relative-name)))))
 839     ((eq desktop-file-name-format 'local) (file-relative-name filename dirname))
 840     (t (expand-file-name filename))))
 841
 842 ;; ----------------------------------------------------------------------------
 843 ;;;###autoload
 844 (defun desktop-save (dirname &optional release)
 845   "Save the desktop in a desktop file.
 846 Parameter DIRNAME specifies where to save the desktop file.
 847 Optional parameter RELEASE says whether we're done with this desktop.
 848 See also `desktop-base-file-name'."
 849   (interactive "DDirectory to save desktop file in: ")
 850   (setq desktop-dirname (file-name-as-directory (expand-file-name dirname)))
 851   (save-excursion
 852     (let ((eager desktop-restore-eager)
 853           (new-modtime (nth 5 (file-attributes (desktop-full-file-name)))))
 854       (when
 855           (or (not new-modtime)         ; nothing to overwrite
 856               (equal desktop-file-modtime new-modtime)
 857               (yes-or-no-p (if desktop-file-modtime
 858                                (if (> (float-time new-modtime) (float-time desktop-file-modtime))
 859                                    "Desktop file is more recent than the one loaded.  Save anyway? "
 860                                  "Desktop file isn't the one loaded.  Overwrite it? ")
 861                              "Current desktop was not loaded from a file.  Overwrite this desktop file? "))
 862               (unless release (error "Desktop file conflict")))
 863
 864         ;; If we're done with it, release the lock.
 865         ;; Otherwise, claim it if it's unclaimed or if we created it.
 866         (if release
 867             (desktop-release-lock)
 868           (unless (and new-modtime (desktop-owner)) (desktop-claim-lock)))
 869
 870         (with-temp-buffer
 871           (insert
 872            ";; -*- mode: emacs-lisp; coding: emacs-mule; -*-\n"
 873            desktop-header
 874            ";; Created " (current-time-string) "\n"
 875            ";; Desktop file format version " desktop-file-version "\n"
 876            ";; Emacs version " emacs-version "\n")
 877           (save-excursion (run-hooks 'desktop-save-hook))
 878           (goto-char (point-max))
 879           (insert "\n;; Global section:\n")
 880           (mapc (function desktop-outvar) desktop-globals-to-save)
 881           (when (memq 'kill-ring desktop-globals-to-save)
 882             (insert
 883              "(setq kill-ring-yank-pointer (nthcdr "
 884              (int-to-string (- (length kill-ring) (length kill-ring-yank-pointer)))
 885              " kill-ring))\n"))
 886
 887           (insert "\n;; Buffer section -- buffers listed in same order as in buffer list:\n")
 888           (dolist (l (mapcar 'desktop-buffer-info (buffer-list)))
 889             (when (apply 'desktop-save-buffer-p l)
 890               (insert "("
 891                       (if (or (not (integerp eager))
 892                               (if (zerop eager)
 893                                   nil
 894                                 (setq eager (1- eager))))
 895                           "desktop-create-buffer"
 896                         "desktop-append-buffer-args")
 897                       " "
 898                       desktop-file-version)
 899               (dolist (e l)
 900                 (insert "\n  " (desktop-value-to-string e)))
 901               (insert ")\n\n")))
 902
 903           (setq default-directory desktop-dirname)
 904           (let ((coding-system-for-write 'emacs-mule))
 905             (write-region (point-min) (point-max) (desktop-full-file-name) nil 'nomessage))
 906           ;; We remember when it was modified (which is presumably just now).
 907           (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name)))))))))
 908
 909 ;; ----------------------------------------------------------------------------
 910 ;;;###autoload
 911 (defun desktop-remove ()
 912   "Delete desktop file in `desktop-dirname'.
 913 This function also sets `desktop-dirname' to nil."
 914   (interactive)
 915   (when desktop-dirname
 916     (let ((filename (desktop-full-file-name)))
 917       (setq desktop-dirname nil)
 918       (when (file-exists-p filename)
 919         (delete-file filename)))))
 920
 921 (defvar desktop-buffer-args-list nil
 922   "List of args for `desktop-create-buffer'.")
 923
 924 (defvar desktop-lazy-timer nil)
 925
 926 ;; ----------------------------------------------------------------------------
 927 ;;;###autoload
 928 (defun desktop-read (&optional dirname)
 929   "Read and process the desktop file in directory DIRNAME.
 930 Look for a desktop file in DIRNAME, or if DIRNAME is omitted, look in
 931 directories listed in `desktop-path'.  If a desktop file is found, it
 932 is processed and `desktop-after-read-hook' is run.  If no desktop file
 933 is found, clear the desktop and run `desktop-no-desktop-file-hook'.
 934 This function is a no-op when Emacs is running in batch mode.
 935 It returns t if a desktop file was loaded, nil otherwise."
 936   (interactive)
 937   (unless noninteractive
 938     (setq desktop-dirname
 939           (file-name-as-directory
 940            (expand-file-name
 941             (or
 942              ;; If DIRNAME is specified, use it.
 943              (and (< 0 (length dirname)) dirname)
 944              ;; Otherwise search desktop file in desktop-path.
 945              (let ((dirs desktop-path))
 946                (while (and dirs
 947                            (not (file-exists-p
 948                                  (desktop-full-file-name (car dirs)))))
 949                  (setq dirs (cdr dirs)))
 950                (and dirs (car dirs)))
 951              ;; If not found and `desktop-path' is non-nil, use its first element.
 952              (and desktop-path (car desktop-path))
 953              ;; Default: Home directory.
 954              "~"))))
 955     (if (file-exists-p (desktop-full-file-name))
 956         ;; Desktop file found, but is it already in use?
 957         (let ((desktop-first-buffer nil)
 958               (desktop-buffer-ok-count 0)
 959               (desktop-buffer-fail-count 0)
 960               (owner (desktop-owner))
 961               ;; Avoid desktop saving during evaluation of desktop buffer.
 962               (desktop-save nil))
 963           (if (and owner
 964                    (memq desktop-load-locked-desktop '(nil ask))
 965                    (or (null desktop-load-locked-desktop)
 966                        (not (y-or-n-p (format "Warning: desktop file appears to be in use by PID %s.\n\
 967 Using it may cause conflicts.  Use it anyway? " owner)))))
 968               (progn
 969                 (let ((default-directory desktop-dirname))
 970                   (run-hooks 'desktop-not-loaded-hook))
 971                 (setq desktop-dirname nil)
 972                 (message "Desktop file in use; not loaded."))
 973             (desktop-lazy-abort)
 974             ;; Evaluate desktop buffer and remember when it was modified.
 975             (load (desktop-full-file-name) t t t)
 976             (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name))))
 977             ;; If it wasn't already, mark it as in-use, to bother other
 978             ;; desktop instances.
 979             (unless owner
 980               (condition-case nil
 981                   (desktop-claim-lock)
 982                 (file-error (message "Couldn't record use of desktop file")
 983                             (sit-for 1))))
 984
 985             ;; `desktop-create-buffer' puts buffers at end of the buffer list.
 986             ;; We want buffers existing prior to evaluating the desktop (and
 987             ;; not reused) to be placed at the end of the buffer list, so we
 988             ;; move them here.
 989             (mapc 'bury-buffer
 990                   (nreverse (cdr (memq desktop-first-buffer (nreverse (buffer-list))))))
 991             (switch-to-buffer (car (buffer-list)))
 992             (run-hooks 'desktop-delay-hook)
 993             (setq desktop-delay-hook nil)
 994             (run-hooks 'desktop-after-read-hook)
 995             (message "Desktop: %d buffer%s restored%s%s."
 996                      desktop-buffer-ok-count
 997                      (if (= 1 desktop-buffer-ok-count) "" "s")
 998                      (if (< 0 desktop-buffer-fail-count)
 999                          (format ", %d failed to restore" desktop-buffer-fail-count)
1000                        "")
1001                      (if desktop-buffer-args-list
1002                          (format ", %d to restore lazily"
1003                                  (length desktop-buffer-args-list))
1004                        ""))
1005             t))
1006       ;; No desktop file found.
1007       (desktop-clear)
1008       (let ((default-directory desktop-dirname))
1009         (run-hooks 'desktop-no-desktop-file-hook))
1010       (message "No desktop file.")
1011       nil)))
1012
1013 ;; ----------------------------------------------------------------------------
1014 ;; Maintained for backward compatibility
1015 ;;;###autoload
1016 (defun desktop-load-default ()
1017   "Load the `default' start-up library manually.
1018 Also inhibit further loading of it."
1019   (unless inhibit-default-init          ; safety check
1020     (load "default" t t)
1021     (setq inhibit-default-init t)))
1022 (make-obsolete 'desktop-load-default
1023                'desktop-save-mode "22.1")
1024
1025 ;; ----------------------------------------------------------------------------
1026 ;;;###autoload
1027 (defun desktop-change-dir (dirname)
1028   "Change to desktop saved in DIRNAME.
1029 Kill the desktop as specified by variables `desktop-save-mode' and
1030 `desktop-save', then clear the desktop and load the desktop file in
1031 directory DIRNAME."
1032   (interactive "DChange to directory: ")
1033   (setq dirname (file-name-as-directory (expand-file-name dirname desktop-dirname)))
1034   (desktop-kill)
1035   (desktop-clear)
1036   (desktop-read dirname))
1037
1038 ;; ----------------------------------------------------------------------------
1039 ;;;###autoload
1040 (defun desktop-save-in-desktop-dir ()
1041   "Save the desktop in directory `desktop-dirname'."
1042   (interactive)
1043   (if desktop-dirname
1044       (desktop-save desktop-dirname)
1045     (call-interactively 'desktop-save))
1046   (message "Desktop saved in %s" desktop-dirname))
1047
1048 ;; ----------------------------------------------------------------------------
1049 ;;;###autoload
1050 (defun desktop-revert ()
1051   "Revert to the last loaded desktop."
1052   (interactive)
1053   (unless desktop-dirname
1054     (error "Unknown desktop directory"))
1055   (unless (file-exists-p (desktop-full-file-name))
1056     (error "No desktop file found"))
1057   (desktop-clear)
1058   (desktop-read desktop-dirname))
1059
1060 (defvar desktop-buffer-major-mode)
1061 (defvar desktop-buffer-locals)
1062 ;; ----------------------------------------------------------------------------
1063 (defun desktop-restore-file-buffer (desktop-buffer-file-name
1064                                     desktop-buffer-name
1065                                     desktop-buffer-misc)
1066   "Restore a file buffer."
1067   (when desktop-buffer-file-name
1068     (if (or (file-exists-p desktop-buffer-file-name)
1069             (let ((msg (format "Desktop: File \"%s\" no longer exists."
1070                                desktop-buffer-file-name)))
1071               (if desktop-missing-file-warning
1072                   (y-or-n-p (concat msg " Re-create buffer? "))
1073                 (message "%s" msg)
1074                 nil)))
1075         (let* ((auto-insert nil) ; Disable auto insertion
1076                (coding-system-for-read
1077                 (or coding-system-for-read
1078                     (cdr (assq 'buffer-file-coding-system
1079                                desktop-buffer-locals))))
1080                (buf (find-file-noselect desktop-buffer-file-name)))
1081           (condition-case nil
1082               (switch-to-buffer buf)
1083             (error (pop-to-buffer buf)))
1084           (and (not (eq major-mode desktop-buffer-major-mode))
1085                (functionp desktop-buffer-major-mode)
1086                (funcall desktop-buffer-major-mode))
1087           buf)
1088       nil)))
1089
1090 (defun desktop-load-file (function)
1091   "Load the file where auto loaded FUNCTION is defined."
1092   (when function
1093     (let ((fcell (and (fboundp function) (symbol-function function))))
1094       (when (and (listp fcell)
1095                  (eq 'autoload (car fcell)))
1096         (load (cadr fcell))))))
1097
1098 ;; ----------------------------------------------------------------------------
1099 ;; Create a buffer, load its file, set its mode, ...;
1100 ;; called from Desktop file only.
1101
1102 ;; Just to silence the byte compiler.
1103
1104 (defvar desktop-first-buffer)          ; Dynamically bound in `desktop-read'
1105
1106 ;; Bound locally in `desktop-read'.
1107 (defvar desktop-buffer-ok-count)
1108 (defvar desktop-buffer-fail-count)
1109
1110 (defun desktop-create-buffer
1111   (desktop-file-version
1112    desktop-buffer-file-name
1113    desktop-buffer-name
1114    desktop-buffer-major-mode
1115    desktop-buffer-minor-modes
1116    desktop-buffer-point
1117    desktop-buffer-mark
1118    desktop-buffer-read-only
1119    desktop-buffer-misc
1120    &optional
1121    desktop-buffer-locals)
1122   ;; To make desktop files with relative file names possible, we cannot
1123   ;; allow `default-directory' to change. Therefore we save current buffer.
1124   (save-current-buffer
1125     ;; Give major mode module a chance to add a handler.
1126     (desktop-load-file desktop-buffer-major-mode)
1127     (let ((buffer-list (buffer-list))
1128           (result
1129            (condition-case err
1130                (funcall (or (cdr (assq desktop-buffer-major-mode
1131                                        desktop-buffer-mode-handlers))
1132                             'desktop-restore-file-buffer)
1133                         desktop-buffer-file-name
1134                         desktop-buffer-name
1135                         desktop-buffer-misc)
1136              (error
1137               (message "Desktop: Can't load buffer %s: %s"
1138                        desktop-buffer-name
1139                        (error-message-string err))
1140               (when desktop-missing-file-warning (sit-for 1))
1141               nil))))
1142       (if (bufferp result)
1143           (setq desktop-buffer-ok-count (1+ desktop-buffer-ok-count))
1144         (setq desktop-buffer-fail-count (1+ desktop-buffer-fail-count))
1145         (setq result nil))
1146       ;; Restore buffer list order with new buffer at end. Don't change
1147       ;; the order for old desktop files (old desktop module behaviour).
1148       (unless (< desktop-file-version 206)
1149         (mapc 'bury-buffer buffer-list)
1150         (when result (bury-buffer result)))
1151       (when result
1152         (unless (or desktop-first-buffer (< desktop-file-version 206))
1153           (setq desktop-first-buffer result))
1154         (set-buffer result)
1155         (unless (equal (buffer-name) desktop-buffer-name)
1156           (rename-buffer desktop-buffer-name t))
1157         ;; minor modes
1158         (cond ((equal '(t) desktop-buffer-minor-modes) ; backwards compatible
1159                (auto-fill-mode 1))
1160               ((equal '(nil) desktop-buffer-minor-modes) ; backwards compatible
1161                (auto-fill-mode 0))
1162               (t
1163                (dolist (minor-mode desktop-buffer-minor-modes)
1164                  ;; Give minor mode module a chance to add a handler.
1165                  (desktop-load-file minor-mode)
1166                  (let ((handler (cdr (assq minor-mode desktop-minor-mode-handlers))))
1167                    (if handler
1168                        (funcall handler desktop-buffer-locals)
1169                      (when (functionp minor-mode)
1170                        (funcall minor-mode 1)))))))
1171         ;; Even though point and mark are non-nil when written by
1172         ;; `desktop-save', they may be modified by handlers wanting to set
1173         ;; point or mark themselves.
1174         (when desktop-buffer-point
1175           (goto-char
1176             (condition-case err
1177                 ;; Evaluate point.  Thus point can be something like
1178                 ;; '(search-forward ...
1179                 (eval desktop-buffer-point)
1180               (error (message "%s" (error-message-string err)) 1))))
1181         (when desktop-buffer-mark
1182           (if (consp desktop-buffer-mark)
1183               (progn
1184                 (set-mark (car desktop-buffer-mark))
1185                 (setq mark-active (car (cdr desktop-buffer-mark))))
1186             (set-mark desktop-buffer-mark)))
1187         ;; Never override file system if the file really is read-only marked.
1188         (when desktop-buffer-read-only (setq buffer-read-only desktop-buffer-read-only))
1189         (while desktop-buffer-locals
1190           (let ((this (car desktop-buffer-locals)))
1191             (if (consp this)
1192                 ;; an entry of this form `(symbol . value)'
1193                 (progn
1194                   (make-local-variable (car this))
1195                   (set (car this) (cdr this)))
1196               ;; an entry of the form `symbol'
1197               (make-local-variable this)
1198               (makunbound this)))
1199           (setq desktop-buffer-locals (cdr desktop-buffer-locals)))))))
1200
1201 ;; ----------------------------------------------------------------------------
1202 ;; Backward compatibility -- update parameters to 205 standards.
1203 (defun desktop-buffer (desktop-buffer-file-name desktop-buffer-name
1204                        desktop-buffer-major-mode
1205                        mim pt mk ro tl fc cfs cr desktop-buffer-misc)
1206   (desktop-create-buffer 205 desktop-buffer-file-name desktop-buffer-name
1207                          desktop-buffer-major-mode (cdr mim) pt mk ro
1208                          desktop-buffer-misc
1209                          (list (cons 'truncate-lines tl)
1210                                (cons 'fill-column fc)
1211                                (cons 'case-fold-search cfs)
1212                                (cons 'case-replace cr)
1213                                (cons 'overwrite-mode (car mim)))))
1214
1215 (defun desktop-append-buffer-args (&rest args)
1216   "Append ARGS at end of `desktop-buffer-args-list'.
1217 ARGS must be an argument list for `desktop-create-buffer'."
1218   (setq desktop-buffer-args-list (nconc desktop-buffer-args-list (list args)))
1219   (unless desktop-lazy-timer
1220     (setq desktop-lazy-timer
1221           (run-with-idle-timer desktop-lazy-idle-delay t 'desktop-idle-create-buffers))))
1222
1223 (defun desktop-lazy-create-buffer ()
1224   "Pop args from `desktop-buffer-args-list', create buffer and bury it."
1225   (when desktop-buffer-args-list
1226     (let* ((remaining (length desktop-buffer-args-list))
1227            (args (pop desktop-buffer-args-list))
1228            (buffer-name (nth 2 args))
1229            (msg (format "Desktop lazily opening %s (%s remaining)..."
1230                             buffer-name remaining)))
1231       (when desktop-lazy-verbose
1232         (message "%s" msg))
1233       (let ((desktop-first-buffer nil)
1234             (desktop-buffer-ok-count 0)
1235             (desktop-buffer-fail-count 0))
1236         (apply 'desktop-create-buffer args)
1237         (run-hooks 'desktop-delay-hook)
1238         (setq desktop-delay-hook nil)
1239         (bury-buffer (get-buffer buffer-name))
1240         (when desktop-lazy-verbose
1241           (message "%s%s" msg (if (> desktop-buffer-ok-count 0) "done" "failed")))))))
1242
1243 (defun desktop-idle-create-buffers ()
1244   "Create buffers until the user does something, then stop.
1245 If there are no buffers left to create, kill the timer."
1246   (let ((repeat 1))
1247     (while (and repeat desktop-buffer-args-list)
1248       (save-window-excursion
1249         (desktop-lazy-create-buffer))
1250       (setq repeat (sit-for 0.2))
1251     (unless desktop-buffer-args-list
1252       (cancel-timer desktop-lazy-timer)
1253       (setq desktop-lazy-timer nil)
1254       (message "Lazy desktop load complete")
1255       (sit-for 3)
1256       (message "")))))
1257
1258 (defun desktop-lazy-complete ()
1259   "Run the desktop load to completion."
1260   (interactive)
1261   (let ((desktop-lazy-verbose t))
1262     (while desktop-buffer-args-list
1263       (save-window-excursion
1264         (desktop-lazy-create-buffer)))
1265     (message "Lazy desktop load complete")))
1266
1267 (defun desktop-lazy-abort ()
1268   "Abort lazy loading of the desktop."
1269   (interactive)
1270   (when desktop-lazy-timer
1271     (cancel-timer desktop-lazy-timer)
1272     (setq desktop-lazy-timer nil))
1273   (when desktop-buffer-args-list
1274     (setq desktop-buffer-args-list nil)
1275     (when (interactive-p)
1276       (message "Lazy desktop load aborted"))))
1277
1278 ;; ----------------------------------------------------------------------------
1279 ;; When `desktop-save-mode' is non-nil and "--no-desktop" is not specified on the
1280 ;; command line, we do the rest of what it takes to use desktop, but do it
1281 ;; after finishing loading the init file.
1282 ;; We cannot use `command-switch-alist' to process "--no-desktop" because these
1283 ;; functions are processed after `after-init-hook'.
1284 (add-hook
1285   'after-init-hook
1286   (lambda ()
1287     (let ((key "--no-desktop"))
1288       (when (member key command-line-args)
1289         (setq command-line-args (delete key command-line-args))
1290         (setq desktop-save-mode nil)))
1291     (when desktop-save-mode (desktop-read))))
1292
1293 (provide 'desktop)
1294
1295 ;; arch-tag: 221907c3-1771-4fd3-9c2e-c6f700c6ede9
1296 ;;; desktop.el ends here