m4/mktime.m4

   1 # serial 29
   2 dnl Copyright (C) 2002-2003, 2005-2007, 2009-2017 Free Software Foundation,
   3 dnl Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Jim Meyering.
   9
  10 AC_DEFUN([gl_TIME_T_IS_SIGNED],
  11 [
  12   AC_CACHE_CHECK([whether time_t is signed],
  13     [gl_cv_time_t_is_signed],
  14     [AC_COMPILE_IFELSE(
  15        [AC_LANG_PROGRAM([[#include <time.h>
  16                           char time_t_signed[(time_t) -1 < 0 ? 1 : -1];]])],
  17        [gl_cv_time_t_is_signed=yes],
  18        [gl_cv_time_t_is_signed=no])])
  19   if test $gl_cv_time_t_is_signed = yes; then
  20     AC_DEFINE([TIME_T_IS_SIGNED], [1], [Define to 1 if time_t is signed.])
  21   fi
  22 ])
  23
  24 dnl Test whether mktime works. Set gl_cv_func_working_mktime.
  25 AC_DEFUN([gl_FUNC_MKTIME_WORKS],
  26 [
  27   AC_REQUIRE([gl_TIME_T_IS_SIGNED])
  28   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  29
  30   dnl We don't use AC_FUNC_MKTIME any more, because it is no longer maintained
  31   dnl in Autoconf and because it invokes AC_LIBOBJ.
  32   AC_CHECK_HEADERS_ONCE([unistd.h])
  33   AC_CHECK_DECLS_ONCE([alarm])
  34   AC_CHECK_FUNCS_ONCE([tzset])
  35   AC_REQUIRE([gl_MULTIARCH])
  36   if test $APPLE_UNIVERSAL_BUILD = 1; then
  37     # A universal build on Apple Mac OS X platforms.
  38     # The test result would be 'yes' in 32-bit mode and 'no' in 64-bit mode.
  39     # But we need a configuration result that is valid in both modes.
  40     gl_cv_func_working_mktime=no
  41   fi
  42   AC_CACHE_CHECK([for working mktime], [gl_cv_func_working_mktime],
  43     [AC_RUN_IFELSE(
  44        [AC_LANG_SOURCE(
  45 [[/* Test program from Paul Eggert and Tony Leneis.  */
  46 #include <limits.h>
  47 #include <stdlib.h>
  48 #include <time.h>
  49
  50 #ifdef HAVE_UNISTD_H
  51 # include <unistd.h>
  52 #endif
  53
  54 #if HAVE_DECL_ALARM
  55 # include <signal.h>
  56 #endif
  57
  58 /* Work around redefinition to rpl_putenv by other config tests.  */
  59 #undef putenv
  60
  61 static time_t time_t_max;
  62 static time_t time_t_min;
  63
  64 /* Values we'll use to set the TZ environment variable.  */
  65 static char *tz_strings[] = {
  66   (char *) 0, "TZ=GMT0", "TZ=JST-9",
  67   "TZ=EST+3EDT+2,M10.1.0/00:00:00,M2.3.0/00:00:00"
  68 };
  69 #define N_STRINGS (sizeof (tz_strings) / sizeof (tz_strings[0]))
  70
  71 /* Return 0 if mktime fails to convert a date in the spring-forward gap.
  72    Based on a problem report from Andreas Jaeger.  */
  73 static int
  74 spring_forward_gap ()
  75 {
  76   /* glibc (up to about 1998-10-07) failed this test. */
  77   struct tm tm;
  78
  79   /* Use the portable POSIX.1 specification "TZ=PST8PDT,M4.1.0,M10.5.0"
  80      instead of "TZ=America/Vancouver" in order to detect the bug even
  81      on systems that don't support the Olson extension, or don't have the
  82      full zoneinfo tables installed.  */
  83   putenv ("TZ=PST8PDT,M4.1.0,M10.5.0");
  84
  85   tm.tm_year = 98;
  86   tm.tm_mon = 3;
  87   tm.tm_mday = 5;
  88   tm.tm_hour = 2;
  89   tm.tm_min = 0;
  90   tm.tm_sec = 0;
  91   tm.tm_isdst = -1;
  92   return mktime (&tm) != (time_t) -1;
  93 }
  94
  95 static int
  96 mktime_test1 (time_t now)
  97 {
  98   struct tm *lt;
  99   return ! (lt = localtime (&now)) || mktime (lt) == now;
 100 }
 101
 102 static int
 103 mktime_test (time_t now)
 104 {
 105   return (mktime_test1 (now)
 106           && mktime_test1 ((time_t) (time_t_max - now))
 107           && mktime_test1 ((time_t) (time_t_min + now)));
 108 }
 109
 110 static int
 111 irix_6_4_bug ()
 112 {
 113   /* Based on code from Ariel Faigon.  */
 114   struct tm tm;
 115   tm.tm_year = 96;
 116   tm.tm_mon = 3;
 117   tm.tm_mday = 0;
 118   tm.tm_hour = 0;
 119   tm.tm_min = 0;
 120   tm.tm_sec = 0;
 121   tm.tm_isdst = -1;
 122   mktime (&tm);
 123   return tm.tm_mon == 2 && tm.tm_mday == 31;
 124 }
 125
 126 static int
 127 bigtime_test (int j)
 128 {
 129   struct tm tm;
 130   time_t now;
 131   tm.tm_year = tm.tm_mon = tm.tm_mday = tm.tm_hour = tm.tm_min = tm.tm_sec = j;
 132   now = mktime (&tm);
 133   if (now != (time_t) -1)
 134     {
 135       struct tm *lt = localtime (&now);
 136       if (! (lt
 137              && lt->tm_year == tm.tm_year
 138              && lt->tm_mon == tm.tm_mon
 139              && lt->tm_mday == tm.tm_mday
 140              && lt->tm_hour == tm.tm_hour
 141              && lt->tm_min == tm.tm_min
 142              && lt->tm_sec == tm.tm_sec
 143              && lt->tm_yday == tm.tm_yday
 144              && lt->tm_wday == tm.tm_wday
 145              && ((lt->tm_isdst < 0 ? -1 : 0 < lt->tm_isdst)
 146                   == (tm.tm_isdst < 0 ? -1 : 0 < tm.tm_isdst))))
 147         return 0;
 148     }
 149   return 1;
 150 }
 151
 152 static int
 153 year_2050_test ()
 154 {
 155   /* The correct answer for 2050-02-01 00:00:00 in Pacific time,
 156      ignoring leap seconds.  */
 157   unsigned long int answer = 2527315200UL;
 158
 159   struct tm tm;
 160   time_t t;
 161   tm.tm_year = 2050 - 1900;
 162   tm.tm_mon = 2 - 1;
 163   tm.tm_mday = 1;
 164   tm.tm_hour = tm.tm_min = tm.tm_sec = 0;
 165   tm.tm_isdst = -1;
 166
 167   /* Use the portable POSIX.1 specification "TZ=PST8PDT,M4.1.0,M10.5.0"
 168      instead of "TZ=America/Vancouver" in order to detect the bug even
 169      on systems that don't support the Olson extension, or don't have the
 170      full zoneinfo tables installed.  */
 171   putenv ("TZ=PST8PDT,M4.1.0,M10.5.0");
 172
 173   t = mktime (&tm);
 174
 175   /* Check that the result is either a failure, or close enough
 176      to the correct answer that we can assume the discrepancy is
 177      due to leap seconds.  */
 178   return (t == (time_t) -1
 179           || (0 < t && answer - 120 <= t && t <= answer + 120));
 180 }
 181
 182 int
 183 main ()
 184 {
 185   int result = 0;
 186   time_t t, delta;
 187   int i, j;
 188   int time_t_signed_magnitude = (time_t) ~ (time_t) 0 < (time_t) -1;
 189
 190 #if HAVE_DECL_ALARM
 191   /* This test makes some buggy mktime implementations loop.
 192      Give up after 60 seconds; a mktime slower than that
 193      isn't worth using anyway.  */
 194   signal (SIGALRM, SIG_DFL);
 195   alarm (60);
 196 #endif
 197
 198   time_t_max = (! TIME_T_IS_SIGNED
 199                 ? (time_t) -1
 200                 : ((((time_t) 1 << (sizeof (time_t) * CHAR_BIT - 2)) - 1)
 201                    * 2 + 1));
 202   time_t_min = (! TIME_T_IS_SIGNED
 203                 ? (time_t) 0
 204                 : time_t_signed_magnitude
 205                 ? ~ (time_t) 0
 206                 : ~ time_t_max);
 207
 208   delta = time_t_max / 997; /* a suitable prime number */
 209   for (i = 0; i < N_STRINGS; i++)
 210     {
 211       if (tz_strings[i])
 212         putenv (tz_strings[i]);
 213
 214       for (t = 0; t <= time_t_max - delta && (result & 1) == 0; t += delta)
 215         if (! mktime_test (t))
 216           result |= 1;
 217       if ((result & 2) == 0
 218           && ! (mktime_test ((time_t) 1)
 219                 && mktime_test ((time_t) (60 * 60))
 220                 && mktime_test ((time_t) (60 * 60 * 24))))
 221         result |= 2;
 222
 223       for (j = 1; (result & 4) == 0; j <<= 1)
 224         {
 225           if (! bigtime_test (j))
 226             result |= 4;
 227           if (INT_MAX / 2 < j)
 228             break;
 229         }
 230       if ((result & 8) == 0 && ! bigtime_test (INT_MAX))
 231         result |= 8;
 232     }
 233   if (! irix_6_4_bug ())
 234     result |= 16;
 235   if (! spring_forward_gap ())
 236     result |= 32;
 237   if (! year_2050_test ())
 238     result |= 64;
 239   return result;
 240 }]])],
 241        [gl_cv_func_working_mktime=yes],
 242        [gl_cv_func_working_mktime=no],
 243        [case "$host_os" in
 244                   # Guess no on native Windows.
 245           mingw*) gl_cv_func_working_mktime="guessing no" ;;
 246           *)      gl_cv_func_working_mktime="guessing no" ;;
 247         esac
 248        ])
 249     ])
 250 ])
 251
 252 dnl Main macro of module 'mktime'.
 253 AC_DEFUN([gl_FUNC_MKTIME],
 254 [
 255   AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
 256   AC_REQUIRE([AC_CANONICAL_HOST])
 257   AC_REQUIRE([gl_FUNC_MKTIME_WORKS])
 258
 259   REPLACE_MKTIME=0
 260   if test "$gl_cv_func_working_mktime" != yes; then
 261     REPLACE_MKTIME=1
 262     AC_DEFINE([NEED_MKTIME_WORKING], [1],
 263       [Define if the compilation of mktime.c should define 'mktime'
 264        with the algorithmic workarounds.])
 265   fi
 266   case "$host_os" in
 267     mingw*)
 268       REPLACE_MKTIME=1
 269       AC_DEFINE([NEED_MKTIME_WINDOWS], [1],
 270         [Define if the compilation of mktime.c should define 'mktime'
 271          with the native Windows TZ workaround.])
 272       ;;
 273   esac
 274 ])
 275
 276 dnl Main macro of module 'mktime-internal'.
 277 AC_DEFUN([gl_FUNC_MKTIME_INTERNAL], [
 278   AC_REQUIRE([gl_FUNC_MKTIME_WORKS])
 279
 280   WANT_MKTIME_INTERNAL=0
 281   dnl BeOS has __mktime_internal in libc, but other platforms don't.
 282   AC_CHECK_FUNC([__mktime_internal],
 283     [AC_DEFINE([mktime_internal], [__mktime_internal],
 284        [Define to the real name of the mktime_internal function.])
 285     ],
 286     [dnl mktime works but it doesn't export __mktime_internal,
 287      dnl so we need to substitute our own mktime implementation.
 288      WANT_MKTIME_INTERNAL=1
 289      AC_DEFINE([NEED_MKTIME_INTERNAL], [1],
 290        [Define if the compilation of mktime.c should define 'mktime_internal'.])
 291     ])
 292 ])
 293
 294 # Prerequisites of lib/mktime.c.
 295 AC_DEFUN([gl_PREREQ_MKTIME], [:])