test/indent/prolog.prolog

   1 %% -*- mode: prolog; coding: utf-8; fill-column: 78 -*-
   2
   3 %% Testing correct tokenizing.
   4 foo(X) :- 0'= = X.
   5 foo(X) :- 8'234 = X.
   6 foo(X) :- '\x45\' = X.
   7 foo(X) :- 'test 0'=X.
   8 foo(X) :- 'test 8'=X.
   9
  10 %% wf(+E)
  11 %% Vérifie que E est une expression syntaxiquement correcte.
  12 wf(X) :- atom(X); integer(X); var(X).         %Une variable ou un entier.
  13 wf(lambda(X, T, B)) :- atom(X), wf(T), wf(B). %Une fonction.
  14 wf(app(E1, E2)) :- wf(E1), wf(E2).            %Un appel de fonction.
  15 wf(pi(X, T, B)) :- atom(X), wf(T), wf(B).     %Le type d'une fonction.
  16
  17 %% Éléments additionnels utilisés dans le langage source.
  18 wf(lambda(X, B)) :- atom(X), wf(B).
  19 wf(let(X, E1, E2)) :- atom(X), wf(E1), wf(E2).
  20 wf(let(X, T, E1, E2)) :- atom(X), wf(T), wf(E1), wf(E2).
  21 wf((T1 -> T2)) :- wf(T1), wf(T2).
  22 wf(forall(X, T, B)) :- atom(X), wf(T), wf(B).
  23 wf(fix(X,T,E1,E2)) :- atom(X), wf(T), wf(E1), wf(E2).
  24 wf(fix(X,E1,E2)) :- atom(X), wf(E1), wf(E2).
  25 wf(app(E1,E2,E3)) :- wf(E1), wf(E2), wf(E3).
  26 wf(app(E1,E2,E3,E4)) :- wf(E1), wf(E2), wf(E3), wf(E4).
  27
  28 %% subst(+X, +V, +FV, +Ei, -Eo)
  29 %% Remplace X par V dans Ei.  Les variables qui apparaissent libres dans
  30 %% V et peuvent aussi apparaître dans Ei doivent toutes être inclues
  31 %% dans l'environnement FV.
  32 subst(X, V, _, X, E) :- !, E = V.
  33 subst(_, _, _, Y, Y) :- atom(Y); integer(Y).
  34 %% Residualize the substitution when applied to an uninstantiated variable.
  35 %% subst(X, V, _, Y, app(lambda(X,_,Y),V)) :- var(Y).
  36 %% Rather than residualize and leave us with unifications that fail, let's
  37 %% rather assume that Y will not refer to X.
  38 subst(X, V, _, Y, Y) :- var(Y).
  39 subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)) :-
  40     subst(X, V, FV, Ti, To),
  41     (X = Y ->
  42          %% If X is equal to Y, X is shadowed, so no subst can take place.
  43          Y1 = Y, Bo = Bi;
  44      (member((Y, _), FV) ->
  45           %% If Y appears in FV, it can appear in V, so we need to
  46           %% rename it to avoid name capture.
  47           new_atom(Y, Y1),
  48           subst(Y, Y1, [], Bi, Bi1);
  49       Y1 = Y, Bi1 = Bi),
  50      %% Perform substitution on the body.
  51      subst(X, V, FV, Bi1, Bo)).
  52 subst(X, V, FV, pi(Y, Ti, Bi), pi(Y1, To, Bo)) :-
  53     subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)).
  54 subst(X, V, FV, forall(Y, Ti, Bi), forall(Y1, To, Bo)) :-
  55     subst(X, V, FV, lambda(Y, Ti, Bi), lambda(Y1, To, Bo)).
  56 subst(X, V, FV, app(E1i, E2i), app(E1o, E2o)) :-
  57     subst(X, V, FV, E1i, E1o), subst(X, V, FV, E2i, E2o).
  58
  59 %% apply(+F, +Arg, +Env, -E)
  60 apply(lambda(X, _, B), Arg, Env, E) :- \+ var(B), subst(X, Arg, Env, B, E).
  61 apply(app(plus, N1), N2, _, N) :- integer(N1), integer(N2), N is N1 + N2.
  62 apply(app(minus, N1), N2, _, N) :- integer(N1), integer(N2), N is N1 - N2.
  63
  64
  65 %% normalize(+E1, +Env, -E2)
  66 %% Applique toutes les réductions possibles sur E1.
  67 normalize(X, _, X) :- integer(X); var(X); atom(X).
  68 %% normalize(X, Env, E) :- atom(X), member((X, E), Env).
  69 normalize(lambda(X, T, B), Env, lambda(X, Tn, Bn)) :-
  70     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  71 normalize(pi(X, T, B), Env, pi(X, Tn, Bn)) :-
  72     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  73 normalize(forall(X, T, B), Env, forall(X, Tn, Bn)) :-
  74     normalize(T, [(X,T)|Env], Tn), normalize(B, [(X,T)|Env], Bn).
  75 normalize(app(E1, E2), Env, En) :-
  76     normalize(E1, Env, E1n),
  77     normalize(E2, Env, E2n),
  78     (apply(E1n, E2n, Env, E) ->
  79          normalize(E, Env, En);
  80      En = app(E1n, E2n)).
  81
  82 %% infer(+E, +Env, -T)
  83 %% Infère le type de E dans Env.  On essaie d'être permissif, dans le sens
  84 %% que l'on présume que l'expression est typée correctement.
  85 infer(X, _, int) :- integer(X).
  86 infer(X, _, _) :- var(X).            %Une expression encore inconnue.
  87 infer(X, Env, T) :-
  88     atom(X),
  89     (member((X, T1), Env) ->
  90          %% X est déjà dans Env: vérifie que le type est correct.
  91          T = T1;
  92      %% X est une variable libre.
  93      true).
  94 infer(lambda(X,T,B), Env, pi(Y,T,TB)) :-
  95     infer(B, [(X,T)|Env], TBx),
  96     (var(Y) ->
  97          Y = X, TB = TBx;
  98      subst(X, Y, Env, TBx, TB)).
  99 infer(app(E1, E2), Env, Tn) :-
 100     infer(E1, Env, T1),
 101     (T1 = pi(X,T2,B); T1 = forall(X,T2,B)),
 102     infer(E2, Env, T2),
 103     subst(X, E2, Env, B, T),
 104     normalize(T, Env, Tn).
 105 infer(pi(X,T1,T2), Env, type) :-
 106     infer(T1, Env, type),
 107     infer(T2, [(X,T1)|Env], type).
 108 infer(forall(X,T1,T2), Env, type) :-
 109     infer(T1, Env, type),
 110     infer(T2, [(X,T1)|Env], type).
 111
 112 %% freevars(+E, +Env, -Vs)
 113 %% Renvoie les variables libres de E.  Vs est une liste associative
 114 %% où chaque élément est de la forme (X,T) où X est une variable et T est
 115 %% son type.
 116 freevars(X, _, []) :- integer(X).
 117 freevars(X, Env, Vs) :-
 118     atom(X),
 119     (member((X,_), Env) ->
 120          %% Variable liée.
 121          Vs = [];
 122      %% Variable libre.  Type inconnu :-(
 123      Vs = [(X,_)]).
 124 %% Les variables non-instanciées peuvent être remplacées par des paramètres
 125 %% qui seront liés par `closetype' selon le principe de Hindley-Milner.
 126 freevars(X, _, [(X, _)]) :- var(X), new_atom(X).
 127 freevars(app(E1, E2), Env, Vs) :-
 128     freevars(E1, Env, Vs1),
 129     append(Vs1, Env, Env1),
 130     freevars(E2, Env1, Vs2),
 131     append(Vs1, Vs2, Vs).
 132 freevars(lambda(X, T, B), Env, Vs) :-
 133     freevars(T, Env, TVs),
 134     append(TVs, Env, Env1),
 135     freevars(B, [(X,T)|Env1], BVs),
 136     append(TVs, BVs, Vs).
 137 freevars(pi(X, T, B), Env, Vs)     :- freevars(lambda(X, T, B), Env, Vs).
 138 freevars(forall(X, T, B), Env, Vs) :- freevars(lambda(X, T, B), Env, Vs).
 139
 140 %% close(+Eo, +To, +Vs, -Ec, -Tc)
 141 %% Ferme un type ouvert To en liant chaque variable libre (listées dans Vs)
 142 %% avec `forall'.
 143 closetype(E, T, [], E, T).
 144 closetype(Eo, To, [(X,T)|Vs], lambda(X, T, Ec), forall(X, T, Tc)) :-
 145     closetype(Eo, To, Vs, Ec, Tc).
 146
 147 %% elab_type(+Ee, +Te, +Env, -Eg, -Tg)
 148 %% Ajoute les arguments implicites de E:T.
 149 generalize(Ee, Te, Env, Eg, Tg) :-
 150     freevars(Te, Env, Vs),
 151     append(Vs, Env, EnvX),
 152     %% Essaie d'instancier les types des paramètres que `generalize' vient
 153     %% d'ajouter.
 154     infer(Te, EnvX, type),
 155     closetype(Ee, Te, Vs, Eg, Tg).
 156
 157 %% instantiate(+X, +T, -E)
 158 %% Utilise la variable X de type T.  Le résultat E est X auquel on ajoute
 159 %% tous les arguments implicites (de valeur inconnue).
 160 instantiate(X, T, X) :- var(T), !.
 161 instantiate(X, forall(_, _, T), app(E, _)) :- !, instantiate(X, T, E).
 162 instantiate(X, _, X).
 163
 164 %% elaborate(+E1, +Env, -E2)
 165 %% Transforme E1 en une expression E2 où le sucre syntaxique a été éliminé
 166 %% et où les arguments implicites ont été rendus explicites.
 167 elaborate(X, _, X) :- integer(X); var(X).
 168 elaborate(X, Env, E) :-
 169     atom(X),
 170     (member((X, T), Env) ->
 171          instantiate(X, T, E);
 172      %% Si X n'est pas dans l'environnement, c'est une variable libre que
 173      %% l'on voudra probablement généraliser.
 174      X = E).
 175 elaborate(lambda(X, T, B), Env, lambda(X, Te, Be)) :-
 176     elaborate(T, Env, Te),
 177     elaborate(B, [(X,Te)|Env], Be).
 178 elaborate(pi(X, T, B), Env, pi(X, Te, Be)) :-
 179     elaborate(T, Env, Te),
 180     elaborate(B, [(X,Te)|Env], Be).
 181 elaborate(app(E1, E2), Env, app(E1e, E2e)) :-
 182     elaborate(E1, Env, E1e),
 183     elaborate(E2, Env, E2e).
 184 elaborate(let(X, T, E1, E2), Env, app(lambda(X, Tg, E2e), E1g)) :-
 185     elaborate(E1, Env, E1e),
 186     elaborate(T, Env, Te),
 187     infer(E1e, Env, Te),
 188     generalize(E1e, Te, Env, E1g, Tg),
 189     elaborate(E2, [(X,Te)|Env], E2e).
 190 %% Expansion du sucre syntaxique.
 191 elaborate((T1 -> T2), Env, Ee) :-
 192     new_atom(X), elaborate(pi(X, T1, T2), Env, Ee).
 193 elaborate(app(E1, E2, E3, E4), Env, Ee) :-
 194     elaborate(app(app(E1,E2,E3),E4), Env, Ee).
 195 elaborate(app(E1, E2, E3), Env, Ee) :- elaborate(app(app(E1,E2),E3), Env, Ee).
 196 elaborate(lambda(X, B), Env, Ee) :- elaborate(lambda(X, _, B), Env, Ee).
 197 elaborate(let(X, E1, E2), Env, Ee) :- elaborate(let(X, _, E1, E2), Env, Ee).
 198 elaborate(fix(F,B,E), Env, Ee) :- elaborate(fix(F,_,B,E), Env, Ee).
 199 elaborate(fix(F,T,B,E), Env, Ee) :-
 200     elaborate(let(F,T,app(fix,lambda(F,T,B)),E), Env, Ee).
 201
 202 %% elab_bindings(+TS, +Env, -TS).
 203 %% Applique `elaborate' sur l'environnement de type TS.
 204 elab_tenv([], _, []).
 205 elab_tenv([(X,T)|TS], Env, [(X, Tg)|TSe]) :-
 206     elaborate(T, Env, Te),
 207     infer(Te, Env, type),
 208     generalize(_, Te, Env, _, Tg),
 209     elab_tenv(TS, [(X, Tg)|Env], TSe).
 210
 211
 212 %% elaborate(+E1, -E2)
 213 %% Comme le `elaborate' ci-dessus, mais avec un environnement par défaut.
 214 elaborate(SRC, E) :-
 215     elab_tenv([(int, type),
 216                (fix, ((t -> t) -> t)),
 217                %% list: type → int → type
 218                (list, (type -> int -> type)),
 219                %% plus: int → int → int
 220                (plus, (int -> int -> int)),
 221                %% minus: int → int → int
 222                (minus, (int -> int -> int)),
 223                %% nil: list t 0
 224                (nil, app(app(list,t),0)),
 225                %% cons: t -> list t n → list t (n + 1)
 226                (cons, (t -> app(app(list,t),n) ->
 227                             app(app(list,t), app(app(plus,n),1)))) %fixindent
 228               ],
 229               [(type,type)],
 230               Env),
 231     elaborate(SRC, Env, E).