lisp/macros.el

   1 ;;; macros.el --- non-primitive commands for keyboard macros
   2
   3 ;; Copyright (C) 1985, 86, 87, 92, 94, 95 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Extension commands for keyboard macros.  These permit you to assign
  28 ;; a name to the last-defined keyboard macro, expand and insert the
  29 ;; lisp corresponding to a macro, query the user from within a macro,
  30 ;; or apply a macro to each line in the reason.
  31
  32 ;;; Code:
  33
  34 ;;;###autoload
  35 (defun name-last-kbd-macro (symbol)
  36   "Assign a name to the last keyboard macro defined.
  37 Argument SYMBOL is the name to define.
  38 The symbol's function definition becomes the keyboard macro string.
  39 Such a \"function\" cannot be called from Lisp, but it is a valid editor command."
  40   (interactive "SName for last kbd macro: ")
  41   (or last-kbd-macro
  42       (error "No keyboard macro defined"))
  43   (and (fboundp symbol)
  44        (not (stringp (symbol-function symbol)))
  45        (not (vectorp (symbol-function symbol)))
  46        (error "Function %s is already defined and not a keyboard macro"
  47               symbol))
  48   (if (string-equal symbol "")
  49       (error "No command name given"))
  50   (fset symbol last-kbd-macro))
  51
  52 ;;;###autoload
  53 (defun insert-kbd-macro (macroname &optional keys)
  54   "Insert in buffer the definition of kbd macro NAME, as Lisp code.
  55 Optional second arg KEYS means also record the keys it is on
  56 \(this is the prefix argument, when calling interactively).
  57
  58 This Lisp code will, when executed, define the kbd macro with the same
  59 definition it has now.  If you say to record the keys, the Lisp code
  60 will also rebind those keys to the macro.  Only global key bindings
  61 are recorded since executing this Lisp code always makes global
  62 bindings.
  63
  64 To save a kbd macro, visit a file of Lisp code such as your `~/.emacs',
  65 use this command, and then save the file."
  66   (interactive "CInsert kbd macro (name): \nP")
  67   (let (definition)
  68     (if (string= (symbol-name macroname) "")
  69         (progn
  70           (setq macroname 'last-kbd-macro definition last-kbd-macro)
  71           (insert "(setq "))
  72       (setq definition (symbol-function macroname))
  73       (insert "(fset '"))
  74     (prin1 macroname (current-buffer))
  75     (insert "\n   ")
  76     (if (stringp definition)
  77         (let ((beg (point)) end)
  78           (prin1 definition (current-buffer))
  79           (setq end (point-marker))
  80           (goto-char beg)
  81           (while (< (point) end)
  82             (let ((char (following-char)))
  83               (cond ((= char 0)
  84                      (delete-region (point) (1+ (point)))
  85                      (insert "\\C-@"))
  86                     ((< char 27)
  87                      (delete-region (point) (1+ (point)))
  88                      (insert "\\C-" (+ 96 char)))
  89                     ((= char ?\C-\\)
  90                      (delete-region (point) (1+ (point)))
  91                      (insert "\\C-\\\\"))
  92                     ((< char 32)
  93                      (delete-region (point) (1+ (point)))
  94                      (insert "\\C-" (+ 64 char)))
  95                     ((< char 127)
  96                      (forward-char 1))
  97                     ((= char 127)
  98                      (delete-region (point) (1+ (point)))
  99                      (insert "\\C-?"))
 100                     ((= char 128)
 101                      (delete-region (point) (1+ (point)))
 102                      (insert "\\M-\\C-@"))
 103                     ((= char (aref "\M-\C-\\" 0))
 104                      (delete-region (point) (1+ (point)))
 105                      (insert "\\M-\\C-\\\\"))
 106                     ((< char 155)
 107                      (delete-region (point) (1+ (point)))
 108                      (insert "\\M-\\C-" (- char 32)))
 109                     ((< char 160)
 110                      (delete-region (point) (1+ (point)))
 111                      (insert "\\M-\\C-" (- char 64)))
 112                     ((= char (aref "\M-\\" 0))
 113                      (delete-region (point) (1+ (point)))
 114                      (insert "\\M-\\\\"))
 115                     ((< char 255)
 116                      (delete-region (point) (1+ (point)))
 117                      (insert "\\M-" (- char 128)))
 118                     ((= char 255)
 119                      (delete-region (point) (1+ (point)))
 120                      (insert "\\M-\\C-?"))))))
 121       (if (vectorp definition)
 122           (let ((len (length definition)) (i 0) char mods)
 123             (while (< i len)
 124               (insert (if (zerop i) ?\[ ?\ ))
 125               (setq char (aref definition i)
 126                     i (1+ i))
 127               (cond ((not (numberp char))
 128                      (prin1 char (current-buffer)))
 129                     (t
 130                      (insert "?")
 131                      (setq mods (event-modifiers char)
 132                            char (event-basic-type char))
 133                      (while mods
 134                        (cond ((eq (car mods) 'control)
 135                               (insert "\\C-"))
 136                              ((eq (car mods) 'meta)
 137                               (insert "\\M-"))
 138                              ((eq (car mods) 'hyper)
 139                               (insert "\\H-"))
 140                              ((eq (car mods) 'super)
 141                               (insert "\\s-"))
 142                              ((eq (car mods) 'alt)
 143                               (insert "\\A-"))
 144                              ((and (eq (car mods) 'shift)
 145                                    (>= char ?a)
 146                                    (<= char ?z))
 147                               (setq char (upcase char)))
 148                              ((eq (car mods) 'shift)
 149                               (insert "\\S-")))
 150                        (setq mods (cdr mods)))
 151                      (cond ((= char ?\\)
 152                             (insert "\\\\"))
 153                            ((= char ?\")
 154                             (insert "\\\""))
 155                            ((= char ?\;)
 156                             (insert "\\;"))
 157                            ((= char 127)
 158                             (insert "\\C-?"))
 159                            ((< char 127)
 160                             (insert char))
 161                            (t (insert "\\" (format "%o" char)))))))
 162             (insert ?\]))
 163         (prin1 definition (current-buffer))))
 164     (insert ")\n")
 165     (if keys
 166         (let ((keys (where-is-internal macroname '(keymap))))
 167           (while keys
 168             (insert "(global-set-key ")
 169             (prin1 (car keys) (current-buffer))
 170             (insert " '")
 171             (prin1 macroname (current-buffer))
 172             (insert ")\n")
 173             (setq keys (cdr keys)))))))
 174
 175 ;;;###autoload
 176 (defun kbd-macro-query (flag)
 177   "Query user during kbd macro execution.
 178   With prefix argument, enters recursive edit, reading keyboard
 179 commands even within a kbd macro.  You can give different commands
 180 each time the macro executes.
 181   Without prefix argument, asks whether to continue running the macro.
 182 Your options are: \\<query-replace-map>
 183 \\[act] Finish this iteration normally and continue with the next.
 184 \\[skip]        Skip the rest of this iteration, and start the next.
 185 \\[exit]        Stop the macro entirely right now.
 186 \\[recenter]    Redisplay the screen, then ask again.
 187 \\[edit]        Enter recursive edit; ask again when you exit from that."
 188   (interactive "P")
 189   (or executing-kbd-macro
 190       defining-kbd-macro
 191       (error "Not defining or executing kbd macro"))
 192   (if flag
 193       (let (executing-kbd-macro defining-kbd-macro)
 194         (recursive-edit))
 195     (if (not executing-kbd-macro)
 196         nil
 197       (let ((loop t)
 198             (msg (substitute-command-keys
 199                   "Proceed with macro?\\<query-replace-map>\
 200  (\\[act], \\[skip], \\[exit], \\[recenter], \\[edit]) ")))
 201         (while loop
 202           (let ((key (let ((executing-kbd-macro nil)
 203                            (defining-kbd-macro nil))
 204                        (message "%s" msg)
 205                        (read-event)))
 206                 def)
 207             (setq key (vector key))
 208             (setq def (lookup-key query-replace-map key))
 209             (cond ((eq def 'act)
 210                    (setq loop nil))
 211                   ((eq def 'skip)
 212                    (setq loop nil)
 213                    (setq executing-kbd-macro ""))
 214                   ((eq def 'exit)
 215                    (setq loop nil)
 216                    (setq executing-kbd-macro t))
 217                   ((eq def 'recenter)
 218                    (recenter nil))
 219                   ((eq def 'edit)
 220                    (let (executing-kbd-macro defining-kbd-macro)
 221                      (recursive-edit)))
 222                   ((eq def 'quit)
 223                    (setq quit-flag t))
 224                   (t
 225                    (or (eq def 'help)
 226                        (ding))
 227                    (with-output-to-temp-buffer "*Help*"
 228                      (princ
 229                       (substitute-command-keys
 230                        "Specify how to proceed with keyboard macro execution.
 231 Possibilities: \\<query-replace-map>
 232 \\[act] Finish this iteration normally and continue with the next.
 233 \\[skip]        Skip the rest of this iteration, and start the next.
 234 \\[exit]        Stop the macro entirely right now.
 235 \\[recenter]    Redisplay the screen, then ask again.
 236 \\[edit]        Enter recursive edit; ask again when you exit from that."))
 237                      (save-excursion
 238                        (set-buffer standard-output)
 239                        (help-mode)))))))))))
 240
 241 ;;;###autoload
 242 (defun apply-macro-to-region-lines (top bottom &optional macro)
 243   "For each complete line between point and mark, move to the beginning
 244 of the line, and run the last keyboard macro.
 245
 246 When called from lisp, this function takes two arguments TOP and
 247 BOTTOM, describing the current region.  TOP must be before BOTTOM.
 248 The optional third argument MACRO specifies a keyboard macro to
 249 execute.
 250
 251 This is useful for quoting or unquoting included text, adding and
 252 removing comments, or producing tables where the entries are regular.
 253
 254 For example, in Usenet articles, sections of text quoted from another
 255 author are indented, or have each line start with `>'.  To quote a
 256 section of text, define a keyboard macro which inserts `>', put point
 257 and mark at opposite ends of the quoted section, and use
 258 `\\[apply-macro-to-region-lines]' to mark the entire section.
 259
 260 Suppose you wanted to build a keyword table in C where each entry
 261 looked like this:
 262
 263     { \"foo\", foo_data, foo_function },
 264     { \"bar\", bar_data, bar_function },
 265     { \"baz\", baz_data, baz_function },
 266
 267 You could enter the names in this format:
 268
 269     foo
 270     bar
 271     baz
 272
 273 and write a macro to massage a word into a table entry:
 274
 275     \\C-x (
 276        \\M-d { \"\\C-y\", \\C-y_data, \\C-y_function },
 277     \\C-x )
 278
 279 and then select the region of un-tablified names and use
 280 `\\[apply-macro-to-region-lines]' to build the table from the names.
 281 "
 282   (interactive "r")
 283   (or macro
 284       (progn
 285         (if (null last-kbd-macro)
 286             (error "No keyboard macro has been defined"))
 287         (setq macro last-kbd-macro)))
 288   (save-excursion
 289     (let ((end-marker (progn
 290                         (goto-char bottom)
 291                         (beginning-of-line)
 292                         (point-marker)))
 293           next-line-marker)
 294       (goto-char top)
 295       (if (not (bolp))
 296           (forward-line 1))
 297       (setq next-line-marker (point-marker))
 298       (while (< next-line-marker end-marker)
 299         (goto-char next-line-marker)
 300         (save-excursion
 301           (forward-line 1)
 302           (set-marker next-line-marker (point)))
 303         (save-excursion
 304           (let ((mark-active nil))
 305             (execute-kbd-macro (or macro last-kbd-macro)))))
 306       (set-marker end-marker nil)
 307       (set-marker next-line-marker nil))))
 308
 309 ;;;###autoload (define-key ctl-x-map "q" 'kbd-macro-query)
 310
 311 (provide 'macros)
 312
 313 ;;; arch-tag: 346ed1a5-1220-4bc8-b533-961ee704361f
 314 ;;; macros.el ends here