lisp/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon
   2
   3 ;; Copyright (C) 1992, 1993, 1995, 1997, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: moon, lunar phases, calendar, diary
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; See calendar.el.
  29
  30 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  31 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
  32 ;; Willmann-Bell, Inc., 1991.
  33 ;;
  34 ;; WARNING: The calculations will be accurate only to within a few minutes.
  35
  36 ;; The author would be delighted to have an astronomically more sophisticated
  37 ;; person rewrite the code for the lunar calculations in this file!
  38
  39 ;;; Code:
  40
  41 (require 'calendar)
  42 (require 'solar)
  43 (require 'cal-dst)
  44 ;; calendar-astro-to-absolute and v versa are cal-autoloads.
  45 ;;;(require 'cal-julian)
  46
  47 (defcustom lunar-phase-names
  48   '("New Moon" "First Quarter Moon" "Full Moon" "Last Quarter Moon")
  49   "List of names for the lunar phases."
  50   :type '(list
  51           (string :tag "New Moon")
  52           (string :tag "First Quarter Moon")
  53           (string :tag "Full Moon")
  54           (string :tag "Last Quarter Moon"))
  55   :group 'calendar
  56   :version "23.2")
  57
  58 (defun lunar-phase (index)
  59   "Local date and time of lunar phase INDEX.
  60 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  61 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  62 3 last quarter.  Returns a list (DATE TIME PHASE)."
  63   (let* ((phase (mod index 4))
  64          (index (/ index 4.0))
  65          (time (/ index 1236.85))
  66          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
  67                   0.75933
  68                   (* 29.53058868 index) ; FIXME 29.530588853?
  69                   (* 0.0001178 time time)
  70                   (* -0.000000155 time time time)
  71                   (* 0.00033
  72                      (solar-sin-degrees (+ 166.56
  73                                            (* 132.87 time)
  74                                            (* -0.009173 time time))))))
  75          (sun-anomaly (mod
  76                        (+ 359.2242
  77                           (* 29.105356 index)
  78                           (* -0.0000333 time time)
  79                           (* -0.00000347 time time time))
  80                        360.0))
  81          (moon-anomaly (mod
  82                         (+ 306.0253
  83                            (* 385.81691806 index)
  84                            (* 0.0107306 time time)
  85                            (* 0.00001236 time time time))
  86                         360.0))
  87          (moon-lat (mod
  88                     (+ 21.2964
  89                        (* 390.67050646 index)
  90                        (* -0.0016528 time time)
  91                        (* -0.00000239 time time time))
  92                     360.0))
  93          (adjustment
  94           (if (memq phase '(0 2))
  95               (+ (* (- 0.1734 (* 0.000393 time))
  96                     (solar-sin-degrees sun-anomaly))
  97                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
  98                  (* -0.4068 (solar-sin-degrees moon-anomaly))
  99                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 100                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 101                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 102                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 103                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 104                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 105                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 106                  (* -0.0006 (solar-sin-degrees
 107                              (+ (* 2 moon-lat) moon-anomaly)))
 108                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 109                  (* 0.0005 (solar-sin-degrees
 110                             (+ (* 2 moon-anomaly) sun-anomaly))))
 111             (+ (* (- 0.1721 (* 0.0004 time))
 112                   (solar-sin-degrees sun-anomaly))
 113                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 114                (* -0.6280 (solar-sin-degrees moon-anomaly))
 115                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 116                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 117                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 118                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 119                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 120                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 121                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 122                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 123                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 124                (* 0.0003 (solar-sin-degrees
 125                           (+ (* 2 moon-anomaly) sun-anomaly)))
 126                (* 0.0004 (solar-sin-degrees
 127                           (- sun-anomaly (* 2 moon-anomaly))))
 128                (* -0.0003 (solar-sin-degrees
 129                            (+ (* 2 sun-anomaly) moon-anomaly))))))
 130          (adj (+ 0.0028
 131                  (* -0.0004 (solar-cosine-degrees
 132                              sun-anomaly))
 133                  (* 0.0003 (solar-cosine-degrees
 134                             moon-anomaly))))
 135          (adjustment (cond ((= phase 1) (+ adjustment adj))
 136                            ((= phase 2) (- adjustment adj))
 137                            (t adjustment)))
 138          (date (+ date adjustment))
 139          (date (+ date (/ (- calendar-time-zone
 140                              (solar-ephemeris-correction
 141                               (calendar-extract-year
 142                                (calendar-gregorian-from-absolute
 143                                 (truncate date)))))
 144                           60.0 24.0)))
 145          (time (* 24 (- date (truncate date))))
 146          (date (calendar-gregorian-from-absolute (truncate date)))
 147          (adj (dst-adjust-time date time)))
 148     (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
 149
 150 (defconst lunar-cycles-per-year 12.3685 ; 365.25/29.530588853
 151   "Mean number of lunar cycles per 365.25 day year.")
 152
 153 ;; FIXME new-moon index; use in lunar-phase-list implies always below.
 154 (defun lunar-index (date)
 155   "Return the lunar index for Gregorian date DATE.
 156 This is 4 times the approximate number of new moons since 1 Jan 1900.
 157 The factor of 4 allows (mod INDEX 4) to represent the four quarters."
 158   (* 4 (truncate
 159         (* lunar-cycles-per-year
 160            ;; Years since 1900, as a real.
 161            (+ (calendar-extract-year date)
 162               (/ (calendar-day-number date) 366.0)
 163               -1900)))))
 164
 165 (defun lunar-phase-list (month year)
 166   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
 167   (let* ((index (lunar-index (list month 1 year)))
 168          (new-moon (lunar-phase index))
 169          (end-date (let ((end-month month)
 170                          (end-year year))
 171                      (calendar-increment-month end-month end-year 3)
 172                      (list (list end-month 1 end-year))))
 173          ;; Alternative for start-date:
 174 ;;;         (calendar-gregorian-from-absolute
 175 ;;;          (1- (calendar-absolute-from-gregorian (list month 1 year))))
 176          (start-date (progn
 177                        (calendar-increment-month month year -1)
 178                        (list (list month
 179                                    (calendar-last-day-of-month month year)
 180                                    year))))
 181          list)
 182     (while (calendar-date-compare new-moon end-date)
 183       (if (calendar-date-compare start-date new-moon)
 184           (setq list (append list (list new-moon))))
 185       (setq index (1+ index)
 186             new-moon (lunar-phase index)))
 187     list))
 188
 189 (defun lunar-phase-name (phase)
 190   "Name of lunar PHASE.
 191 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 192   (nth phase lunar-phase-names))
 193
 194 (defvar displayed-month)                ; from calendar-generate
 195 (defvar displayed-year)
 196
 197 ;;;###cal-autoload
 198 (defun calendar-lunar-phases (&optional event)
 199   "Create a buffer with the lunar phases for the current calendar window.
 200 If EVENT is non-nil, it's an event indicating the buffer position to
 201 use instead of point."
 202   (interactive (list last-nonmenu-event))
 203   ;; If called from a menu, with the calendar window not selected.
 204   (with-current-buffer
 205       (if event (window-buffer (posn-window (event-start event)))
 206         (current-buffer))
 207     (message "Computing phases of the moon...")
 208     (let ((m1 displayed-month)
 209           (y1 displayed-year)
 210           (m2 displayed-month)
 211           (y2 displayed-year))
 212       (calendar-increment-month m1 y1 -1)
 213       (calendar-increment-month m2 y2 1)
 214       (calendar-in-read-only-buffer lunar-phases-buffer
 215         (calendar-set-mode-line
 216          (if (= y1 y2)
 217              (format "Phases of the Moon from %s to %s, %d%%-"
 218                      (calendar-month-name m1) (calendar-month-name m2) y2)
 219            (format "Phases of the Moon from %s, %d to %s, %d%%-"
 220                    (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 221         (insert
 222          (mapconcat
 223           (lambda (x)
 224             (format "%s: %s %s" (calendar-date-string (car x))
 225                     (lunar-phase-name (nth 2 x))
 226                     (cadr x)))
 227           (lunar-phase-list m1 y1) "\n")))
 228       (message "Computing phases of the moon...done"))))
 229
 230 ;;;###cal-autoload
 231 (define-obsolete-function-alias 'calendar-phases-of-moon
 232   'calendar-lunar-phases "23.1")
 233
 234 ;;;###autoload
 235 (defun lunar-phases (&optional arg)
 236   "Display the quarters of the moon for last month, this month, and next month.
 237 If called with an optional prefix argument ARG, prompts for month and year.
 238 This function is suitable for execution in a .emacs file."
 239   (interactive "P")
 240   (save-excursion
 241     (let* ((date (if arg (calendar-read-date t)
 242                    (calendar-current-date)))
 243            (displayed-month (calendar-extract-month date))
 244            (displayed-year (calendar-extract-year date)))
 245       (calendar-lunar-phases))))
 246
 247 ;;;###autoload
 248 (define-obsolete-function-alias 'phases-of-moon 'lunar-phases "23.1")
 249
 250 (defvar date)
 251
 252 ;; To be called from diary-list-sexp-entries, where DATE is bound.
 253
 254 ;;;###diary-autoload
 255 (defun diary-lunar-phases (&optional mark)
 256   "Moon phases diary entry.
 257 An optional parameter MARK specifies a face or single-character string to
 258 use when highlighting the day in the calendar."
 259   (let* ((index (lunar-index date))
 260          (phase (lunar-phase index)))
 261     (while (calendar-date-compare phase (list date))
 262       (setq index (1+ index)
 263             phase (lunar-phase index)))
 264     (if (calendar-date-equal (car phase) date)
 265         (cons mark (concat (lunar-phase-name (nth 2 phase)) " "
 266                            (cadr phase))))))
 267
 268 ;;;###diary-autoload
 269 (define-obsolete-function-alias 'diary-phases-of-moon
 270   'diary-lunar-phases "23.1")
 271
 272 ;; For the Chinese calendar the calculations for the new moon need to be more
 273 ;; accurate than those above, so we use more terms in the approximation.
 274 (defun lunar-new-moon-time (k)
 275   "Astronomical (Julian) day number of K th new moon."
 276   (let* ((T (/ k 1236.85))
 277          (T2 (* T T))
 278          (T3 (* T T T))
 279          (T4 (* T2 T2))
 280          (JDE (+ 2451550.09765
 281                  (* 29.530588853 k)
 282                  (* 0.0001337 T2)
 283                  (* -0.000000150 T3)
 284                  (* 0.00000000073 T4)))
 285          (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
 286          (sun-anomaly (+ 2.5534
 287                          (* 29.10535669 k)
 288                          (* -0.0000218 T2)
 289                          (* -0.00000011 T3)))
 290          (moon-anomaly (+ 201.5643
 291                           (* 385.81693528 k)
 292                           (* 0.0107438 T2)
 293                           (* 0.00001239 T3)
 294                           (* -0.000000058 T4)))
 295          (moon-argument (+ 160.7108
 296                            (* 390.67050274 k)
 297                            (* -0.0016341 T2)
 298                            (* -0.00000227 T3)
 299                            (* 0.000000011 T4)))
 300          (omega (+ 124.7746
 301                    (* -1.56375580 k)
 302                    (* 0.0020691 T2)
 303                    (* 0.00000215 T3)))
 304          (A1  (+ 299.77 (*  0.107408 k) (* -0.009173 T2)))
 305          (A2  (+ 251.88 (*  0.016321 k)))
 306          (A3  (+ 251.83 (* 26.641886 k)))
 307          (A4  (+ 349.42 (* 36.412478 k)))
 308          (A5  (+  84.66 (* 18.206239 k)))
 309          (A6  (+ 141.74 (* 53.303771 k)))
 310          (A7  (+ 207.14 (*  2.453732 k)))
 311          (A8  (+ 154.84 (*  7.306860 k)))
 312          (A9  (+  34.52 (* 27.261239 k)))
 313          (A10 (+ 207.19 (*  0.121824 k)))
 314          (A11 (+ 291.34 (*  1.844379 k)))
 315          (A12 (+ 161.72 (* 24.198154 k)))
 316          (A13 (+ 239.56 (* 25.513099 k)))
 317          (A14 (+ 331.55 (*  3.592518 k)))
 318          (correction
 319           (+ (* -0.40720   (solar-sin-degrees moon-anomaly))
 320              (*  0.17241 E (solar-sin-degrees sun-anomaly))
 321              (*  0.01608   (solar-sin-degrees (* 2 moon-anomaly)))
 322              (*  0.01039   (solar-sin-degrees (* 2 moon-argument)))
 323              (*  0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
 324              (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
 325              (*  0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
 326              (* -0.00111   (solar-sin-degrees
 327                             (- moon-anomaly (* 2 moon-argument))))
 328              (* -0.00057   (solar-sin-degrees
 329                             (+ moon-anomaly (* 2 moon-argument))))
 330              (*  0.00056 E (solar-sin-degrees
 331                             (+ (* 2 moon-anomaly) sun-anomaly)))
 332              (* -0.00042   (solar-sin-degrees (* 3 moon-anomaly)))
 333              (*  0.00042 E (solar-sin-degrees
 334                             (+ sun-anomaly (* 2 moon-argument))))
 335              (*  0.00038 E (solar-sin-degrees
 336                             (- sun-anomaly (* 2 moon-argument))))
 337              (* -0.00024 E (solar-sin-degrees
 338                             (- (* 2 moon-anomaly) sun-anomaly)))
 339              (* -0.00017   (solar-sin-degrees omega))
 340              (* -0.00007   (solar-sin-degrees
 341                             (+ moon-anomaly (* 2 sun-anomaly))))
 342              (*  0.00004   (solar-sin-degrees
 343                             (- (* 2 moon-anomaly) (* 2 moon-argument))))
 344              (*  0.00004   (solar-sin-degrees (* 3 sun-anomaly)))
 345              (*  0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 346                                                  (* -2 moon-argument))))
 347              (*  0.00003   (solar-sin-degrees
 348                             (+ (* 2 moon-anomaly) (* 2 moon-argument))))
 349              (* -0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 350                                                  (* 2 moon-argument))))
 351              (*  0.00003   (solar-sin-degrees (- moon-anomaly sun-anomaly
 352                                                  (* -2 moon-argument))))
 353              (* -0.00002   (solar-sin-degrees (- moon-anomaly sun-anomaly
 354                                                  (* 2 moon-argument))))
 355              (* -0.00002   (solar-sin-degrees
 356                             (+ (* 3 moon-anomaly) sun-anomaly)))
 357              (*  0.00002   (solar-sin-degrees (* 4 moon-anomaly)))))
 358          (additional
 359           (+ (* 0.000325 (solar-sin-degrees A1))
 360              (* 0.000165 (solar-sin-degrees A2))
 361              (* 0.000164 (solar-sin-degrees A3))
 362              (* 0.000126 (solar-sin-degrees A4))
 363              (* 0.000110 (solar-sin-degrees A5))
 364              (* 0.000062 (solar-sin-degrees A6))
 365              (* 0.000060 (solar-sin-degrees A7))
 366              (* 0.000056 (solar-sin-degrees A8))
 367              (* 0.000047 (solar-sin-degrees A9))
 368              (* 0.000042 (solar-sin-degrees A10))
 369              (* 0.000040 (solar-sin-degrees A11))
 370              (* 0.000037 (solar-sin-degrees A12))
 371              (* 0.000035 (solar-sin-degrees A13))
 372              (* 0.000023 (solar-sin-degrees A14))))
 373          (newJDE (+ JDE correction additional)))
 374     (+ newJDE
 375        (- (solar-ephemeris-correction
 376            (calendar-extract-year
 377             (calendar-gregorian-from-absolute
 378              (floor (calendar-astro-to-absolute newJDE))))))
 379        (/ calendar-time-zone 60.0 24.0))))
 380
 381 (defun lunar-new-moon-on-or-after (d)
 382   "Julian day number of first new moon on or after Julian day number D.
 383 The fractional part is the time of day.
 384
 385 The date and time are local time, including any daylight saving rules,
 386 as governed by the values of `calendar-daylight-savings-starts',
 387 `calendar-daylight-savings-starts-time', `calendar-daylight-savings-ends',
 388 `calendar-daylight-savings-ends-time', `calendar-daylight-time-offset', and
 389 `calendar-time-zone'."
 390   (let* ((date (calendar-gregorian-from-absolute
 391                 (floor (calendar-astro-to-absolute d))))
 392          (year (+ (calendar-extract-year date)
 393                   (/ (calendar-day-number date) 365.25)))
 394          (k (floor (* (- year 2000.0) lunar-cycles-per-year)))
 395          (date (lunar-new-moon-time k))
 396          (a-date (progn
 397                    (while (< date d)
 398                      (setq k (1+ k)
 399                            date (lunar-new-moon-time k)))
 400                    (calendar-astro-to-absolute date)))
 401          (time (* 24 (- a-date (truncate a-date))))
 402          (date (calendar-gregorian-from-absolute (truncate a-date)))
 403          (adj (dst-adjust-time date time)))
 404     (calendar-astro-from-absolute
 405      (+ (calendar-absolute-from-gregorian (car adj))
 406         (/ (cadr adj) 24.0)))))
 407
 408 (provide 'lunar)
 409
 410 ;; arch-tag: 72f0b8a4-7bcc-4a1b-b67a-ff53c4a1d222
 411 ;;; lunar.el ends here