lisp/mail/emacsbug.el

   1 ;;; emacsbug.el --- command to report Emacs bugs to appropriate mailing list
   2
   3 ;; Copyright (C) 1985, 1994, 1997-1998, 2000-2014
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Keywords: maint mail
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; `M-x report-emacs-bug' starts an email note to the Emacs maintainers
  29 ;; describing a problem.  You need to be able to send mail from Emacs
  30 ;; to complete the process.  Alternatively, compose the bug report in
  31 ;; Emacs then paste it into your normal mail client.
  32
  33 ;;; Code:
  34
  35 (require 'sendmail)
  36 (require 'message)
  37
  38 (defgroup emacsbug nil
  39   "Sending Emacs bug reports."
  40   :group 'maint
  41   :group 'mail)
  42
  43 (define-obsolete-variable-alias 'report-emacs-bug-pretest-address
  44   'report-emacs-bug-address "24.1")
  45
  46 (defcustom report-emacs-bug-no-confirmation nil
  47   "If non-nil, suppress the confirmations asked for the sake of novice users."
  48   :group 'emacsbug
  49   :type 'boolean)
  50
  51 (defcustom report-emacs-bug-no-explanations nil
  52   "If non-nil, suppress the explanations given for the sake of novice users."
  53   :group 'emacsbug
  54   :type 'boolean)
  55
  56 ;; User options end here.
  57
  58 (defvar report-emacs-bug-orig-text nil
  59   "The automatically-created initial text of the bug report.")
  60
  61 (defvar report-emacs-bug-send-command nil
  62   "Name of the command to send the bug report, as a string.")
  63 (make-variable-buffer-local 'report-emacs-bug-send-command)
  64
  65 (defvar report-emacs-bug-send-hook nil
  66   "Hook run before sending the bug report.")
  67 (make-variable-buffer-local 'report-emacs-bug-send-hook)
  68
  69 (declare-function x-server-vendor "xfns.c" (&optional terminal))
  70 (declare-function x-server-version "xfns.c" (&optional terminal))
  71 (declare-function message-sort-headers "message" ())
  72 (defvar message-strip-special-text-properties)
  73
  74 (defun report-emacs-bug-can-use-osx-open ()
  75   "Return non-nil if the OS X \"open\" command is available for mailing."
  76   (and (featurep 'ns)
  77        (equal (executable-find "open") "/usr/bin/open")
  78        (memq system-type '(darwin))))
  79
  80 ;; FIXME this duplicates much of the logic from browse-url-can-use-xdg-open.
  81 (defun report-emacs-bug-can-use-xdg-email ()
  82   "Return non-nil if the \"xdg-email\" command can be used.
  83 xdg-email is a desktop utility that calls your preferred mail client.
  84 This requires you to be running either Gnome, KDE, or Xfce4."
  85   (and (getenv "DISPLAY")
  86        (executable-find "xdg-email")
  87        (or (getenv "GNOME_DESKTOP_SESSION_ID")
  88            ;; GNOME_DESKTOP_SESSION_ID is deprecated, check on Dbus also.
  89            (condition-case nil
  90                (eq 0 (call-process
  91                       "dbus-send" nil nil nil
  92                                   "--dest=org.gnome.SessionManager"
  93                                   "--print-reply"
  94                                   "/org/gnome/SessionManager"
  95                                   "org.gnome.SessionManager.CanShutdown"))
  96              (error nil))
  97            (equal (getenv "KDE_FULL_SESSION") "true")
  98            ;; FIXME? browse-url-can-use-xdg-open also accepts LXDE.
  99            ;; Is that no good here, or just overlooked?
 100            (condition-case nil
 101                (eq 0 (call-process
 102                       "/bin/sh" nil nil nil
 103                       "-c"
 104                       ;; FIXME use string-match rather than grep.
 105                       "xprop -root _DT_SAVE_MODE|grep xfce4"))
 106              (error nil)))))
 107
 108 (defun report-emacs-bug-insert-to-mailer ()
 109   "Send the message to your preferred mail client.
 110 This requires either the OS X \"open\" command, or the freedesktop
 111 \"xdg-email\" command to be available."
 112   (interactive)
 113   (save-excursion
 114     ;; FIXME? use mail-fetch-field?
 115     (let* ((to (progn
 116                  (goto-char (point-min))
 117                  (forward-line)
 118                  (and (looking-at "^To: \\(.*\\)")
 119                       (match-string-no-properties 1))))
 120            (subject (progn
 121                       (forward-line)
 122                       (and (looking-at "^Subject: \\(.*\\)")
 123                            (match-string-no-properties 1))))
 124            (body (progn
 125                    (forward-line 2)
 126                    (if (> (point-max) (point))
 127                        (buffer-substring-no-properties (point) (point-max))))))
 128       (if (and to subject body)
 129           (if (report-emacs-bug-can-use-osx-open)
 130               (start-process "/usr/bin/open" nil "open"
 131                              (concat "mailto:" to
 132                                      "?subject=" (url-hexify-string subject)
 133                                      "&body=" (url-hexify-string body)))
 134             (start-process "xdg-email" nil "xdg-email"
 135                            "--subject" subject
 136                            "--body" body
 137                            (concat "mailto:" to)))
 138         (error "Subject, To or body not found")))))
 139
 140 ;; It's the default mail mode, so it seems OK to use its features.
 141 (autoload 'message-bogus-recipient-p "message")
 142 (autoload 'message-make-address "message")
 143 (defvar message-send-mail-function)
 144 (defvar message-sendmail-envelope-from)
 145
 146 ;;;###autoload
 147 (defun report-emacs-bug (topic &optional unused)
 148   "Report a bug in GNU Emacs.
 149 Prompts for bug subject.  Leaves you in a mail buffer."
 150   (declare (advertised-calling-convention (topic) "24.5"))
 151   (interactive "sBug Subject: ")
 152   ;; The syntax `version;' is preferred to `[version]' because the
 153   ;; latter could be mistakenly stripped by mailing software.
 154   (if (eq system-type 'ms-dos)
 155       (setq topic (concat emacs-version "; " topic))
 156     (when (string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
 157       (setq topic (concat (match-string 1 emacs-version) "; " topic))))
 158   (let ((from-buffer (current-buffer))
 159         (can-insert-mail (or (report-emacs-bug-can-use-xdg-email)
 160                              (report-emacs-bug-can-use-osx-open)))
 161         user-point message-end-point)
 162     (setq message-end-point
 163           (with-current-buffer (messages-buffer)
 164             (point-max-marker)))
 165     (compose-mail report-emacs-bug-address topic)
 166     ;; The rest of this does not execute if the user was asked to
 167     ;; confirm and said no.
 168     (when (eq major-mode 'message-mode)
 169       ;; Message-mode sorts the headers before sending.  We sort now so
 170       ;; that report-emacs-bug-orig-text remains valid.  (Bug#5178)
 171       (message-sort-headers)
 172       ;; Stop message-mode stealing the properties we will add.
 173       (set (make-local-variable 'message-strip-special-text-properties) nil)
 174       ;; Make sure we default to the From: address as envelope when sending
 175       ;; through sendmail.
 176       (when (and (not message-sendmail-envelope-from)
 177                  (message-bogus-recipient-p (message-make-address)))
 178         (set (make-local-variable 'message-sendmail-envelope-from) 'header)))
 179     (rfc822-goto-eoh)
 180     (forward-line 1)
 181     ;; Move the mail signature to the proper place.
 182     (let ((signature (buffer-substring (point) (point-max)))
 183           (inhibit-read-only t))
 184       (delete-region (point) (point-max))
 185       (insert signature)
 186       (backward-char (length signature)))
 187     (unless report-emacs-bug-no-explanations
 188       ;; Insert warnings for novice users.
 189       (if (not (equal "bug-gnu-emacs@gnu.org" report-emacs-bug-address))
 190           (insert (format "The report will be sent to %s.\n\n"
 191                           report-emacs-bug-address))
 192         (insert "This bug report will be sent to the ")
 193         (insert-text-button
 194          "Bug-GNU-Emacs"
 195          'face 'link
 196          'help-echo (concat "mouse-2, RET: Follow this link")
 197          'action (lambda (button)
 198                    (browse-url "http://lists.gnu.org/archive/html/bug-gnu-emacs/"))
 199          'follow-link t)
 200         (insert " mailing list\nand the GNU bug tracker at ")
 201         (insert-text-button
 202          "debbugs.gnu.org"
 203          'face 'link
 204          'help-echo (concat "mouse-2, RET: Follow this link")
 205          'action (lambda (button)
 206                    (browse-url "http://debbugs.gnu.org/"))
 207          'follow-link t)
 208
 209         (insert ".  Please check that
 210 the From: line contains a valid email address.  After a delay of up
 211 to one day, you should receive an acknowledgment at that address.
 212
 213 Please write in English if possible, as the Emacs maintainers
 214 usually do not have translators for other languages.\n\n")))
 215
 216     (insert "Please describe exactly what actions triggered the bug, and\n"
 217             "the precise symptoms of the bug.  If you can, give a recipe\n"
 218             "starting from `emacs -Q':\n\n")
 219     (let ((txt (delete-and-extract-region
 220                 (save-excursion (rfc822-goto-eoh) (line-beginning-position 2))
 221                 (point))))
 222       (insert (propertize "\n" 'display txt)))
 223     (setq user-point (point))
 224     (insert "\n\n")
 225
 226     (insert "If Emacs crashed, and you have the Emacs process in the gdb debugger,\n"
 227             "please include the output from the following gdb commands:\n"
 228             "    `bt full' and `xbacktrace'.\n")
 229
 230     (let ((debug-file (expand-file-name "DEBUG" data-directory)))
 231       (if (file-readable-p debug-file)
 232           (insert "For information about debugging Emacs, please read the file\n"
 233                   debug-file ".\n")))
 234     (let ((txt (delete-and-extract-region (1+ user-point) (point))))
 235       (insert (propertize "\n" 'display txt)))
 236
 237     (insert "\n\nIn " (emacs-version) "\n")
 238     (if (stringp emacs-repository-version)
 239         (insert "Repository revision: " emacs-repository-version "\n"))
 240     (if (fboundp 'x-server-vendor)
 241         (condition-case nil
 242             ;; This is used not only for X11 but also W32 and others.
 243             (insert "Windowing system distributor `" (x-server-vendor)
 244                     "', version "
 245                     (mapconcat 'number-to-string (x-server-version) ".") "\n")
 246           (error t)))
 247     (let ((lsb (with-temp-buffer
 248                  (if (eq 0 (ignore-errors
 249                              (call-process "lsb_release" nil '(t nil)
 250                                            nil "-d")))
 251                      (buffer-string)))))
 252       (if (stringp lsb)
 253           (insert "System " lsb "\n")))
 254     (when (and system-configuration-options
 255                (not (equal system-configuration-options "")))
 256       (insert "Configured using:\n `configure "
 257               system-configuration-options "'\n\n")
 258       (fill-region (line-beginning-position -1) (point)))
 259     (insert "Configured features:\n" system-configuration-features "\n\n")
 260     (fill-region (line-beginning-position -1) (point))
 261     (insert "Important settings:\n")
 262     (mapc
 263      (lambda (var)
 264        (let ((val (getenv var)))
 265          (if val (insert (format "  value of $%s: %s\n" var val)))))
 266      '("EMACSDATA" "EMACSDOC" "EMACSLOADPATH" "EMACSPATH"
 267        "LC_ALL" "LC_COLLATE" "LC_CTYPE" "LC_MESSAGES"
 268        "LC_MONETARY" "LC_NUMERIC" "LC_TIME" "LANG" "XMODIFIERS"))
 269     (insert (format "  locale-coding-system: %s\n" locale-coding-system))
 270     ;; Only ~ 0.2% of people from a sample of 3200 changed this from
 271     ;; the default, t.
 272     (or (default-value 'enable-multibyte-characters)
 273         (insert (format "  default enable-multibyte-characters: %s\n"
 274                         (default-value 'enable-multibyte-characters))))
 275     (insert "\n")
 276     (insert (format "Major mode: %s\n"
 277                     (format-mode-line
 278                      (buffer-local-value 'mode-name from-buffer)
 279                      nil nil from-buffer)))
 280     (insert "\n")
 281     (insert "Minor modes in effect:\n")
 282     (dolist (mode minor-mode-list)
 283       (and (boundp mode) (buffer-local-value mode from-buffer)
 284            (insert (format "  %s: %s\n" mode
 285                            (buffer-local-value mode from-buffer)))))
 286     (let ((message-buf (get-buffer "*Messages*")))
 287       (if message-buf
 288           (let (beg-pos
 289                 (end-pos message-end-point))
 290             (with-current-buffer message-buf
 291               (goto-char end-pos)
 292               (forward-line -10)
 293               (setq beg-pos (point)))
 294             (insert "\nRecent messages:\n")
 295             (insert-buffer-substring message-buf beg-pos end-pos))))
 296     ;; After Recent messages, to avoid the messages produced by
 297     ;; list-load-path-shadows.
 298     (unless (looking-back "\n")
 299       (insert "\n"))
 300     (insert "\n")
 301     (insert "Load-path shadows:\n")
 302     (let* ((msg "Checking for load-path shadows...")
 303            (result "done")
 304            (shadows (progn (message "%s" msg)
 305                            (condition-case nil (list-load-path-shadows t)
 306                              (error
 307                               (setq result "error")
 308                               "Error during checking")))))
 309       (message "%s%s" msg result)
 310       (insert (if (zerop (length shadows))
 311                   "None found.\n"
 312                 shadows)))
 313     (insert (format "\nFeatures:\n%s\n" features))
 314     (fill-region (line-beginning-position 0) (point))
 315
 316     (insert (format "\nMemory information:\n"))
 317     (pp (garbage-collect) (current-buffer))
 318
 319     ;; This is so the user has to type something in order to send easily.
 320     (use-local-map (nconc (make-sparse-keymap) (current-local-map)))
 321     (define-key (current-local-map) "\C-c\C-i" 'info-emacs-bug)
 322     (if can-insert-mail
 323         (define-key (current-local-map) "\C-c\M-i"
 324           'report-emacs-bug-insert-to-mailer))
 325     (setq report-emacs-bug-send-command (get mail-user-agent 'sendfunc)
 326           report-emacs-bug-send-hook (get mail-user-agent 'hookvar))
 327     (if report-emacs-bug-send-command
 328         (setq report-emacs-bug-send-command
 329               (symbol-name report-emacs-bug-send-command)))
 330     (unless report-emacs-bug-no-explanations
 331       (with-output-to-temp-buffer "*Bug Help*"
 332         (princ "While in the mail buffer:\n\n")
 333         (if report-emacs-bug-send-command
 334             (princ (substitute-command-keys
 335                     (format "  Type \\[%s] to send the bug report.\n"
 336                             report-emacs-bug-send-command))))
 337         (princ (substitute-command-keys
 338                 "  Type \\[kill-buffer] RET to cancel (don't send it).\n"))
 339         (if can-insert-mail
 340             (princ (substitute-command-keys
 341                     "  Type \\[report-emacs-bug-insert-to-mailer] to copy text to your preferred mail program.\n")))
 342         (terpri)
 343         (princ (substitute-command-keys
 344                 "  Type \\[info-emacs-bug] to visit in Info the Emacs Manual section
 345     about when and how to write a bug report, and what
 346     information you should include to help fix the bug.")))
 347       (shrink-window-if-larger-than-buffer (get-buffer-window "*Bug Help*")))
 348     ;; Make it less likely people will send empty messages.
 349     (if report-emacs-bug-send-hook
 350         (add-hook report-emacs-bug-send-hook 'report-emacs-bug-hook nil t))
 351     (goto-char (point-max))
 352     (skip-chars-backward " \t\n")
 353     (make-local-variable 'report-emacs-bug-orig-text)
 354     (setq report-emacs-bug-orig-text
 355           (buffer-substring-no-properties (point-min) (point)))
 356     (goto-char user-point)))
 357
 358 (define-obsolete-function-alias 'report-emacs-bug-info 'info-emacs-bug "24.3")
 359
 360 (defun report-emacs-bug-hook ()
 361   "Do some checking before sending a bug report."
 362   (save-excursion
 363     (goto-char (point-max))
 364     (skip-chars-backward " \t\n")
 365     (and (= (- (point) (point-min))
 366             (length report-emacs-bug-orig-text))
 367          (string-equal (buffer-substring-no-properties (point-min) (point))
 368                        report-emacs-bug-orig-text)
 369          (error "No text entered in bug report"))
 370     ;; Warning for novice users.
 371     (unless (or report-emacs-bug-no-confirmation
 372                 (yes-or-no-p
 373                  "Send this bug report to the Emacs maintainers? "))
 374       (goto-char (point-min))
 375       (if (search-forward "To: ")
 376           (delete-region (point) (line-end-position)))
 377       (if report-emacs-bug-send-hook
 378           (kill-local-variable report-emacs-bug-send-hook))
 379       (with-output-to-temp-buffer "*Bug Help*"
 380         (princ (substitute-command-keys
 381                 (format "\
 382 You invoked the command M-x report-emacs-bug,
 383 but you decided not to mail the bug report to the Emacs maintainers.
 384
 385 If you want to mail it to someone else instead,
 386 please insert the proper e-mail address after \"To: \",
 387 and send the mail again%s."
 388                         (if report-emacs-bug-send-command
 389                             (format " using \\[%s]"
 390                                     report-emacs-bug-send-command)
 391                           "")))))
 392       (error "M-x report-emacs-bug was canceled, please read *Bug Help* buffer"))
 393     ;; Query the user for the SMTP method, so that we can skip
 394     ;; questions about From header validity if the user is going to
 395     ;; use mailclient, anyway.
 396     (when (or (and (derived-mode-p 'message-mode)
 397                    (eq message-send-mail-function 'sendmail-query-once))
 398               (and (not (derived-mode-p 'message-mode))
 399                    (eq send-mail-function 'sendmail-query-once)))
 400       (sendmail-query-user-about-smtp)
 401       (when (derived-mode-p 'message-mode)
 402         (setq message-send-mail-function (message-default-send-mail-function))))
 403     (or report-emacs-bug-no-confirmation
 404         ;; mailclient.el does not need a valid From
 405         (if (derived-mode-p 'message-mode)
 406             (eq message-send-mail-function 'message-send-mail-with-mailclient)
 407           (eq send-mail-function 'mailclient-send-it))
 408         ;; Not narrowing to the headers, but that's OK.
 409         (let ((from (mail-fetch-field "From")))
 410           (and (or (not from)
 411                    (message-bogus-recipient-p from)
 412                    ;; This is the default user-mail-address.  On today's
 413                    ;; systems, it seems more likely to be wrong than right,
 414                    ;; since most people don't run their own mail server.
 415                    (string-match (format "\\<%s@%s\\>"
 416                                          (regexp-quote (user-login-name))
 417                                          (regexp-quote (system-name)))
 418                                  from))
 419                (not (yes-or-no-p
 420                      (format "Is `%s' really your email address? " from)))
 421                (error "Please edit the From address and try again"))))))
 422
 423
 424 (provide 'emacsbug)
 425
 426 ;;; emacsbug.el ends here