lisp/gnus/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Ted Zlatanov <tzz@lifelogs.com>
   7 ;; Keywords: network, spam, mail, gmane, report
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (autoload 'mm-url-insert "mm-url")
  35
  36 (defgroup spam-report nil
  37   "Spam reporting configuration."
  38   :group 'mail
  39   :group 'news)
  40
  41 (defcustom spam-report-gmane-regex nil
  42   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  43 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  44 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  45 instead."
  46   :type '(radio (const nil)
  47                 (regexp :value "^nntp\+.*:gmane\."))
  48   :group 'spam-report)
  49
  50 (defcustom spam-report-gmane-use-article-number t
  51   "Whether the article number (faster!) or the header should be used.
  52
  53 You must set this to nil if you don't read Gmane groups directly
  54 from news.gmane.org, e.g. when using local newsserver such as
  55 leafnode."
  56   :type 'boolean
  57   :group 'spam-report)
  58
  59 (defcustom spam-report-url-ping-function
  60   'spam-report-url-ping-plain
  61   "Function to use for url ping spam reporting.
  62 The function must accept the arguments `host' and `report'."
  63   :type '(choice
  64           (const :tag "Connect directly"
  65                  spam-report-url-ping-plain)
  66           (const :tag "Use the external program specified in `mm-url-program'"
  67                  spam-report-url-ping-mm-url)
  68           (const :tag "Store request URLs in `spam-report-requests-file'"
  69                  spam-report-url-to-file)
  70           (function :tag "User defined function" nil))
  71   :group 'spam-report)
  72
  73 (defcustom spam-report-requests-file
  74   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  75   ;; Is there a convention for the extension of such a file?
  76   ;; Should we use `spam-directory'?
  77   "File where spam report request are stored."
  78   :type 'file
  79   :group 'spam-report)
  80
  81 (defcustom spam-report-resend-to nil
  82   "Email address that spam articles are resent to when reporting.
  83 If not set, the user will be prompted to enter a value which will be
  84 saved for future use."
  85   :type 'string
  86   :group 'spam-report)
  87
  88 (defvar spam-report-url-ping-temp-agent-function nil
  89   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  90 This variable will store the value of `spam-report-url-ping-function' from
  91 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  92 undo that change.")
  93
  94 (defun spam-report-resend (articles &optional ham)
  95   "Report an article as spam by resending via email.
  96 Reports is as ham when HAM is set."
  97   (dolist (article articles)
  98     (gnus-message 6
  99                   "Reporting %s article %d to <%s>..."
 100                   (if ham "ham" "spam")
 101                   article spam-report-resend-to)
 102     (unless spam-report-resend-to
 103       (customize-set-variable
 104        spam-report-resend-to
 105        (read-from-minibuffer "email address to resend SPAM/HAM to? ")))
 106     ;; This is ganked from the `gnus-summary-resend-message' function.
 107     ;; It involves rendering the SPAM, which is undesirable, but there does
 108     ;; not seem to be a nicer way to achieve this.
 109     ;; select this particular article
 110     (gnus-summary-select-article nil nil nil article)
 111     ;; resend it to the destination address
 112     (with-current-buffer gnus-original-article-buffer
 113       (message-resend spam-report-resend-to))))
 114
 115 (defun spam-report-resend-ham (articles)
 116   "Report an article as ham by resending via email."
 117   (spam-report-resend articles t))
 118
 119 (defconst spam-report-gmane-max-requests 4
 120   "Number of reports to send before waiting for a response.")
 121
 122 (defvar spam-report-gmane-wait nil
 123   "When non-nil, wait until we get a server response.
 124 This makes sure we don't DOS the host, if many reports are
 125 submitted at once.  Internal variable.")
 126
 127 (defun spam-report-gmane-ham (&rest articles)
 128   "Report ARTICLES as ham (unregister) through Gmane."
 129   (interactive (gnus-summary-work-articles current-prefix-arg))
 130   (let ((count 0))
 131     (dolist (article articles)
 132       (setq count (1+ count))
 133       (let ((spam-report-gmane-wait
 134              (zerop (% count spam-report-gmane-max-requests))))
 135         (spam-report-gmane-internal t article)))))
 136
 137 (defun spam-report-gmane-spam (&rest articles)
 138   "Report ARTICLES as spam through Gmane."
 139   (interactive (gnus-summary-work-articles current-prefix-arg))
 140   (let ((count 0))
 141     (dolist (article articles)
 142       (setq count (1+ count))
 143       (let ((spam-report-gmane-wait
 144              (zerop (% count spam-report-gmane-max-requests))))
 145         (spam-report-gmane-internal nil article)))))
 146
 147 ;; `spam-report-gmane' was an interactive entry point, so we should provide an
 148 ;; alias.
 149 (defalias 'spam-report-gmane 'spam-report-gmane-spam)
 150
 151 (defun spam-report-gmane-internal (unspam article)
 152   "Report ARTICLE as spam or not-spam through Gmane, depending on UNSPAM."
 153   (when (and gnus-newsgroup-name
 154              (or (null spam-report-gmane-regex)
 155                  (string-match spam-report-gmane-regex gnus-newsgroup-name)))
 156     (let ((rpt-host (if unspam "unspam.gmane.org" "spam.gmane.org")))
 157       (gnus-message 6 "Reporting article %d to %s..." article rpt-host)
 158       (cond
 159        ;; Special-case nnweb groups -- these have the URL to use in
 160        ;; the Xref headers.
 161        ((eq (car (gnus-find-method-for-group gnus-newsgroup-name)) 'nnweb)
 162         (spam-report-url-ping
 163          rpt-host
 164          (concat
 165           "/"
 166           (gnus-replace-in-string
 167            (gnus-replace-in-string
 168             (gnus-replace-in-string
 169              (mail-header-xref (gnus-summary-article-header article))
 170              "/raw" ":silent")
 171             "^.*article.gmane.org/" "")
 172            "/" ":"))))
 173        (spam-report-gmane-use-article-number
 174         (spam-report-url-ping
 175          rpt-host
 176          (format "/%s:%d"
 177                  (gnus-group-real-name gnus-newsgroup-name)
 178                  article)))
 179        (t
 180         (with-current-buffer nntp-server-buffer
 181           (erase-buffer)
 182           (gnus-request-head article gnus-newsgroup-name)
 183           (let ((case-fold-search t)
 184                 field host report url)
 185             ;; First check for X-Report-Spam because it's more specific to
 186             ;; spam reporting than Archived-At.  OTOH, all new articles on
 187             ;; Gmane don't have X-Report-Spam anymore (unless Lars changes his
 188             ;; mind :-)).
 189             ;;
 190             ;; There might be more than one Archived-At header so we need to
 191             ;; find (and transform) the one related to Gmane.
 192             (setq field (or (gnus-fetch-field "X-Report-Spam")
 193                             (gnus-fetch-field "X-Report-Unspam")
 194                             (gnus-fetch-field "Archived-At")))
 195             (if (not (stringp field))
 196                 (if (and (setq field (gnus-fetch-field "Xref"))
 197                          (string-match "[^ ]+ +\\([^ ]+\\)" field))
 198                     (setq report (concat "/" (match-string 1 field))
 199                           host rpt-host))
 200               (setq host
 201                     (progn
 202                       (string-match
 203                        (concat "http://\\([a-z]+\\.gmane\\.org\\)"
 204                                "\\(/[^:/]+[:/][0-9]+\\)")
 205                        field)
 206                       (match-string 1 field)))
 207               (setq report (match-string 2 field)))
 208             (when host
 209               (when (string-equal "permalink.gmane.org" host)
 210                 (setq host rpt-host)
 211                 (setq report (gnus-replace-in-string
 212                               report "/\\([0-9]+\\)$" ":\\1")))
 213               (setq url (format "http://%s%s" host report)))
 214             (if (not (and host report url))
 215                 (gnus-message
 216                  3 "Could not find a spam report header in article %d..."
 217                  article)
 218               (gnus-message 7 "Reporting article through URL %s..." url)
 219               (spam-report-url-ping host report)))))))))
 220
 221 (defun spam-report-url-ping (host report)
 222   "Ping a host through HTTP, addressing a specific GET resource using
 223 the function specified by `spam-report-url-ping-function'."
 224   ;; Example:
 225   ;; host: "spam.gmane.org"
 226   ;; report: "/gmane.some.group:123456"
 227   (funcall spam-report-url-ping-function host report))
 228
 229 (defcustom spam-report-user-mail-address
 230   (and (stringp user-mail-address)
 231        (gnus-replace-in-string user-mail-address "@" "<at>"))
 232   "Mail address of this user used for spam reports to Gmane.
 233 This is initialized based on `user-mail-address'."
 234   :type '(choice string
 235                  (const :tag "Don't expose address" nil))
 236   :version "23.1" ;; No Gnus
 237   :group 'spam-report)
 238
 239 (defvar spam-report-user-agent
 240   (if spam-report-user-mail-address
 241       (format "%s (%s) %s" "spam-report.el"
 242               spam-report-user-mail-address
 243               (gnus-extended-version))
 244     (format "%s %s" "spam-report.el"
 245             (gnus-extended-version))))
 246
 247 (defun spam-report-url-ping-plain (host report)
 248   "Ping a host through HTTP, addressing a specific GET resource."
 249   (let ((tcp-connection))
 250     (with-temp-buffer
 251       (or (setq tcp-connection
 252                 (open-network-stream
 253                  "URL ping"
 254                  (buffer-name)
 255                  host
 256                  80))
 257           (error "Could not open connection to %s" host))
 258       (set-marker (process-mark tcp-connection) (point-min))
 259       (gnus-set-process-query-on-exit-flag tcp-connection nil)
 260       (process-send-string
 261        tcp-connection
 262        (format "GET %s HTTP/1.1\nUser-Agent: %s\nHost: %s\n\n"
 263                report spam-report-user-agent host))
 264       ;; Wait until we get something so we don't DOS the host, if
 265       ;; `spam-report-gmane-wait' is let-bound to t.
 266       (when spam-report-gmane-wait
 267         (gnus-message 7 "Waiting for response from %s..." host)
 268         (while (and (memq (process-status tcp-connection) '(open run))
 269                     (zerop (buffer-size)))
 270           (accept-process-output tcp-connection 1))
 271         (gnus-message 7 "Waiting for response from %s... done" host)))))
 272
 273 ;;;###autoload
 274 (defun spam-report-process-queue (&optional file keep)
 275   "Report all queued requests from `spam-report-requests-file'.
 276
 277 If FILE is given, use it instead of `spam-report-requests-file'.
 278 If KEEP is t, leave old requests in the file.  If KEEP is the
 279 symbol `ask', query before flushing the queue file."
 280   (interactive
 281    (list (read-file-name
 282           "File: "
 283           (file-name-directory spam-report-requests-file)
 284           spam-report-requests-file
 285           nil
 286           (file-name-nondirectory spam-report-requests-file))
 287          current-prefix-arg))
 288   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 289       (error (concat "Cannot process requests when "
 290                      "`spam-report-url-ping-function' is "
 291                      "`spam-report-url-to-file'."))
 292     (gnus-message 7 "Processing requests using `%s'."
 293                   spam-report-url-ping-function))
 294   (or file (setq file spam-report-requests-file))
 295   (with-current-buffer (find-file-noselect file)
 296     (goto-char (point-min))
 297     (while (and (not (eobp))
 298                 (re-search-forward
 299                  "http://\\([^/]+\\)\\(/.*\\) *$" (point-at-eol) t))
 300       (let ((spam-report-gmane-wait
 301              (zerop (% (mm-line-number-at-pos)
 302                        spam-report-gmane-max-requests))))
 303         (gnus-message 6 "Reporting %s%s..."
 304                       (match-string 1) (match-string 2))
 305         (funcall spam-report-url-ping-function
 306                  (match-string 1) (match-string 2)))
 307       (forward-line 1))
 308     (if (or (eq keep nil)
 309             (and (eq keep 'ask)
 310                  (y-or-n-p
 311                   (format
 312                    "Flush requests from `%s'? " (current-buffer)))))
 313         (progn
 314           (gnus-message 7 "Flushing request file `%s'"
 315                         spam-report-requests-file)
 316           (erase-buffer)
 317           (save-buffer)
 318           (kill-buffer (current-buffer)))
 319       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 320
 321 ;;;###autoload
 322 (defun spam-report-url-ping-mm-url (host report)
 323   "Ping a host through HTTP, addressing a specific GET resource. Use
 324 the external program specified in `mm-url-program' to connect to
 325 server."
 326   (with-temp-buffer
 327     (let ((url (format "http://%s%s" host report)))
 328       (mm-url-insert url t))))
 329
 330 ;;;###autoload
 331 (defun spam-report-url-to-file (host report)
 332   "Collect spam report requests in `spam-report-requests-file'.
 333 Customize `spam-report-url-ping-function' to use this function."
 334   (let ((url (format "http://%s%s" host report))
 335         (file spam-report-requests-file))
 336     (gnus-make-directory (file-name-directory file))
 337     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 338     (with-temp-buffer
 339       (insert url)
 340       (newline)
 341       (append-to-file (point-min) (point-max) file))))
 342
 343 ;;;###autoload
 344 (defun spam-report-agentize ()
 345   "Add spam-report support to the Agent.
 346 Spam reports will be queued with \\[spam-report-url-to-file] when
 347 the Agent is unplugged, and will be submitted in a batch when the
 348 Agent is plugged."
 349   (interactive)
 350   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 351   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 352
 353 ;;;###autoload
 354 (defun spam-report-deagentize ()
 355   "Remove spam-report support from the Agent.
 356 Spam reports will be queued with the method used when
 357 \\[spam-report-agentize] was run."
 358   (interactive)
 359   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 360   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 361
 362 (defun spam-report-plug-agent ()
 363   "Adjust spam report settings for plugged state.
 364 Process queued spam reports."
 365   ;; Process the queue, unless the user only wanted to report to a file
 366   ;; anyway.
 367   (unless (equal spam-report-url-ping-temp-agent-function
 368                  'spam-report-url-to-file)
 369     (spam-report-process-queue))
 370   ;; Set the reporting function, if we have memorized something otherwise,
 371   ;; stick with plain URL reporting.
 372   (setq spam-report-url-ping-function
 373         (or spam-report-url-ping-temp-agent-function
 374             'spam-report-url-ping-plain)))
 375
 376 (defun spam-report-unplug-agent ()
 377   "Restore spam report settings for unplugged state."
 378   ;; save the old value
 379   (setq spam-report-url-ping-temp-agent-function
 380         spam-report-url-ping-function)
 381   ;; store all reports to file
 382   (setq spam-report-url-ping-function
 383         'spam-report-url-to-file))
 384
 385 (provide 'spam-report)
 386
 387 ;;; spam-report.el ends here.