configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.4.1)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h:src/config.in)
   8
   9 lispdir='${datadir}/emacs/${version}/lisp'
  10 locallisppath='${datadir}/emacs/site-lisp'
  11 lisppath='${locallisppath}:${lispdir}'
  12 etcdir='${datadir}/emacs/${version}/etc'
  13 lockdir='${sharedstatedir}/emacs/lock'
  14 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  15 docdir='${datadir}/emacs/${version}/etc'
  16
  17 AC_ARG_WITH(gcc,
  18 [  --with-gcc              use GCC to compile Emacs])
  19 AC_ARG_WITH(pop,
  20 [  --with-pop              support POP for mail retrieval],
  21 [AC_DEFINE(MAIL_USE_POP)])
  22 AC_ARG_WITH(kerberos,
  23 [  --with-kerberos         support Kerberos-authenticated POP],
  24 [AC_DEFINE(KERBEROS)])
  25 AC_ARG_WITH(hesiod,
  26 [  --with-hesiod           support Hesiod to get the POP server host],
  27 [AC_DEFINE(HESIOD)])
  28 dnl This should be the last --with option, because --with-x is
  29 dnl added later on when we find the path of X, and it's best to
  30 dnl keep them together visually.
  31 AC_ARG_WITH(x-toolkit,
  32 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  33 [         case "${withval}" in
  34             y | ye | yes )      val=athena ;;
  35             n | no )            val=no  ;;
  36             l | lu | luc | luci | lucid )       val=lucid ;;
  37             a | at | ath | athe | athena )      val=athena ;;
  38             m | mo | mot | moti | motif )       val=motif ;;
  39 dnl These don't currently work.
  40 dnl         o | op | ope | open | open- | open-l | open-lo \
  41 dnl             | open-loo | open-look )        val=open-look ;;
  42             * )
  43 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  44 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  45 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  46 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  47 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  48             ;;
  49           esac
  50           with_x_toolkit=$val
  51 ])
  52
  53 #### Make srcdir absolute, if it isn't already.  It's important to
  54 #### avoid running the path through pwd unnecessary, since pwd can
  55 #### give you automounter prefixes, which can go away.  We do all this
  56 #### so Emacs can find its files when run uninstalled.
  57 case "${srcdir}" in
  58   /* ) ;;
  59   . )
  60     ## We may be able to use the $PWD environment variable to make this
  61     ## absolute.  But sometimes PWD is inaccurate.
  62     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  63     CDPATH=
  64     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  65     then
  66       srcdir="$PWD"
  67     else
  68       srcdir="`(cd ${srcdir}; pwd)`"
  69     fi
  70   ;;
  71   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  72 esac
  73
  74 #### Check if the source directory already has a configured system in it.
  75 if test `pwd` != `(cd ${srcdir} && pwd)` \
  76    && test -f "${srcdir}/src/config.h" ; then
  77   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  78    as a build directory right now; it has been configured in its own
  79    right.  To configure in another directory as well, you MUST
  80    use GNU make.  If you do not have GNU make, then you must
  81    now do \`make distclean' in ${srcdir},
  82    and then run $0 again.])
  83
  84 changequote(, )dnl
  85   extrasub='/^VPATH[     ]*=/c\
  86 changequote([, ])dnl
  87 vpath %.c $(srcdir)\
  88 vpath %.h $(srcdir)\
  89 vpath %.y $(srcdir)\
  90 vpath %.l $(srcdir)\
  91 vpath %.s $(srcdir)\
  92 vpath %.in $(srcdir)'
  93 fi
  94
  95 #### Given the configuration name, set machfile and opsysfile to the
  96 #### names of the m/*.h and s/*.h files we should use.
  97
  98 ### Canonicalize the configuration name.
  99
 100 AC_CANONICAL_HOST
 101 canonical=$host
 102 configuration=$host_alias
 103
 104 changequote(, )dnl
 105
 106 ### If you add support for a new configuration, add code to this
 107 ### switch statement to recognize your configuration name and select
 108 ### the appropriate operating system and machine description files.
 109
 110 ### You would hope that you could choose an m/*.h file pretty much
 111 ### based on the machine portion of the configuration name, and an s-
 112 ### file based on the operating system portion.  However, it turns out
 113 ### that each m/*.h file is pretty manufacturer-specific - for
 114 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 115 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 116 ### machines.  So we basically have to have a special case for each
 117 ### configuration name.
 118 ###
 119 ### As far as handling version numbers on operating systems is
 120 ### concerned, make sure things will fail in a fixable way.  If
 121 ### /etc/MACHINES doesn't say anything about version numbers, be
 122 ### prepared to handle anything reasonably.  If version numbers
 123 ### matter, be sure /etc/MACHINES says something about it.
 124 ###
 125 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 126 ### "System V Release 4"; he writes, "The old convention encouraged
 127 ### confusion between `system' and `release' levels'."
 128
 129 machine='' opsys='' unported=no
 130 case "${canonical}" in
 131
 132   ## NetBSD ports
 133   *-*-netbsd* )
 134     opsys=netbsd
 135     case "${canonical}" in
 136       i[345]86-*-netbsd*) machine=intel386 ;;
 137       m68k-*-netbsd*)
 138                         # This is somewhat bogus.
 139                         machine=hp9000s300 ;;
 140       mips-*-netbsd*)   machine=pmax ;;
 141       ns32k-*-netbsd*)  machine=ns32000 ;;
 142       sparc-*-netbsd*)  machine=sparc ;;
 143     esac
 144   ;;
 145
 146   ## Acorn RISCiX:
 147   arm-acorn-riscix1.1* )
 148     machine=acorn opsys=riscix1-1
 149   ;;
 150   arm-acorn-riscix1.2* | arm-acorn-riscix )
 151     machine=acorn opsys=riscix1-2
 152   ;;
 153
 154   ## Alliant machines
 155   ## Strictly speaking, we need the version of the alliant operating
 156   ## system to choose the right machine file, but currently the
 157   ## configuration name doesn't tell us enough to choose the right
 158   ## one; we need to give alliants their own operating system name to
 159   ## do this right.  When someone cares, they can help us.
 160   fx80-alliant-* )
 161     machine=alliant4 opsys=bsd4-2
 162   ;;
 163   i860-alliant-* )
 164     machine=alliant-2800 opsys=bsd4-3
 165   ;;
 166
 167   alpha-dec-osf* )
 168     machine=alpha opsys=osf1
 169   ;;
 170
 171   ## Altos 3068
 172   m68*-altos-sysv* )
 173     machine=altos opsys=usg5-2
 174   ;;
 175
 176   ## Amdahl UTS
 177   580-amdahl-sysv* )
 178     machine=amdahl opsys=usg5-2-2
 179   ;;
 180
 181   ## Apollo, Domain/OS
 182   m68*-apollo-* )
 183     machine=apollo opsys=bsd4-3
 184   ;;
 185
 186   ## AT&T 3b2, 3b5, 3b15, 3b20
 187   we32k-att-sysv* )
 188     machine=att3b opsys=usg5-2-2
 189   ;;
 190
 191   ## AT&T 3b1 - The Mighty Unix PC!
 192   m68*-att-sysv* )
 193     machine=7300 opsys=usg5-2-2
 194   ;;
 195
 196   ## Bull dpx20
 197   rs6000-bull-bosx* )
 198     machine=ibmrs6000 opsys=aix3-2
 199   ;;
 200
 201   ## Bull dpx2
 202   m68*-bull-sysv3* )
 203     machine=dpx2 opsys=usg5-3
 204   ;;
 205
 206   ## Bull sps7
 207   m68*-bull-sysv2* )
 208     machine=sps7 opsys=usg5-2
 209   ;;
 210
 211   ## CCI 5/32, 6/32 -- see "Tahoe".
 212
 213   ## Celerity
 214   ## I don't know what configuration name to use for this; config.sub
 215   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 216   ## in touch with us!
 217   celerity-celerity-bsd* )
 218     machine=celerity opsys=bsd4-2
 219   ;;
 220
 221   ## Clipper
 222   ## What operating systems does this chip run that Emacs has been
 223   ## tested on?
 224   clipper-* )
 225     machine=clipper
 226     ## We'll use the catch-all code at the bottom to guess the
 227     ## operating system.
 228   ;;
 229
 230   ## Convex
 231   *-convex-bsd* | *-convex-convexos* )
 232     machine=convex opsys=bsd4-3
 233     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 234     NON_GNU_CPP="cc -E -P"
 235   ;;
 236
 237   ## Cubix QBx/386
 238   i[345]86-cubix-sysv* )
 239     machine=intel386 opsys=usg5-3
 240   ;;
 241
 242   ## Cydra 5
 243   cydra*-cydrome-sysv* )
 244     machine=cydra5 opsys=usg5-3
 245   ;;
 246
 247   ## Data General AViiON Machines
 248   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 249     machine=aviion opsys=dgux5-4r3
 250   ;;
 251   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 252     machine=aviion opsys=dgux5-4r2
 253   ;;
 254   m88k-dg-dgux* )
 255     machine=aviion opsys=dgux
 256   ;;
 257
 258   ## DECstations
 259   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 260     machine=pmax opsys=bsd4-2
 261   ;;
 262   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 263     machine=pmax opsys=bsd4-3
 264   ;;
 265   mips-dec-ultrix* )
 266     machine=pmax opsys=ultrix4-3
 267   ;;
 268   mips-dec-osf* )
 269     machine=pmax opsys=osf1
 270   ;;
 271   mips-dec-mach_bsd4.3* )
 272     machine=pmax opsys=mach-bsd4-3
 273   ;;
 274
 275   ## Motorola Delta machines
 276   m68k-motorola-sysv* | m68000-motorola-sysv* )
 277     machine=delta opsys=usg5-3
 278     if test -z "`type gnucc | grep 'not found'`"
 279     then
 280       if test -s /etc/167config
 281       then CC="gnucc -m68040"
 282       else CC="gnucc -m68881"
 283       fi
 284     else
 285       if test -z "`type gcc | grep 'not found'`"
 286       then CC=gcc
 287       else CC=cc
 288       fi
 289     fi
 290   ;;
 291   m88k-motorola-sysv4* )
 292     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 293     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 294     # I hope there are not other 4.0 versions for this machine
 295     # which really need usg5-4 instead.
 296     machine=delta88k opsys=usg5-4-2
 297   ;;
 298   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 299     machine=delta88k opsys=usg5-3
 300   ;;
 301
 302   ## Dual machines
 303   m68*-dual-sysv* )
 304     machine=dual opsys=usg5-2
 305   ;;
 306   m68*-dual-uniplus* )
 307     machine=dual opsys=unipl5-2
 308   ;;
 309
 310   ## Elxsi 6400
 311   elxsi-elxsi-sysv* )
 312     machine=elxsi opsys=usg5-2
 313   ;;
 314
 315   ## Encore machines
 316   ns16k-encore-bsd* )
 317     machine=ns16000 opsys=umax
 318   ;;
 319
 320   ## The GEC 93 - apparently, this port isn't really finished yet.
 321
 322   ## Gould Power Node and NP1
 323   pn-gould-bsd4.2* )
 324     machine=gould opsys=bsd4-2
 325   ;;
 326   pn-gould-bsd4.3* )
 327     machine=gould opsys=bsd4-3
 328   ;;
 329   np1-gould-bsd* )
 330     machine=gould-np1 opsys=bsd4-3
 331   ;;
 332
 333   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 334   ## as far as Emacs is concerned).
 335   m88k-harris-cxux* )
 336     # Build needs to be different on 7.0 and later releases
 337     case "`uname -r`" in
 338        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 339        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 340     esac
 341   ;;
 342   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 343   m68k-harris-cxux* )
 344     machine=nh3000 opsys=cxux
 345   ;;
 346
 347   ## Honeywell XPS100
 348   xps*-honeywell-sysv* )
 349     machine=xps100 opsys=usg5-2
 350   ;;
 351
 352   ## HP 9000 series 200 or 300
 353   m68*-hp-bsd* )
 354     machine=hp9000s300 opsys=bsd4-3
 355   ;;
 356   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 357   m68*-hp-hpux* )
 358     case "`uname -r`" in
 359       ## Someone's system reports A.B8.05 for this.
 360       ## I wonder what other possibilities there are.
 361       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 362       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 363       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 364       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 365       *) machine=hp9000s300 opsys=hpux ;;
 366     esac
 367   ;;
 368
 369   ## HP 9000 series 700 and 800, running HP/UX
 370   hppa*-hp-hpux7* )
 371     machine=hp800 opsys=hpux
 372   ;;
 373   hppa*-hp-hpux8* )
 374     machine=hp800 opsys=hpux8
 375   ;;
 376   hppa*-hp-hpux9shr* )
 377     machine=hp800 opsys=hpux9shr
 378   ;;
 379   hppa*-hp-hpux9* )
 380     machine=hp800 opsys=hpux9
 381   ;;
 382   hppa*-hp-hpux10* )
 383     machine=hp800 opsys=hpux9shr
 384   ;;
 385
 386   ## HP 9000 series 700 and 800, running HP/UX
 387   hppa*-hp-hpux* )
 388     ## Cross-compilation?  Nah!
 389     case "`uname -r`" in
 390       ## Someone's system reports A.B8.05 for this.
 391       ## I wonder what other possibilities there are.
 392       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 393       *.08.* ) machine=hp800 opsys=hpux8 ;;
 394       *.09.* ) machine=hp800 opsys=hpux9 ;;
 395       *) machine=hp800 opsys=hpux ;;
 396     esac
 397   ;;
 398
 399   ## Orion machines
 400   orion-orion-bsd* )
 401     machine=orion opsys=bsd4-2
 402   ;;
 403   clipper-orion-bsd* )
 404     machine=orion105 opsys=bsd4-2
 405   ;;
 406
 407   ## IBM machines
 408   i[345]86-ibm-aix1.1* )
 409     machine=ibmps2-aix opsys=usg5-2-2
 410   ;;
 411   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 412     machine=ibmps2-aix opsys=usg5-3
 413   ;;
 414   i370-ibm-aix*)
 415     machine=ibm370aix opsys=usg5-3
 416   ;;
 417   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 418     machine=ibmrs6000 opsys=aix3-1
 419   ;;
 420   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 421     machine=ibmrs6000 opsys=aix3-2-5
 422   ;;
 423   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 424     machine=ibmrs6000 opsys=aix4-1
 425   ;;
 426   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 427     machine=ibmrs6000 opsys=aix4
 428   ;;
 429   rs6000-ibm-aix* | powerpc-ibm-aix* )
 430     machine=ibmrs6000 opsys=aix3-2
 431   ;;
 432   romp-ibm-bsd4.3* )
 433     machine=ibmrt opsys=bsd4-3
 434   ;;
 435   romp-ibm-bsd4.2* )
 436     machine=ibmrt opsys=bsd4-2
 437   ;;
 438   romp-ibm-aos4.3* )
 439     machine=ibmrt opsys=bsd4-3
 440   ;;
 441   romp-ibm-aos4.2* )
 442     machine=ibmrt opsys=bsd4-2
 443   ;;
 444   romp-ibm-aos* )
 445     machine=ibmrt opsys=bsd4-3
 446   ;;
 447   romp-ibm-bsd* )
 448     machine=ibmrt opsys=bsd4-3
 449   ;;
 450   romp-ibm-aix* )
 451     machine=ibmrt-aix opsys=usg5-2-2
 452   ;;
 453
 454   ## Integrated Solutions `Optimum V'
 455   m68*-isi-bsd4.2* )
 456     machine=isi-ov opsys=bsd4-2
 457   ;;
 458   m68*-isi-bsd4.3* )
 459     machine=isi-ov opsys=bsd4-3
 460   ;;
 461
 462   ## Intel 386 machines where we do care about the manufacturer
 463   i[345]86-intsys-sysv* )
 464     machine=is386 opsys=usg5-2-2
 465   ;;
 466
 467   ## Prime EXL
 468   i[345]86-prime-sysv* )
 469     machine=i386 opsys=usg5-3
 470   ;;
 471
 472   ## Sequent Symmetry running Dynix
 473   i[345]86-sequent-bsd* )
 474     machine=symmetry opsys=bsd4-3
 475   ;;
 476
 477   ## Sequent Symmetry running DYNIX/ptx
 478   ## Use the old cpp rather than the newer ANSI one.
 479   i[345]86-sequent-ptx* )
 480     machine=sequent-ptx opsys=ptx
 481     NON_GNU_CPP="/lib/cpp"
 482   ;;
 483
 484   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 485   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 486   i[345]86-ncr-sysv* )
 487     machine=ncr386 opsys=usg5-4-2
 488   ;;
 489
 490   ## Intel Paragon OSF/1
 491   i860-intel-osf1* )
 492     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 493   ;;
 494
 495   ## Intel 860
 496   i860-*-sysv4* )
 497     machine=i860 opsys=usg5-4
 498     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 499     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 500   ;;
 501
 502   ## Masscomp machines
 503   m68*-masscomp-rtu* )
 504     machine=masscomp opsys=rtu
 505   ;;
 506
 507   ## Megatest machines
 508   m68*-megatest-bsd* )
 509     machine=mega68 opsys=bsd4-2
 510   ;;
 511
 512   ## Workstations sold by MIPS
 513   ## This is not necessarily all workstations using the MIPS processor -
 514   ## Irises are produced by SGI, and DECstations by DEC.
 515
 516   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 517   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 518   ## it gives for choosing between the alternatives seems to be "Use
 519   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 520   ## the BSD world."  I'll assume that these are instructions for
 521   ## handling two odd situations, and that every other situation
 522   ## should use mips.h and usg5-2-2, they being listed first.
 523   mips-mips-usg* )
 524     machine=mips4
 525     ## Fall through to the general code at the bottom to decide on the OS.
 526   ;;
 527   mips-mips-riscos4* )
 528     machine=mips4 opsys=bsd4-3
 529     NON_GNU_CC="cc -systype bsd43"
 530     NON_GNU_CPP="cc -systype bsd43 -E"
 531   ;;
 532   mips-mips-riscos5* )
 533     machine=mips4 opsys=riscos5
 534     NON_GNU_CC="cc -systype bsd43"
 535     NON_GNU_CPP="cc -systype bsd43 -E"
 536   ;;
 537   mips-mips-bsd* )
 538     machine=mips opsys=bsd4-3
 539   ;;
 540   mips-mips-* )
 541     machine=mips opsys=usg5-2-2
 542   ;;
 543
 544   ## NeXT
 545   m68*-next-* | i[345]86-next-* )
 546     machine=next opsys=mach2
 547   ;;
 548
 549   ## The complete machine from National Semiconductor
 550   ns32k-ns-genix* )
 551     machine=ns32000 opsys=usg5-2
 552   ;;
 553
 554   ## NCR machines
 555   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 556     machine=tower32 opsys=usg5-2-2
 557   ;;
 558   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 559     machine=tower32v3 opsys=usg5-3
 560   ;;
 561
 562   ## Nixdorf Targon 31
 563   m68*-nixdorf-sysv* )
 564     machine=targon31 opsys=usg5-2-2
 565   ;;
 566
 567   ## Nu (TI or LMI)
 568   m68*-nu-sysv* )
 569     machine=nu opsys=usg5-2
 570   ;;
 571
 572   ## Plexus
 573   m68*-plexus-sysv* )
 574     machine=plexus opsys=usg5-2
 575   ;;
 576
 577   ## Pyramid machines
 578   ## I don't really have any idea what sort of processor the Pyramid has,
 579   ## so I'm assuming it is its own architecture.
 580   pyramid-pyramid-bsd* )
 581     machine=pyramid opsys=bsd4-2
 582   ;;
 583
 584   ## Sequent Balance
 585   ns32k-sequent-bsd4.2* )
 586     machine=sequent opsys=bsd4-2
 587   ;;
 588   ns32k-sequent-bsd4.3* )
 589     machine=sequent opsys=bsd4-3
 590   ;;
 591
 592   ## Siemens Nixdorf
 593   mips-siemens-sysv* )
 594     machine=mips-siemens opsys=usg5-4
 595     NON_GNU_CC=/usr/ccs/bin/cc
 596     NON_GNU_CPP=/usr/ccs/lib/cpp
 597   ;;
 598
 599   ## Silicon Graphics machines
 600   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 601   m68*-sgi-iris3.5* )
 602     machine=irist opsys=iris3-5
 603   ;;
 604   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 605     machine=irist opsys=iris3-6
 606   ;;
 607   ## Iris 4D
 608   mips-sgi-irix3* )
 609     machine=iris4d opsys=irix3-3
 610   ;;
 611   mips-sgi-irix4* )
 612     machine=iris4d opsys=irix4-0
 613   ;;
 614   mips-sgi-irix6* )
 615     machine=iris4d opsys=irix6-0
 616   ;;
 617   mips-sgi-irix5.[01]* )
 618     machine=iris4d opsys=irix5-0
 619   ;;
 620   mips-sgi-irix5* | mips-sgi-irix* )
 621     machine=iris4d opsys=irix5-2
 622   ;;
 623
 624   ## SONY machines
 625   m68*-sony-bsd4.2* )
 626     machine=news opsys=bsd4-2
 627   ;;
 628   m68*-sony-bsd4.3* )
 629     machine=news opsys=bsd4-3
 630   ;;
 631   m68*-sony-newsos3* | m68*-sony-news3*)
 632     machine=news opsys=bsd4-3
 633   ;;
 634   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 635     machine=news-risc opsys=bsd4-3
 636   ;;
 637   mips-sony-news* )
 638     machine=news-risc opsys=newsos5
 639   ;;
 640
 641   ## Stride
 642   m68*-stride-sysv* )
 643     machine=stride opsys=usg5-2
 644   ;;
 645
 646   ## Suns
 647   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 648     case "${canonical}" in
 649       m68*-sunos1* )    machine=sun1 ;;
 650       m68*-sunos2* )    machine=sun2 ;;
 651       m68* )            machine=sun3 ;;
 652       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 653       i[345]86-*-* )     machine=intel386 ;;
 654       sparc* )          machine=sparc ;;
 655       * )               unported=yes ;;
 656     esac
 657     case "${canonical}" in
 658       ## The Sun386 didn't get past 4.0.
 659       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 660       *-sunos4.0*         ) opsys=sunos4-0 ;;
 661       *-sunos4.1.[3-9]* )
 662                 opsys=sunos4shr
 663                 NON_GNU_CPP=/usr/lib/cpp
 664                 ;;
 665       *-sunos4* | *-sunos ) opsys=sunos4-1
 666                 NON_GCC_TEST_OPTIONS=-Bstatic
 667                 GCC_TEST_OPTIONS=-static
 668                 ;;
 669       *-sunos5.3* | *-solaris2.3* )
 670                 opsys=sol2-3
 671                 NON_GNU_CPP=/usr/ccs/lib/cpp
 672                 ;;
 673       *-sunos5.4* | *-solaris2.4* )
 674                 opsys=sol2-4
 675                 NON_GNU_CPP=/usr/ccs/lib/cpp
 676                 ;;
 677       *-sunos5.5* | *-solaris2.5* )
 678                 opsys=sol2-5
 679                 NON_GNU_CPP=/usr/ccs/lib/cpp
 680                 ;;
 681       *-sunos5* | *-solaris* )
 682                 opsys=sol2
 683                 NON_GNU_CPP=/usr/ccs/lib/cpp
 684                 ;;
 685       *                   ) opsys=bsd4-2   ;;
 686     esac
 687   ;;
 688
 689   ## Tadpole 68k
 690   m68*-tadpole-sysv* )
 691     machine=tad68k opsys=usg5-3
 692   ;;
 693
 694   ## Tahoe machines
 695   tahoe-tahoe-bsd4.2* )
 696     machine=tahoe opsys=bsd4-2
 697   ;;
 698   tahoe-tahoe-bsd4.3* )
 699     machine=tahoe opsys=bsd4-3
 700   ;;
 701
 702   ## Tandem Integrity S2
 703   mips-tandem-sysv* )
 704     machine=tandem-s2 opsys=usg5-3
 705   ;;
 706
 707   ## Tektronix XD88
 708   m88k-tektronix-sysv3* )
 709   machine=tekxd88 opsys=usg5-3
 710   ;;
 711
 712   ## Tektronix 16000 box (6130?)
 713   ns16k-tektronix-bsd* )
 714     machine=ns16000 opsys=bsd4-2
 715   ;;
 716   ## Tektronix 4300
 717   ## src/m/tek4300.h hints that this is a m68k machine.
 718   m68*-tektronix-bsd* )
 719     machine=tek4300 opsys=bsd4-3
 720   ;;
 721
 722   ## Titan P2 or P3
 723   ## We seem to have lost the machine-description file titan.h!
 724   titan-titan-sysv* )
 725     machine=titan opsys=usg5-3
 726   ;;
 727
 728   ## Ustation E30 (SS5E)
 729   m68*-unisys-uniplus* )
 730     machine=ustation opsystem=unipl5-2
 731   ;;
 732
 733   ## Vaxen.
 734   vax-dec-* )
 735     machine=vax
 736     case "${canonical}" in
 737       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 738       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 739       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 740       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 741       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 742       *-vms* )                                          opsys=vms ;;
 743       * )                                               unported=yes
 744     esac
 745   ;;
 746
 747   ## Whitechapel MG1
 748   ns16k-whitechapel-* )
 749     machine=mg1
 750     ## We don't know what sort of OS runs on these; we'll let the
 751     ## operating system guessing code below try.
 752   ;;
 753
 754   ## Wicat
 755   m68*-wicat-sysv* )
 756     machine=wicat opsys=usg5-2
 757   ;;
 758
 759   ## Intel 386 machines where we don't care about the manufacturer
 760   i[345]86-*-* )
 761     machine=intel386
 762     case "${canonical}" in
 763       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 764       *-isc2.2* )               opsys=isc2-2 ;;
 765       *-isc4.0* )               opsys=isc4-0 ;;
 766       *-isc4.* )                opsys=isc4-1 ;;
 767       *-isc* )                  opsys=isc3-0 ;;
 768       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 769       *-esix* )                 opsys=esix ;;
 770       *-xenix* )                opsys=xenix ;;
 771       *-linux* )                opsys=linux ;;
 772       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 773       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
 774       *-bsdi2* )                opsys=bsdos2 ;;
 775       *-386bsd* )               opsys=386bsd ;;
 776       *-freebsd* )              opsys=freebsd ;;
 777       *-nextstep* )             opsys=mach2 ;;
 778       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 779     esac
 780   ;;
 781
 782   * )
 783     unported=yes
 784   ;;
 785 esac
 786
 787 ### If the code above didn't choose an operating system, just choose
 788 ### an operating system based on the configuration name.  You really
 789 ### only want to use this when you have no idea what the right
 790 ### operating system is; if you know what operating systems a machine
 791 ### runs, it's cleaner to make it explicit in the case statement
 792 ### above.
 793 if test x"${opsys}" = x; then
 794   case "${canonical}" in
 795     *-gnu* )                            opsys=gnu ;;
 796     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 797     *-bsd4.2 )                          opsys=bsd4-2 ;;
 798     *-bsd4.3 )                          opsys=bsd4-3 ;;
 799     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 800     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 801     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 802     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 803     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 804     *-sysv4.1 | *-sysvr4.1 )
 805         NON_GNU_CPP=/usr/lib/cpp
 806         opsys=usg5-4 ;;
 807     *-sysv4.2 | *-sysvr4.2 )
 808         if [ x$NON_GNU_CPP = x ]; then
 809           NON_GNU_CPP=/usr/ccs/lib/cpp
 810         fi
 811         opsys=usg5-4-2 ;;
 812     * )
 813       unported=yes
 814     ;;
 815   esac
 816 fi
 817
 818 changequote([, ])dnl
 819
 820 if test $unported = yes; then
 821   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 822 Check \`etc/MACHINES' for recognized configuration names.])
 823 fi
 824
 825 machfile="m/${machine}.h"
 826 opsysfile="s/${opsys}.h"
 827
 828
 829 #### Choose a compiler.
 830 test -n "$CC" && cc_specified=yes
 831
 832 case ${with_gcc} in
 833   "yes" ) CC="gcc" GCC=yes ;;
 834   "no"  ) : ${CC=cc} ;;
 835   * ) AC_PROG_CC
 836 esac
 837
 838 # On Suns, sometimes $CPP names a directory.
 839 if test -n "$CPP" && test -d "$CPP"; then
 840   CPP=
 841 fi
 842
 843 #### Some systems specify a CPP to use unless we are using GCC.
 844 #### Now that we know whether we are using GCC, we can decide whether
 845 #### to use that one.
 846 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 847 then
 848   CPP="$NON_GNU_CPP"
 849 fi
 850
 851 #### Some systems specify a CC to use unless we are using GCC.
 852 #### Now that we know whether we are using GCC, we can decide whether
 853 #### to use that one.
 854 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 855   test x$cc_specified != xyes
 856 then
 857   CC="$NON_GNU_CC"
 858 fi
 859
 860 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 861 then
 862   CC="$CC $GCC_TEST_OPTIONS"
 863 fi
 864
 865 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 866 then
 867   CC="$CC $NON_GCC_TEST_OPTIONS"
 868 fi
 869
 870 #### Some other nice autoconf tests.  If you add a test here which
 871 #### should make an entry in src/config.h, don't forget to add an
 872 #### #undef clause to src/config.h.in for autoconf to modify.
 873
 874 dnl checks for programs
 875 AC_PROG_LN_S
 876 AC_PROG_CPP
 877 AC_PROG_INSTALL
 878 AC_PROG_YACC
 879
 880 dnl checks for Unix variants
 881 AC_AIX
 882
 883 dnl checks for header files
 884 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 885 AC_HEADER_STDC
 886 AC_HEADER_TIME
 887 AC_DECL_SYS_SIGLIST
 888
 889 dnl Some systems have utime.h but don't declare the struct anyplace.
 890 AC_MSG_CHECKING(for struct utimbuf)
 891 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 892 #include <sys/time.h>
 893 #include <time.h>
 894 #else
 895 #ifdef HAVE_SYS_TIME_H
 896 #include <sys/time.h>
 897 #else
 898 #include <time.h>
 899 #endif
 900 #endif
 901 #ifdef HAVE_UTIME_H
 902 #include <utime.h>
 903 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 904   [AC_MSG_RESULT(yes)
 905    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 906   AC_MSG_RESULT(no))
 907
 908 dnl checks for typedefs
 909 AC_TYPE_SIGNAL
 910
 911 AC_MSG_CHECKING(for struct timeval)
 912 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 913 #include <sys/time.h>
 914 #include <time.h>
 915 #else
 916 #ifdef HAVE_SYS_TIME_H
 917 #include <sys/time.h>
 918 #else
 919 #include <time.h>
 920 #endif
 921 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 922   [AC_MSG_RESULT(yes)
 923    AC_DEFINE(HAVE_TIMEVAL)],
 924   AC_MSG_RESULT(no))
 925
 926 dnl checks for structure members
 927 AC_STRUCT_TM
 928 AC_STRUCT_TIMEZONE
 929
 930 dnl checks for compiler characteristics
 931 AC_C_CONST
 932
 933 dnl check for Make feature
 934 AC_PROG_MAKE_SET
 935
 936 dnl checks for operating system services
 937 AC_SYS_LONG_FILE_NAMES
 938
 939 #### Choose a window system.
 940
 941 AC_PATH_X
 942 if test "$no_x" = yes; then
 943   window_system=none
 944 else
 945   window_system=x11
 946 fi
 947
 948 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 949   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
 950   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
 951 fi
 952 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 953   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
 954 fi
 955
 956 if test x"${x_includes}" = x; then
 957   bitmapdir=/usr/include/X11/bitmaps
 958 else
 959   # accumulate include directories that have X11 bitmap sudirectories
 960   bmd_acc="dummyval"
 961   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
 962     if test -d "${bmd}/X11/bitmaps"; then
 963       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
 964     elif test -d "${bmd}/bitmaps"; then
 965       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
 966     fi
 967   done
 968   if test ${bmd_acc} != "dummyval"; then
 969     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
 970   fi
 971 fi
 972
 973 case "${window_system}" in
 974   x11 )
 975     HAVE_X_WINDOWS=yes
 976     HAVE_X11=yes
 977     case "${with_x_toolkit}" in
 978       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 979       motif ) USE_X_TOOLKIT=MOTIF ;;
 980 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 981       * ) USE_X_TOOLKIT=none ;;
 982     esac
 983   ;;
 984   none )
 985     HAVE_X_WINDOWS=no
 986     HAVE_X11=no
 987     USE_X_TOOLKIT=none
 988   ;;
 989 esac
 990 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 991
 992 ### If we're using X11, we should use the X menu package.
 993 HAVE_X_MENU=no
 994 case ${HAVE_X11} in
 995   yes ) HAVE_X_MENU=yes ;;
 996 esac
 997
 998 if test "${opsys}" = "hpux9"; then
 999   case "${x_libraries}" in
1000     *X11R4* )
1001       opsysfile="s/hpux9-x11r4.h"
1002       ;;
1003   esac
1004 fi
1005
1006 if test "${opsys}" = "hpux9shr"; then
1007   case "${x_libraries}" in
1008     *X11R4* )
1009       opsysfile="s/hpux9shxr4.h"
1010       ;;
1011   esac
1012 fi
1013
1014 #### Extract some information from the operating system and machine files.
1015
1016 AC_CHECKING([the machine- and system-dependent files to find out
1017  - which libraries the lib-src programs will want, and
1018  - whether the GNU malloc routines are usable])
1019
1020 ### First figure out CFLAGS (which we use for running the compiler here)
1021 ### and REAL_CFLAGS (which we use for real compilation).
1022 ### The two are the same except on a few systems, where they are made
1023 ### different to work around various lossages.  For example,
1024 ### GCC 2.5 on Linux needs them to be different because it treats -g
1025 ### as implying static linking.
1026
1027 ### If the CFLAGS env var is specified, we use that value
1028 ### instead of the default.
1029
1030 ### It's not important that this name contain the PID; you can't run
1031 ### two configures in the same directory and have anything work
1032 ### anyway.
1033 tempcname="conftest.c"
1034
1035 echo '
1036 #include "'${srcdir}'/src/'${opsysfile}'"
1037 #include "'${srcdir}'/src/'${machfile}'"
1038 #ifndef LIBS_MACHINE
1039 #define LIBS_MACHINE
1040 #endif
1041 #ifndef LIBS_SYSTEM
1042 #define LIBS_SYSTEM
1043 #endif
1044 #ifndef C_SWITCH_SYSTEM
1045 #define C_SWITCH_SYSTEM
1046 #endif
1047 #ifndef C_SWITCH_MACHINE
1048 #define C_SWITCH_MACHINE
1049 #endif
1050 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1051 configure___ c_switch_system=C_SWITCH_SYSTEM
1052 configure___ c_switch_machine=C_SWITCH_MACHINE
1053
1054 #ifndef LIB_X11_LIB
1055 #define LIB_X11_LIB -lX11
1056 #endif
1057
1058 #ifndef LIBX11_MACHINE
1059 #define LIBX11_MACHINE
1060 #endif
1061
1062 #ifndef LIBX11_SYSTEM
1063 #define LIBX11_SYSTEM
1064 #endif
1065 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1066
1067 #ifdef UNEXEC
1068 configure___ unexec=UNEXEC
1069 #else
1070 configure___ unexec=unexec.o
1071 #endif
1072
1073 #ifdef SYSTEM_MALLOC
1074 configure___ system_malloc=yes
1075 #else
1076 configure___ system_malloc=no
1077 #endif
1078
1079 #ifndef C_DEBUG_SWITCH
1080 #define C_DEBUG_SWITCH -g
1081 #endif
1082
1083 #ifndef C_OPTIMIZE_SWITCH
1084 #define C_OPTIMIZE_SWITCH -O
1085 #endif
1086
1087 #ifdef THIS_IS_CONFIGURE
1088
1089 /* Get the CFLAGS for tests in configure.  */
1090 #ifdef __GNUC__
1091 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1092 #else
1093 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1094 #endif
1095
1096 #else /* not THIS_IS_CONFIGURE */
1097
1098 /* Get the CFLAGS for real compilation.  */
1099 #ifdef __GNUC__
1100 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1101 #else
1102 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1103 #endif
1104
1105 #endif /* not THIS_IS_CONFIGURE */
1106 ' > ${tempcname}
1107
1108 # The value of CPP is a quoted variable reference, so we need to do this
1109 # to get its actual value...
1110 CPP=`eval "echo $CPP"`
1111 changequote(, )dnl
1112 eval `${CPP} -Isrc ${tempcname} \
1113        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1114 if test "x$CFLAGS" = x; then
1115   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1116          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1117 else
1118   REAL_CFLAGS="$CFLAGS"
1119 fi
1120 changequote([, ])dnl
1121 rm ${tempcname}
1122
1123 ### Compute the unexec source name from the object name.
1124 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1125
1126 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1127 # Assume not, until told otherwise.
1128 GNU_MALLOC=yes
1129 if test "${system_malloc}" = "yes"; then
1130   GNU_MALLOC=no
1131   GNU_MALLOC_reason="
1132   (The GNU allocators don't work with this system configuration.)"
1133 fi
1134
1135 if test x"${REL_ALLOC}" = x; then
1136   REL_ALLOC=${GNU_MALLOC}
1137 fi
1138
1139 LISP_FLOAT_TYPE=yes
1140
1141
1142 #### Add the libraries to LIBS and check for some functions.
1143
1144 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1145 LIBS="$libsrc_libs"
1146
1147 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1148 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1149 AC_CHECK_LIB(dnet, dnet_ntoa)
1150 dnl This causes -lresolv to get used in subsequent tests,
1151 dnl which causes failures on some systems such as HPUX 9.
1152 dnl AC_CHECK_LIB(resolv, gethostbyname)
1153
1154 dnl FIXME replace main with a function we actually want from this library.
1155 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1156
1157 AC_CHECK_LIB(pthreads, cma_open)
1158
1159 AC_MSG_CHECKING(for XFree86)
1160 if test -d /usr/X386/include; then
1161   HAVE_XFREE386=yes
1162   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1163 else
1164   HAVE_XFREE386=no
1165 fi
1166 AC_MSG_RESULT($HAVE_XFREE386)
1167
1168 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1169 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1170
1171 if test "${HAVE_X11}" = "yes"; then
1172   DEFS="$C_SWITCH_X_SITE $DEFS"
1173   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1174   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1175
1176   if test "${opsys}" = "linux"; then
1177     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1178     AC_TRY_LINK([],
1179      [XOpenDisplay ("foo");],
1180      [xlinux_first_failure=no],
1181      [xlinux_first_failure=yes])
1182     if test "${xlinux_first_failure}" = "yes"; then
1183       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1184       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1185       OLD_CPPFLAGS="$CPPFLAGS"
1186       OLD_LIBS="$LIBS"
1187       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1188       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1189       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1190       LIBS="$LIBS -b i486-linuxaout"
1191       AC_TRY_LINK([],
1192        [XOpenDisplay ("foo");],
1193        [xlinux_second_failure=no],
1194        [xlinux_second_failure=yes])
1195       if test "${xlinux_second_failure}" = "yes"; then
1196         # If we get the same failure with -b, there is no use adding -b.
1197         # So take it out.  This plays safe.
1198         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1199         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1200         CPPFLAGS="$OLD_CPPFLAGS"
1201         LIBS="$OLD_LIBS"
1202         AC_MSG_RESULT(no)
1203       else
1204         AC_MSG_RESULT(yes)
1205       fi
1206     else
1207       AC_MSG_RESULT(no)
1208     fi
1209   fi
1210
1211   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1212 XScreenNumberOfScreen XSetWMProtocols)
1213 fi
1214
1215 if test "${USE_X_TOOLKIT}" != "none"; then
1216   AC_MSG_CHECKING(X11 toolkit version)
1217   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1218 [#if XtSpecificationRelease < 6
1219 fail;
1220 #endif
1221 ], [AC_MSG_RESULT(6)
1222     AC_DEFINE(HAVE_X11XTR6)],
1223    [AC_MSG_RESULT(not 6)])
1224 fi
1225
1226 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1227 AC_MSG_CHECKING(whether netdb declares h_errno)
1228 AC_TRY_LINK([#include <netdb.h>],
1229   [return h_errno;],
1230   [AC_MSG_RESULT(yes)
1231    AC_DEFINE(HAVE_H_ERRNO)],
1232   [AC_MSG_RESULT(no)])
1233
1234 AC_FUNC_ALLOCA
1235
1236 # fmod, logb, and frexp are found in -lm on most systems.
1237 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1238 AC_CHECK_LIB(m, sqrt(0.0) + t)
1239 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1240 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1241 strerror fpathconf select mktime eaccess getpagesize)
1242
1243 ok_so_far=yes
1244 AC_CHECK_FUNC(socket, , ok_so_far=no)
1245 if test $ok_so_far = yes; then
1246   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1247 fi
1248 if test $ok_so_far = yes; then
1249   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1250 fi
1251 if test $ok_so_far = yes; then
1252   AC_DEFINE(HAVE_INET_SOCKETS)
1253 fi
1254
1255 if test -f /usr/lpp/X11/bin/smt.exp; then
1256   AC_DEFINE(HAVE_AIX_SMT_EXP)
1257 fi
1258
1259 # Set up the CFLAGS for real compilation, so we can substitute it.
1260 CFLAGS="$REAL_CFLAGS"
1261
1262 changequote(, )dnl
1263 #### Find out which version of Emacs this is.
1264 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1265          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1266 changequote([, ])dnl
1267 if test x"${version}" = x; then
1268   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1269 fi
1270
1271 ### Specify what sort of things we'll be editing into Makefile and config.h.
1272 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1273 AC_SUBST(version)
1274 AC_SUBST(configuration)
1275 AC_SUBST(canonical)
1276 AC_SUBST(srcdir)
1277 AC_SUBST(prefix)
1278 AC_SUBST(exec_prefix)
1279 AC_SUBST(bindir)
1280 AC_SUBST(datadir)
1281 AC_SUBST(sharedstatedir)
1282 AC_SUBST(libexecdir)
1283 AC_SUBST(mandir)
1284 AC_SUBST(infodir)
1285 AC_SUBST(lispdir)
1286 AC_SUBST(locallisppath)
1287 AC_SUBST(lisppath)
1288 AC_SUBST(etcdir)
1289 AC_SUBST(lockdir)
1290 AC_SUBST(archlibdir)
1291 AC_SUBST(docdir)
1292 AC_SUBST(bitmapdir)
1293 AC_SUBST(c_switch_system)
1294 AC_SUBST(c_switch_machine)
1295 AC_SUBST(LD_SWITCH_X_SITE)
1296 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1297 AC_SUBST(C_SWITCH_X_SITE)
1298 AC_SUBST(CFLAGS)
1299 AC_SUBST(X_TOOLKIT_TYPE)
1300 AC_SUBST(machfile)
1301 AC_SUBST(opsysfile)
1302
1303 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1304 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1305 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1306 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1307 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1308 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1309 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1310 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1311
1312 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1313   AC_DEFINE(HAVE_X_WINDOWS)
1314 fi
1315 if test "${USE_X_TOOLKIT}" != "none" ; then
1316   AC_DEFINE(USE_X_TOOLKIT)
1317 fi
1318 if test "${HAVE_X11}" = "yes" ; then
1319   AC_DEFINE(HAVE_X11)
1320 fi
1321 if test "${HAVE_XFREE386}" = "yes" ; then
1322   AC_DEFINE(HAVE_XFREE386)
1323 fi
1324 if test "${HAVE_X_MENU}" = "yes" ; then
1325   AC_DEFINE(HAVE_X_MENU)
1326 fi
1327 if test "${GNU_MALLOC}" = "yes" ; then
1328   AC_DEFINE(GNU_MALLOC)
1329 fi
1330 if test "${REL_ALLOC}" = "yes" ; then
1331   AC_DEFINE(REL_ALLOC)
1332 fi
1333 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1334   AC_DEFINE(LISP_FLOAT_TYPE)
1335 fi
1336
1337 #### Report on what we decided to do.
1338 echo "
1339 Configured for \`${canonical}'.
1340
1341   Where should the build process find the source code?    ${srcdir}
1342   What operating system and machine description files should Emacs use?
1343         \`${opsysfile}' and \`${machfile}'
1344   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1345   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1346   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1347   What window system should Emacs use?                    ${window_system}
1348   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
1349
1350 if test -n "${x_includes}"; then
1351 echo "  Where do we find X Windows header files?                ${x_includes}"
1352 else
1353 echo "  Where do we find X Windows header files?                Standard dirs"
1354 fi
1355 if test -n "${x_libraries}"; then
1356 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
1357 else
1358 echo "  Where do we find X Windows libraries?                   Standard dirs"
1359 fi
1360
1361 echo
1362
1363 # Remove any trailing slashes in these variables.
1364 changequote(, )dnl
1365 test "${prefix}" != NONE &&
1366   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1367 test "${exec_prefix}" != NONE &&
1368   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1369 changequote([, ])dnl
1370
1371 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1372         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1373
1374 ### Make the necessary directories, if they don't exist.
1375 for dir in cpp etc ; do
1376   test -d ${dir} || mkdir ${dir}
1377 done
1378
1379 # Build src/Makefile from ${srcdir}/src/Makefile.c
1380 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1381 # This must be done after src/config.h is built, since we rely on that file.
1382
1383 changequote(, )dnl The horror, the horror.
1384 # Now get this: Some word that is part of the ${srcdir} directory name
1385 # or the ${configuration} value might, just might, happen to be an
1386 # identifier like `sun4' or `i386' or something, and be predefined by
1387 # the C preprocessor to some helpful value like 1, or maybe the empty
1388 # string.  Needless to say consequent macro substitutions are less
1389 # than conducive to the makefile finding the correct directory.
1390 undefs="`echo $top_srcdir $configuration $canonical |
1391 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1392     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1393 `"
1394 changequote([, ])dnl
1395
1396 echo creating lib-src/Makefile
1397 ( cd lib-src
1398   rm -f junk.c junk1.c junk2.c
1399   sed -e '/start of cpp stuff/q' \
1400       < Makefile.c > junk1.c
1401   sed -e '1,/start of cpp stuff/d'\
1402       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1403       < Makefile.c > junk.c
1404   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1405       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1406   cat junk1.c junk2.c > Makefile.new
1407   rm -f junk.c junk1.c junk2.c
1408   chmod 444 Makefile.new
1409   mv -f Makefile.new Makefile
1410 )
1411
1412 echo creating src/Makefile
1413 ( cd src
1414   rm -f junk.c junk1.c junk2.c
1415   sed -e '/start of cpp stuff/q' \
1416       < Makefile.c > junk1.c
1417   sed -e '1,/start of cpp stuff/d'\
1418       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1419       < Makefile.c > junk.c
1420   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1421       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1422   cat junk1.c junk2.c > Makefile.new
1423   rm -f junk.c junk1.c junk2.c
1424   chmod 444 Makefile.new
1425   mv -f Makefile.new Makefile
1426 )
1427
1428 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1429   echo creating src/.gdbinit
1430   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1431 fi
1432
1433 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])