lisp/timezone.el

   1 ;;; timezone.el --- time zone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1996, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu Umeda
   6 ;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar timezone-world-timezones
  31   '(("PST" .  -800)
  32     ("PDT" .  -700)
  33     ("MST" .  -700)
  34     ("MDT" .  -600)
  35     ("CST" .  -600)
  36     ("CDT" .  -500)
  37     ("EST" .  -500)
  38     ("EDT" .  -400)
  39     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  40     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  41     ("UT"  .  +000)
  42     ("GMT" .  +000)
  43     ("BST" .  +100)
  44     ("MET" .  +100)
  45     ("EET" .  +200)
  46     ("JST" .  +900)
  47     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  48     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  49     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  50     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  51     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  52     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  53     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  54     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  55   "*Time differentials of timezone from GMT in +-HHMM form.
  56 This list is obsolescent, and is present only for backwards compatibility,
  57 because time zone names are ambiguous in practice.
  58 Use `current-time-zone' instead.")
  59
  60 (defvar timezone-months-assoc
  61   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  62     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  63     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  64     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  65   "Alist of first three letters of a month and its numerical representation.")
  66
  67 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  68   "Convert DATE to an arpanet standard date.
  69 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  70 if nil, GMT is assumed.
  71 Optional 3rd argument TIMEZONE specifies a time zone to be represented in;
  72 if nil, the local time zone is assumed."
  73   (let ((new (timezone-fix-time date local timezone)))
  74     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  75                              (timezone-make-time-string
  76                               (aref new 3) (aref new 4) (aref new 5))
  77                              (aref new 6))
  78     ))
  79
  80 (defun timezone-make-date-sortable (date &optional local timezone)
  81   "Convert DATE to a sortable date string.
  82 Optional 2nd argument LOCAL specifies the default local timezone of the DATE;
  83 if nil, GMT is assumed.
  84 Optional 3rd argument TIMEZONE specifies a timezone to be represented in;
  85 if nil, the local time zone is assumed."
  86   (let ((new (timezone-fix-time date local timezone)))
  87     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  88                                  (timezone-make-time-string
  89                                   (aref new 3) (aref new 4) (aref new 5)))
  90     ))
  91
  92 \f
  93 ;;
  94 ;; Parsers and Constructors of Date and Time
  95 ;;
  96
  97 (defun timezone-make-arpa-date (year month day time &optional timezone)
  98   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  99 Optional argument TIMEZONE specifies a time zone."
 100   (let ((zone
 101          (if (listp timezone)
 102              (let* ((m (timezone-zone-to-minute timezone))
 103                     (absm (if (< m 0) (- m) m)))
 104                (format "%c%02d%02d"
 105                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 106            timezone)))
 107     (format "%02d %s %04d %s %s"
 108             day
 109             (capitalize (car (rassq month timezone-months-assoc)))
 110             year
 111             time
 112             zone)))
 113
 114 (defun timezone-make-sortable-date (year month day time)
 115   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 116   (format "%4d%02d%02d%s"
 117           year month day time))
 118
 119 (defun timezone-make-time-string (hour minute second)
 120   "Make time string from HOUR, MINUTE, and SECOND."
 121   (format "%02d:%02d:%02d" hour minute second))
 122
 123 (defun timezone-parse-date (date)
 124   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 125 Two-digit dates are `windowed'.  Those <69 have 2000 added; otherwise 1900
 126 is added.  Three-digit dates have 1900 added.
 127 TIMEZONE is nil for DATEs without a zone field.
 128
 129 Understands the following styles:
 130  (1) 14 Apr 89 03:20[:12] [GMT]
 131  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 132  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 133  (4) 6 May 1992 1641-JST (Wednesday)
 134  (5) 22-AUG-1993 10:59:12.82
 135  (6) Thu, 11 Apr 16:17:12 91 [MET]
 136  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]
 137  (8) 1996-06-24 21:13:12 [GMT]
 138  (9) 1996-06-24 21:13-ZONE"
 139  ;; Get rid of any text properties.
 140   (and (stringp date)
 141        (or (text-properties-at 0 date)
 142            (next-property-change 0 date))
 143        (setq date (copy-sequence date))
 144        (set-text-properties 0 (length date) nil date))
 145   (let ((date (or date ""))
 146         (year nil)
 147         (month nil)
 148         (day nil)
 149         (time nil)
 150         (zone nil))                     ;This may be nil.
 151     (cond ((string-match
 152             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 153            ;; Styles: (1) and (2) with timezone and buggy timezone
 154            ;; This is most common in mail and news,
 155            ;; so it is worth trying first.
 156            (setq year 3 month 2 day 1 time 4 zone 5))
 157           ((string-match
 158             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 159            ;; Styles: (1) and (2) without timezone
 160            (setq year 3 month 2 day 1 time 4 zone nil))
 161           ((string-match
 162             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 163            ;; Styles: (6) and (7) without timezone
 164            (setq year 6 month 3 day 2 time 4 zone nil))
 165           ((string-match
 166             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 167            ;; Styles: (6) and (7) with timezone and buggy timezone
 168            (setq year 6 month 3 day 2 time 4 zone 7))
 169           ((string-match
 170             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 171            ;; Styles: (3) without timezone
 172            (setq year 4 month 1 day 2 time 3 zone nil))
 173           ((string-match
 174             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 175            ;; Styles: (3) with timezone
 176            (setq year 5 month 1 day 2 time 3 zone 4))
 177           ((string-match
 178             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 179            ;; Styles: (4) with timezone
 180            (setq year 3 month 2 day 1 time 4 zone 5))
 181           ((string-match
 182             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 183            ;; Styles: (5) with timezone.
 184            (setq year 3 month 2 day 1 time 4 zone 6))
 185           ((string-match
 186             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)?" date)
 187            ;; Styles: (5) without timezone.
 188            (setq year 3 month 2 day 1 time 4 zone nil))
 189           ((string-match
 190             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)" date)
 191            ;; Styles: (8) with timezone.
 192            (setq year 1 month 2 day 3 time 4 zone 5))
 193           ((string-match
 194             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+\\)[ \t]+\\([-+a-zA-Z0-9:]+\\)" date)
 195            ;; Styles: (8) with timezone with a colon in it.
 196            (setq year 1 month 2 day 3 time 4 zone 5))
 197           ((string-match
 198             "\\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)" date)
 199            ;; Styles: (8) without timezone.
 200            (setq year 1 month 2 day 3 time 4 zone nil))
 201           )
 202     (when year
 203       (setq year (match-string year date))
 204       ;; Guess ambiguous years.  Assume years < 69 don't predate the
 205       ;; Unix Epoch, so are 2000+.  Three-digit years are assumed to
 206       ;; be relative to 1900.
 207       (if (< (length year) 4)
 208           (let ((y (string-to-int year)))
 209             (if (< y 69)
 210                 (setq y (+ y 100)))
 211             (setq year (int-to-string (+ 1900 y)))))
 212       (setq month
 213             (if (= (aref date (+ (match-beginning month) 2)) ?-)
 214                 ;; Handle numeric months, spanning exactly two digits.
 215                 (substring date
 216                            (match-beginning month)
 217                            (+ (match-beginning month) 2))
 218               (let* ((string (substring date
 219                                         (match-beginning month)
 220                                         (+ (match-beginning month) 3)))
 221                      (monthnum
 222                       (cdr (assoc (upcase string) timezone-months-assoc))))
 223                 (if monthnum
 224                     (int-to-string monthnum)))))
 225       (setq day (match-string day date))
 226       (setq time (match-string time date)))
 227     (if zone (setq zone (match-string zone date)))
 228     ;; Return a vector.
 229     (if (and year month)
 230         (vector year month day time zone)
 231       (vector "0" "0" "0" "0" nil))))
 232
 233 (defun timezone-parse-time (time)
 234   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 235 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 236   (let ((time (or time ""))
 237         hour minute second)
 238     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 239            ;; HH:MM:SS
 240            (setq hour 1 minute 2 second 3))
 241           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 242            ;; HH:MM
 243            (setq hour 1 minute 2 second nil))
 244           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 245            ;; HHMMSS
 246            (setq hour 1 minute 2 second 3))
 247           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 248            ;; HHMM
 249            (setq hour 1 minute 2 second nil))
 250           )
 251     ;; Return [hour minute second]
 252     (vector
 253      (if hour (match-string hour time) "0")
 254      (if minute (match-string minute time) "0")
 255      (if second (match-string second time) "0"))))
 256
 257 \f
 258 ;; Miscellaneous
 259
 260 (defun timezone-zone-to-minute (timezone)
 261   "Translate TIMEZONE to an integer minute offset from GMT.
 262 TIMEZONE can be a cons cell containing the output of current-time-zone,
 263 or an integer of the form +-HHMM, or a time zone name."
 264   (cond
 265      ((consp timezone)
 266       (/ (car timezone) 60))
 267      (timezone
 268       (progn
 269         (setq timezone
 270               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 271                   ;; +900
 272                   timezone))
 273         (if (stringp timezone)
 274             (setq timezone (string-to-int timezone)))
 275         ;; Taking account of minute in timezone.
 276         ;; HHMM -> MM
 277         (let* ((abszone (abs timezone))
 278                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 279           (if (< timezone 0) (- minutes) minutes))))
 280      (t 0)))
 281
 282 (defun timezone-time-from-absolute (date seconds)
 283   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 284 Return a list suitable as an argument to current-time-zone,
 285 or nil if the date cannot be thus represented.
 286 DATE is the number of days elapsed since the (imaginary)
 287 Gregorian date Sunday, December 31, 1 BC."
 288   (let* ((current-time-origin 719163)
 289             ;; (timezone-absolute-from-gregorian 1 1 1970)
 290          (days (- date current-time-origin))
 291          (seconds-per-day (float 86400))
 292          (seconds (+ seconds (* days seconds-per-day)))
 293          (current-time-arithmetic-base (float 65536))
 294          (hi (floor (/ seconds current-time-arithmetic-base)))
 295          (hibase (* hi current-time-arithmetic-base))
 296          (lo (floor (- seconds hibase))))
 297      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 298           (cons hi lo))))
 299
 300 (defun timezone-time-zone-from-absolute (date seconds)
 301   "Compute the local time zone for DATE at time SECONDS after midnight.
 302 Return a list in the same format as current-time-zone's result,
 303 or nil if the local time zone could not be computed.
 304 DATE is the number of days elapsed since the (imaginary)
 305 Gregorian date Sunday, December 31, 1 BC."
 306    (and (fboundp 'current-time-zone)
 307         (let ((utc-time (timezone-time-from-absolute date seconds)))
 308           (and utc-time
 309                (let ((zone (current-time-zone utc-time)))
 310                  (and (car zone) zone))))))
 311
 312 (defun timezone-fix-time (date local timezone)
 313   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 314 If LOCAL is nil, it is assumed to be GMT.
 315 If TIMEZONE is nil, use the local time zone."
 316   (let* ((date   (timezone-parse-date date))
 317          (year   (string-to-int (aref date 0)))
 318          (year   (cond ((< year 69)
 319                         (+ year 2000))
 320                        ((< year 100)
 321                         (+ year 1900))
 322                        ((< year 1000)   ; possible 3-digit years.
 323                         (+ year 1900))
 324                        (t year)))
 325          (month  (string-to-int (aref date 1)))
 326          (day    (string-to-int (aref date 2)))
 327          (time   (timezone-parse-time (aref date 3)))
 328          (hour   (string-to-int (aref time 0)))
 329          (minute (string-to-int (aref time 1)))
 330          (second (string-to-int (aref time 2)))
 331          (local  (or (aref date 4) local)) ;Use original if defined
 332          (timezone
 333           (or timezone
 334               (timezone-time-zone-from-absolute
 335                (timezone-absolute-from-gregorian month day year)
 336                (+ second (* 60 (+ minute (* 60 hour)))))))
 337          (diff   (- (timezone-zone-to-minute timezone)
 338                     (timezone-zone-to-minute local)))
 339          (minute (+ minute diff))
 340          (hour-fix (floor minute 60)))
 341     (setq hour (+ hour hour-fix))
 342     (setq minute (- minute (* 60 hour-fix)))
 343     ;; HOUR may be larger than 24 or smaller than 0.
 344     (cond ((<= 24 hour)                 ;24 -> 00
 345            (setq hour (- hour 24))
 346            (setq day  (1+ day))
 347            (when (< (timezone-last-day-of-month month year) day)
 348              (setq month (1+ month))
 349              (setq day 1)
 350              (when (< 12 month)
 351                (setq month 1)
 352                (setq year (1+ year)))))
 353           ((> 0 hour)
 354            (setq hour (+ hour 24))
 355            (setq day  (1- day))
 356            (when (> 1 day)
 357              (setq month (1- month))
 358              (when (> 1 month)
 359                (setq month 12)
 360                (setq year (1- year)))
 361              (setq day (timezone-last-day-of-month month year)))))
 362     (vector year month day hour minute second timezone)))
 363
 364 ;; Partly copied from Calendar program by Edward M. Reingold.
 365 ;; Thanks a lot.
 366
 367 (defun timezone-last-day-of-month (month year)
 368   "The last day in MONTH during YEAR."
 369   (if (and (= month 2) (timezone-leap-year-p year))
 370       29
 371     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 372
 373 (defun timezone-leap-year-p (year)
 374   "Returns t if YEAR is a Gregorian leap year."
 375   (or (and (zerop  (% year 4))
 376            (not (zerop (% year 100))))
 377       (zerop (% year 400))))
 378
 379 (defun timezone-day-number (month day year)
 380   "Return the day number within the year of the date month/day/year."
 381   (let ((day-of-year (+ day (* 31 (1- month)))))
 382     (if (> month 2)
 383         (progn
 384           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 385           (if (timezone-leap-year-p year)
 386               (setq day-of-year (1+ day-of-year)))))
 387     day-of-year))
 388
 389 (defun timezone-absolute-from-gregorian (month day year)
 390   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 391 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 392   (+ (timezone-day-number month day year);; Days this year
 393      (* 365 (1- year));;        + Days in prior years
 394      (/ (1- year) 4);;          + Julian leap years
 395      (- (/ (1- year) 100));;    - century years
 396      (/ (1- year) 400)));;      + Gregorian leap years
 397
 398 (provide 'timezone)
 399
 400 ;;; arch-tag: e23d5bc6-f32d-48ba-8996-323e9d654b3f
 401 ;;; timezone.el ends here