lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.12.03
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Lazy Lock mode is a Font Lock support mode.
  29 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30 ;; properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (setq font-lock-support-mode 'fast-lock-mode)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55 \f
  56 ;; History:
  57 ;;
  58 ;; 0.02--1.00:
  59 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61 ;; 1.00--1.01:
  62 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64 ;; - Moved save-all conditions to `fast-lock-save-cache'
  65 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66 ;; 1.01--2.00: complete rewrite---not worth the space to document
  67 ;; - Changed structure of text properties cache and threw out file mod checks
  68 ;; 2.00--2.01:
  69 ;; - Made `condition-case' forms understand `quit'.
  70 ;; - Made `fast-lock' require `font-lock'
  71 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72 ;; 2.01--3.00:
  73 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75 ;; - Removed `fast-lock-read-others'
  76 ;; - Made `fast-lock-read-cache' ignore cache owner
  77 ;; - Made `fast-lock-save-cache-external' create cache directory
  78 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81 ;; - Package now provides itself
  82 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83 ;; - Lucid: Use `list-faces' for `face-list'
  84 ;; - Lucid: Added `set-text-properties'
  85 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92 ;; 3.02--3.03:
  93 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95 ;; 3.03--3.04:
  96 ;; - Corrected `subrp' test of Lucid code
  97 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 100 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 101 ;; 3.04--3.05:
 102 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 103 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 104 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 105 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 106 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 107 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 108 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 109 ;; - XEmacs: Removed `list-faces' `defalias'
 110 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 111 ;; - Added `fast-lock-submit-bug-report'
 112 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 113 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 114 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 115 ;; - Made `fast-lock-cache-data' output a message if load attempted
 116 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 117 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 118 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 119 ;; - Added `fast-lock-save-events'
 120 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 121 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 122 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 123 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 124 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 125 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 126 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 127 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 128 ;; - Added `fast-lock-after-fontify-buffer'
 129 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 130 ;; - Made `fast-lock-get-face-properties' functions use it
 131 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 132 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 133 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 134 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 135 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 136 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 137 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 138 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 139 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 140 ;; 3.06--3.07:
 141 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 142 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 143 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 144 ;; 3.07--3.08:
 145 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 146 ;; 3.08--3.09:
 147 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 148 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 149 ;; - Added `fast-lock-after-unfontify-buffer'
 150 ;; 3.09--3.10:
 151 ;; - Rewrite for Common Lisp macros
 152 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 153 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 154 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 155 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 156 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 157 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 158 ;; 3.10--3.11:
 159 ;; - Made `fast-lock-get-face-properties' cope with face lists
 160 ;; - Added `fast-lock-verbose'
 161 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 162 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 163 ;; 3.11--3.12:
 164 ;; - Added Custom support (Hrvoje Niksic help)
 165 ;; - Made `save-buffer-state' wrap `inhibit-point-motion-hooks'
 166 ;; - Made `fast-lock-cache-data' simplify calls of `font-lock-compile-keywords'
 167 ;; 3.12--3.13:
 168 ;; - Removed `byte-*' variables from `eval-when-compile' (Erik Naggum hint)
 169 ;; - Changed structure of cache to include `font-lock-syntactic-keywords'
 170 ;; - Made `fast-lock-save-cache-1' save syntactic fontification data
 171 ;; - Made `fast-lock-cache-data' take syntactic fontification data
 172 ;; - Added `fast-lock-get-syntactic-properties'
 173 ;; - Renamed `fast-lock-set-face-properties' to `fast-lock-add-properties'
 174 ;; - Made `fast-lock-add-properties' add syntactic and face fontification data
 175 \f
 176 ;;; Code:
 177
 178 (require 'font-lock)
 179
 180 ;; Make sure fast-lock.el is supported.
 181 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 182     (error "`fast-lock' was written for long file name systems"))
 183
 184 (eval-when-compile
 185   ;;
 186   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 187   (require 'cl)
 188   ;;
 189   ;; We use this to preserve or protect things when modifying text properties.
 190   (defmacro save-buffer-state (varlist &rest body)
 191     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 192     (` (let* ((,@ (append varlist
 193                    '((modified (buffer-modified-p)) (buffer-undo-list t)
 194                      (inhibit-read-only t) (inhibit-point-motion-hooks t)
 195                      before-change-functions after-change-functions
 196                      deactivate-mark buffer-file-name buffer-file-truename))))
 197          (,@ body)
 198          (when (and (not modified) (buffer-modified-p))
 199            (set-buffer-modified-p nil)))))
 200   (put 'save-buffer-state 'lisp-indent-function 1)
 201   ;;
 202   ;; We use this to verify that a face should be saved.
 203   (defmacro fast-lock-save-facep (face)
 204     "Return non-nil if FACE is one of `fast-lock-save-faces'."
 205     (` (or (null fast-lock-save-faces)
 206            (if (symbolp (, face))
 207                (memq (, face) fast-lock-save-faces)
 208              (let ((faces (, face)))
 209                (while (unless (memq (car faces) fast-lock-save-faces)
 210                         (setq faces (cdr faces))))
 211                faces)))))
 212   ;;
 213   ;; We use this for compatibility with a future Emacs.
 214   (or (fboundp 'defcustom)
 215       (defmacro defcustom (symbol value doc &rest args)
 216         (` (defvar (, symbol) (, value) (, doc))))))
 217
 218 ;(defun fast-lock-submit-bug-report ()
 219 ;  "Submit via mail a bug report on fast-lock.el."
 220 ;  (interactive)
 221 ;  (let ((reporter-prompt-for-summary-p t))
 222 ;    (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.12.03"
 223 ;     '(fast-lock-cache-directories fast-lock-minimum-size
 224 ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 225 ;       fast-lock-verbose)
 226 ;     nil nil
 227 ;     (concat "Hi Si.,
 228 ;
 229 ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 230 ;know how to make a clear and unambiguous report.  To reproduce the bug:
 231 ;
 232 ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 233 ;In the `*scratch*' buffer, evaluate:"))))
 234
 235 (defvar fast-lock-mode nil)             ; Whether we are turned on.
 236 (defvar fast-lock-cache-timestamp nil)  ; For saving/reading.
 237 (defvar fast-lock-cache-filename nil)   ; For deleting.
 238 \f
 239 ;; User Variables:
 240
 241 (defcustom fast-lock-minimum-size (* 25 1024)
 242   "*Minimum size of a buffer for cached fontification.
 243 Only buffers more than this can have associated Font Lock cache files saved.
 244 If nil, means cache files are never created.
 245 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 246 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 247  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 248 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 249 for buffers in Rmail mode, and size is irrelevant otherwise."
 250   :type '(choice (const :tag "none" nil)
 251                  (integer :tag "size")
 252                  (repeat :menu-tag "mode specific" :tag "mode specific"
 253                          :value ((t . nil))
 254                          (cons :tag "Instance"
 255                                (radio :tag "Mode"
 256                                       (const :tag "all" t)
 257                                       (symbol :tag "name"))
 258                                (radio :tag "Size"
 259                                       (const :tag "none" nil)
 260                                       (integer :tag "size")))))
 261   :group 'fast-lock)
 262
 263 (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
 264 ; - `internal', keep each file's Font Lock cache file in the same file.
 265 ; - `external', keep each file's Font Lock cache file in the same directory.
 266   "*Directories in which Font Lock cache files are saved and read.
 267 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 268 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 269
 270 An attempt will be made to save or read Font Lock cache files using these items
 271 until one succeeds (i.e., until a readable or writable one is found).  If an
 272 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 273 For example:
 274
 275  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 276    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 277     =>
 278  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 279
 280 would cause a file's current directory to be used if the file is under your
 281 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
 282   :type '(repeat (radio (directory :tag "directory")
 283                         (cons :tag "Matching"
 284                               (regexp :tag "regexp")
 285                               (directory :tag "directory"))))
 286   :group 'fast-lock)
 287
 288 (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
 289   "*Events under which caches will be saved.
 290 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 291 If concurrent editing sessions use the same associated cache file for a file's
 292 buffer, then you should add `save-buffer' to this list."
 293   :type '(set (const :tag "buffer saving" save-buffer)
 294               (const :tag "buffer killing" kill-buffer)
 295               (const :tag "emacs killing" kill-emacs))
 296   :group 'fast-lock)
 297
 298 (defcustom fast-lock-save-others t
 299   "*If non-nil, save Font Lock cache files irrespective of file owner.
 300 If nil, means only buffer files known to be owned by you can have associated
 301 Font Lock cache files saved.  Ownership may be unknown for networked files."
 302   :type 'boolean
 303   :group 'fast-lock)
 304
 305 (defcustom fast-lock-verbose font-lock-verbose
 306   "*If non-nil, means show status messages for cache processing.
 307 If a number, only buffers greater than this size have processing messages."
 308   :type '(choice (const :tag "never" nil)
 309                  (const :tag "always" t)
 310                  (integer :tag "size"))
 311   :group 'fast-lock)
 312
 313 (defvar fast-lock-save-faces
 314   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 315     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 316     font-lock-face-list)
 317   "Faces that will be saved in a Font Lock cache file.
 318 If nil, means information for all faces will be saved.")
 319 \f
 320 ;; User Functions:
 321
 322 ;;;###autoload
 323 (defun fast-lock-mode (&optional arg)
 324   "Toggle Fast Lock mode.
 325 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 326 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 327
 328  (setq font-lock-support-mode 'fast-lock-mode)
 329
 330 If Fast Lock mode is enabled, and the current buffer does not contain any text
 331 properties, any associated Font Lock cache is used if its timestamp matches the
 332 buffer's file, and its `font-lock-keywords' match those that you are using.
 333
 334 Font Lock caches may be saved:
 335 - When you save the file's buffer.
 336 - When you kill an unmodified file's buffer.
 337 - When you exit Emacs, for all unmodified or saved buffers.
 338 Depending on the value of `fast-lock-save-events'.
 339 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 340
 341 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 342
 343 Various methods of control are provided for the Font Lock cache.  In general,
 344 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 345 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 346 `fast-lock-save-others' and `fast-lock-save-faces'."
 347   (interactive "P")
 348   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 349   ;; but many packages temporarily wrap that to nil when doing their own thing.
 350   (set (make-local-variable 'fast-lock-mode)
 351        (and buffer-file-truename
 352             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 353             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 354   (if (and fast-lock-mode (not font-lock-mode))
 355       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 356       (let ((font-lock-support-mode 'fast-lock-mode))
 357         (font-lock-mode t))
 358     ;; Let's get down to business.
 359     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 360     (set (make-local-variable 'fast-lock-cache-filename) nil)
 361     (when (and fast-lock-mode (not font-lock-fontified))
 362       (fast-lock-read-cache))))
 363
 364 (defun fast-lock-read-cache ()
 365   "Read the Font Lock cache for the current buffer.
 366
 367 The following criteria must be met for a Font Lock cache file to be read:
 368 - Fast Lock mode must be turned on in the buffer.
 369 - The buffer must not be modified.
 370 - The buffer's `font-lock-keywords' must match the cache's.
 371 - The buffer file's timestamp must match the cache's.
 372 - Criteria imposed by `fast-lock-cache-directories'.
 373
 374 See `fast-lock-mode'."
 375   (interactive)
 376   (let ((directories fast-lock-cache-directories)
 377         (modified (buffer-modified-p)) (inhibit-read-only t)
 378         (fontified font-lock-fontified))
 379     (set (make-local-variable 'font-lock-fontified) nil)
 380     ;; Keep trying directories until fontification is turned off.
 381     (while (and directories (not font-lock-fontified))
 382       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 383         (condition-case nil
 384             (when directory
 385               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 386               (when (file-readable-p fast-lock-cache-filename)
 387                 (load fast-lock-cache-filename t t t)))
 388           (error nil) (quit nil))
 389         (setq directories (cdr directories))))
 390     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 391     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 392     ;; of `fast-lock-cache-timestamp'.)
 393     (set-buffer-modified-p modified)
 394     (unless font-lock-fontified
 395       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 396
 397 (defun fast-lock-save-cache (&optional buffer)
 398   "Save the Font Lock cache of BUFFER or the current buffer.
 399
 400 The following criteria must be met for a Font Lock cache file to be saved:
 401 - Fast Lock mode must be turned on in the buffer.
 402 - The event must be one of `fast-lock-save-events'.
 403 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 404 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 405 - The buffer must contain at least one `face' text property.
 406 - The buffer must not be modified.
 407 - The buffer file's timestamp must be the same as the file's on disk.
 408 - The on disk file's timestamp must be different than the buffer's cache.
 409 - Criteria imposed by `fast-lock-cache-directories'.
 410
 411 See `fast-lock-mode'."
 412   (interactive)
 413   (save-excursion
 414     (when buffer
 415       (set-buffer buffer))
 416     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 417           (file-timestamp (visited-file-modtime)) (saved nil))
 418       (when (and fast-lock-mode
 419              ;;
 420              ;; "Only save if the buffer matches the file, the file has
 421              ;; changed, and it was changed by the current emacs session."
 422              ;;
 423              ;; Only save if the buffer is not modified,
 424              ;; (i.e., so we don't save for something not on disk)
 425              (not (buffer-modified-p))
 426              ;; and the file's timestamp is the same as the buffer's,
 427              ;; (i.e., someone else hasn't written the file in the meantime)
 428              (verify-visited-file-modtime (current-buffer))
 429              ;; and the file's timestamp is different from the cache's.
 430              ;; (i.e., a save has occurred since the cache was read)
 431              (not (equal fast-lock-cache-timestamp file-timestamp))
 432              ;;
 433              ;; Only save if user's restrictions are satisfied.
 434              (and min-size (>= (buffer-size) min-size))
 435              (or fast-lock-save-others
 436                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 437              ;;
 438              ;; Only save if there are `face' properties to save.
 439              (text-property-not-all (point-min) (point-max) 'face nil))
 440         ;;
 441         ;; Try each directory until we manage to save or the user quits.
 442         (let ((directories fast-lock-cache-directories))
 443           (while (and directories (memq saved '(nil error)))
 444             (let* ((dir (fast-lock-cache-directory (car directories) t))
 445                    (file (and dir (fast-lock-cache-name dir))))
 446               (when (and file (file-writable-p file))
 447                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 448               (setq directories (cdr directories)))))))))
 449
 450 ;;;###autoload
 451 (defun turn-on-fast-lock ()
 452   "Unconditionally turn on Fast Lock mode."
 453   (fast-lock-mode t))
 454 \f
 455 ;;; API Functions:
 456
 457 (defun fast-lock-after-fontify-buffer ()
 458   ;; Delete the Font Lock cache file used to restore fontification, if any.
 459   (when fast-lock-cache-filename
 460     (if (file-writable-p fast-lock-cache-filename)
 461         (delete-file fast-lock-cache-filename)
 462       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 463   ;; Flag so that a cache will be saved later even if the file is never saved.
 464   (setq fast-lock-cache-timestamp nil))
 465
 466 (defalias 'fast-lock-after-unfontify-buffer
 467   'ignore)
 468 \f
 469 ;; Miscellaneous Functions:
 470
 471 (defun fast-lock-save-cache-after-save-file ()
 472   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 473   (when (memq 'save-buffer fast-lock-save-events)
 474     (fast-lock-save-cache)))
 475
 476 (defun fast-lock-save-cache-before-kill-buffer ()
 477   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 478   (when (memq 'kill-buffer fast-lock-save-events)
 479     (fast-lock-save-cache)))
 480
 481 (defun fast-lock-save-caches-before-kill-emacs ()
 482   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 483   (when (memq 'kill-emacs fast-lock-save-events)
 484     (mapcar 'fast-lock-save-cache (buffer-list))))
 485
 486 (defun fast-lock-cache-directory (directory create)
 487   "Return usable directory based on DIRECTORY.
 488 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 489 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 490 See `fast-lock-cache-directories'."
 491   (let ((dir
 492          (cond ((not buffer-file-name)
 493                 ;; Should never be nil, but `crypt++' screws it up.
 494                 nil)
 495                ((stringp directory)
 496                 ;; Just a directory.
 497                 directory)
 498                (t
 499                 ;; A directory iff the file name matches the regexp.
 500                 (let ((bufile (expand-file-name buffer-file-truename))
 501                       (case-fold-search nil))
 502                   (when (save-match-data (string-match (car directory) bufile))
 503                     (cdr directory)))))))
 504     (cond ((not dir)
 505            nil)
 506           ((file-accessible-directory-p dir)
 507            dir)
 508           (create
 509            (condition-case nil
 510                (progn (make-directory dir t) dir)
 511              (error nil))))))
 512
 513 ;; If you are wondering why we only hash if the directory is not ".", rather
 514 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 515 ;; relative cache directories (that are not ".") then it is possible that more
 516 ;; than one file would have the same cache name in that directory, if the luser
 517 ;; made a link from one relative cache directory to another.  (Phew!)
 518 (defun fast-lock-cache-name (directory)
 519   "Return full cache path name using caching DIRECTORY.
 520 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 521 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 522 abbreviated file name, with all `/' characters in the name replaced with `#'
 523 characters, and appended with `.flc'.
 524
 525 If the same file has different cache path names when edited on different
 526 machines, e.g., on one machine the cache file name has the prefix `#home',
 527 perhaps due to automount, try putting in your `~/.emacs' something like:
 528
 529  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 530
 531 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 532
 533 See `fast-lock-cache-directory'."
 534   (if (string-equal directory ".")
 535       (concat buffer-file-name ".flc")
 536     (let* ((bufile (expand-file-name buffer-file-truename))
 537            (chars-alist
 538             (if (eq system-type 'emx)
 539                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 540               '((?/ . (?#)) (?# . (?# ?#)))))
 541            (mapchars
 542             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 543       (concat
 544        (file-name-as-directory (expand-file-name directory))
 545        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 546        ".flc"))))
 547 \f
 548 ;; Font Lock Cache Processing Functions:
 549
 550 ;; The version 3 format of the cache is:
 551 ;;
 552 ;; (fast-lock-cache-data VERSION TIMESTAMP
 553 ;;  font-lock-syntactic-keywords SYNTACTIC-PROPERTIES
 554 ;;  font-lock-keywords FACE-PROPERTIES)
 555
 556 (defun fast-lock-save-cache-1 (file timestamp)
 557   ;; Save the FILE with the TIMESTAMP plus fontification data.
 558   ;; Returns non-nil if a save was attempted to a writable cache file.
 559   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 560         (verbose (if (numberp fast-lock-verbose)
 561                      (> (buffer-size) fast-lock-verbose)
 562                    fast-lock-verbose))
 563         (saved t))
 564     (if verbose (message "Saving %s font lock cache..." (buffer-name)))
 565     (condition-case nil
 566         (save-excursion
 567           (print (list 'fast-lock-cache-data 3
 568                        (list 'quote timestamp)
 569                        (list 'quote font-lock-syntactic-keywords)
 570                        (list 'quote (fast-lock-get-syntactic-properties))
 571                        (list 'quote font-lock-keywords)
 572                        (list 'quote (fast-lock-get-face-properties)))
 573                  tpbuf)
 574           (set-buffer tpbuf)
 575           (write-region (point-min) (point-max) file nil 'quietly)
 576           (setq fast-lock-cache-timestamp timestamp
 577                 fast-lock-cache-filename file))
 578       (error (setq saved 'error)) (quit (setq saved 'quit)))
 579     (kill-buffer tpbuf)
 580     (if verbose (message "Saving %s font lock cache...%s" (buffer-name)
 581                          (cond ((eq saved 'error) "failed")
 582                                ((eq saved 'quit) "aborted")
 583                                (t "done"))))
 584     ;; We return non-nil regardless of whether a failure occurred.
 585     saved))
 586
 587 (defun fast-lock-cache-data (version timestamp
 588                              syntactic-keywords syntactic-properties
 589                              keywords face-properties
 590                              &rest ignored)
 591   ;; Find value of syntactic keywords in case it is a symbol.
 592   (setq font-lock-syntactic-keywords (font-lock-eval-keywords
 593                                       font-lock-syntactic-keywords))
 594   ;; Compile all keywords in case some are and some aren't.
 595   (setq font-lock-syntactic-keywords (font-lock-compile-keywords
 596                                       font-lock-syntactic-keywords)
 597         syntactic-keywords (font-lock-compile-keywords syntactic-keywords)
 598
 599         font-lock-keywords (font-lock-compile-keywords font-lock-keywords)
 600         keywords (font-lock-compile-keywords keywords))
 601   ;; Use the Font Lock cache SYNTACTIC-PROPERTIES and FACE-PROPERTIES if we're
 602   ;; using cache VERSION format 3, the current buffer's file timestamp matches
 603   ;; the TIMESTAMP, the current buffer's `font-lock-syntactic-keywords' are the
 604   ;; same as SYNTACTIC-KEYWORDS, and the current buffer's `font-lock-keywords'
 605   ;; are the same as KEYWORDS.
 606   (let ((buf-timestamp (visited-file-modtime))
 607         (verbose (if (numberp fast-lock-verbose)
 608                      (> (buffer-size) fast-lock-verbose)
 609                    fast-lock-verbose))
 610         (loaded t))
 611     (if (or (/= version 3)
 612             (buffer-modified-p)
 613             (not (equal timestamp buf-timestamp))
 614             (not (equal syntactic-keywords font-lock-syntactic-keywords))
 615             (not (equal keywords font-lock-keywords)))
 616         (setq loaded nil)
 617       (if verbose (message "Loading %s font lock cache..." (buffer-name)))
 618       (condition-case nil
 619           (fast-lock-add-properties syntactic-properties face-properties)
 620         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 621       (if verbose (message "Loading %s font lock cache...%s" (buffer-name)
 622                            (cond ((eq loaded 'error) "failed")
 623                                  ((eq loaded 'quit) "aborted")
 624                                  (t "done")))))
 625     (setq font-lock-fontified (eq loaded t)
 626           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 627 \f
 628 ;; Text Properties Processing Functions:
 629
 630 ;; This is fast, but fails if adjacent characters have different `face' text
 631 ;; properties.  Maybe that's why I dropped it in the first place?
 632 ;(defun fast-lock-get-face-properties ()
 633 ;  "Return a list of `face' text properties in the current buffer.
 634 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 635 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 636 ;  (save-restriction
 637 ;    (widen)
 638 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 639 ;         (limit (point-max)) end properties value cell)
 640 ;      (while start
 641 ;       (setq end (next-single-property-change start 'face nil limit)
 642 ;             value (get-text-property start 'face))
 643 ;       ;; Make, or add to existing, list of regions with same `face'.
 644 ;       (if (setq cell (assq value properties))
 645 ;           (setcdr cell (cons start (cons end (cdr cell))))
 646 ;         (setq properties (cons (list value start end) properties)))
 647 ;       (setq start (next-single-property-change end 'face)))
 648 ;      properties)))
 649
 650 ;; This is slow, but copes if adjacent characters have different `face' text
 651 ;; properties, but fails if they are lists.
 652 ;(defun fast-lock-get-face-properties ()
 653 ;  "Return a list of `face' text properties in the current buffer.
 654 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 655 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 656 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 657 ;  (save-restriction
 658 ;    (widen)
 659 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 660 ;         properties regions face start end)
 661 ;      (while faces
 662 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 663 ;       ;; Make a list of start/end regions with `face' property face.
 664 ;       (while (setq start (text-property-any end limit 'face face))
 665 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 666 ;               regions (cons start (cons end regions))))
 667 ;       ;; Add `face' face's regions, if any, to properties.
 668 ;       (when regions
 669 ;         (push (cons face regions) properties)))
 670 ;      properties)))
 671
 672 (defun fast-lock-get-face-properties ()
 673   "Return a list of `face' text properties in the current buffer.
 674 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 675 where VALUE is a `face' property value and STARTx and ENDx are positions."
 676   (save-restriction
 677     (widen)
 678     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 679           end properties value cell)
 680       (while start
 681         (setq end (next-single-property-change start 'face nil (point-max))
 682               value (get-text-property start 'face))
 683         ;; Make, or add to existing, list of regions with same `face'.
 684         (cond ((setq cell (assoc value properties))
 685                (setcdr cell (cons start (cons end (cdr cell)))))
 686               ((fast-lock-save-facep value)
 687                (push (list value start end) properties)))
 688         (setq start (text-property-not-all end (point-max) 'face nil)))
 689       properties)))
 690
 691 (defun fast-lock-get-syntactic-properties ()
 692   "Return a list of `syntax-table' text properties in the current buffer.
 693 See `fast-lock-get-face-properties'."
 694   (save-restriction
 695     (widen)
 696     (let ((start (text-property-not-all (point-min) (point-max) 'syntax-table
 697                                         nil))
 698           end properties value cell)
 699       (while start
 700         (setq end (next-single-property-change start 'syntax-table nil
 701                                                (point-max))
 702               value (get-text-property start 'syntax-table))
 703         ;; Make, or add to existing, list of regions with same `syntax-table'.
 704         (if (setq cell (assoc value properties))
 705             (setcdr cell (cons start (cons end (cdr cell))))
 706           (push (list value start end) properties))
 707         (setq start (text-property-not-all end (point-max) 'syntax-table nil)))
 708       properties)))
 709
 710 (defun fast-lock-add-properties (syntactic-properties face-properties)
 711   "Add `syntax-table' and `face' text properties to the current buffer.
 712 Any existing `syntax-table' and `face' text properties are removed first.
 713 See `fast-lock-get-face-properties'."
 714   (save-buffer-state (plist regions)
 715     (save-restriction
 716       (widen)
 717       (font-lock-unfontify-region (point-min) (point-max))
 718       ;;
 719       ;; Set the `syntax-table' property for each start/end region.
 720       (while syntactic-properties
 721         (setq plist (list 'syntax-table (car (car syntactic-properties)))
 722               regions (cdr (car syntactic-properties))
 723               syntactic-properties (cdr syntactic-properties))
 724         (while regions
 725           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 726           (setq regions (nthcdr 2 regions))))
 727       ;;
 728       ;; Set the `face' property for each start/end region.
 729       (while face-properties
 730         (setq plist (list 'face (car (car face-properties)))
 731               regions (cdr (car face-properties))
 732               face-properties (cdr face-properties))
 733         (while regions
 734           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 735           (setq regions (nthcdr 2 regions)))))))
 736 \f
 737 ;; Functions for XEmacs:
 738
 739 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 740   ;;
 741   ;; It would be better to use XEmacs' `map-extents' over extents with a
 742   ;; `font-lock' property, but `face' properties are on different extents.
 743   (defun fast-lock-get-face-properties ()
 744     "Return a list of `face' text properties in the current buffer.
 745 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 746 where VALUE is a `face' property value and STARTx and ENDx are positions.
 747 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 748     (save-restriction
 749       (widen)
 750       (let ((properties ()) cell)
 751         (map-extents
 752          (function (lambda (extent ignore)
 753             (let ((value (extent-face extent)))
 754               ;; We're only interested if it's one of `fast-lock-save-faces'.
 755               (when (and value (fast-lock-save-facep value))
 756                 (let ((start (extent-start-position extent))
 757                       (end (extent-end-position extent)))
 758                   ;; Make or add to existing list of regions with the same
 759                   ;; `face' property value.
 760                   (if (setq cell (assoc value properties))
 761                       (setcdr cell (cons start (cons end (cdr cell))))
 762                     (push (list value start end) properties))))
 763               ;; Return nil to keep `map-extents' going.
 764               nil))))
 765         properties)))
 766   ;;
 767   ;; XEmacs does not support the `syntax-table' text property.
 768   (defalias 'fast-lock-get-syntactic-properties
 769     'ignore)
 770   ;;
 771   ;; Make extents just like XEmacs' font-lock.el does.
 772   (defun fast-lock-add-properties (syntactic-properties face-properties)
 773     "Set `face' text properties in the current buffer.
 774 Any existing `face' text properties are removed first.
 775 See `fast-lock-get-face-properties'."
 776     (save-restriction
 777       (widen)
 778       (font-lock-unfontify-region (point-min) (point-max))
 779       ;; Set the `face' property, etc., for each start/end region.
 780       (while face-properties
 781         (let ((face (car (car face-properties)))
 782               (regions (cdr (car face-properties))))
 783           (while regions
 784             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 785             (setq regions (nthcdr 2 regions)))
 786           (setq face-properties (cdr face-properties))))
 787       ;; XEmacs does not support the `syntax-table' text property.
 788       ))
 789   ;;
 790   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 791   (add-hook 'font-lock-after-fontify-buffer-hook
 792             'fast-lock-after-fontify-buffer))
 793
 794 (unless (boundp 'font-lock-syntactic-keywords)
 795   (defvar font-lock-syntactic-keywords nil))
 796
 797 (unless (boundp 'font-lock-inhibit-thing-lock)
 798   (defvar font-lock-inhibit-thing-lock nil))
 799
 800 (unless (fboundp 'font-lock-compile-keywords)
 801   (defalias 'font-lock-compile-keywords 'identity))
 802
 803 (unless (fboundp 'font-lock-eval-keywords)
 804   (defun font-lock-eval-keywords (keywords)
 805     (if (symbolp keywords)
 806         (font-lock-eval-keywords (if (fboundp keywords)
 807                                      (funcall keywords)
 808                                    (eval keywords)))
 809       keywords)))
 810
 811 (unless (fboundp 'font-lock-value-in-major-mode)
 812   (defun font-lock-value-in-major-mode (alist)
 813     (if (consp alist)
 814         (cdr (or (assq major-mode alist) (assq t alist)))
 815       alist)))
 816 \f
 817 ;; Install ourselves:
 818
 819 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 820 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 821 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 822
 823 ;;;###autoload
 824 (when (fboundp 'add-minor-mode)
 825   (defvar fast-lock-mode nil)
 826   (add-minor-mode 'fast-lock-mode nil))
 827 ;;;###dont-autoload
 828 (unless (assq 'fast-lock-mode minor-mode-alist)
 829   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 830
 831 ;; Provide ourselves:
 832
 833 (provide 'fast-lock)
 834
 835 ;;; fast-lock.el ends here