lisp/edmacro.el

   1 ;;; edmacro.el --- keyboard macro editor
   2
   3 ;; Copyright (C) 1993, 1994, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Maintainer: Dave Gillespie <daveg@synaptics.com>
   8 ;; Version: 2.01
   9 ;; Keywords: abbrev
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Usage:
  31 ;;
  32 ;; The `C-x C-k e' (`edit-kbd-macro') command edits a keyboard macro
  33 ;; in a special buffer.  It prompts you to type a key sequence,
  34 ;; which should be one of:
  35 ;;
  36 ;;  * RET or `C-x e' (call-last-kbd-macro), to edit the most
  37 ;;    recently defined keyboard macro.
  38 ;;
  39 ;;  * `M-x' followed by a command name, to edit a named command
  40 ;;    whose definition is a keyboard macro.
  41 ;;
  42 ;;  * `C-h l' (view-lossage), to edit the 100 most recent keystrokes
  43 ;;    and install them as the "current" macro.
  44 ;;
  45 ;;  * any key sequence whose definition is a keyboard macro.
  46 ;;
  47 ;; This file includes a version of `insert-kbd-macro' that uses the
  48 ;; more readable format defined by these routines.
  49 ;;
  50 ;; Also, the `read-kbd-macro' command parses the region as
  51 ;; a keyboard macro, and installs it as the "current" macro.
  52 ;; This and `format-kbd-macro' can also be called directly as
  53 ;; Lisp functions.
  54
  55 ;; Type `C-h m', or see the documentation for `edmacro-mode' below,
  56 ;; for information about the format of written keyboard macros.
  57
  58 ;; `edit-kbd-macro' formats the macro with one command per line,
  59 ;; including the command names as comments on the right.  If the
  60 ;; formatter gets confused about which keymap was used for the
  61 ;; characters, the command-name comments will be wrong but that
  62 ;; won't hurt anything.
  63
  64 ;; With a prefix argument, `edit-kbd-macro' will format the
  65 ;; macro in a more concise way that omits the comments.
  66
  67 ;; This package requires GNU Emacs 19 or later, and daveg's CL
  68 ;; package 2.02 or later.  (CL 2.02 comes standard starting with
  69 ;; Emacs 19.18.)  This package does not work with Emacs 18 or
  70 ;; Lucid Emacs.
  71
  72 ;;; Code:
  73 \f
  74 (eval-when-compile
  75  (require 'cl))
  76
  77 (require 'kmacro)
  78
  79 ;;; The user-level commands for editing macros.
  80
  81 ;;;###autoload
  82 (defvar edmacro-eight-bits nil
  83   "*Non-nil if edit-kbd-macro should leave 8-bit characters intact.
  84 Default nil means to write characters above \\177 in octal notation.")
  85
  86 (defvar edmacro-mode-map nil)
  87 (unless edmacro-mode-map
  88   (setq edmacro-mode-map (make-sparse-keymap))
  89   (define-key edmacro-mode-map "\C-c\C-c" 'edmacro-finish-edit)
  90   (define-key edmacro-mode-map "\C-c\C-q" 'edmacro-insert-key))
  91
  92 (defvar edmacro-store-hook)
  93 (defvar edmacro-finish-hook)
  94 (defvar edmacro-original-buffer)
  95
  96 ;;;###autoload
  97 (defun edit-kbd-macro (keys &optional prefix finish-hook store-hook)
  98   "Edit a keyboard macro.
  99 At the prompt, type any key sequence which is bound to a keyboard macro.
 100 Or, type `C-x e' or RET to edit the last keyboard macro, `C-h l' to edit
 101 the last 100 keystrokes as a keyboard macro, or `M-x' to edit a macro by
 102 its command name.
 103 With a prefix argument, format the macro in a more concise way."
 104   (interactive "kKeyboard macro to edit (C-x e, M-x, C-h l, or keys): \nP")
 105   (when keys
 106     (let ((cmd (if (arrayp keys) (key-binding keys) keys))
 107           (mac nil) (mac-counter nil) (mac-format nil)
 108           kmacro)
 109       (cond (store-hook
 110              (setq mac keys)
 111              (setq cmd nil))
 112             ((or (memq cmd '(call-last-kbd-macro kmacro-call-macro
 113                              kmacro-end-or-call-macro kmacro-end-and-call-macro))
 114                  (member keys '("\r" [return])))
 115              (or last-kbd-macro
 116                  (y-or-n-p "No keyboard macro defined.  Create one? ")
 117                  (keyboard-quit))
 118              (setq mac (or last-kbd-macro ""))
 119              (setq keys nil)
 120              (setq cmd 'last-kbd-macro))
 121             ((eq cmd 'execute-extended-command)
 122              (setq cmd (read-command "Name of keyboard macro to edit: "))
 123              (if (string-equal cmd "")
 124                  (error "No command name given"))
 125              (setq keys nil)
 126              (setq mac (symbol-function cmd)))
 127             ((memq cmd '(view-lossage electric-view-lossage))
 128              (setq mac (recent-keys))
 129              (setq keys nil)
 130              (setq cmd 'last-kbd-macro))
 131             ((null cmd)
 132              (error "Key sequence %s is not defined" (key-description keys)))
 133             ((symbolp cmd)
 134              (setq mac (symbol-function cmd)))
 135             (t
 136              (setq mac cmd)
 137              (setq cmd nil)))
 138       (when (setq kmacro (kmacro-extract-lambda mac))
 139         (setq mac (car kmacro)
 140               mac-counter (nth 1 kmacro)
 141               mac-format (nth 2 kmacro)))
 142       (unless (arrayp mac)
 143         (error "Key sequence %s is not a keyboard macro"
 144                (key-description keys)))
 145       (message "Formatting keyboard macro...")
 146       (let* ((oldbuf (current-buffer))
 147              (mmac (edmacro-fix-menu-commands mac))
 148              (fmt (edmacro-format-keys mmac 1))
 149              (fmtv (edmacro-format-keys mmac (not prefix)))
 150              (buf (get-buffer-create "*Edit Macro*")))
 151         (message "Formatting keyboard macro...done")
 152         (switch-to-buffer buf)
 153         (kill-all-local-variables)
 154         (use-local-map edmacro-mode-map)
 155         (setq buffer-read-only nil)
 156         (setq major-mode 'edmacro-mode)
 157         (setq mode-name "Edit Macro")
 158         (set (make-local-variable 'edmacro-original-buffer) oldbuf)
 159         (set (make-local-variable 'edmacro-finish-hook) finish-hook)
 160         (set (make-local-variable 'edmacro-store-hook) store-hook)
 161         (erase-buffer)
 162         (insert ";; Keyboard Macro Editor.  Press C-c C-c to finish; "
 163                 "press C-x k RET to cancel.\n")
 164         (insert ";; Original keys: " fmt "\n")
 165         (unless store-hook
 166           (insert "\nCommand: " (if cmd (symbol-name cmd) "none") "\n")
 167           (let ((gkeys (where-is-internal (or cmd mac) '(keymap))))
 168             (if (and keys (not (member keys gkeys)))
 169                 (setq gkeys (cons keys gkeys)))
 170             (if gkeys
 171                 (while gkeys
 172                   (insert "Key: " (edmacro-format-keys (pop gkeys) 1) "\n"))
 173               (insert "Key: none\n")))
 174           (when (and mac-counter mac-format)
 175             (insert (format "Counter: %d\nFormat: \"%s\"\n" mac-counter mac-format))))
 176         (insert "\nMacro:\n\n")
 177         (save-excursion
 178           (insert fmtv "\n"))
 179         (recenter '(4))
 180         (when (eq mac mmac)
 181           (set-buffer-modified-p nil))
 182         (run-hooks 'edmacro-format-hook)))))
 183
 184 ;;; The next two commands are provided for convenience and backward
 185 ;;; compatibility.
 186
 187 ;;;###autoload
 188 (defun edit-last-kbd-macro (&optional prefix)
 189   "Edit the most recently defined keyboard macro."
 190   (interactive "P")
 191   (edit-kbd-macro 'call-last-kbd-macro prefix))
 192
 193 ;;;###autoload
 194 (defun edit-named-kbd-macro (&optional prefix)
 195   "Edit a keyboard macro which has been given a name by `name-last-kbd-macro'."
 196   (interactive "P")
 197   (edit-kbd-macro 'execute-extended-command prefix))
 198
 199 ;;;###autoload
 200 (defun read-kbd-macro (start &optional end)
 201   "Read the region as a keyboard macro definition.
 202 The region is interpreted as spelled-out keystrokes, e.g., \"M-x abc RET\".
 203 See documentation for `edmacro-mode' for details.
 204 Leading/trailing \"C-x (\" and \"C-x )\" in the text are allowed and ignored.
 205 The resulting macro is installed as the \"current\" keyboard macro.
 206
 207 In Lisp, may also be called with a single STRING argument in which case
 208 the result is returned rather than being installed as the current macro.
 209 The result will be a string if possible, otherwise an event vector.
 210 Second argument NEED-VECTOR means to return an event vector always."
 211   (interactive "r")
 212   (if (stringp start)
 213       (edmacro-parse-keys start end)
 214     (setq last-kbd-macro (edmacro-parse-keys (buffer-substring start end)))))
 215
 216 ;;;###autoload
 217 (defun format-kbd-macro (&optional macro verbose)
 218   "Return the keyboard macro MACRO as a human-readable string.
 219 This string is suitable for passing to `read-kbd-macro'.
 220 Second argument VERBOSE means to put one command per line with comments.
 221 If VERBOSE is `1', put everything on one line.  If VERBOSE is omitted
 222 or nil, use a compact 80-column format."
 223   (and macro (symbolp macro) (setq macro (symbol-function macro)))
 224   (edmacro-format-keys (or macro last-kbd-macro) verbose))
 225 \f
 226 ;;; Commands for *Edit Macro* buffer.
 227
 228 (defun edmacro-finish-edit ()
 229   (interactive)
 230   (unless (eq major-mode 'edmacro-mode)
 231     (error
 232      "This command is valid only in buffers created by `edit-kbd-macro'"))
 233   (run-hooks 'edmacro-finish-hook)
 234   (let ((cmd nil) (keys nil) (no-keys nil)
 235         (mac-counter nil) (mac-format nil) (kmacro nil)
 236         (top (point-min)))
 237     (goto-char top)
 238     (let ((case-fold-search nil))
 239       (while (cond ((looking-at "[ \t]*\\($\\|;;\\|REM[ \t\n]\\)")
 240                     t)
 241                    ((looking-at "Command:[ \t]*\\([^ \t\n]*\\)[ \t]*$")
 242                     (when edmacro-store-hook
 243                       (error "\"Command\" line not allowed in this context"))
 244                     (let ((str (buffer-substring (match-beginning 1)
 245                                                  (match-end 1))))
 246                       (unless (equal str "")
 247                         (setq cmd (and (not (equal str "none"))
 248                                        (intern str)))
 249                         (and (fboundp cmd) (not (arrayp (symbol-function cmd)))
 250                              (not (setq kmacro (get cmd 'kmacro)))
 251                              (not (y-or-n-p
 252                                    (format "Command %s is already defined; %s"
 253                                            cmd "proceed? ")))
 254                              (keyboard-quit))))
 255                     t)
 256                    ((looking-at "Key:\\(.*\\)$")
 257                     (when edmacro-store-hook
 258                       (error "\"Key\" line not allowed in this context"))
 259                     (let ((key (edmacro-parse-keys
 260                                 (buffer-substring (match-beginning 1)
 261                                                   (match-end 1)))))
 262                       (unless (equal key "")
 263                         (if (equal key "none")
 264                             (setq no-keys t)
 265                           (push key keys)
 266                           (let ((b (key-binding key)))
 267                             (and b (commandp b) (not (arrayp b))
 268                                  (not (kmacro-extract-lambda b))
 269                                  (or (not (fboundp b))
 270                                      (not (or (arrayp (symbol-function b))
 271                                               (get b 'kmacro))))
 272                                  (not (y-or-n-p
 273                                        (format "Key %s is already defined; %s"
 274                                                (edmacro-format-keys key 1)
 275                                                "proceed? ")))
 276                                  (keyboard-quit))))))
 277                     t)
 278                    ((looking-at "Counter:[ \t]*\\([^ \t\n]*\\)[ \t]*$")
 279                     (when edmacro-store-hook
 280                       (error "\"Counter\" line not allowed in this context"))
 281                     (let ((str (buffer-substring (match-beginning 1)
 282                                                  (match-end 1))))
 283                       (unless (equal str "")
 284                         (setq mac-counter (string-to-number str))))
 285                     t)
 286                    ((looking-at "Format:[ \t]*\"\\([^\n]*\\)\"[ \t]*$")
 287                     (when edmacro-store-hook
 288                       (error "\"Format\" line not allowed in this context"))
 289                     (let ((str (buffer-substring (match-beginning 1)
 290                                                  (match-end 1))))
 291                       (unless (equal str "")
 292                         (setq mac-format str)))
 293                     t)
 294                    ((looking-at "Macro:[ \t\n]*")
 295                     (goto-char (match-end 0))
 296                     nil)
 297                    ((eobp) nil)
 298                    (t (error "Expected a `Macro:' line")))
 299         (forward-line 1))
 300       (setq top (point)))
 301     (let* ((buf (current-buffer))
 302            (str (buffer-substring top (point-max)))
 303            (modp (buffer-modified-p))
 304            (obuf edmacro-original-buffer)
 305            (store-hook edmacro-store-hook)
 306            (finish-hook edmacro-finish-hook))
 307       (unless (or cmd keys store-hook (equal str ""))
 308         (error "No command name or keys specified"))
 309       (when modp
 310         (when (buffer-name obuf)
 311           (set-buffer obuf))
 312         (message "Compiling keyboard macro...")
 313         (let ((mac (edmacro-parse-keys str)))
 314           (message "Compiling keyboard macro...done")
 315           (if store-hook
 316               (funcall store-hook mac)
 317             (when (eq cmd 'last-kbd-macro)
 318               (setq last-kbd-macro (and (> (length mac) 0) mac))
 319               (setq cmd nil))
 320             (when cmd
 321               (if (= (length mac) 0)
 322                   (fmakunbound cmd)
 323                 (fset cmd
 324                       (if (and mac-counter mac-format)
 325                           (kmacro-lambda-form mac mac-counter mac-format)
 326                         mac))))
 327             (if no-keys
 328                 (when cmd
 329                   (loop for key in (where-is-internal cmd '(keymap)) do
 330                         (global-unset-key key)))
 331               (when keys
 332                 (if (= (length mac) 0)
 333                     (loop for key in keys do (global-unset-key key))
 334                   (loop for key in keys do
 335                         (global-set-key key
 336                                         (or cmd
 337                                             (if (and mac-counter mac-format)
 338                                                 (kmacro-lambda-form mac mac-counter mac-format)
 339                                               mac))))))))))
 340       (kill-buffer buf)
 341       (when (buffer-name obuf)
 342         (switch-to-buffer obuf))
 343       (when finish-hook
 344         (funcall finish-hook)))))
 345
 346 (defun edmacro-insert-key (key)
 347   "Insert the written name of a key in the buffer."
 348   (interactive "kKey to insert: ")
 349   (if (bolp)
 350       (insert (edmacro-format-keys key t) "\n")
 351     (insert (edmacro-format-keys key) " ")))
 352
 353 (defun edmacro-mode ()
 354   "\\<edmacro-mode-map>Keyboard Macro Editing mode.  Press
 355 \\[edmacro-finish-edit] to save and exit.
 356 To abort the edit, just kill this buffer with \\[kill-buffer] RET.
 357
 358 Press \\[edmacro-insert-key] to insert the name of any key by typing the key.
 359
 360 The editing buffer contains a \"Command:\" line and any number of
 361 \"Key:\" lines at the top.  These are followed by a \"Macro:\" line
 362 and the macro itself as spelled-out keystrokes: `C-x C-f foo RET'.
 363
 364 The \"Command:\" line specifies the command name to which the macro
 365 is bound, or \"none\" for no command name.  Write \"last-kbd-macro\"
 366 to refer to the current keyboard macro (as used by \\[call-last-kbd-macro]).
 367
 368 The \"Key:\" lines specify key sequences to which the macro is bound,
 369 or \"none\" for no key bindings.
 370
 371 You can edit these lines to change the places where the new macro
 372 is stored.
 373
 374
 375 Format of keyboard macros during editing:
 376
 377 Text is divided into \"words\" separated by whitespace.  Except for
 378 the words described below, the characters of each word go directly
 379 as characters of the macro.  The whitespace that separates words
 380 is ignored.  Whitespace in the macro must be written explicitly,
 381 as in \"foo SPC bar RET\".
 382
 383  * The special words RET, SPC, TAB, DEL, LFD, ESC, and NUL represent
 384    special control characters.  The words must be written in uppercase.
 385
 386  * A word in angle brackets, e.g., <return>, <down>, or <f1>, represents
 387    a function key.  (Note that in the standard configuration, the
 388    function key <return> and the control key RET are synonymous.)
 389    You can use angle brackets on the words RET, SPC, etc., but they
 390    are not required there.
 391
 392  * Keys can be written by their ASCII code, using a backslash followed
 393    by up to six octal digits.  This is the only way to represent keys
 394    with codes above \\377.
 395
 396  * One or more prefixes M- (meta), C- (control), S- (shift), A- (alt),
 397    H- (hyper), and s- (super) may precede a character or key notation.
 398    For function keys, the prefixes may go inside or outside of the
 399    brackets:  C-<down> = <C-down>.  The prefixes may be written in
 400    any order:  M-C-x = C-M-x.
 401
 402    Prefixes are not allowed on multi-key words, e.g., C-abc, except
 403    that the Meta prefix is allowed on a sequence of digits and optional
 404    minus sign:  M--123 = M-- M-1 M-2 M-3.
 405
 406  * The `^' notation for control characters also works:  ^M = C-m.
 407
 408  * Double angle brackets enclose command names:  <<next-line>> is
 409    shorthand for M-x next-line RET.
 410
 411  * Finally, REM or ;; causes the rest of the line to be ignored as a
 412    comment.
 413
 414 Any word may be prefixed by a multiplier in the form of a decimal
 415 number and `*':  3*<right> = <right> <right> <right>, and
 416 10*foo = foofoofoofoofoofoofoofoofoofoo.
 417
 418 Multiple text keys can normally be strung together to form a word,
 419 but you may need to add whitespace if the word would look like one
 420 of the above notations:  `; ; ;' is a keyboard macro with three
 421 semicolons, but `;;;' is a comment.  Likewise, `\\ 1 2 3' is four
 422 keys but `\\123' is a single key written in octal, and `< right >'
 423 is seven keys but `<right>' is a single function key.  When in
 424 doubt, use whitespace."
 425   (interactive)
 426   (error "This mode can be enabled only by `edit-kbd-macro'"))
 427 (put 'edmacro-mode 'mode-class 'special)
 428 \f
 429 ;;; Formatting a keyboard macro as human-readable text.
 430
 431 (defun edmacro-format-keys (macro &optional verbose)
 432   (setq macro (edmacro-fix-menu-commands macro))
 433   (let* ((maps (current-active-maps))
 434          (pkeys '(end-macro ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9 ?- ?\C-u
 435                   ?\M-- ?\M-0 ?\M-1 ?\M-2 ?\M-3 ?\M-4 ?\M-5 ?\M-6
 436                   ?\M-7 ?\M-8 ?\M-9))
 437          (mdigs (nthcdr 13 pkeys))
 438          (maxkey (if edmacro-eight-bits 255 127))
 439          (case-fold-search nil)
 440          (res-words '("NUL" "TAB" "LFD" "RET" "ESC" "SPC" "DEL" "REM"))
 441          (rest-mac (vconcat macro [end-macro]))
 442          (res "")
 443          (len 0)
 444          (one-line (eq verbose 1)))
 445     (if one-line (setq verbose nil))
 446     (when (stringp macro)
 447       (loop for i below (length macro) do
 448             (when (>= (aref rest-mac i) 128)
 449               (incf (aref rest-mac i) (- ?\M-\^@ 128)))))
 450     (while (not (eq (aref rest-mac 0) 'end-macro))
 451       (let* ((prefix
 452               (or (and (integerp (aref rest-mac 0))
 453                        (memq (aref rest-mac 0) mdigs)
 454                        (memq (key-binding (edmacro-subseq rest-mac 0 1))
 455                              '(digit-argument negative-argument))
 456                        (let ((i 1))
 457                          (while (memq (aref rest-mac i) (cdr mdigs))
 458                            (incf i))
 459                          (and (not (memq (aref rest-mac i) pkeys))
 460                               (prog1 (vconcat "M-" (edmacro-subseq rest-mac 0 i) " ")
 461                                 (callf edmacro-subseq rest-mac i)))))
 462                   (and (eq (aref rest-mac 0) ?\C-u)
 463                        (eq (key-binding [?\C-u]) 'universal-argument)
 464                        (let ((i 1))
 465                          (while (eq (aref rest-mac i) ?\C-u)
 466                            (incf i))
 467                          (and (not (memq (aref rest-mac i) pkeys))
 468                               (prog1 (loop repeat i concat "C-u ")
 469                                 (callf edmacro-subseq rest-mac i)))))
 470                   (and (eq (aref rest-mac 0) ?\C-u)
 471                        (eq (key-binding [?\C-u]) 'universal-argument)
 472                        (let ((i 1))
 473                          (when (eq (aref rest-mac i) ?-)
 474                            (incf i))
 475                          (while (memq (aref rest-mac i)
 476                                       '(?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9))
 477                            (incf i))
 478                          (and (not (memq (aref rest-mac i) pkeys))
 479                               (prog1 (vconcat "C-u " (edmacro-subseq rest-mac 1 i) " ")
 480                                 (callf edmacro-subseq rest-mac i)))))))
 481              (bind-len (apply 'max 1
 482                               (loop for map in maps
 483                                     for b = (lookup-key map rest-mac)
 484                                     when b collect b)))
 485              (key (edmacro-subseq rest-mac 0 bind-len))
 486              (fkey nil) tlen tkey
 487              (bind (or (loop for map in maps for b = (lookup-key map key)
 488                              thereis (and (not (integerp b)) b))
 489                        (and (setq fkey (lookup-key function-key-map rest-mac))
 490                             (setq tlen fkey tkey (edmacro-subseq rest-mac 0 tlen)
 491                                   fkey (lookup-key function-key-map tkey))
 492                             (loop for map in maps
 493                                   for b = (lookup-key map fkey)
 494                                   when (and (not (integerp b)) b)
 495                                   do (setq bind-len tlen key tkey)
 496                                   and return b
 497                                   finally do (setq fkey nil)))))
 498              (first (aref key 0))
 499              (text (loop for i from bind-len below (length rest-mac)
 500                          for ch = (aref rest-mac i)
 501                          while (and (integerp ch)
 502                                     (> ch 32) (< ch maxkey) (/= ch 92)
 503                                     (eq (key-binding (char-to-string ch))
 504                                         'self-insert-command)
 505                                     (or (> i (- (length rest-mac) 2))
 506                                         (not (eq ch (aref rest-mac (+ i 1))))
 507                                         (not (eq ch (aref rest-mac (+ i 2))))))
 508                          finally return i))
 509              desc)
 510         (if (stringp bind) (setq bind nil))
 511         (cond ((and (eq bind 'self-insert-command) (not prefix)
 512                     (> text 1) (integerp first)
 513                     (> first 32) (<= first maxkey) (/= first 92)
 514                     (progn
 515                       (if (> text 30) (setq text 30))
 516                       (setq desc (concat (edmacro-subseq rest-mac 0 text)))
 517                       (when (string-match "^[ACHMsS]-." desc)
 518                         (setq text 2)
 519                         (callf substring desc 0 2))
 520                       (not (string-match
 521                             "^;;\\|^<.*>$\\|^\\\\[0-9]+$\\|^[0-9]+\\*."
 522                             desc))))
 523                (when (or (string-match "^\\^.$" desc)
 524                          (member desc res-words))
 525                  (setq desc (mapconcat 'char-to-string desc " ")))
 526                (when verbose
 527                  (setq bind (format "%s * %d" bind text)))
 528                (setq bind-len text))
 529               ((and (eq bind 'execute-extended-command)
 530                     (> text bind-len)
 531                     (memq (aref rest-mac text) '(return 13))
 532                     (progn
 533                       (setq desc (concat (edmacro-subseq rest-mac bind-len text)))
 534                       (commandp (intern-soft desc))))
 535                (if (commandp (intern-soft desc)) (setq bind desc))
 536                (setq desc (format "<<%s>>" desc))
 537                (setq bind-len (1+ text)))
 538               (t
 539                (setq desc (mapconcat
 540                            (function
 541                             (lambda (ch)
 542                               (cond
 543                                ((integerp ch)
 544                                 (concat
 545                                  (loop for pf across "ACHMsS"
 546                                        for bit in '(?\A-\^@ ?\C-\^@ ?\H-\^@
 547                                                     ?\M-\^@ ?\s-\^@ ?\S-\^@)
 548                                        when (/= (logand ch bit) 0)
 549                                        concat (format "%c-" pf))
 550                                  (let ((ch2 (logand ch (1- (lsh 1 18)))))
 551                                    (cond ((<= ch2 32)
 552                                           (case ch2
 553                                             (0 "NUL") (9 "TAB") (10 "LFD")
 554                                             (13 "RET") (27 "ESC") (32 "SPC")
 555                                             (t
 556                                              (format "C-%c"
 557                                                      (+ (if (<= ch2 26) 96 64)
 558                                                         ch2)))))
 559                                          ((= ch2 127) "DEL")
 560                                          ((<= ch2 maxkey) (char-to-string ch2))
 561                                          (t (format "\\%o" ch2))))))
 562                                ((symbolp ch)
 563                                 (format "<%s>" ch))
 564                                (t
 565                                 (error "Unrecognized item in macro: %s" ch)))))
 566                            (or fkey key) " "))))
 567         (if prefix
 568             (setq desc (concat (edmacro-sanitize-for-string prefix) desc)))
 569         (unless (string-match " " desc)
 570           (let ((times 1) (pos bind-len))
 571             (while (not (edmacro-mismatch rest-mac rest-mac
 572                                           0 bind-len pos (+ bind-len pos)))
 573               (incf times)
 574               (incf pos bind-len))
 575             (when (> times 1)
 576               (setq desc (format "%d*%s" times desc))
 577               (setq bind-len (* bind-len times)))))
 578         (setq rest-mac (edmacro-subseq rest-mac bind-len))
 579         (if verbose
 580             (progn
 581               (unless (equal res "") (callf concat res "\n"))
 582               (callf concat res desc)
 583               (when (and bind (or (stringp bind) (symbolp bind)))
 584                 (callf concat res
 585                   (make-string (max (- 3 (/ (length desc) 8)) 1) 9)
 586                   ";; " (if (stringp bind) bind (symbol-name bind))))
 587               (setq len 0))
 588           (if (and (> (+ len (length desc) 2) 72) (not one-line))
 589               (progn
 590                 (callf concat res "\n ")
 591                 (setq len 1))
 592             (unless (equal res "")
 593               (callf concat res " ")
 594               (incf len)))
 595           (callf concat res desc)
 596           (incf len (length desc)))))
 597     res))
 598
 599 (defun edmacro-mismatch (cl-seq1 cl-seq2 cl-start1 cl-end1 cl-start2 cl-end2)
 600   "Compare SEQ1 with SEQ2, return index of first mismatching element.
 601 Return nil if the sequences match.  If one sequence is a prefix of the
 602 other, the return value indicates the end of the shorted sequence."
 603   (let (cl-test cl-test-not cl-key cl-from-end)
 604     (or cl-end1 (setq cl-end1 (length cl-seq1)))
 605     (or cl-end2 (setq cl-end2 (length cl-seq2)))
 606     (if cl-from-end
 607         (progn
 608           (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 609                       (cl-check-match (elt cl-seq1 (1- cl-end1))
 610                                       (elt cl-seq2 (1- cl-end2))))
 611             (setq cl-end1 (1- cl-end1) cl-end2 (1- cl-end2)))
 612           (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 613                (1- cl-end1)))
 614       (let ((cl-p1 (and (listp cl-seq1) (nthcdr cl-start1 cl-seq1)))
 615             (cl-p2 (and (listp cl-seq2) (nthcdr cl-start2 cl-seq2))))
 616         (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 617                     (cl-check-match (if cl-p1 (car cl-p1)
 618                                       (aref cl-seq1 cl-start1))
 619                                     (if cl-p2 (car cl-p2)
 620                                       (aref cl-seq2 cl-start2))))
 621           (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)
 622                 cl-start1 (1+ cl-start1) cl-start2 (1+ cl-start2)))
 623         (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 624              cl-start1)))))
 625
 626 (defun edmacro-subseq (seq start &optional end)
 627   "Return the subsequence of SEQ from START to END.
 628 If END is omitted, it defaults to the length of the sequence.
 629 If START or END is negative, it counts from the end."
 630   (if (stringp seq) (substring seq start end)
 631     (let (len)
 632       (and end (< end 0) (setq end (+ end (setq len (length seq)))))
 633       (if (< start 0) (setq start (+ start (or len (setq len (length seq))))))
 634       (cond ((listp seq)
 635              (if (> start 0) (setq seq (nthcdr start seq)))
 636              (if end
 637                  (let ((res nil))
 638                    (while (>= (setq end (1- end)) start)
 639                      (push (pop seq) res))
 640                    (nreverse res))
 641                (copy-sequence seq)))
 642             (t
 643              (or end (setq end (or len (length seq))))
 644              (let ((res (make-vector (max (- end start) 0) nil))
 645                    (i 0))
 646                (while (< start end)
 647                  (aset res i (aref seq start))
 648                  (setq i (1+ i) start (1+ start)))
 649                res))))))
 650
 651 (defun edmacro-sanitize-for-string (seq)
 652   "Convert a key sequence vector into a string.
 653 The string represents the same events; Meta is indicated by bit 7.
 654 This function assumes that the events can be stored in a string."
 655   (setq seq (copy-sequence seq))
 656   (loop for i below (length seq) do
 657         (when (logand (aref seq i) 128)
 658           (setf (aref seq i) (logand (aref seq i) 127))))
 659   seq)
 660
 661 (defun edmacro-fix-menu-commands (macro &optional noerror)
 662   (if (vectorp macro)
 663       (let (result)
 664         ;; Make a list of the elements.
 665         (setq macro (append macro nil))
 666         (dolist (ev macro)
 667           (cond ((atom ev)
 668                  (push ev result))
 669                 ((eq (car ev) 'help-echo))
 670                 ((eq (car ev) 'switch-frame))
 671                 ((equal ev '(menu-bar))
 672                  (push 'menu-bar result))
 673                 ((equal (cadadr ev) '(menu-bar))
 674                  (push (vector 'menu-bar (car ev)) result))
 675                 ;; It would be nice to do pop-up menus, too, but not enough
 676                 ;; info is recorded in macros to make this possible.
 677                 (noerror
 678                  ;; Just ignore mouse events.
 679                  nil)
 680                 (t
 681                  (error "Macros with mouse clicks are not %s"
 682                         "supported by this command"))))
 683         ;; Reverse them again and make them back into a vector.
 684         (vconcat (nreverse result)))
 685     macro))
 686 \f
 687 ;;; Parsing a human-readable keyboard macro.
 688
 689 (defun edmacro-parse-keys (string &optional need-vector)
 690   (let ((case-fold-search nil)
 691         (pos 0)
 692         (res []))
 693     (while (and (< pos (length string))
 694                 (string-match "[^ \t\n\f]+" string pos))
 695       (let ((word (substring string (match-beginning 0) (match-end 0)))
 696             (key nil)
 697             (times 1))
 698         (setq pos (match-end 0))
 699         (when (string-match "\\([0-9]+\\)\\*." word)
 700           (setq times (string-to-number (substring word 0 (match-end 1))))
 701           (setq word (substring word (1+ (match-end 1)))))
 702         (cond ((string-match "^<<.+>>$" word)
 703                (setq key (vconcat (if (eq (key-binding [?\M-x])
 704                                           'execute-extended-command)
 705                                       [?\M-x]
 706                                     (or (car (where-is-internal
 707                                               'execute-extended-command))
 708                                         [?\M-x]))
 709                                   (substring word 2 -2) "\r")))
 710               ((and (string-match "^\\(\\([ACHMsS]-\\)*\\)<\\(.+\\)>$" word)
 711                     (progn
 712                       (setq word (concat (substring word (match-beginning 1)
 713                                                     (match-end 1))
 714                                          (substring word (match-beginning 3)
 715                                                     (match-end 3))))
 716                       (not (string-match
 717                             "\\<\\(NUL\\|RET\\|LFD\\|ESC\\|SPC\\|DEL\\)$"
 718                             word))))
 719                (setq key (list (intern word))))
 720               ((or (equal word "REM") (string-match "^;;" word))
 721                (setq pos (string-match "$" string pos)))
 722               (t
 723                (let ((orig-word word) (prefix 0) (bits 0))
 724                  (while (string-match "^[ACHMsS]-." word)
 725                    (incf bits (cdr (assq (aref word 0)
 726                                          '((?A . ?\A-\^@) (?C . ?\C-\^@)
 727                                            (?H . ?\H-\^@) (?M . ?\M-\^@)
 728                                            (?s . ?\s-\^@) (?S . ?\S-\^@)))))
 729                    (incf prefix 2)
 730                    (callf substring word 2))
 731                  (when (string-match "^\\^.$" word)
 732                    (incf bits ?\C-\^@)
 733                    (incf prefix)
 734                    (callf substring word 1))
 735                  (let ((found (assoc word '(("NUL" . "\0") ("RET" . "\r")
 736                                             ("LFD" . "\n") ("TAB" . "\t")
 737                                             ("ESC" . "\e") ("SPC" . " ")
 738                                             ("DEL" . "\177")))))
 739                    (when found (setq word (cdr found))))
 740                  (when (string-match "^\\\\[0-7]+$" word)
 741                    (loop for ch across word
 742                          for n = 0 then (+ (* n 8) ch -48)
 743                          finally do (setq word (vector n))))
 744                  (cond ((= bits 0)
 745                         (setq key word))
 746                        ((and (= bits ?\M-\^@) (stringp word)
 747                              (string-match "^-?[0-9]+$" word))
 748                         (setq key (loop for x across word collect (+ x bits))))
 749                        ((/= (length word) 1)
 750                         (error "%s must prefix a single character, not %s"
 751                                (substring orig-word 0 prefix) word))
 752                        ((and (/= (logand bits ?\C-\^@) 0) (stringp word)
 753                              ;; We used to accept . and ? here,
 754                              ;; but . is simply wrong,
 755                              ;; and C-? is not used (we use DEL instead).
 756                              (string-match "[@-_a-z]" word))
 757                         (setq key (list (+ bits (- ?\C-\^@)
 758                                            (logand (aref word 0) 31)))))
 759                        (t
 760                         (setq key (list (+ bits (aref word 0)))))))))
 761         (when key
 762           (loop repeat times do (callf vconcat res key)))))
 763     (when (and (>= (length res) 4)
 764                (eq (aref res 0) ?\C-x)
 765                (eq (aref res 1) ?\()
 766                (eq (aref res (- (length res) 2)) ?\C-x)
 767                (eq (aref res (- (length res) 1)) ?\)))
 768       (setq res (edmacro-subseq res 2 -2)))
 769     (if (and (not need-vector)
 770              (loop for ch across res
 771                    always (and (char-valid-p ch)
 772                                (let ((ch2 (logand ch (lognot ?\M-\^@))))
 773                                  (and (>= ch2 0) (<= ch2 127))))))
 774         (concat (loop for ch across res
 775                       collect (if (= (logand ch ?\M-\^@) 0)
 776                                   ch (+ ch 128))))
 777       res)))
 778
 779 (provide 'edmacro)
 780
 781 ;;; arch-tag: 726807b4-3ae6-49de-b0ae-b9590973e0d7
 782 ;;; edmacro.el ends here