lisp/gnus/gnus-mh.el

   1 ;;; gnus-mh.el --- mh-e interface for Gnus
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   7 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   8 ;; Keywords: news
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Send mail using mh-e.
  28
  29 ;; The following mh-e interface is all cooperative works of
  30 ;; tanaka@flab.fujitsu.CO.JP (TANAKA Hiroshi), kawabe@sra.CO.JP
  31 ;; (Yoshikatsu Kawabe), and shingu@casund.cpr.canon.co.jp (Toshiaki
  32 ;; SHINGU).
  33
  34 ;;; Code:
  35
  36 (require 'gnus)
  37 (require 'mh-e)
  38 (require 'mh-comp)
  39 (require 'gnus-msg)
  40 (require 'gnus-sum)
  41
  42 (defvar mh-lib-progs)
  43
  44 (defun gnus-summary-save-article-folder (&optional arg)
  45   "Append the current article to an mh folder.
  46 If N is a positive number, save the N next articles.
  47 If N is a negative number, save the N previous articles.
  48 If N is nil and any articles have been marked with the process mark,
  49 save those articles instead."
  50   (interactive "P")
  51   (require 'gnus-art)
  52   (let ((gnus-default-article-saver 'gnus-summary-save-in-folder))
  53     (gnus-summary-save-article arg)))
  54
  55 (defun gnus-summary-save-in-folder (&optional folder)
  56   "Save this article to MH folder (using `rcvstore' in MH library).
  57 Optional argument FOLDER specifies folder name."
  58   ;; Thanks to yuki@flab.Fujitsu.JUNET and ohm@kaba.junet.
  59   (mh-find-path)
  60   (let ((folder
  61          (cond ((and (eq folder 'default)
  62                      gnus-newsgroup-last-folder)
  63                 gnus-newsgroup-last-folder)
  64                (folder folder)
  65                (t (mh-prompt-for-folder
  66                    "Save article in"
  67                    (funcall gnus-folder-save-name gnus-newsgroup-name
  68                             gnus-current-headers gnus-newsgroup-last-folder)
  69                    t))))
  70         (errbuf (gnus-get-buffer-create " *Gnus rcvstore*"))
  71         ;; Find the rcvstore program.
  72         (exec-path (cond
  73                     ((and (boundp 'mh-lib-progs) mh-lib-progs)
  74                      (cons mh-lib-progs exec-path))
  75                     (mh-lib (cons mh-lib exec-path))
  76                     (t exec-path))))
  77     (with-current-buffer gnus-original-article-buffer
  78       (save-restriction
  79         (widen)
  80         (unwind-protect
  81             (call-process-region
  82              (point-min) (point-max) "rcvstore" nil errbuf nil folder)
  83           (set-buffer errbuf)
  84           (if (zerop (buffer-size))
  85               (message "Article saved in folder: %s" folder)
  86             (message "%s" (buffer-string)))
  87           (kill-buffer errbuf))))
  88     (setq gnus-newsgroup-last-folder folder)))
  89
  90 (defun gnus-Folder-save-name (newsgroup headers &optional last-folder)
  91   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
  92 If variable `gnus-use-long-file-name' is nil, it is +News.group.
  93 Otherwise, it is like +news/group."
  94   (or last-folder
  95       (concat "+"
  96               (if gnus-use-long-file-name
  97                   (gnus-capitalize-newsgroup newsgroup)
  98                 (gnus-newsgroup-directory-form newsgroup)))))
  99
 100 (defun gnus-folder-save-name (newsgroup headers &optional last-folder)
 101   "Generate folder name from NEWSGROUP, HEADERS, and optional LAST-FOLDER.
 102 If variable `gnus-use-long-file-name' is nil, it is +news.group.
 103 Otherwise, it is like +news/group."
 104   (or last-folder
 105       (concat "+"
 106               (if gnus-use-long-file-name
 107                   newsgroup
 108                 (gnus-newsgroup-directory-form newsgroup)))))
 109
 110 (provide 'gnus-mh)
 111
 112 ;;; gnus-mh.el ends here