lisp/fringe.el

   1 ;;; fringe.el --- fringe setup and control
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: frames
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains code to initialize the built-in fringe bitmaps
  27 ;; as well as helpful functions for customizing the appearance of the
  28 ;; fringe.
  29
  30 ;; The code is influenced by scroll-bar.el and avoid.el.  The author
  31 ;; gratefully acknowledge comments and suggestions made by Miles
  32 ;; Bader, Eli Zaretski, Richard Stallman, Pavel Janík and others which
  33 ;; improved this package.
  34
  35 ;;; Code:
  36
  37 (defgroup fringe nil
  38   "Window fringes."
  39   :version "22.1"
  40   :group 'frames)
  41
  42 ;; Define the built-in fringe bitmaps and setup default mappings
  43
  44 (when (boundp 'fringe-bitmaps)
  45   (let ((bitmaps '(question-mark
  46                    left-arrow right-arrow up-arrow down-arrow
  47                    left-curly-arrow right-curly-arrow
  48                    left-triangle right-triangle
  49                    top-left-angle top-right-angle
  50                    bottom-left-angle bottom-right-angle
  51                    left-bracket right-bracket
  52                    filled-rectangle hollow-rectangle
  53                    filled-square hollow-square
  54                    vertical-bar horizontal-bar
  55                    empty-line))
  56         (bn 1))
  57     (while bitmaps
  58       (push (car bitmaps) fringe-bitmaps)
  59       (put (car bitmaps) 'fringe bn)
  60       (setq bitmaps (cdr bitmaps)
  61             bn (1+ bn))))
  62
  63   (setq-default fringe-indicator-alist
  64                 '((truncation . (left-arrow right-arrow))
  65                   (continuation . (left-curly-arrow right-curly-arrow))
  66                   (overlay-arrow . right-triangle)
  67                   (up . up-arrow)
  68                   (down . down-arrow)
  69                   (top . (top-left-angle top-right-angle))
  70                   (bottom . (bottom-left-angle bottom-right-angle
  71                              top-right-angle top-left-angle))
  72                   (top-bottom . (left-bracket right-bracket
  73                                  top-right-angle top-left-angle))
  74                   (empty-line . empty-line)
  75                   (unknown . question-mark)))
  76
  77   (setq-default fringe-cursor-alist
  78                 '((box . filled-rectangle)
  79                   (hollow . hollow-rectangle)
  80                   (bar . vertical-bar)
  81                   (hbar . horizontal-bar)
  82                   (hollow-small . hollow-square))))
  83
  84
  85 (defmacro fringe-bitmap-p (symbol)
  86   "Return non-nil if SYMBOL is a fringe bitmap."
  87   `(get ,symbol 'fringe))
  88
  89
  90 ;; Control presence of fringes
  91
  92 (defvar fringe-mode)
  93
  94 (defvar fringe-mode-explicit nil
  95   "Non-nil means `set-fringe-mode' should really do something.
  96 This is nil while loading `fringe.el', and t afterward.")
  97
  98 (defun set-fringe-mode-1 (ignore value)
  99   "Call `set-fringe-mode' with VALUE.
 100 See `fringe-mode' for valid values and their effect.
 101 This is usually invoked when setting `fringe-mode' via customize."
 102   (set-fringe-mode value))
 103
 104 (defun set-fringe-mode (value)
 105   "Set `fringe-mode' to VALUE and put the new value into effect.
 106 See `fringe-mode' for possible values and their effect."
 107   (setq fringe-mode value)
 108
 109   (when fringe-mode-explicit
 110     (modify-all-frames-parameters
 111      (list (cons 'left-fringe (if (consp fringe-mode)
 112                                   (car fringe-mode)
 113                                 fringe-mode))
 114            (cons 'right-fringe (if (consp fringe-mode)
 115                                    (cdr fringe-mode)
 116                                  fringe-mode))))))
 117
 118 ;; For initialization of fringe-mode, take account of changes
 119 ;; made explicitly to default-frame-alist.
 120 (defun fringe-mode-initialize (symbol value)
 121   (let* ((left-pair (assq 'left-fringe default-frame-alist))
 122          (right-pair (assq 'right-fringe default-frame-alist))
 123          (left (cdr left-pair))
 124          (right (cdr right-pair)))
 125     (if (or left-pair right-pair)
 126         ;; If there's something in default-frame-alist for fringes,
 127         ;; don't change it, but reflect that into the value of fringe-mode.
 128         (progn
 129           (setq fringe-mode (cons left right))
 130           (if (equal fringe-mode '(nil . nil))
 131               (setq fringe-mode nil))
 132           (if (equal fringe-mode '(0 . 0))
 133               (setq fringe-mode 0)))
 134       ;; Otherwise impose the user-specified value of fringe-mode.
 135       (custom-initialize-reset symbol value))))
 136
 137 (defcustom fringe-mode nil
 138   "Specify appearance of fringes on all frames.
 139 This variable can be nil (the default) meaning the fringes should have
 140 the default width (8 pixels), it can be an integer value specifying
 141 the width of both left and right fringe (where 0 means no fringe), or
 142 a cons cell where car indicates width of left fringe and cdr indicates
 143 width of right fringe (where again 0 can be used to indicate no
 144 fringe).
 145 To set this variable in a Lisp program, use `set-fringe-mode' to make
 146 it take real effect.
 147 Setting the variable with a customization buffer also takes effect.
 148 If you only want to modify the appearance of the fringe in one frame,
 149 you can use the interactive function `set-fringe-style'."
 150   :type '(choice (const :tag "Default width" nil)
 151                  (const :tag "No fringes" 0)
 152                  (const :tag "Only right" (0 . nil))
 153                  (const :tag "Only left" (nil . 0))
 154                  (const :tag "Half width" (5 . 5))
 155                  (const :tag "Minimal" (1 . 1))
 156                  (integer :tag "Specific width")
 157                  (cons :tag "Different left/right sizes"
 158                        (integer :tag "Left width")
 159                        (integer :tag "Right width")))
 160   :group 'fringe
 161   :require 'fringe
 162   :initialize 'fringe-mode-initialize
 163   :set 'set-fringe-mode-1)
 164
 165 ;; We just set fringe-mode, but that was the default.
 166 ;; If it is set again, that is for real.
 167 (setq fringe-mode-explicit t)
 168
 169 (defun fringe-query-style (&optional all-frames)
 170   "Query user for fringe style.
 171 Returns values suitable for left-fringe and right-fringe frame parameters.
 172 If ALL-FRAMES, the negation of the fringe values in
 173 `default-frame-alist' is used when user enters the empty string.
 174 Otherwise the negation of the fringe value in the currently selected
 175 frame parameter is used."
 176   (let ((mode (intern (completing-read
 177                        (concat
 178                         "Select fringe mode for "
 179                         (if all-frames "all frames" "selected frame")
 180                         " (type ? for list): ")
 181                        '(("none") ("default") ("left-only")
 182                          ("right-only") ("half") ("minimal"))
 183                        nil t))))
 184     (cond ((eq mode 'none) 0)
 185           ((eq mode 'default) nil)
 186           ((eq mode 'left-only) '(nil . 0))
 187           ((eq mode 'right-only) '(0 . nil))
 188           ((eq mode 'half) '(5 . 5))
 189           ((eq mode 'minimal) '(1 . 1))
 190           ((eq mode (intern ""))
 191            (if (eq 0 (cdr (assq 'left-fringe
 192                                 (if all-frames
 193                                     default-frame-alist
 194                                   (frame-parameters (selected-frame))))))
 195                nil
 196              0)))))
 197
 198 (defun fringe-mode (&optional mode)
 199   "Set the default appearance of fringes on all frames.
 200
 201 When called interactively, query the user for MODE.  Valid values
 202 for MODE include `none', `default', `left-only', `right-only',
 203 `minimal' and `half'.
 204
 205 When used in a Lisp program, MODE can be a cons cell where the
 206 integer in car specifies the left fringe width and the integer in
 207 cdr specifies the right fringe width.  MODE can also be a single
 208 integer that specifies both the left and the right fringe width.
 209 If a fringe width specification is nil, that means to use the
 210 default width (8 pixels).  This command may round up the left and
 211 right width specifications to ensure that their sum is a multiple
 212 of the character width of a frame.  It never rounds up a fringe
 213 width of 0.
 214
 215 Fringe widths set by `set-window-fringes' override the default
 216 fringe widths set by this command.  This command applies to all
 217 frames that exist and frames to be created in the future.  If you
 218 want to set the default appearance of fringes on the selected
 219 frame only, see the command `set-fringe-style'."
 220   (interactive (list (fringe-query-style 'all-frames)))
 221   (set-fringe-mode mode))
 222
 223 (defun set-fringe-style (&optional mode)
 224   "Set the default appearance of fringes on the selected frame.
 225
 226 When called interactively, query the user for MODE.  Valid values
 227 for MODE include `none', `default', `left-only', `right-only',
 228 `minimal' and `half'.
 229
 230 When used in a Lisp program, MODE can be a cons cell where the
 231 integer in car specifies the left fringe width and the integer in
 232 cdr specifies the right fringe width.  MODE can also be a single
 233 integer that specifies both the left and the right fringe width.
 234 If a fringe width specification is nil, that means to use the
 235 default width (8 pixels).  This command may round up the left and
 236 right width specifications to ensure that their sum is a multiple
 237 of the character width of a frame.  It never rounds up a fringe
 238 width of 0.
 239
 240 Fringe widths set by `set-window-fringes' override the default
 241 fringe widths set by this command.  If you want to set the
 242 default appearance of fringes on all frames, see the command
 243 `fringe-mode'."
 244   (interactive (list (fringe-query-style)))
 245   (modify-frame-parameters
 246    (selected-frame)
 247    (list (cons 'left-fringe (if (consp mode) (car mode) mode))
 248          (cons 'right-fringe (if (consp mode) (cdr mode) mode)))))
 249
 250 (defsubst fringe-columns (side &optional real)
 251   "Return the width, measured in columns, of the fringe area on SIDE.
 252 If optional argument REAL is non-nil, return a real floating point
 253 number instead of a rounded integer value.
 254 SIDE must be the symbol `left' or `right'."
 255   (funcall (if real '/ 'ceiling)
 256            (or (funcall (if (eq side 'left) 'car 'cadr)
 257                         (window-fringes))
 258                0)
 259            (float (frame-char-width))))
 260
 261 (provide 'fringe)
 262
 263 ;; arch-tag: 6611ef60-0869-47ed-8b93-587ee7d3ff5d
 264 ;;; fringe.el ends here