lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001, 2002
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 If optional argument FRAME is nil or omitted, use the selected frame."
 229   (check-face face)
 230   (get face 'face))
 231
 232
 233 (defun face-equal (face1 face2 &optional frame)
 234   "Non-nil if faces FACE1 and FACE2 are equal.
 235 Faces are considered equal if all their attributes are equal.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame."
 239   (internal-lisp-face-equal-p face1 face2 frame))
 240
 241
 242 (defun face-differs-from-default-p (face &optional frame)
 243   "Non-nil if FACE displays differently from the default face.
 244 If the optional argument FRAME is given, report on face FACE in that frame.
 245 If FRAME is t, report on the defaults for face FACE (for new frames).
 246 If FRAME is omitted or nil, use the selected frame.
 247 A face is considered to be ``the same'' as the default face if it is
 248 actually specified in the same way (equal attributes) or if it is
 249 fully-unspecified, and thus inherits the attributes of any face it
 250 is displayed on top of."
 251   (cond ((eq frame t) (setq frame nil))
 252         ((null frame) (setq frame (selected-frame))))
 253   (let* ((v1 (internal-lisp-face-p face frame))
 254          (n (if v1 (length v1) 0))
 255          (v2 (internal-lisp-face-p 'default frame))
 256          (i 1))
 257     (unless v1
 258       (error "Not a face: %S" face))
 259     (while (and (< i n)
 260                 (or (eq 'unspecified (aref v1 i))
 261                     (equal (aref v1 i) (aref v2 i))))
 262       (setq i (1+ i)))
 263     (< i n)))
 264
 265
 266 (defun face-nontrivial-p (face &optional frame)
 267   "True if face FACE has some non-nil attribute.
 268 If the optional argument FRAME is given, report on face FACE in that frame.
 269 If FRAME is t, report on the defaults for face FACE (for new frames).
 270 If FRAME is omitted or nil, use the selected frame."
 271   (not (internal-lisp-face-empty-p face frame)))
 272
 273
 274 \f
 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 276 ;;; Setting face attributes from X resources.
 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 278
 279 (defcustom face-x-resources
 280   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 281     (:width (".attributeWidth" . "Face.AttributeWidth"))
 282     (:height (".attributeHeight" . "Face.AttributeHeight"))
 283     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 284     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 285     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 286     (:background (".attributeBackground" . "Face.AttributeBackground"))
 287     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 288     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 289     (:box (".attributeBox" . "Face.AttributeBox"))
 290     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 291     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 292     (:stipple
 293      (".attributeStipple" . "Face.AttributeStipple")
 294      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 295     (:bold (".attributeBold" . "Face.AttributeBold"))
 296     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 297     (:font (".attributeFont" . "Face.AttributeFont"))
 298     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 299   "*List of X resources and classes for face attributes.
 300 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 301 the name of a face attribute, and each ENTRY is a cons of the form
 302 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 303 X resource class for the attribute."
 304   :type '(repeat (cons symbol (repeat (cons string string))))
 305   :group 'faces)
 306
 307
 308 (defun set-face-attribute-from-resource (face attribute resource class frame)
 309   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 310 Value is the attribute value specified by the resource, or nil
 311 if not present.  This function displays a message if the resource
 312 specifies an invalid attribute."
 313   (let* ((face-name (face-name face))
 314          (value (internal-face-x-get-resource (concat face-name resource)
 315                                               class frame)))
 316     (when value
 317       (condition-case ()
 318           (internal-set-lisp-face-attribute-from-resource
 319            face attribute (downcase value) frame)
 320         (error
 321          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 322                   face-name frame attribute value))))
 323     value))
 324
 325
 326 (defun set-face-attributes-from-resources (face frame)
 327   "Set attributes of FACE from X resources for FRAME."
 328   (when (memq (framep frame) '(x w32 mac))
 329     (dolist (definition face-x-resources)
 330       (let ((attribute (car definition)))
 331         (dolist (entry (cdr definition))
 332           (set-face-attribute-from-resource face attribute (car entry)
 333                                             (cdr entry) frame))))))
 334
 335
 336 (defun make-face-x-resource-internal (face &optional frame)
 337   "Fill frame-local FACE on FRAME from X resources.
 338 FRAME nil or not specified means do it for all frames."
 339   (if (null frame)
 340       (dolist (frame (frame-list))
 341         (set-face-attributes-from-resources face frame))
 342     (set-face-attributes-from-resources face frame)))
 343
 344
 345 \f
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347 ;;; Retrieving face attributes.
 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 349
 350 (defun face-name (face)
 351   "Return the name of face FACE."
 352   (symbol-name (check-face face)))
 353
 354
 355 (defun face-attribute (face attribute &optional frame inherit)
 356   "Return the value of FACE's ATTRIBUTE on FRAME.
 357 If the optional argument FRAME is given, report on face FACE in that frame.
 358 If FRAME is t, report on the defaults for face FACE (for new frames).
 359 If FRAME is omitted or nil, use the selected frame.
 360
 361 If INHERIT is nil, only attributes directly defined by FACE are considered,
 362   so the return value may be `unspecified', or a relative value.
 363 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 364   faces specified by its `:inherit' attribute; however the return value
 365   may still be `unspecified' or relative.
 366 If INHERIT is a face or a list of faces, then the result is further merged
 367   with that face (or faces), until it becomes specified and absolute.
 368
 369 To ensure that the return value is always specified and absolute, use a
 370 value of `default' for INHERIT; this will resolve any unspecified or
 371 relative values by merging with the `default' face (which is always
 372 completely specified)."
 373   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 374     (when (and inherit (face-attribute-relative-p attribute value))
 375       ;; VALUE is relative, so merge with inherited faces
 376       (let ((inh-from (face-attribute face :inherit frame)))
 377         (unless (or (null inh-from) (eq inh-from 'unspecified))
 378           (setq value
 379                 (face-attribute-merged-with attribute value inh-from frame)))))
 380     (when (and inherit
 381                (not (eq inherit t))
 382                (face-attribute-relative-p attribute value))
 383       ;; We should merge with INHERIT as well
 384       (setq value (face-attribute-merged-with attribute value inherit frame)))
 385     value))
 386
 387 (defun face-attribute-merged-with (attribute value faces &optional frame)
 388   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 389 FACES may be either a single face or a list of faces.
 390 \[This is an internal function]"
 391   (cond ((not (face-attribute-relative-p attribute value))
 392          value)
 393         ((null faces)
 394          value)
 395         ((consp faces)
 396          (face-attribute-merged-with
 397           attribute
 398           (face-attribute-merged-with attribute value (car faces) frame)
 399           (cdr faces)
 400           frame))
 401         (t
 402          (merge-face-attribute attribute
 403                                value
 404                                (face-attribute faces attribute frame t)))))
 405
 406
 407 (defmacro face-attribute-specified-or (value &rest body)
 408   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 409   (let ((temp (make-symbol "value")))
 410     `(let ((,temp ,value))
 411        (if (not (eq ,temp 'unspecified))
 412            ,temp
 413          ,@body))))
 414
 415 (defun face-foreground (face &optional frame inherit)
 416   "Return the foreground color name of FACE, or nil if unspecified.
 417 If the optional argument FRAME is given, report on face FACE in that frame.
 418 If FRAME is t, report on the defaults for face FACE (for new frames).
 419 If FRAME is omitted or nil, use the selected frame.
 420
 421 If INHERIT is nil, only a foreground color directly defined by FACE is
 422   considered, so the return value may be nil.
 423 If INHERIT is t, and FACE doesn't define a foreground color, then any
 424   foreground color that FACE inherits through its `:inherit' attribute
 425   is considered as well; however the return value may still be nil.
 426 If INHERIT is a face or a list of faces, then it is used to try to
 427   resolve an unspecified foreground color.
 428
 429 To ensure that a valid color is always returned, use a value of
 430 `default' for INHERIT; this will resolve any unspecified values by
 431 merging with the `default' face (which is always completely specified)."
 432   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 433                                nil))
 434
 435 (defun face-background (face &optional frame inherit)
 436   "Return the background color name of FACE, or nil if unspecified.
 437 If the optional argument FRAME is given, report on face FACE in that frame.
 438 If FRAME is t, report on the defaults for face FACE (for new frames).
 439 If FRAME is omitted or nil, use the selected frame.
 440
 441 If INHERIT is nil, only a background color directly defined by FACE is
 442   considered, so the return value may be nil.
 443 If INHERIT is t, and FACE doesn't define a background color, then any
 444   background color that FACE inherits through its `:inherit' attribute
 445   is considered as well; however the return value may still be nil.
 446 If INHERIT is a face or a list of faces, then it is used to try to
 447   resolve an unspecified background color.
 448
 449 To ensure that a valid color is always returned, use a value of
 450 `default' for INHERIT; this will resolve any unspecified values by
 451 merging with the `default' face (which is always completely specified)."
 452   (face-attribute-specified-or (face-attribute face :background frame inherit)
 453                                nil))
 454
 455 (defun face-stipple (face &optional frame inherit)
 456  "Return the stipple pixmap name of FACE, or nil if unspecified.
 457 If the optional argument FRAME is given, report on face FACE in that frame.
 458 If FRAME is t, report on the defaults for face FACE (for new frames).
 459 If FRAME is omitted or nil, use the selected frame.
 460
 461 If INHERIT is nil, only a stipple directly defined by FACE is
 462   considered, so the return value may be nil.
 463 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 464   that FACE inherits through its `:inherit' attribute is considered as
 465   well; however the return value may still be nil.
 466 If INHERIT is a face or a list of faces, then it is used to try to
 467   resolve an unspecified stipple.
 468
 469 To ensure that a valid stipple or nil is always returned, use a value of
 470 `default' for INHERIT; this will resolve any unspecified values by merging
 471 with the `default' face (which is always completely specified)."
 472   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 473                                nil))
 474
 475
 476 (defalias 'face-background-pixmap 'face-stipple)
 477
 478
 479 (defun face-underline-p (face &optional frame)
 480  "Return non-nil if FACE is underlined.
 481 If the optional argument FRAME is given, report on face FACE in that frame.
 482 If FRAME is t, report on the defaults for face FACE (for new frames).
 483 If FRAME is omitted or nil, use the selected frame."
 484  (eq (face-attribute face :underline frame) t))
 485
 486
 487 (defun face-inverse-video-p (face &optional frame)
 488  "Return non-nil if FACE is in inverse video on FRAME.
 489 If the optional argument FRAME is given, report on face FACE in that frame.
 490 If FRAME is t, report on the defaults for face FACE (for new frames).
 491 If FRAME is omitted or nil, use the selected frame."
 492  (eq (face-attribute face :inverse-video frame) t))
 493
 494
 495 (defun face-bold-p (face &optional frame)
 496   "Return non-nil if the font of FACE is bold on FRAME.
 497 If the optional argument FRAME is given, report on face FACE in that frame.
 498 If FRAME is t, report on the defaults for face FACE (for new frames).
 499 If FRAME is omitted or nil, use the selected frame.
 500 Use `face-attribute' for finer control."
 501   (let ((bold (face-attribute face :weight frame)))
 502     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 503
 504
 505 (defun face-italic-p (face &optional frame)
 506   "Return non-nil if the font of FACE is italic on FRAME.
 507 If the optional argument FRAME is given, report on face FACE in that frame.
 508 If FRAME is t, report on the defaults for face FACE (for new frames).
 509 If FRAME is omitted or nil, use the selected frame.
 510 Use `face-attribute' for finer control."
 511   (let ((italic (face-attribute face :slant frame)))
 512     (memq italic '(italic oblique))))
 513
 514
 515 \f
 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 517 ;;; Face documentation.
 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 519
 520 (defun face-documentation (face)
 521   "Get the documentation string for FACE."
 522   (get face 'face-documentation))
 523
 524
 525 (defun set-face-documentation (face string)
 526   "Set the documentation string for FACE to STRING."
 527   ;; Perhaps the text should go in DOC.
 528   (put face 'face-documentation (purecopy string)))
 529
 530
 531 (defalias 'face-doc-string 'face-documentation)
 532 (defalias 'set-face-doc-string 'set-face-documentation)
 533
 534
 535 \f
 536 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 537 ;; Setting face attributes.
 538 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 539
 540
 541 (defun set-face-attribute (face frame &rest args)
 542   "Set attributes of FACE on FRAME from ARGS.
 543
 544 FRAME nil means change attributes on all frames.  FRAME t means change
 545 the default for new frames (this is done automatically each time an
 546 attribute is changed on all frames).
 547
 548 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 549 face attribute name.  All attributes can be set to `unspecified';
 550 this fact is not further mentioned below.
 551
 552 The following attributes are recognized:
 553
 554 `:family'
 555
 556 VALUE must be a string specifying the font family, e.g. ``courier'',
 557 or a fontset alias name.  If a font family is specified, wild-cards `*'
 558 and `?' are allowed.
 559
 560 `:width'
 561
 562 VALUE specifies the relative proportionate width of the font to use.
 563 It must be one of the symbols `ultra-condensed', `extra-condensed',
 564 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 565 `extra-expanded', or `ultra-expanded'.
 566
 567 `:height'
 568
 569 VALUE must be either an integer specifying the height of the font to use
 570 in 1/10 pt, a floating point number specifying the amount by which to
 571 scale any underlying face, or a function, which is called with the old
 572 height (from the underlying face), and should return the new height.
 573
 574 `:weight'
 575
 576 VALUE specifies the weight of the font to use.  It must be one of the
 577 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 578 `semi-light', `light', `extra-light', `ultra-light'.
 579
 580 `:slant'
 581
 582 VALUE specifies the slant of the font to use.  It must be one of the
 583 symbols `italic', `oblique', `normal', `reverse-italic', or
 584 `reverse-oblique'.
 585
 586 `:foreground', `:background'
 587
 588 VALUE must be a color name, a string.
 589
 590 `:underline'
 591
 592 VALUE specifies whether characters in FACE should be underlined.  If
 593 VALUE is t, underline with foreground color of the face.  If VALUE is
 594 a string, underline with that color.  If VALUE is nil, explicitly
 595 don't underline.
 596
 597 `:overline'
 598
 599 VALUE specifies whether characters in FACE should be overlined.  If
 600 VALUE is t, overline with foreground color of the face.  If VALUE is a
 601 string, overline with that color.  If VALUE is nil, explicitly don't
 602 overline.
 603
 604 `:strike-through'
 605
 606 VALUE specifies whether characters in FACE should be drawn with a line
 607 striking through them.  If VALUE is t, use the foreground color of the
 608 face.  If VALUE is a string, strike-through with that color.  If VALUE
 609 is nil, explicitly don't strike through.
 610
 611 `:box'
 612
 613 VALUE specifies whether characters in FACE should have a box drawn
 614 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 615 VALUE is t, draw a box with lines of width 1 in the foreground color
 616 of the face.  If VALUE is a string, the string must be a color name,
 617 and the box is drawn in that color with a line width of 1.  Otherwise,
 618 VALUE must be a property list of the form `(:line-width WIDTH
 619 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 620 the property list, a default value will be used for the value, as
 621 specified below.  WIDTH specifies the width of the lines to draw; it
 622 defaults to 1.  If WIDTH is negative, the absolute value is the width
 623 of the lines, and draw top/bottom lines inside the characters area,
 624 not around it.  COLOR is the name of the color to draw in, default is
 625 the foreground color of the face for simple boxes, and the background
 626 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 627 should be draw.  If STYLE is `released-button', draw a box looking
 628 like a released 3D button.  If STYLE is `pressed-button' draw a box
 629 that appears like a pressed button.  If STYLE is nil, the default if
 630 the property list doesn't contain a style specification, draw a 2D
 631 box.
 632
 633 `:inverse-video'
 634
 635 VALUE specifies whether characters in FACE should be displayed in
 636 inverse video.  VALUE must be one of t or nil.
 637
 638 `:stipple'
 639
 640 If VALUE is a string, it must be the name of a file of pixmap data.
 641 The directories listed in the `x-bitmap-file-path' variable are
 642 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 643 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 644 is a string containing the raw bits of the bitmap.  VALUE nil means
 645 explicitly don't use a stipple pattern.
 646
 647 For convenience, attributes `:family', `:width', `:height', `:weight',
 648 and `:slant' may also be set in one step from an X font name:
 649
 650 `:font'
 651
 652 Set font-related face attributes from VALUE.  VALUE must be a valid
 653 XLFD font name.  If it is a font name pattern, the first matching font
 654 will be used.
 655
 656 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 657 be used to specify that a bold or italic font should be used.  VALUE
 658 must be t or nil in that case.  A value of `unspecified' is not allowed.
 659
 660 `:inherit'
 661
 662 VALUE is the name of a face from which to inherit attributes, or a list
 663 of face names.  Attributes from inherited faces are merged into the face
 664 like an underlying face would be, with higher priority than underlying faces."
 665   (let ((where (if (null frame) 0 frame)))
 666     (setq args (purecopy args))
 667     ;; If we set the new-frame defaults, this face is modified outside Custom.
 668     (if (memq where '(0 t))
 669         (put face 'face-modified t))
 670     (while args
 671       (internal-set-lisp-face-attribute face (car args)
 672                                         (purecopy (cadr args))
 673                                         where)
 674       (setq args (cdr (cdr args))))))
 675
 676
 677 (defun make-face-bold (face &optional frame noerror)
 678   "Make the font of FACE be bold, if possible.
 679 FRAME nil or not specified means change face on all frames.
 680 Argument NOERROR is ignored and retained for compatibility.
 681 Use `set-face-attribute' for finer control of the font weight."
 682   (interactive (list (read-face-name "Make which face bold")))
 683   (set-face-attribute face frame :weight 'bold))
 684
 685
 686 (defun make-face-unbold (face &optional frame noerror)
 687   "Make the font of FACE be non-bold, if possible.
 688 FRAME nil or not specified means change face on all frames.
 689 Argument NOERROR is ignored and retained for compatibility."
 690   (interactive (list (read-face-name "Make which face non-bold")))
 691   (set-face-attribute face frame :weight 'normal))
 692
 693
 694 (defun make-face-italic (face &optional frame noerror)
 695   "Make the font of FACE be italic, if possible.
 696 FRAME nil or not specified means change face on all frames.
 697 Argument NOERROR is ignored and retained for compatibility.
 698 Use `set-face-attribute' for finer control of the font slant."
 699   (interactive (list (read-face-name "Make which face italic")))
 700   (set-face-attribute face frame :slant 'italic))
 701
 702
 703 (defun make-face-unitalic (face &optional frame noerror)
 704   "Make the font of FACE be non-italic, if possible.
 705 FRAME nil or not specified means change face on all frames.
 706 Argument NOERROR is ignored and retained for compatibility."
 707   (interactive (list (read-face-name "Make which face non-italic")))
 708   (set-face-attribute face frame :slant 'normal))
 709
 710
 711 (defun make-face-bold-italic (face &optional frame noerror)
 712   "Make the font of FACE be bold and italic, if possible.
 713 FRAME nil or not specified means change face on all frames.
 714 Argument NOERROR is ignored and retained for compatibility.
 715 Use `set-face-attribute' for finer control of font weight and slant."
 716   (interactive (list (read-face-name "Make which face bold-italic")))
 717   (set-face-attribute face frame :weight 'bold :slant 'italic))
 718
 719
 720 (defun set-face-font (face font &optional frame)
 721   "Change font-related attributes of FACE to those of FONT (a string).
 722 FRAME nil or not specified means change face on all frames.
 723 This sets the attributes `:family', `:width', `:height', `:weight',
 724 and `:slant'.  When called interactively, prompt for the face and font."
 725   (interactive (read-face-and-attribute :font))
 726   (set-face-attribute face frame :font font))
 727
 728
 729 ;; Implementation note: Emulating gray background colors with a
 730 ;; stipple pattern is now part of the face realization process, and is
 731 ;; done in C depending on the frame on which the face is realized.
 732
 733 (defun set-face-background (face color &optional frame)
 734   "Change the background color of face FACE to COLOR (a string).
 735 FRAME nil or not specified means change face on all frames.
 736 When called interactively, prompt for the face and color."
 737   (interactive (read-face-and-attribute :background))
 738   (set-face-attribute face frame :background (or color 'unspecified)))
 739
 740
 741 (defun set-face-foreground (face color &optional frame)
 742   "Change the foreground color of face FACE to COLOR (a string).
 743 FRAME nil or not specified means change face on all frames.
 744 When called interactively, prompt for the face and color."
 745   (interactive (read-face-and-attribute :foreground))
 746   (set-face-attribute face frame :foreground (or color 'unspecified)))
 747
 748
 749 (defun set-face-stipple (face stipple &optional frame)
 750   "Change the stipple pixmap of face FACE to STIPPLE.
 751 FRAME nil or not specified means change face on all frames.
 752 STIPPLE should be a string, the name of a file of pixmap data.
 753 The directories listed in the `x-bitmap-file-path' variable are searched.
 754
 755 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 756 where WIDTH and HEIGHT are the size in pixels,
 757 and DATA is a string, containing the raw bits of the bitmap."
 758   (interactive (read-face-and-attribute :stipple))
 759   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 760
 761
 762 (defun set-face-underline (face underline &optional frame)
 763   "Specify whether face FACE is underlined.
 764 UNDERLINE nil means FACE explicitly doesn't underline.
 765 UNDERLINE non-nil means FACE explicitly does underlining
 766 with the same of the foreground color.
 767 If UNDERLINE is a string, underline with the color named UNDERLINE.
 768 FRAME nil or not specified means change face on all frames.
 769 Use `set-face-attribute' to ``unspecify'' underlining."
 770   (interactive
 771    (let ((list (read-face-and-attribute :underline)))
 772      (list (car list) (eq (car (cdr list)) t))))
 773   (set-face-attribute face frame :underline underline))
 774
 775
 776 (defun set-face-underline-p (face underline-p &optional frame)
 777   "Specify whether face FACE is underlined.
 778 UNDERLINE-P nil means FACE explicitly doesn't underline.
 779 UNDERLINE-P non-nil means FACE explicitly does underlining.
 780 FRAME nil or not specified means change face on all frames.
 781 Use `set-face-attribute' to ``unspecify'' underlining."
 782   (interactive
 783    (let ((list (read-face-and-attribute :underline)))
 784      (list (car list) (eq (car (cdr list)) t))))
 785   (set-face-attribute face frame :underline underline-p))
 786
 787
 788 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 789   "Specify whether face FACE is in inverse video.
 790 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 791 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 792 FRAME nil or not specified means change face on all frames.
 793 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 794   (interactive
 795    (let ((list (read-face-and-attribute :inverse-video)))
 796      (list (car list) (eq (car (cdr list)) t))))
 797   (set-face-attribute face frame :inverse-video inverse-video-p))
 798
 799
 800 (defun set-face-bold-p (face bold-p &optional frame)
 801   "Specify whether face FACE is bold.
 802 BOLD-P non-nil means FACE should explicitly display bold.
 803 BOLD-P nil means FACE should explicitly display non-bold.
 804 FRAME nil or not specified means change face on all frames.
 805 Use `set-face-attribute' or `modify-face' for finer control."
 806   (if (null bold-p)
 807       (make-face-unbold face frame)
 808     (make-face-bold face frame)))
 809
 810
 811 (defun set-face-italic-p (face italic-p &optional frame)
 812   "Specify whether face FACE is italic.
 813 ITALIC-P non-nil means FACE should explicitly display italic.
 814 ITALIC-P nil means FACE should explicitly display non-italic.
 815 FRAME nil or not specified means change face on all frames.
 816 Use `set-face-attribute' or `modify-face' for finer control."
 817   (if (null italic-p)
 818       (make-face-unitalic face frame)
 819     (make-face-italic face frame)))
 820
 821
 822 (defalias 'set-face-background-pixmap 'set-face-stipple)
 823
 824
 825 (defun invert-face (face &optional frame)
 826   "Swap the foreground and background colors of FACE.
 827 If FRAME is omitted or nil, it means change face on all frames.
 828 If FACE specifies neither foreground nor background color,
 829 set its foreground and background to the background and foreground
 830 of the default face.  Value is FACE."
 831   (interactive (list (read-face-name "Invert face")))
 832   (let ((fg (face-attribute face :foreground frame))
 833         (bg (face-attribute face :background frame)))
 834     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 835         (set-face-attribute face frame :foreground bg :background fg)
 836       (set-face-attribute face frame
 837                           :foreground
 838                           (face-attribute 'default :background frame)
 839                           :background
 840                           (face-attribute 'default :foreground frame))))
 841   face)
 842
 843 \f
 844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 845 ;;; Interactively modifying faces.
 846 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 847
 848 (defun read-face-name (prompt &optional string-describing-default multiple)
 849   "Read a face, defaulting to the face or faces on the char after point.
 850 If it has a `read-face-name' property, that overrides the `face' property.
 851 PROMPT describes what you will do with the face (don't end in a space).
 852 STRING-DESCRIBING-DEFAULT describes what default you will use
 853 if this function returns nil.
 854 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 855 Otherwise, return a single face."
 856   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 857                       (get-char-property (point) 'face)))
 858         faces)
 859     ;; Make a list of the named faces that the `face' property uses.
 860     (if (listp faceprop)
 861         (dolist (f faceprop)
 862           (if (symbolp f)
 863               (push f faces)))
 864       (if (symbolp faceprop)
 865           (setq faces (list faceprop))))
 866     ;; If there are none, try to get a face name from the buffer.
 867     (if (and (null faces)
 868              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 869         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 870
 871     ;; If we only want one, and the default is more than one,
 872     ;; discard the unwanted ones now.
 873     (unless multiple
 874       (if faces
 875           (setq faces (list (car faces)))))
 876     (let* ((input
 877             ;; Read the input.
 878             (completing-read
 879              (if (or faces string-describing-default)
 880                  (format "%s (default %s): " prompt
 881                          (if faces (mapconcat 'symbol-name faces ", ")
 882                            string-describing-default))
 883                (format "%s: " prompt))
 884              obarray 'custom-facep t))
 885            ;; Canonicalize the output.
 886            (output
 887             (if (equal input "")
 888                 faces
 889               (if (stringp input)
 890                   (list (intern input))
 891                 input))))
 892       ;; Return either a list of faces or just one face.
 893       (if multiple
 894           output
 895         (car output)))))
 896
 897
 898 (defun face-valid-attribute-values (attribute &optional frame)
 899   "Return valid values for face attribute ATTRIBUTE.
 900 The optional argument FRAME is used to determine available fonts
 901 and colors.  If it is nil or not specified, the selected frame is
 902 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 903 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 904 an integer value."
 905   (let ((valid
 906          (case attribute
 907            (:family
 908             (if window-system
 909                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 910                         (x-font-family-list))
 911               ;; Only one font on TTYs.
 912               (list (cons "default" "default"))))
 913            ((:width :weight :slant :inverse-video)
 914             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 915                     (internal-lisp-face-attribute-values attribute)))
 916            ((:underline :overline :strike-through :box)
 917             (if window-system
 918                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 919                                (internal-lisp-face-attribute-values attribute))
 920                        (mapcar #'(lambda (c) (cons c c))
 921                                (x-defined-colors frame)))
 922               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 923                       (internal-lisp-face-attribute-values attribute))))
 924            ((:foreground :background)
 925             (mapcar #'(lambda (c) (cons c c))
 926                     (defined-colors frame)))
 927            ((:height)
 928             'integerp)
 929            (:stipple
 930             (and (memq window-system '(x w32 mac))
 931                  (mapcar #'list
 932                          (apply #'nconc
 933                                 (mapcar (lambda (dir)
 934                                           (and (file-readable-p dir)
 935                                                (file-directory-p dir)
 936                                                (directory-files dir)))
 937                                         x-bitmap-file-path)))))
 938            (:inherit
 939             (cons '("none" . nil)
 940                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 941                           (face-list))))
 942            (t
 943             (error "Internal error")))))
 944     (if (and (listp valid) (not (memq attribute '(:inherit))))
 945         (nconc (list (cons "unspecified" 'unspecified)) valid)
 946       valid)))
 947
 948
 949 (defvar face-attribute-name-alist
 950   '((:family . "font family")
 951     (:width . "character set width")
 952     (:height . "height in 1/10 pt")
 953     (:weight . "weight")
 954     (:slant . "slant")
 955     (:underline . "underline")
 956     (:overline . "overline")
 957     (:strike-through . "strike-through")
 958     (:box . "box")
 959     (:inverse-video . "inverse-video display")
 960     (:foreground . "foreground color")
 961     (:background . "background color")
 962     (:stipple . "background stipple")
 963     (:inherit . "inheritance"))
 964   "An alist of descriptive names for face attributes.
 965 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 966 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 967 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 968
 969
 970 (defun face-descriptive-attribute-name (attribute)
 971   "Return a descriptive name for ATTRIBUTE."
 972   (cdr (assq attribute face-attribute-name-alist)))
 973
 974
 975 (defun face-read-string (face default name &optional completion-alist)
 976   "Interactively read a face attribute string value.
 977 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 978 default string to return if no new value is entered.  NAME is a
 979 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 980 alist of valid values, if non-nil.
 981
 982 Entering nothing accepts the default string DEFAULT.
 983 Value is the new attribute value."
 984   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 985   ;; each word in a string separately).
 986   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 987   (let* ((completion-ignore-case t)
 988          (value (completing-read
 989                  (if default
 990                      (format "%s for face `%s' (default %s): "
 991                              name face default)
 992                    (format "%s for face `%s': " name face))
 993                  completion-alist)))
 994     (if (equal value "") default value)))
 995
 996
 997 (defun face-read-integer (face default name)
 998   "Interactively read an integer face attribute value.
 999 FACE is the face whose attribute is read.  DEFAULT is the default
1000 value to return if no new value is entered.  NAME is a descriptive
1001 name of the attribute for prompting.  Value is the new attribute value."
1002   (let ((new-value
1003          (face-read-string face
1004                            (format "%s" default)
1005                            name
1006                            (list (cons "unspecified" 'unspecified)))))
1007     (cond ((equal new-value "unspecified")
1008            'unspecified)
1009           ((member new-value '("unspecified-fg" "unspecified-bg"))
1010            new-value)
1011           (t
1012            (string-to-int new-value)))))
1013
1014
1015 (defun read-face-attribute (face attribute &optional frame)
1016   "Interactively read a new value for FACE's ATTRIBUTE.
1017 Optional argument FRAME nil or unspecified means read an attribute value
1018 of a global face.  Value is the new attribute value."
1019   (let* ((old-value (face-attribute face attribute frame))
1020          (attribute-name (face-descriptive-attribute-name attribute))
1021          (valid (face-valid-attribute-values attribute frame))
1022          new-value)
1023     ;; Represent complex attribute values as strings by printing them
1024     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1025     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1026     ;; SHADOW)'.
1027     (when (and (or (eq attribute :stipple)
1028                    (eq attribute :box))
1029                (or (consp old-value)
1030                    (vectorp old-value)))
1031       (setq old-value (prin1-to-string old-value)))
1032     (cond ((listp valid)
1033            (let ((default
1034                    (or (car (rassoc old-value valid))
1035                        (format "%s" old-value))))
1036              (setq new-value
1037                    (face-read-string face default attribute-name valid))
1038              (if (equal new-value default)
1039                  ;; Nothing changed, so don't bother with all the stuff
1040                  ;; below.  In particular, this avoids a non-tty color
1041                  ;; from being canonicalized for a tty when the user
1042                  ;; just uses the default.
1043                  (setq new-value old-value)
1044                ;; Terminal frames can support colors that don't appear
1045                ;; explicitly in VALID, using color approximation code
1046                ;; in tty-colors.el.
1047                (when (and (memq attribute '(:foreground :background))
1048                           (not (memq window-system '(x w32 mac)))
1049                           (not (member new-value
1050                                        '("unspecified"
1051                                          "unspecified-fg" "unspecified-bg"))))
1052                  (setq new-value (car (tty-color-desc new-value frame))))
1053                (when (assoc new-value valid)
1054                  (setq new-value (cdr (assoc new-value valid)))))))
1055           ((eq valid 'integerp)
1056            (setq new-value (face-read-integer face old-value attribute-name)))
1057           (t (error "Internal error")))
1058     ;; Convert stipple and box value text we read back to a list or
1059     ;; vector if it looks like one.  This makes the assumption that a
1060     ;; pixmap file name won't start with an open-paren.
1061     (when (and (or (eq attribute :stipple)
1062                    (eq attribute :box))
1063                (stringp new-value)
1064                (string-match "^[[(]" new-value))
1065       (setq new-value (read new-value)))
1066     new-value))
1067
1068
1069 (defun read-face-font (face &optional frame)
1070   "Read the name of a font for FACE on FRAME.
1071 If optional argument FRAME Is nil or omitted, use the selected frame."
1072   (let ((completion-ignore-case t))
1073     (completing-read (format "Set font attributes of face `%s' from font: " face)
1074                      (mapcar 'list (x-list-fonts "*" nil frame)))))
1075
1076
1077 (defun read-all-face-attributes (face &optional frame)
1078   "Interactively read all attributes for FACE.
1079 If optional argument FRAME Is nil or omitted, use the selected frame.
1080 Value is a property list of attribute names and new values."
1081   (let (result)
1082     (dolist (attribute face-attribute-name-alist result)
1083       (setq result (cons (car attribute)
1084                          (cons (read-face-attribute face (car attribute) frame)
1085                                result))))))
1086
1087 (defun modify-face (&optional face foreground background stipple
1088                               bold-p italic-p underline-p inverse-p frame)
1089   "Modify attributes of faces interactively.
1090 If optional argument FRAME is nil or omitted, modify the face used
1091 for newly created frame, i.e. the global face.
1092 For non-interactive use, `set-face-attribute' is preferred.
1093 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1094 and the face and its settings are obtained by querying the user."
1095   (interactive)
1096   (if face
1097       (set-face-attribute face frame
1098                           :foreground (or foreground 'unspecified)
1099                           :background (or background 'unspecified)
1100                           :stipple stipple
1101                           :bold bold-p
1102                           :italic italic-p
1103                           :underline underline-p
1104                           :inverse-video inverse-p)
1105     (setq face (read-face-name "Modify face"))
1106     (apply #'set-face-attribute face frame
1107            (read-all-face-attributes face frame))))
1108
1109 (defun read-face-and-attribute (attribute &optional frame)
1110   "Read face name and face attribute value.
1111 ATTRIBUTE is the attribute whose new value is read.
1112 FRAME nil or unspecified means read attribute value of global face.
1113 Value is a list (FACE NEW-VALUE) where FACE is the face read
1114 \(a symbol), and NEW-VALUE is value read."
1115   (cond ((eq attribute :font)
1116          (let* ((prompt "Set font-related attributes of face")
1117                 (face (read-face-name prompt))
1118                 (font (read-face-font face frame)))
1119            (list face font)))
1120         (t
1121          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1122                 (prompt (format "Set %s of face" attribute-name))
1123                 (face (read-face-name prompt))
1124                 (new-value (read-face-attribute face attribute frame)))
1125            (list face new-value)))))
1126
1127
1128 \f
1129 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1130 ;;; Listing faces.
1131 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1132
1133 (defvar list-faces-sample-text
1134   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1135   "*Text string to display as the sample text for `list-faces-display'.")
1136
1137
1138 ;; The name list-faces would be more consistent, but let's avoid a
1139 ;; conflict with Lucid, which uses that name differently.
1140
1141 (defvar help-xref-stack)
1142 (defun list-faces-display ()
1143   "List all faces, using the same sample text in each.
1144 The sample text is a string that comes from the variable
1145 `list-faces-sample-text'."
1146   (interactive)
1147   (let ((faces (sort (face-list) #'string-lessp))
1148         (face nil)
1149         (frame (selected-frame))
1150         disp-frame window face-name)
1151     (with-output-to-temp-buffer "*Faces*"
1152       (save-excursion
1153         (set-buffer standard-output)
1154         (setq truncate-lines t)
1155         (insert
1156          (substitute-command-keys
1157           (concat
1158            "Use "
1159            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1160            "\\[help-follow] on a face name to customize it\n"
1161            "or on its sample text for a description of the face.\n\n")))
1162         (setq help-xref-stack nil)
1163         (while faces
1164           (setq face (car faces))
1165           (setq faces (cdr faces))
1166           (setq face-name (symbol-name face))
1167           (insert (format "%25s " face-name))
1168           ;; Hyperlink to a customization buffer for the face.  Using
1169           ;; the help xref mechanism may not be the best way.
1170           (save-excursion
1171             (save-match-data
1172               (search-backward face-name)
1173               (help-xref-button 0 'help-customize-face face)))
1174           (let ((beg (point))
1175                 (line-beg (line-beginning-position)))
1176             (insert list-faces-sample-text)
1177             ;; Hyperlink to a help buffer for the face.
1178             (save-excursion
1179               (save-match-data
1180                 (search-backward list-faces-sample-text)
1181                 (help-xref-button 0 'help-face face)))
1182             (insert "\n")
1183             (put-text-property beg (1- (point)) 'face face)
1184             ;; Make all face commands default to the proper face
1185             ;; anywhere in the line.
1186             (put-text-property line-beg (1- (point)) 'read-face-name face)
1187             ;; If the sample text has multiple lines, line up all of them.
1188             (goto-char beg)
1189             (forward-line 1)
1190             (while (not (eobp))
1191               (insert "                          ")
1192               (forward-line 1))))
1193         (goto-char (point-min)))
1194       (print-help-return-message))
1195     ;; If the *Faces* buffer appears in a different frame,
1196     ;; copy all the face definitions from FRAME,
1197     ;; so that the display will reflect the frame that was selected.
1198     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1199     (setq disp-frame (if window (window-frame window)
1200                        (car (frame-list))))
1201     (or (eq frame disp-frame)
1202         (let ((faces (face-list)))
1203           (while faces
1204             (copy-face (car faces) (car faces) frame disp-frame)
1205             (setq faces (cdr faces)))))))
1206
1207 (defun describe-face (face &optional frame)
1208   "Display the properties of face FACE on FRAME.
1209 Interactively, FACE defaults to the faces of the character after point
1210 and FRAME defaults to the selected frame.
1211
1212 If the optional argument FRAME is given, report on face FACE in that frame.
1213 If FRAME is t, report on the defaults for face FACE (for new frames).
1214 If FRAME is omitted or nil, use the selected frame."
1215   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1216   (let* ((attrs '((:family . "Family")
1217                   (:width . "Width")
1218                   (:height . "Height")
1219                   (:weight . "Weight")
1220                   (:slant . "Slant")
1221                   (:foreground . "Foreground")
1222                   (:background . "Background")
1223                   (:underline . "Underline")
1224                   (:overline . "Overline")
1225                   (:strike-through . "Strike-through")
1226                   (:box . "Box")
1227                   (:inverse-video . "Inverse")
1228                   (:stipple . "Stipple")
1229                   (:font . "Font or fontset")
1230                   (:inherit . "Inherit")))
1231         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1232                                         attrs))))
1233     (help-setup-xref (list #'describe-face face) (interactive-p))
1234     (unless face
1235       (setq face 'default))
1236     (if (not (listp face))
1237         (setq face (list face)))
1238     (with-output-to-temp-buffer (help-buffer)
1239       (save-excursion
1240         (set-buffer standard-output)
1241         (dolist (f face)
1242           (insert "Face: " (symbol-name f))
1243           (if (not (facep f))
1244               (insert "   undefined face.\n")
1245             (let ((customize-label "customize this face"))
1246               (princ (concat " (" customize-label ")\n"))
1247               (insert "Documentation: "
1248                       (or (face-documentation f)
1249                           "Not documented as a face.")
1250                       "\n\n")
1251               (with-current-buffer standard-output
1252                 (save-excursion
1253                   (re-search-backward
1254                    (concat "\\(" customize-label "\\)") nil t)
1255                   (help-xref-button 1 'help-customize-face f)))
1256               (dolist (a attrs)
1257                 (let ((attr (face-attribute f (car a) frame)))
1258                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1259                           (cdr a) ": " (format "%s" attr) "\n")))))
1260           (terpri)))
1261       (print-help-return-message))))
1262
1263 \f
1264 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1265 ;;; Face specifications (defface).
1266 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1267
1268 ;; Parameter FRAME Is kept for call compatibility to with previous
1269 ;; face implementation.
1270
1271 (defun face-attr-construct (face &optional frame)
1272   "Return a defface-style attribute list for FACE on FRAME.
1273 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1274 face attributes of FACE where ATTRIBUTE is the attribute name and
1275 VALUE is the specified value of that attribute."
1276   (let (result)
1277     (dolist (entry face-attribute-name-alist result)
1278       (let* ((attribute (car entry))
1279              (value (face-attribute face attribute)))
1280         (unless (eq value 'unspecified)
1281           (setq result (nconc (list attribute value) result)))))))
1282
1283
1284 (defun face-spec-set-match-display (display frame)
1285   "Non-nil if DISPLAY matches FRAME.
1286 DISPLAY is part of a spec such as can be used in `defface'.
1287 If FRAME is nil, the current FRAME is used."
1288   (let* ((conjuncts display)
1289          conjunct req options
1290          ;; t means we have succeeded against all the conjuncts in
1291          ;; DISPLAY that have been tested so far.
1292          (match t))
1293     (if (eq conjuncts t)
1294         (setq conjuncts nil))
1295     (while (and conjuncts match)
1296       (setq conjunct (car conjuncts)
1297             conjuncts (cdr conjuncts)
1298             req (car conjunct)
1299             options (cdr conjunct)
1300             match (cond ((eq req 'type)
1301                          (or (memq window-system options)
1302                              ;; FIXME: This should be revisited to use
1303                              ;; display-graphic-p, provided that the
1304                              ;; color selection depends on the number
1305                              ;; of supported colors, and all defface's
1306                              ;; are changed to look at number of colors
1307                              ;; instead of (type graphic) etc.
1308                              (and (null window-system)
1309                                   (memq 'tty options))
1310                              (and (memq 'motif options)
1311                                   (featurep 'motif))
1312                              (and (memq 'lucid options)
1313                                   (featurep 'x-toolkit)
1314                                   (not (featurep 'motif)))
1315                              (and (memq 'x-toolkit options)
1316                                   (featurep 'x-toolkit))))
1317                         ((eq req 'class)
1318                          (memq (frame-parameter frame 'display-type) options))
1319                         ((eq req 'background)
1320                          (memq (frame-parameter frame 'background-mode)
1321                                options))
1322                         ((eq req 'supports)
1323                          (display-supports-face-attributes-p options frame))
1324                         (t (error "Unknown req `%S' with options `%S'"
1325                                   req options)))))
1326     match))
1327
1328
1329 (defun face-spec-choose (spec &optional frame)
1330   "Choose the proper attributes for FRAME, out of SPEC.
1331 If SPEC is nil, return nil."
1332   (unless frame
1333     (setq frame (selected-frame)))
1334   (let ((tail spec)
1335         result all)
1336     (while tail
1337       (let* ((entry (pop tail))
1338              (display (car entry))
1339              (attrs (cdr entry)))
1340         (when (face-spec-set-match-display display frame)
1341           (setq result (if (null (cdr attrs)) ;; was (listp (car attrs))
1342                            ;; Old-style entry, the attribute list is the
1343                            ;; first element.
1344                            (car attrs)
1345                          attrs))
1346           (if (eq display t)
1347               (setq all result result nil)
1348             (setq tail nil)))))
1349     (if all (append result all) result)))
1350
1351
1352 (defun face-spec-reset-face (face &optional frame)
1353   "Reset all attributes of FACE on FRAME to unspecified."
1354   (let ((attrs face-attribute-name-alist))
1355     (while attrs
1356       (let ((attr-and-name (car attrs)))
1357         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1358       (setq attrs (cdr attrs)))))
1359
1360
1361 (defun face-spec-set (face spec &optional frame)
1362   "Set FACE's attributes according to the first matching entry in SPEC.
1363 FRAME is the frame whose frame-local face is set.  FRAME nil means
1364 do it on all frames.  See `defface' for information about SPEC.
1365 If SPEC is nil, do nothing."
1366   (let ((attrs (face-spec-choose spec frame)))
1367     (when attrs
1368       (face-spec-reset-face face frame))
1369     (while attrs
1370       (let ((attribute (car attrs))
1371             (value (car (cdr attrs))))
1372         ;; Support some old-style attribute names and values.
1373         (case attribute
1374           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1375           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1376           ((:foreground :background)
1377            ;; Compatibility with 20.x.  Some bogus face specs seem to
1378            ;; exist containing things like `:foreground nil'.
1379            (if (null value) (setq value 'unspecified)))
1380           (t (unless (assq attribute face-x-resources)
1381                (setq attribute nil))))
1382         (when attribute
1383           (set-face-attribute face frame attribute value)))
1384       (setq attrs (cdr (cdr attrs)))))
1385   ;; When we reset the face based on its spec, then it is unmodified
1386   ;; as far as Custom is concerned.
1387   (if (null frame)
1388       (put face 'face-modified nil)))
1389
1390
1391 (defun face-attr-match-p (face attrs &optional frame)
1392   "Return t if attributes of FACE match values in plist ATTRS.
1393 Optional parameter FRAME is the frame whose definition of FACE
1394 is used.  If nil or omitted, use the selected frame."
1395   (unless frame
1396     (setq frame (selected-frame)))
1397   (let ((list face-attribute-name-alist)
1398         (match t))
1399     (while (and match (not (null list)))
1400       (let* ((attr (car (car list)))
1401              (specified-value
1402               (if (plist-member attrs attr)
1403                   (plist-get attrs attr)
1404                 'unspecified))
1405              (value-now (face-attribute face attr frame)))
1406         (setq match (equal specified-value value-now))
1407         (setq list (cdr list))))
1408     match))
1409
1410 (defun face-spec-match-p (face spec &optional frame)
1411   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1412   (face-attr-match-p face (face-spec-choose spec frame) frame))
1413
1414 (defsubst face-default-spec (face)
1415   "Return the default face-spec for FACE, ignoring any user customization.
1416 If there is no default for FACE, return nil."
1417   (get face 'face-defface-spec))
1418
1419 (defsubst face-user-default-spec (face)
1420   "Return the user's customized face-spec for FACE, or the default if none.
1421 If there is neither a user setting nor a default for FACE, return nil."
1422   (or (get face 'saved-face)
1423       (face-default-spec face)))
1424
1425 \f
1426 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1427 ;;; Frame-type independent color support.
1428 ;;; We keep the old x-* names as aliases for back-compatibility.
1429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1430
1431 (defun defined-colors (&optional frame)
1432   "Return a list of colors supported for a particular frame.
1433 The argument FRAME specifies which frame to try.
1434 The value may be different for frames on different display types.
1435 If FRAME doesn't support colors, the value is nil."
1436   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1437       (xw-defined-colors frame)
1438     (mapcar 'car (tty-color-alist frame))))
1439 (defalias 'x-defined-colors 'defined-colors)
1440
1441 (defun color-defined-p (color &optional frame)
1442   "Return non-nil if color COLOR is supported on frame FRAME.
1443 If FRAME is omitted or nil, use the selected frame.
1444 If COLOR is the symbol `unspecified' or one of the strings
1445 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1446   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1447       nil
1448     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1449         (xw-color-defined-p color frame)
1450       (numberp (tty-color-translate color frame)))))
1451 (defalias 'x-color-defined-p 'color-defined-p)
1452
1453 (defun color-values (color &optional frame)
1454   "Return a description of the color named COLOR on frame FRAME.
1455 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1456 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1457 If FRAME is omitted or nil, use the selected frame.
1458 If FRAME cannot display COLOR, the value is nil.
1459 If COLOR is the symbol `unspecified' or one of the strings
1460 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1461   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1462       nil
1463     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1464         (xw-color-values color frame)
1465       (tty-color-values color frame))))
1466 (defalias 'x-color-values 'color-values)
1467
1468 (defun display-color-p (&optional display)
1469   "Return t if DISPLAY supports color.
1470 The optional argument DISPLAY specifies which display to ask about.
1471 DISPLAY should be either a frame or a display name (a string).
1472 If omitted or nil, that stands for the selected frame's display."
1473   (if (memq (framep-on-display display) '(x w32 mac))
1474       (xw-display-color-p display)
1475     (tty-display-color-p display)))
1476 (defalias 'x-display-color-p 'display-color-p)
1477
1478 (defun display-grayscale-p (&optional display)
1479   "Return non-nil if frames on DISPLAY can display shades of gray."
1480   (let ((frame-type (framep-on-display display)))
1481     (cond
1482      ((memq frame-type '(x w32 mac))
1483       (x-display-grayscale-p display))
1484      (t
1485       (> (tty-color-gray-shades display) 2)))))
1486
1487 (defun display-supports-face-attributes-p (attributes &optional display)
1488   "Return non-nil if all the face attributes in ATTRIBUTES are supported.
1489 The optional argument DISPLAY can be a display name, a frame, or
1490 nil (meaning the selected frame's display)
1491
1492 The definition of `supported' is somewhat heuristic, but basically means
1493 that a face containing all the attributes in ATTRIBUTES, when merged
1494 with the default face for display, can be represented in a way that's
1495
1496  (1) different in appearance than the default face, and
1497  (2) `close in spirit' to what the attributes specify, if not exact.
1498
1499 Point (2) implies that a `:weight black' attribute will be satisfied by
1500 any display that can display bold, and a `:foreground \"yellow\"' as long
1501 as it can display a yellowish color, but `:slant italic' will _not_ be
1502 satisfied by the tty display code's automatic substitution of a `dim'
1503 face for italic."
1504   (let ((frame
1505          (if (framep display)
1506              display
1507            (car (frames-on-display-list display)))))
1508     ;; For now, we assume that non-tty displays can support everything.
1509     ;; Later, we should add the ability to query about specific fonts,
1510     ;; colors, etc.
1511     (or (memq (framep frame) '(x w32 mac))
1512         (tty-supports-face-attributes-p attributes frame))))
1513
1514 \f
1515 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1516 ;;; Background mode.
1517 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1518
1519 (defcustom frame-background-mode nil
1520   "*The brightness of the background.
1521 Set this to the symbol `dark' if your background color is dark, `light' if
1522 your background is light, or nil (default) if you want Emacs to
1523 examine the brightness for you.  Don't set this variable with `setq';
1524 this won't have the expected effect."
1525   :group 'faces
1526   :set #'(lambda (var value)
1527            (set-default var value)
1528            (mapc 'frame-set-background-mode (frame-list)))
1529   :initialize 'custom-initialize-changed
1530   :type '(choice (choice-item dark)
1531                  (choice-item light)
1532                  (choice-item :tag "default" nil)))
1533
1534
1535 (defun frame-set-background-mode (frame)
1536   "Set up display-dependent faces on FRAME.
1537 Display-dependent faces are those which have different definitions
1538 according to the `background-mode' and `display-type' frame parameters."
1539   (let* ((bg-resource
1540           (and window-system
1541                (x-get-resource "backgroundMode" "BackgroundMode")))
1542          (bg-color (frame-parameter frame 'background-color))
1543          (bg-mode
1544           (cond (frame-background-mode)
1545                 (bg-resource
1546                  (intern (downcase bg-resource)))
1547                 ((and (null window-system) (null bg-color))
1548                  ;; No way to determine this automatically (?).
1549                  'dark)
1550                 ;; Unspecified frame background color can only happen
1551                 ;; on tty's.
1552                 ((member bg-color '(unspecified "unspecified-bg"))
1553                  'dark)
1554                 ((equal bg-color "unspecified-fg") ; inverted colors
1555                  'light)
1556                 ((>= (apply '+ (x-color-values bg-color frame))
1557                     ;; Just looking at the screen, colors whose
1558                     ;; values add up to .6 of the white total
1559                     ;; still look dark to me.
1560                     (* (apply '+ (x-color-values "white" frame)) .6))
1561                  'light)
1562                 (t 'dark)))
1563          (display-type
1564           (cond ((null window-system)
1565                  (if (tty-display-color-p frame) 'color 'mono))
1566                 ((x-display-color-p frame)
1567                  'color)
1568                 ((x-display-grayscale-p frame)
1569                  'grayscale)
1570                 (t 'mono)))
1571          (old-bg-mode
1572           (frame-parameter frame 'background-mode))
1573          (old-display-type
1574           (frame-parameter frame 'display-type)))
1575
1576     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1577       (let ((locally-modified-faces nil))
1578         ;; Before modifying the frame parameters, we collect a list of
1579         ;; faces that don't match what their face-spec says they should
1580         ;; look like; we then avoid changing these faces below.  A
1581         ;; negative list is used on the assumption that most faces will
1582         ;; be unmodified, so we can avoid consing in the common case.
1583         (dolist (face (face-list))
1584           (when (not (face-spec-match-p face
1585                                         (face-user-default-spec face)
1586                                         (selected-frame)))
1587             (push face locally-modified-faces)))
1588         ;; Now change to the new frame parameters
1589         (modify-frame-parameters frame
1590                                  (list (cons 'background-mode bg-mode)
1591                                        (cons 'display-type display-type)))
1592         ;; For all named faces, choose face specs matching the new frame
1593         ;; parameters, unless they have been locally modified.
1594         (dolist (face (face-list))
1595           (unless (memq face locally-modified-faces)
1596             (face-spec-set face (face-user-default-spec face) frame)))))))
1597
1598 \f
1599 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1600 ;;; Frame creation.
1601 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1602
1603 (defun x-handle-named-frame-geometry (parameters)
1604   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1605 Value is the new parameter list."
1606   (let* ((name (or (cdr (assq 'name parameters))
1607                    (cdr (assq 'name default-frame-alist))))
1608          (x-resource-name name)
1609          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1610     (when res-geometry
1611       (let ((parsed (x-parse-geometry res-geometry)))
1612         ;; If the resource specifies a position, call the position
1613         ;; and size "user-specified".
1614         (when (or (assq 'top parsed)
1615                   (assq 'left parsed))
1616           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1617         ;; Put the geometry parameters at the end.  Copy
1618         ;; default-frame-alist so that they go after it.
1619         (setq parameters (append parameters default-frame-alist parsed))))
1620     parameters))
1621
1622
1623 (defun x-handle-reverse-video (frame parameters)
1624   "Handle the reverse-video frame parameter and X resource.
1625 `x-create-frame' does not handle this one."
1626   (when (cdr (or (assq 'reverse parameters)
1627                  (assq 'reverse default-frame-alist)
1628                  (let ((resource (x-get-resource "reverseVideo"
1629                                                  "ReverseVideo")))
1630                    (if resource
1631                        (cons nil (member (downcase resource)
1632                                          '("on" "true")))))))
1633       (let* ((params (frame-parameters frame))
1634              (bg (cdr (assq 'foreground-color params)))
1635              (fg (cdr (assq 'background-color params))))
1636         (modify-frame-parameters frame
1637                                  (list (cons 'foreground-color fg)
1638                                        (cons 'background-color bg)))
1639         (if (equal bg (cdr (assq 'border-color params)))
1640             (modify-frame-parameters frame
1641                                      (list (cons 'border-color fg))))
1642         (if (equal bg (cdr (assq 'mouse-color params)))
1643             (modify-frame-parameters frame
1644                                      (list (cons 'mouse-color fg))))
1645         (if (equal bg (cdr (assq 'cursor-color params)))
1646             (modify-frame-parameters frame
1647                                      (list (cons 'cursor-color fg)))))))
1648
1649
1650 (defun x-create-frame-with-faces (&optional parameters)
1651   "Create a frame from optional frame parameters PARAMETERS.
1652 Parameters not specified by PARAMETERS are taken from
1653 `default-frame-alist'.  If PARAMETERS specify a frame name,
1654 handle X geometry resources for that name.  If either PARAMETERS
1655 or `default-frame-alist' contains a `reverse' parameter, or
1656 the X resource ``reverseVideo'' is present, handle that.
1657 Value is the new frame created."
1658   (setq parameters (x-handle-named-frame-geometry parameters))
1659   (let ((visibility-spec (assq 'visibility parameters))
1660         (frame-list (frame-list))
1661         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1662         success)
1663     (unwind-protect
1664         (progn
1665           (x-handle-reverse-video frame parameters)
1666           (frame-set-background-mode frame)
1667           (face-set-after-frame-default frame)
1668           (if (or (null frame-list) (null visibility-spec))
1669               (make-frame-visible frame)
1670             (modify-frame-parameters frame (list visibility-spec)))
1671           (setq success t))
1672       (unless success
1673         (delete-frame frame)))
1674     frame))
1675
1676
1677 (defun face-set-after-frame-default (frame)
1678   "Set frame-local faces of FRAME from face specs and resources.
1679 Initialize colors of certain faces from frame parameters."
1680   (if (face-attribute 'default :font t)
1681       (set-face-attribute 'default frame :font
1682                           (face-attribute 'default :font t))
1683     (set-face-attribute 'default frame :family
1684                         (face-attribute 'default :family t))
1685     (set-face-attribute 'default frame :height
1686                         (face-attribute 'default :height t))
1687     (set-face-attribute 'default frame :slant
1688                         (face-attribute 'default :slant t))
1689     (set-face-attribute 'default frame :weight
1690                         (face-attribute 'default :weight t))
1691     (set-face-attribute 'default frame :width
1692                         (face-attribute 'default :width t)))
1693   (dolist (face (face-list))
1694     ;; Don't let frame creation fail because of an invalid face spec.
1695     (condition-case ()
1696         (when (not (equal face 'default))
1697           (face-spec-set face (face-user-default-spec face) frame)
1698           (internal-merge-in-global-face face frame)
1699           (when (and (memq window-system '(x w32 mac))
1700                      (or (not (boundp 'inhibit-default-face-x-resources))
1701                          (not (eq face 'default))))
1702             (make-face-x-resource-internal face frame)))
1703       (error nil)))
1704   ;; Initialize attributes from frame parameters.
1705   (let ((params '((foreground-color default :foreground)
1706                   (background-color default :background)
1707                   (border-color border :background)
1708                   (cursor-color cursor :background)
1709                   (scroll-bar-foreground scroll-bar :foreground)
1710                   (scroll-bar-background scroll-bar :background)
1711                   (mouse-color mouse :background))))
1712     (dolist (param params)
1713       (let ((frame-param (frame-parameter frame (nth 0 param)))
1714             (face (nth 1 param))
1715             (attr (nth 2 param)))
1716         (when (and frame-param
1717                    ;; Don't override face attributes explicitly
1718                    ;; specified for new frames.
1719                    (eq (face-attribute face attr t) 'unspecified))
1720           (set-face-attribute face frame attr frame-param))))))
1721
1722
1723 (defun tty-handle-reverse-video (frame parameters)
1724   "Handle the reverse-video frame parameter for terminal frames."
1725   (when (cdr (or (assq 'reverse parameters)
1726                  (assq 'reverse default-frame-alist)))
1727     (let* ((params (frame-parameters frame))
1728            (bg (cdr (assq 'foreground-color params)))
1729            (fg (cdr (assq 'background-color params))))
1730       (modify-frame-parameters frame
1731                                (list (cons 'foreground-color fg)
1732                                      (cons 'background-color bg)))
1733       (if (equal bg (cdr (assq 'mouse-color params)))
1734           (modify-frame-parameters frame
1735                                    (list (cons 'mouse-color fg))))
1736       (if (equal bg (cdr (assq 'cursor-color params)))
1737           (modify-frame-parameters frame
1738                                    (list (cons 'cursor-color fg)))))))
1739
1740
1741 (defun tty-create-frame-with-faces (&optional parameters)
1742   "Create a frame from optional frame parameters PARAMETERS.
1743 Parameters not specified by PARAMETERS are taken from
1744 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1745 contains a `reverse' parameter, handle that.  Value is the new frame
1746 created."
1747   (let ((frame (make-terminal-frame parameters))
1748         success)
1749     (unwind-protect
1750         (progn
1751           (tty-handle-reverse-video frame (frame-parameters frame))
1752           (frame-set-background-mode frame)
1753           (face-set-after-frame-default frame)
1754           (setq success t))
1755       (unless success
1756         (delete-frame frame)))
1757     frame))
1758
1759
1760 ;; Called from C function init_display to initialize faces of the
1761 ;; dumped terminal frame on startup.
1762
1763 (defun tty-set-up-initial-frame-faces ()
1764   (let ((frame (selected-frame)))
1765     (frame-set-background-mode frame)
1766     (face-set-after-frame-default frame)))
1767
1768
1769
1770 \f
1771 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1772 ;;; Compatiblity with 20.2
1773 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1774
1775 ;; Update a frame's faces when we change its default font.
1776
1777 (defalias 'frame-update-faces 'ignore)
1778 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1779
1780 ;; Update the colors of FACE, after FRAME's own colors have been
1781 ;; changed.
1782
1783 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1784 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1785
1786 \f
1787 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1788 ;;; Standard faces.
1789 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1790
1791 (defgroup basic-faces nil
1792   "The standard faces of Emacs."
1793   :group 'faces)
1794
1795
1796 (defface default
1797   '((t nil))
1798   "Basic default face."
1799   :group 'basic-faces)
1800
1801
1802 (defface mode-line
1803   '((((type x w32 mac) (class color))
1804      :box (:line-width -1 :style released-button)
1805      :background "grey75" :foreground "black")
1806     (t
1807      :inverse-video t))
1808   "Basic mode line face for selected window."
1809   :version "21.1"
1810   :group 'modeline
1811   :group 'basic-faces)
1812
1813 (defface mode-line-inactive
1814   '((t
1815      :inherit mode-line)
1816     (((type x w32 mac) (background light) (class color))
1817      :weight light
1818      :box (:line-width -1 :color "grey75" :style nil)
1819      :foreground "grey20" :background "grey90")
1820     (((type x w32 mac) (background dark) (class color))
1821      :weight light
1822      :box (:line-width -1 :color "grey40" :style nil)
1823      :foreground "grey80" :background "grey30"))
1824   "Basic mode line face for non-selected windows."
1825   :version "21.4"
1826   :group 'modeline
1827   :group 'basic-faces)
1828
1829 ;; Make `modeline' an alias for `mode-line', for compatibility.
1830 (put 'modeline 'face-alias 'mode-line)
1831 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1832
1833 (defface header-line
1834   '((((type tty))
1835      ;; This used to be `:inverse-video t', but that doesn't look very
1836      ;; good when combined with inverse-video mode-lines and multiple
1837      ;; windows.  Underlining looks better, and is more consistent with
1838      ;; the window-system face variants, which deemphasize the
1839      ;; header-line in relation to the mode-line face.  If a terminal
1840      ;; can't underline, then the header-line will end up without any
1841      ;; highlighting; this may be too confusing in general, although it
1842      ;; happens to look good with the only current use of header-lines,
1843      ;; the info browser. XXX
1844      :underline t)
1845     (((class color grayscale) (background light))
1846      :background "grey90" :foreground "grey20"
1847      :box nil
1848      :inherit mode-line)
1849     (((class color grayscale) (background dark))
1850      :background "grey20" :foreground "grey90"
1851      :box nil
1852      :inherit mode-line)
1853     (((class mono) (background light))
1854      :background "white" :foreground "black"
1855      :inverse-video nil
1856      :box nil
1857      :underline t
1858      :inherit mode-line)
1859     (((class mono) (background dark))
1860      :background "black" :foreground "white"
1861      :inverse-video nil
1862      :box nil
1863      :underline t
1864      :inherit mode-line))
1865   "Basic header-line face."
1866   :version "21.1"
1867   :group 'basic-faces)
1868
1869
1870 (defface tool-bar
1871   '((((type x w32 mac) (class color))
1872      :box (:line-width 1 :style released-button)
1873      :background "grey75" :foreground "black")
1874     (((type x) (class mono))
1875      :box (:line-width 1 :style released-button)
1876      :background "grey" :foreground "black")
1877     (t
1878      ()))
1879   "Basic tool-bar face."
1880   :version "21.1"
1881   :group 'basic-faces)
1882
1883
1884 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1885                              (((type pc)) :foreground "magenta")
1886                              (t :foreground "dark blue"))
1887   "Face for minibuffer prompts."
1888   :version "21.4"
1889   :group 'basic-faces)
1890
1891 (setq minibuffer-prompt-properties
1892       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1893
1894 (defface region
1895   '((((type tty) (class color))
1896      :background "blue" :foreground "white")
1897     (((type tty) (class mono))
1898      :inverse-video t)
1899     (((class color) (background dark))
1900      :background "blue3")
1901     (((class color) (background light))
1902      :background "lightgoldenrod2")
1903     (t :background "gray"))
1904   "Basic face for highlighting the region."
1905   :version "21.1"
1906   :group 'basic-faces)
1907
1908
1909 (defface fringe
1910   '((((class color) (background light))
1911      :background "grey95")
1912     (((class color) (background dark))
1913      :background "grey10")
1914     (t
1915      :background "gray"))
1916   "Basic face for the fringes to the left and right of windows under X."
1917   :version "21.1"
1918   :group 'frames
1919   :group 'basic-faces)
1920
1921
1922 (defface scroll-bar '()
1923   "Basic face for the scroll bar colors under X."
1924   :version "21.1"
1925   :group 'frames
1926   :group 'basic-faces)
1927
1928
1929 (defface menu
1930   '((((type tty))
1931      :inverse-video t)
1932     (((type x-toolkit))
1933      )
1934     (t
1935      :inverse-video t))
1936   "Basic face for the font and colors of the menu bar and popup menus."
1937   :version "21.1"
1938   :group 'menu
1939   :group 'basic-faces)
1940
1941
1942 (defface border '()
1943   "Basic face for the frame border under X."
1944   :version "21.1"
1945   :group 'frames
1946   :group 'basic-faces)
1947
1948
1949 (defface cursor '()
1950   "Basic face for the cursor color under X."
1951   :version "21.1"
1952   :group 'cursor
1953   :group 'basic-faces)
1954
1955
1956 (defface mouse '()
1957   "Basic face for the mouse color under X."
1958   :version "21.1"
1959   :group 'mouse
1960   :group 'basic-faces)
1961
1962
1963 (defface bold '((t :weight bold))
1964   "Basic bold face."
1965   :group 'basic-faces)
1966
1967
1968 (defface italic
1969   '((((supports :slant italic))
1970      :slant italic)
1971     (((supports :underline t))
1972      :underline t)
1973     (t
1974      ;; default to italic, even it doesn't appear to be supported,
1975      ;; because in some cases the display engine will do it's own
1976      ;; workaround (to `dim' on ttys)
1977      :slant italic))
1978   "Basic italic font."
1979   :group 'basic-faces)
1980
1981
1982 (defface bold-italic '((t :weight bold :slant italic))
1983   "Basic bold-italic face."
1984   :group 'basic-faces)
1985
1986
1987 (defface underline '((t :underline t))
1988   "Basic underlined face."
1989   :group 'basic-faces)
1990
1991
1992 (defface highlight
1993   '((((type tty) (class color))
1994      :background "green" :foreground "black")
1995     (((class color) (background light))
1996      :background "darkseagreen2")
1997     (((class color) (background dark))
1998      :background "darkolivegreen")
1999     (t :inverse-video t))
2000   "Basic face for highlighting."
2001   :group 'basic-faces)
2002
2003
2004 (defface secondary-selection
2005   '((((type tty) (class color))
2006      :background "cyan" :foreground "black")
2007     (((class color) (background light))
2008      :background "yellow")
2009     (((class color) (background dark))
2010      :background "SkyBlue4")
2011     (t :inverse-video t))
2012   "Basic face for displaying the secondary selection."
2013   :group 'basic-faces)
2014
2015
2016 (defface fixed-pitch '((t :family "courier"))
2017   "The basic fixed-pitch face."
2018   :group 'basic-faces)
2019
2020
2021 (defface variable-pitch '((t :family "helv"))
2022   "The basic variable-pitch face."
2023   :group 'basic-faces)
2024
2025
2026 (defface trailing-whitespace
2027   '((((class color) (background light))
2028      :background "red")
2029     (((class color) (background dark))
2030      :background "red")
2031     (t :inverse-video t))
2032   "Basic face for highlighting trailing whitespace."
2033   :version "21.1"
2034   :group 'font-lock                     ; like `show-trailing-whitespace'
2035   :group 'basic-faces)
2036
2037
2038 \f
2039 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2040 ;;; Manipulating font names.
2041 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2042
2043 ;; This is here for compatibilty with Emacs 20.2.  For example,
2044 ;; international/fontset.el uses x-resolve-font-name.  The following
2045 ;; functions are not used in the face implementation itself.
2046
2047 (defvar x-font-regexp nil)
2048 (defvar x-font-regexp-head nil)
2049 (defvar x-font-regexp-weight nil)
2050 (defvar x-font-regexp-slant nil)
2051
2052 (defconst x-font-regexp-weight-subnum 1)
2053 (defconst x-font-regexp-slant-subnum 2)
2054 (defconst x-font-regexp-swidth-subnum 3)
2055 (defconst x-font-regexp-adstyle-subnum 4)
2056
2057 ;;; Regexps matching font names in "Host Portable Character Representation."
2058 ;;;
2059 (let ((-                "[-?]")
2060       (foundry          "[^-]+")
2061       (family           "[^-]+")
2062       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2063 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2064       (weight\?         "\\([^-]*\\)")                                  ; 1
2065       (slant            "\\([ior]\\)")                                  ; 2
2066 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2067       (slant\?          "\\([^-]?\\)")                                  ; 2
2068 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2069       (swidth           "\\([^-]*\\)")                                  ; 3
2070 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2071       (adstyle          "\\([^-]*\\)")                                  ; 4
2072       (pixelsize        "[0-9]+")
2073       (pointsize        "[0-9][0-9]+")
2074       (resx             "[0-9][0-9]+")
2075       (resy             "[0-9][0-9]+")
2076       (spacing          "[cmp?*]")
2077       (avgwidth         "[0-9]+")
2078       (registry         "[^-]+")
2079       (encoding         "[^-]+")
2080       )
2081   (setq x-font-regexp
2082         (concat "\\`\\*?[-?*]"
2083                 foundry - family - weight\? - slant\? - swidth - adstyle -
2084                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2085                 registry - encoding "\\*?\\'"
2086                 ))
2087   (setq x-font-regexp-head
2088         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2089                 "\\([-*?]\\|\\'\\)"))
2090   (setq x-font-regexp-slant (concat - slant -))
2091   (setq x-font-regexp-weight (concat - weight -))
2092   nil)
2093
2094
2095 (defun x-resolve-font-name (pattern &optional face frame)
2096   "Return a font name matching PATTERN.
2097 All wildcards in PATTERN are instantiated.
2098 If PATTERN is nil, return the name of the frame's base font, which never
2099 contains wildcards.
2100 Given optional arguments FACE and FRAME, return a font which is
2101 also the same size as FACE on FRAME, or fail."
2102   (or (symbolp face)
2103       (setq face (face-name face)))
2104   (and (eq frame t)
2105        (setq frame nil))
2106   (if pattern
2107       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2108       (let ((fonts (x-list-fonts pattern face frame 1)))
2109         (or fonts
2110             (if face
2111                 (if (string-match "\\*" pattern)
2112                     (if (null (face-font face))
2113                         (error "No matching fonts are the same height as the frame default font")
2114                       (error "No matching fonts are the same height as face `%s'" face))
2115                   (if (null (face-font face))
2116                       (error "Height of font `%s' doesn't match the frame default font"
2117                              pattern)
2118                     (error "Height of font `%s' doesn't match face `%s'"
2119                            pattern face)))
2120               (error "No fonts match `%s'" pattern)))
2121         (car fonts))
2122     (cdr (assq 'font (frame-parameters (selected-frame))))))
2123
2124
2125 (defun x-frob-font-weight (font which)
2126   (let ((case-fold-search t))
2127     (cond ((string-match x-font-regexp font)
2128            (concat (substring font 0
2129                               (match-beginning x-font-regexp-weight-subnum))
2130                    which
2131                    (substring font (match-end x-font-regexp-weight-subnum)
2132                               (match-beginning x-font-regexp-adstyle-subnum))
2133                    ;; Replace the ADD_STYLE_NAME field with *
2134                    ;; because the info in it may not be the same
2135                    ;; for related fonts.
2136                    "*"
2137                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2138           ((string-match x-font-regexp-head font)
2139            (concat (substring font 0 (match-beginning 1)) which
2140                    (substring font (match-end 1))))
2141           ((string-match x-font-regexp-weight font)
2142            (concat (substring font 0 (match-beginning 1)) which
2143                    (substring font (match-end 1)))))))
2144 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2145
2146 (defun x-frob-font-slant (font which)
2147   (let ((case-fold-search t))
2148     (cond ((string-match x-font-regexp font)
2149            (concat (substring font 0
2150                               (match-beginning x-font-regexp-slant-subnum))
2151                    which
2152                    (substring font (match-end x-font-regexp-slant-subnum)
2153                               (match-beginning x-font-regexp-adstyle-subnum))
2154                    ;; Replace the ADD_STYLE_NAME field with *
2155                    ;; because the info in it may not be the same
2156                    ;; for related fonts.
2157                    "*"
2158                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2159           ((string-match x-font-regexp-head font)
2160            (concat (substring font 0 (match-beginning 2)) which
2161                    (substring font (match-end 2))))
2162           ((string-match x-font-regexp-slant font)
2163            (concat (substring font 0 (match-beginning 1)) which
2164                    (substring font (match-end 1)))))))
2165 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2166
2167 ;; These aliases are here so that we don't get warnings about obsolete
2168 ;; functions from the byte compiler.
2169 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2170 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2171
2172 (defun x-make-font-bold (font)
2173   "Given an X font specification, make a bold version of it.
2174 If that can't be done, return nil."
2175   (internal-frob-font-weight font "bold"))
2176 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2177
2178 (defun x-make-font-demibold (font)
2179   "Given an X font specification, make a demibold version of it.
2180 If that can't be done, return nil."
2181   (internal-frob-font-weight font "demibold"))
2182 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2183
2184 (defun x-make-font-unbold (font)
2185   "Given an X font specification, make a non-bold version of it.
2186 If that can't be done, return nil."
2187   (internal-frob-font-weight font "medium"))
2188 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2189
2190 (defun x-make-font-italic (font)
2191   "Given an X font specification, make an italic version of it.
2192 If that can't be done, return nil."
2193   (internal-frob-font-slant font "i"))
2194 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2195
2196 (defun x-make-font-oblique (font) ; you say tomayto...
2197   "Given an X font specification, make an oblique version of it.
2198 If that can't be done, return nil."
2199   (internal-frob-font-slant font "o"))
2200 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2201
2202 (defun x-make-font-unitalic (font)
2203   "Given an X font specification, make a non-italic version of it.
2204 If that can't be done, return nil."
2205   (internal-frob-font-slant font "r"))
2206 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2207
2208 (defun x-make-font-bold-italic (font)
2209   "Given an X font specification, make a bold and italic version of it.
2210 If that can't be done, return nil."
2211   (and (setq font (internal-frob-font-weight font "bold"))
2212        (internal-frob-font-slant font "i")))
2213 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2214
2215 (provide 'faces)
2216
2217 ;;; arch-tag: 19a4759f-2963-445f-b004-425b9aadd7d6
2218 ;;; faces.el ends here