lisp/reposition.el

   1 ;;; reposition.el --- center a Lisp function or comment on the screen
   2
   3 ;; Copyright (C) 1991, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael D. Ernst <mernst@theory.lcs.mit.edu>
   7 ;; Created: Jan 1991
   8 ;; Maintainer: FSF
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Reposition-window makes an entire function definition or comment visible,
  28 ;; or, if it is already visible, places it at the top of the window;
  29 ;; additional invocations toggle the visibility of comments preceding the
  30 ;; code.  For the gory details, see the documentation for reposition-window;
  31 ;; rather than reading that, you may just want to play with it.
  32
  33 ;; This tries pretty hard to do the recentering correctly; the precise
  34 ;; action depends on what the buffer looks like.  If you find a situation
  35 ;; where it doesn't behave well, let me know.  This function is modeled
  36 ;; after one of the same name in ZMACS, but the code is all-new and the
  37 ;; behavior in some situations differs.
  38
  39 ;;; Code:
  40
  41 ;;;###autoload
  42 (defun reposition-window (&optional arg)
  43   "Make the current definition and/or comment visible.
  44 Further invocations move it to the top of the window or toggle the
  45 visibility of comments that precede it.
  46   Point is left unchanged unless prefix ARG is supplied.
  47   If the definition is fully onscreen, it is moved to the top of the
  48 window.  If it is partly offscreen, the window is scrolled to get the
  49 definition (or as much as will fit) onscreen, unless point is in a comment
  50 which is also partly offscreen, in which case the scrolling attempts to get
  51 as much of the comment onscreen as possible.
  52   Initially `reposition-window' attempts to make both the definition and
  53 preceding comments visible.  Further invocations toggle the visibility of
  54 the comment lines.
  55   If ARG is non-nil, point may move in order to make the whole defun
  56 visible (if only part could otherwise be made so), to make the defun line
  57 visible (if point is in code and it could not be made so, or if only
  58 comments, including the first comment line, are visible), or to make the
  59 first comment line visible (if point is in a comment)."
  60   (interactive "P")
  61   (let* (;; (here (save-excursion (beginning-of-line) (point)))
  62          (here (point))
  63          ;; change this name once I've gotten rid of references to ht.
  64          ;; this is actually the number of the last screen line
  65          (ht (- (window-height (selected-window)) 2))
  66          (line (repos-count-screen-lines (window-start) (point)))
  67          (comment-height
  68           ;; The call to max deals with the case of cursor between defuns.
  69           (max 0
  70                (repos-count-screen-lines-signed
  71                 ;; the beginning of the preceding comment
  72                 (save-excursion
  73                   (if (not (eobp)) (forward-char 1))
  74                   (end-of-defun -1)
  75                   ;; Skip whitespace, newlines, and form feeds.
  76                   (if (re-search-forward "[^ \t\n\f]" nil t)
  77                       (backward-char 1))
  78                   (point))
  79                 here)))
  80          (defun-height
  81            (repos-count-screen-lines-signed
  82             (save-excursion
  83               (end-of-defun 1) ; so comments associate with following defuns
  84               (beginning-of-defun 1)
  85               (point))
  86             here))
  87          ;; This must be positive, so don't use the signed version.
  88          (defun-depth (repos-count-screen-lines here
  89                                                 (save-excursion
  90                                                   (end-of-defun 1)
  91                                                   (point))))
  92          (defun-line-onscreen-p
  93            (and (<= defun-height line)
  94                 (<= (- line defun-height) ht))))
  95     (cond ((or (= comment-height line)
  96                (and (= line ht)
  97                     (> comment-height line)
  98                     ;; if defun line offscreen, we should be in case 4
  99                     defun-line-onscreen-p))
 100            ;; Either first comment line is at top of screen or (point at
 101            ;; bottom of screen, defun line onscreen, and first comment line
 102            ;; off top of screen).  That is, it looks like we just did
 103            ;; recenter-definition, trying to fit as much of the comment
 104            ;; onscreen as possible.  Put defun line at top of screen; that
 105            ;; is, show as much code, and as few comments, as possible.
 106
 107            (if (and arg (> defun-depth (1+ ht)))
 108                ;; Can't fit whole defun onscreen without moving point.
 109                (progn (end-of-defun) (beginning-of-defun) (recenter 0))
 110              (recenter (max defun-height 0)))
 111            ;;(repos-debug-macro "1")
 112            )
 113
 114           ((or (= defun-height line)
 115                (= line 0)
 116                (and (< line comment-height)
 117                     (< defun-height 0)))
 118            ;; Defun line or cursor at top of screen, OR cursor in comment
 119            ;; whose first line is offscreen.
 120            ;; Avoid moving definition up even if defun runs offscreen;
 121            ;; we care more about getting the comment onscreen.
 122
 123            (cond ((= line ht)
 124                   ;; cursor on last screen line (and so in a comment)
 125                   (if arg (progn (end-of-defun) (beginning-of-defun)))
 126                   (recenter 0)
 127                   ;;(repos-debug-macro "2a")
 128                   )
 129
 130                  ;; This condition, copied from case 4, may not be quite right
 131
 132                  ((and arg (< ht comment-height))
 133                   ;; Can't get first comment line onscreen.
 134                   ;; Go there and try again.
 135                   (forward-line (- comment-height))
 136                   (beginning-of-line)
 137                   ;; was (reposition-window)
 138                   (recenter 0)
 139                   ;;(repos-debug-macro "2b")
 140                   )
 141                  (t
 142                   (recenter (min ht comment-height))
 143                   ;;(repos-debug-macro "2c")
 144                   ))
 145            ;; (recenter (min ht comment-height))
 146            )
 147
 148           ((and (> (+ line defun-depth -1) ht)
 149                 defun-line-onscreen-p)
 150            ;; Defun runs off the bottom of the screen and the defun line
 151            ;; is onscreen.
 152            ;; Move the defun up.
 153            (recenter (max 0 (1+ (- ht defun-depth)) defun-height))
 154            ;;(repos-debug-macro "3")
 155            )
 156
 157           (t
 158            ;; If on the bottom line and comment start is offscreen
 159            ;; then just move all comments offscreen, or at least as
 160            ;; far as they'll go.
 161
 162            ;; Try to get as much of the comments onscreen as possible.
 163            (if (and arg (< ht comment-height))
 164                ;; Can't get defun line onscreen; go there and try again.
 165                (progn (forward-line (- defun-height))
 166                       (beginning-of-line)
 167                       (reposition-window))
 168              (recenter (min ht comment-height)))
 169            ;;(repos-debug-macro "4")
 170            ))))
 171
 172 ;;; Auxiliary functions
 173
 174 ;; Return number of screen lines between START and END.
 175 (defun repos-count-screen-lines (start end)
 176   (save-excursion
 177     (save-restriction
 178       (narrow-to-region start end)
 179       (goto-char (point-min))
 180       (vertical-motion (- (point-max) (point-min))))))
 181
 182 ;; Return number of screen lines between START and END; returns a negative
 183 ;; number if END precedes START.
 184 (defun repos-count-screen-lines-signed (start end)
 185   (let ((lines (repos-count-screen-lines start end)))
 186     (if (< start end)
 187         lines
 188       (- lines))))
 189
 190 ;; (defmacro repos-debug-macro (case-no)
 191 ;;   `(message (concat "Case " ,case-no ": %s %s %s %s %s")
 192 ;;             ht line comment-height defun-height defun-depth))
 193
 194 (provide 'reposition)
 195
 196 ;; arch-tag: 79487039-3bd7-4ab5-a3e8-ecf3b4919010
 197 ;;; reposition.el ends here