lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 221 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 222 positive, and disable it otherwise.  If called from Lisp, enable
 223 the mode if ARG is omitted or nil."
 224   nil nil nil
 225   (unless (derived-mode-p 'ibuffer-mode)
 226     (error "This buffer is not in Ibuffer mode"))
 227   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 228   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 229
 230 (defun ibuffer-auto-update-changed ()
 231   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 232     (dolist (buf (buffer-list))
 233       (ignore-errors
 234         (with-current-buffer buf
 235           (when (and ibuffer-auto-mode
 236                      (derived-mode-p 'ibuffer-mode))
 237             (ibuffer-update nil t)))))))
 238
 239 ;;;###autoload
 240 (defun ibuffer-mouse-filter-by-mode (event)
 241   "Enable or disable filtering by the major mode chosen via mouse."
 242   (interactive "e")
 243   (ibuffer-interactive-filter-by-mode event))
 244
 245 ;;;###autoload
 246 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 247   "Enable or disable filtering by the major mode at point."
 248   (interactive "d")
 249   (if (eventp event-or-point)
 250       (posn-set-point (event-end event-or-point))
 251     (goto-char event-or-point))
 252   (let ((buf (ibuffer-current-buffer)))
 253     (if (assq 'mode ibuffer-filtering-qualifiers)
 254         (setq ibuffer-filtering-qualifiers
 255               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 256       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 257   (ibuffer-update nil t))
 258
 259 ;;;###autoload
 260 (defun ibuffer-mouse-toggle-filter-group (event)
 261   "Toggle the display status of the filter group chosen with the mouse."
 262   (interactive "e")
 263   (ibuffer-toggle-filter-group-1 (save-excursion
 264                                    (mouse-set-point event)
 265                                    (point))))
 266
 267 ;;;###autoload
 268 (defun ibuffer-toggle-filter-group ()
 269   "Toggle the display status of the filter group on this line."
 270   (interactive)
 271   (ibuffer-toggle-filter-group-1 (point)))
 272
 273 (defun ibuffer-toggle-filter-group-1 (posn)
 274   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 275     (unless (stringp name)
 276       (error "No filtering group name present"))
 277     (if (member name ibuffer-hidden-filter-groups)
 278         (setq ibuffer-hidden-filter-groups
 279               (delete name ibuffer-hidden-filter-groups))
 280       (push name ibuffer-hidden-filter-groups))
 281     (ibuffer-update nil t)))
 282
 283 ;;;###autoload
 284 (defun ibuffer-forward-filter-group (&optional count)
 285   "Move point forwards by COUNT filtering groups."
 286   (interactive "P")
 287   (unless count
 288     (setq count 1))
 289   (when (> count 0)
 290     (when (get-text-property (point) 'ibuffer-filter-group-name)
 291       (goto-char (next-single-property-change
 292                   (point) 'ibuffer-filter-group-name
 293                   nil (point-max))))
 294     (goto-char (next-single-property-change
 295                 (point) 'ibuffer-filter-group-name
 296                 nil (point-max)))
 297     (ibuffer-forward-filter-group (1- count)))
 298   (ibuffer-forward-line 0))
 299
 300 ;;;###autoload
 301 (defun ibuffer-backward-filter-group (&optional count)
 302   "Move point backwards by COUNT filtering groups."
 303   (interactive "P")
 304   (unless count
 305     (setq count 1))
 306   (when (> count 0)
 307     (when (get-text-property (point) 'ibuffer-filter-group-name)
 308       (goto-char (previous-single-property-change
 309                   (point) 'ibuffer-filter-group-name
 310                   nil (point-min))))
 311     (goto-char (previous-single-property-change
 312                 (point) 'ibuffer-filter-group-name
 313                 nil (point-min)))
 314     (ibuffer-backward-filter-group (1- count)))
 315   (when (= (point) (point-min))
 316     (goto-char (point-max))
 317     (ibuffer-backward-filter-group 1))
 318   (ibuffer-forward-line 0))
 319
 320 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 321 (define-ibuffer-op shell-command-pipe (command)
 322   "Pipe the contents of each marked buffer to shell command COMMAND."
 323   (:interactive "sPipe to shell command: "
 324    :opstring "Shell command executed on"
 325    :modifier-p nil)
 326   (shell-command-on-region
 327    (point-min) (point-max) command
 328    (get-buffer-create "* ibuffer-shell-output*")))
 329
 330 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 331 (define-ibuffer-op shell-command-pipe-replace (command)
 332   "Replace the contents of marked buffers with output of pipe to COMMAND."
 333   (:interactive "sPipe to shell command (replace): "
 334    :opstring "Buffer contents replaced in"
 335    :active-opstring "replace buffer contents in"
 336    :dangerous t
 337    :modifier-p t)
 338   (with-current-buffer buf
 339     (shell-command-on-region (point-min) (point-max)
 340                              command nil t)))
 341
 342 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 343 (define-ibuffer-op shell-command-file (command)
 344   "Run shell command COMMAND separately on files of marked buffers."
 345   (:interactive "sShell command on buffer's file: "
 346    :opstring "Shell command executed on"
 347    :modifier-p nil)
 348   (shell-command (concat command " "
 349                          (shell-quote-argument
 350                           (if buffer-file-name
 351                               buffer-file-name
 352                             (make-temp-file
 353                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 356 (define-ibuffer-op eval (form)
 357   "Evaluate FORM in each of the buffers.
 358 Does not display the buffer during evaluation. See
 359 `ibuffer-do-view-and-eval' for that."
 360   (:interactive
 361    (list
 362     (read-from-minibuffer
 363      "Eval in buffers (form): "
 364      nil read-expression-map t 'read-expression-history))
 365    :opstring "evaluated in"
 366    :modifier-p :maybe)
 367   (eval form))
 368
 369 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 370 (define-ibuffer-op view-and-eval (form)
 371   "Evaluate FORM while displaying each of the marked buffers.
 372 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 373   (:interactive
 374    (list
 375     (read-from-minibuffer
 376      "Eval viewing in buffers (form): "
 377      nil read-expression-map t 'read-expression-history))
 378    :opstring "evaluated in"
 379    :complex t
 380    :modifier-p :maybe)
 381   (let ((ibuffer-buf (current-buffer)))
 382     (unwind-protect
 383         (progn
 384           (switch-to-buffer buf)
 385           (eval form))
 386       (switch-to-buffer ibuffer-buf))))
 387
 388 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 389 (define-ibuffer-op rename-uniquely ()
 390   "Rename marked buffers as with `rename-uniquely'."
 391   (:opstring "renamed"
 392    :modifier-p t)
 393   (rename-uniquely))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 396 (define-ibuffer-op revert ()
 397   "Revert marked buffers as with `revert-buffer'."
 398   (:dangerous t
 399    :opstring "reverted"
 400    :active-opstring "revert"
 401    :modifier-p :maybe)
 402   (revert-buffer t t))
 403
 404 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 405 (define-ibuffer-op ibuffer-do-isearch ()
 406   "Perform a `isearch-forward' in marked buffers."
 407   (:interactive ()
 408    :opstring "searched in"
 409    :complex t
 410    :modifier-p :maybe)
 411   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 412
 413 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 414 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 415   "Perform a `isearch-forward-regexp' in marked buffers."
 416   (:interactive ()
 417    :opstring "searched regexp in"
 418    :complex t
 419    :modifier-p :maybe)
 420   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 421
 422 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 423 (define-ibuffer-op replace-regexp (from-str to-str)
 424   "Perform a `replace-regexp' in marked buffers."
 425   (:interactive
 426    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 427           (to-str (read-from-minibuffer (concat "Replace " from-str
 428                                                 " with: "))))
 429      (list from-str to-str))
 430    :opstring "replaced in"
 431    :complex t
 432    :modifier-p :maybe)
 433   (save-window-excursion
 434     (switch-to-buffer buf)
 435     (save-excursion
 436       (goto-char (point-min))
 437       (let ((case-fold-search ibuffer-case-fold-search))
 438         (while (re-search-forward from-str nil t)
 439           (replace-match to-str))))
 440     t))
 441
 442 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 443 (define-ibuffer-op query-replace (&rest args)
 444   "Perform a `query-replace' in marked buffers."
 445   (:interactive
 446    (query-replace-read-args "Query replace" t t)
 447    :opstring "replaced in"
 448    :complex t
 449    :modifier-p :maybe)
 450   (save-window-excursion
 451     (switch-to-buffer buf)
 452     (save-excursion
 453       (let ((case-fold-search ibuffer-case-fold-search))
 454         (goto-char (point-min))
 455         (apply #'query-replace args)))
 456     t))
 457
 458 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 459 (define-ibuffer-op query-replace-regexp (&rest args)
 460   "Perform a `query-replace-regexp' in marked buffers."
 461   (:interactive
 462    (query-replace-read-args "Query replace regexp" t t)
 463    :opstring "replaced in"
 464    :complex t
 465    :modifier-p :maybe)
 466   (save-window-excursion
 467     (switch-to-buffer buf)
 468     (save-excursion
 469       (let ((case-fold-search ibuffer-case-fold-search))
 470         (goto-char (point-min))
 471         (apply #'query-replace-regexp args)))
 472     t))
 473
 474 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 475 (define-ibuffer-op print ()
 476   "Print marked buffers as with `print-buffer'."
 477   (:opstring "printed"
 478    :modifier-p nil)
 479   (print-buffer))
 480
 481 ;;;###autoload
 482 (defun ibuffer-included-in-filters-p (buf filters)
 483   (not
 484    (memq nil ;; a filter will return nil if it failed
 485          (mapcar
 486           ;; filter should be like (TYPE . QUALIFIER), or
 487           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 488           #'(lambda (qual)
 489               (ibuffer-included-in-filter-p buf qual))
 490           filters))))
 491
 492 (defun ibuffer-included-in-filter-p (buf filter)
 493   (if (eq (car filter) 'not)
 494       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 495     (ibuffer-included-in-filter-p-1 buf filter)))
 496
 497 (defun ibuffer-included-in-filter-p-1 (buf filter)
 498   (not
 499    (not
 500     (case (car filter)
 501       (or
 502        (memq t (mapcar #'(lambda (x)
 503                            (ibuffer-included-in-filter-p buf x))
 504                        (cdr filter))))
 505       (saved
 506        (let ((data
 507               (assoc (cdr filter)
 508                      ibuffer-saved-filters)))
 509          (unless data
 510            (ibuffer-filter-disable t)
 511            (error "Unknown saved filter %s" (cdr filter)))
 512          (ibuffer-included-in-filters-p buf (cadr data))))
 513       (t
 514        (let ((filterdat (assq (car filter)
 515                               ibuffer-filtering-alist)))
 516          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 517          ;; just a sanity check
 518         (unless filterdat
 519           (ibuffer-filter-disable t)
 520           (error "Undefined filter %s" (car filter)))
 521         (not
 522          (not
 523           (funcall (caddr filterdat)
 524                    buf
 525                    (cdr filter))))))))))
 526
 527 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 528   (let ((filter-group-alist (if nodefault
 529                                 ibuffer-filter-groups
 530                               (append ibuffer-filter-groups
 531                                       (list (cons "Default" nil))))))
 532 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 533 ;;       (setq filter-group-alist (ibuffer-delete-alist
 534 ;;                                 hidden filter-group-alist)))
 535     (let ((vec (make-vector (length filter-group-alist) nil))
 536           (i 0))
 537       (dolist (filtergroup filter-group-alist)
 538         (let ((filterset (cdr filtergroup)))
 539           (multiple-value-bind (hip-crowd lamers)
 540               (values-list
 541                (ibuffer-split-list (lambda (bufmark)
 542                                      (ibuffer-included-in-filters-p (car bufmark)
 543                                                                     filterset))
 544                                    bmarklist))
 545             (aset vec i hip-crowd)
 546             (incf i)
 547             (setq bmarklist lamers))))
 548       (let (ret)
 549         (dotimes (j i ret)
 550           (let ((bufs (aref vec j)))
 551             (unless (and noempty (null bufs))
 552               (push (cons (car (nth j filter-group-alist))
 553                           bufs)
 554                     ret))))))))
 555
 556 ;;;###autoload
 557 (defun ibuffer-filters-to-filter-group (name)
 558   "Make the current filters into a filtering group."
 559   (interactive "sName for filtering group: ")
 560   (when (null ibuffer-filtering-qualifiers)
 561     (error "No filters in effect"))
 562   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 563   (ibuffer-filter-disable))
 564
 565 ;;;###autoload
 566 (defun ibuffer-set-filter-groups-by-mode ()
 567   "Set the current filter groups to filter by mode."
 568   (interactive)
 569   (setq ibuffer-filter-groups
 570         (mapcar (lambda (mode)
 571                   (cons (format "%s" mode) `((mode . ,mode))))
 572                 (let ((modes
 573                        (ibuffer-remove-duplicates
 574                         (mapcar (lambda (buf)
 575                                   (buffer-local-value 'major-mode buf))
 576                                 (buffer-list)))))
 577                   (if ibuffer-view-ibuffer
 578                       modes
 579                     (delq 'ibuffer-mode modes)))))
 580   (ibuffer-update nil t))
 581
 582 ;;;###autoload
 583 (defun ibuffer-pop-filter-group ()
 584   "Remove the first filter group."
 585   (interactive)
 586   (when (null ibuffer-filter-groups)
 587     (error "No filter groups active"))
 588   (setq ibuffer-hidden-filter-groups
 589         (delete (pop ibuffer-filter-groups)
 590                 ibuffer-hidden-filter-groups))
 591   (ibuffer-update nil t))
 592
 593 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 594   (when (and (not noerror) (null ibuffer-filter-groups))
 595     (error "No filter groups active"))
 596   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 597   ;; groups, possibly excluding empty groups or Default.
 598   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 599   ;; Default if necessary.
 600   (completing-read msg (nconc
 601                         (ibuffer-generate-filter-groups
 602                          (ibuffer-current-state-list)
 603                          (not ibuffer-show-empty-filter-groups)
 604                          nodefault)
 605                         (if nodefault
 606                             (remove "Default" ibuffer-hidden-filter-groups)
 607                           ibuffer-hidden-filter-groups))
 608                    nil t))
 609
 610 ;;;###autoload
 611 (defun ibuffer-decompose-filter-group (group)
 612   "Decompose the filter group GROUP into active filters."
 613   (interactive
 614    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 615   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 616     (setq ibuffer-filter-groups (ibuffer-delete-alist
 617                                  group ibuffer-filter-groups)
 618           ibuffer-filtering-qualifiers data))
 619   (ibuffer-update nil t))
 620
 621 ;;;###autoload
 622 (defun ibuffer-clear-filter-groups ()
 623   "Remove all filter groups."
 624   (interactive)
 625   (setq ibuffer-filter-groups nil
 626         ibuffer-hidden-filter-groups nil)
 627   (ibuffer-update nil t))
 628
 629 (defun ibuffer-current-filter-groups-with-position ()
 630   (save-excursion
 631     (goto-char (point-min))
 632     (let ((pos nil)
 633           (result nil))
 634       (while (and (not (eobp))
 635                   (setq pos (next-single-property-change
 636                              (point) 'ibuffer-filter-group-name)))
 637         (goto-char pos)
 638         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 639                     pos)
 640               result)
 641         (goto-char (next-single-property-change
 642                     pos 'ibuffer-filter-group-name)))
 643       (nreverse result))))
 644
 645 ;;;###autoload
 646 (defun ibuffer-jump-to-filter-group (name)
 647   "Move point to the filter group whose name is NAME."
 648   (interactive
 649    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 650   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 651       (goto-char (cdr it))
 652     (error "No filter group with name %s" name)))
 653
 654 ;;;###autoload
 655 (defun ibuffer-kill-filter-group (name)
 656   "Kill the filter group named NAME.
 657 The group will be added to `ibuffer-filter-group-kill-ring'."
 658   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 659   (when (equal name "Default")
 660     (error "Can't kill default filter group"))
 661   (ibuffer-aif (assoc name ibuffer-filter-groups)
 662       (progn
 663         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 664         (setq ibuffer-filter-groups (ibuffer-delete-alist
 665                                      name ibuffer-filter-groups))
 666         (setq ibuffer-hidden-filter-groups
 667               (delete name ibuffer-hidden-filter-groups)))
 668     (error "No filter group with name \"%s\"" name))
 669   (ibuffer-update nil t))
 670
 671 ;;;###autoload
 672 (defun ibuffer-kill-line (&optional arg interactive-p)
 673   "Kill the filter group at point.
 674 See also `ibuffer-kill-filter-group'."
 675   (interactive "P\np")
 676   (ibuffer-aif (save-excursion
 677                  (ibuffer-forward-line 0)
 678                  (get-text-property (point) 'ibuffer-filter-group-name))
 679       (progn
 680         (ibuffer-kill-filter-group it))
 681       (funcall (if interactive-p #'call-interactively #'funcall)
 682                #'kill-line arg)))
 683
 684 (defun ibuffer-insert-filter-group-before (newgroup group)
 685   (let* ((found nil)
 686          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 687                     (res 0))
 688                 (while groups
 689                   (if (equal (car groups) group)
 690                       (setq found t
 691                             groups nil)
 692                     (incf res)
 693                     (setq groups (cdr groups))))
 694                 res)))
 695     (cond ((not found)
 696            (setq ibuffer-filter-groups
 697                  (nconc ibuffer-filter-groups (list newgroup))))
 698           ((zerop pos)
 699            (push newgroup ibuffer-filter-groups))
 700           (t
 701            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 702              (setf (cdr cell) (cons (car cell) (cdr cell)))
 703              (setf (car cell) newgroup))))))
 704
 705 ;;;###autoload
 706 (defun ibuffer-yank ()
 707   "Yank the last killed filter group before group at point."
 708   (interactive)
 709   (ibuffer-yank-filter-group
 710    (or (get-text-property (point) 'ibuffer-filter-group-name)
 711        (get-text-property (point) 'ibuffer-filter-group)
 712        (error "No filter group at point"))))
 713
 714 ;;;###autoload
 715 (defun ibuffer-yank-filter-group (name)
 716   "Yank the last killed filter group before group named NAME."
 717   (interactive (list (ibuffer-read-filter-group-name
 718                         "Yank filter group before group: ")))
 719   (unless ibuffer-filter-group-kill-ring
 720     (error "The Ibuffer filter group kill-ring is empty"))
 721   (save-excursion
 722     (ibuffer-forward-line 0)
 723     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 724                                         name))
 725   (ibuffer-update nil t))
 726
 727 ;;;###autoload
 728 (defun ibuffer-save-filter-groups (name groups)
 729   "Save all active filter groups GROUPS as NAME.
 730 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 731 prompt for NAME, and use the current filters."
 732   (interactive
 733    (if (null ibuffer-filter-groups)
 734        (error "No filter groups active")
 735      (list
 736       (read-from-minibuffer "Save current filter groups as: ")
 737       ibuffer-filter-groups)))
 738   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 739       (setcdr it groups)
 740     (push (cons name groups) ibuffer-saved-filter-groups))
 741   (ibuffer-maybe-save-stuff))
 742
 743 ;;;###autoload
 744 (defun ibuffer-delete-saved-filter-groups (name)
 745   "Delete saved filter groups with NAME.
 746 They are removed from `ibuffer-saved-filter-groups'."
 747   (interactive
 748    (list
 749     (if (null ibuffer-saved-filter-groups)
 750         (error "No saved filter groups")
 751       (completing-read "Delete saved filter group: "
 752                        ibuffer-saved-filter-groups nil t))))
 753   (setq ibuffer-saved-filter-groups
 754         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 755   (ibuffer-maybe-save-stuff)
 756   (ibuffer-update nil t))
 757
 758 ;;;###autoload
 759 (defun ibuffer-switch-to-saved-filter-groups (name)
 760   "Set this buffer's filter groups to saved version with NAME.
 761 The value from `ibuffer-saved-filter-groups' is used."
 762   (interactive
 763    (list
 764     (if (null ibuffer-saved-filter-groups)
 765         (error "No saved filters")
 766       (completing-read "Switch to saved filter group: "
 767                        ibuffer-saved-filter-groups nil t))))
 768   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 769         ibuffer-hidden-filter-groups nil)
 770   (ibuffer-update nil t))
 771
 772 ;;;###autoload
 773 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 774   "Disable all filters currently in effect in this buffer.
 775 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 776 group definitions by setting `ibuffer-filter-groups' to nil."
 777   (interactive)
 778   (setq ibuffer-filtering-qualifiers nil)
 779   (if delete-filter-groups
 780       (setq ibuffer-filter-groups nil))
 781   (let ((buf (ibuffer-current-buffer)))
 782     (ibuffer-update nil t)
 783     (when buf
 784       (ibuffer-jump-to-buffer (buffer-name buf)))))
 785
 786 ;;;###autoload
 787 (defun ibuffer-pop-filter ()
 788   "Remove the top filter in this buffer."
 789   (interactive)
 790   (when (null ibuffer-filtering-qualifiers)
 791     (error "No filters in effect"))
 792   (pop ibuffer-filtering-qualifiers)
 793   (let ((buf (ibuffer-current-buffer)))
 794     (ibuffer-update nil t)
 795     (when buf
 796       (ibuffer-jump-to-buffer (buffer-name buf)))))
 797
 798 (defun ibuffer-push-filter (qualifier)
 799   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 800   (push qualifier ibuffer-filtering-qualifiers))
 801
 802 ;;;###autoload
 803 (defun ibuffer-decompose-filter ()
 804   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 805
 806 This means that the topmost filter on the filtering stack, which must
 807 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 808 turned into two separate filters [name: foo] and [mode: bar-mode]."
 809   (interactive)
 810   (when (null ibuffer-filtering-qualifiers)
 811     (error "No filters in effect"))
 812   (let ((lim (pop ibuffer-filtering-qualifiers)))
 813     (case (car lim)
 814       (or
 815        (setq ibuffer-filtering-qualifiers (append
 816                                           (cdr lim)
 817                                           ibuffer-filtering-qualifiers)))
 818       (saved
 819        (let ((data
 820               (assoc (cdr lim)
 821                      ibuffer-saved-filters)))
 822          (unless data
 823            (ibuffer-filter-disable)
 824            (error "Unknown saved filter %s" (cdr lim)))
 825          (setq ibuffer-filtering-qualifiers (append
 826                                             (cadr data)
 827                                             ibuffer-filtering-qualifiers))))
 828       (not
 829        (push (cdr lim)
 830              ibuffer-filtering-qualifiers))
 831       (t
 832        (error "Filter type %s is not compound" (car lim)))))
 833   (ibuffer-update nil t))
 834
 835 ;;;###autoload
 836 (defun ibuffer-exchange-filters ()
 837   "Exchange the top two filters on the stack in this buffer."
 838   (interactive)
 839   (when (< (length ibuffer-filtering-qualifiers)
 840            2)
 841     (error "Need two filters to exchange"))
 842   (let ((first (pop ibuffer-filtering-qualifiers))
 843         (second (pop ibuffer-filtering-qualifiers)))
 844     (push first ibuffer-filtering-qualifiers)
 845     (push second ibuffer-filtering-qualifiers))
 846   (ibuffer-update nil t))
 847
 848 ;;;###autoload
 849 (defun ibuffer-negate-filter ()
 850   "Negate the sense of the top filter in the current buffer."
 851   (interactive)
 852   (when (null ibuffer-filtering-qualifiers)
 853     (error "No filters in effect"))
 854   (let ((lim (pop ibuffer-filtering-qualifiers)))
 855     (push (if (eq (car lim) 'not)
 856               (cdr lim)
 857             (cons 'not lim))
 858           ibuffer-filtering-qualifiers))
 859   (ibuffer-update nil t))
 860
 861 ;;;###autoload
 862 (defun ibuffer-or-filter (&optional reverse)
 863   "Replace the top two filters in this buffer with their logical OR.
 864 If optional argument REVERSE is non-nil, instead break the top OR
 865 filter into parts."
 866   (interactive "P")
 867   (if reverse
 868       (progn
 869         (when (or (null ibuffer-filtering-qualifiers)
 870                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 871           (error "Top filter is not an OR"))
 872         (let ((lim (pop ibuffer-filtering-qualifiers)))
 873           (setq ibuffer-filtering-qualifiers
 874                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 875     (when (< (length ibuffer-filtering-qualifiers) 2)
 876       (error "Need two filters to OR"))
 877     ;; If the second filter is an OR, just add to it.
 878     (let ((first (pop ibuffer-filtering-qualifiers))
 879           (second (pop ibuffer-filtering-qualifiers)))
 880       (if (eq 'or (car second))
 881           (push (nconc (list 'or first) (cdr second))
 882                 ibuffer-filtering-qualifiers)
 883         (push (list 'or first second)
 884               ibuffer-filtering-qualifiers))))
 885   (ibuffer-update nil t))
 886
 887 (defun ibuffer-maybe-save-stuff ()
 888   (when ibuffer-save-with-custom
 889     (if (fboundp 'customize-save-variable)
 890         (progn
 891           (customize-save-variable 'ibuffer-saved-filters
 892                                    ibuffer-saved-filters)
 893           (customize-save-variable 'ibuffer-saved-filter-groups
 894                                    ibuffer-saved-filter-groups))
 895       (message "Not saved permanently: Customize not available"))))
 896
 897 ;;;###autoload
 898 (defun ibuffer-save-filters (name filters)
 899   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 900 Interactively, prompt for NAME, and use the current filters."
 901   (interactive
 902    (if (null ibuffer-filtering-qualifiers)
 903        (error "No filters currently in effect")
 904      (list
 905       (read-from-minibuffer "Save current filters as: ")
 906       ibuffer-filtering-qualifiers)))
 907   (ibuffer-aif (assoc name ibuffer-saved-filters)
 908       (setcdr it filters)
 909     (push (list name filters) ibuffer-saved-filters))
 910   (ibuffer-maybe-save-stuff))
 911
 912 ;;;###autoload
 913 (defun ibuffer-delete-saved-filters (name)
 914   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 915   (interactive
 916    (list
 917     (if (null ibuffer-saved-filters)
 918         (error "No saved filters")
 919       (completing-read "Delete saved filters: "
 920                        ibuffer-saved-filters nil t))))
 921   (setq ibuffer-saved-filters
 922         (ibuffer-delete-alist name ibuffer-saved-filters))
 923   (ibuffer-maybe-save-stuff)
 924   (ibuffer-update nil t))
 925
 926 ;;;###autoload
 927 (defun ibuffer-add-saved-filters (name)
 928   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 929   (interactive
 930    (list
 931     (if (null ibuffer-saved-filters)
 932         (error "No saved filters")
 933       (completing-read "Add saved filters: "
 934                        ibuffer-saved-filters nil t))))
 935   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 936   (ibuffer-update nil t))
 937
 938 ;;;###autoload
 939 (defun ibuffer-switch-to-saved-filters (name)
 940   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 941   (interactive
 942    (list
 943     (if (null ibuffer-saved-filters)
 944         (error "No saved filters")
 945       (completing-read "Switch to saved filters: "
 946                        ibuffer-saved-filters nil t))))
 947   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 948   (ibuffer-update nil t))
 949
 950 (defun ibuffer-format-filter-group-data (filter)
 951   (if (equal filter "Default")
 952       ""
 953     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 954                                  (cdr (assq filter ibuffer-filter-groups))
 955                                  " "))))
 956
 957 (defun ibuffer-format-qualifier (qualifier)
 958   (if (eq (car-safe qualifier) 'not)
 959       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 960     (ibuffer-format-qualifier-1 qualifier)))
 961
 962 (defun ibuffer-format-qualifier-1 (qualifier)
 963   (case (car qualifier)
 964     (saved
 965      (concat " [filter: " (cdr qualifier) "]"))
 966     (or
 967      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 968                                (cdr qualifier) "") "]"))
 969     (t
 970      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 971        (unless qualifier
 972          (error "Ibuffer: bad qualifier %s" qualifier))
 973        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 974
 975
 976 (defun ibuffer-list-buffer-modes (&optional include-parents)
 977   "Create a completion table of buffer modes currently in use.
 978 If INCLUDE-PARENTS is non-nil then include parent modes."
 979   (let ((modes))
 980     (dolist (buf (buffer-list))
 981       (let ((this-mode (buffer-local-value 'major-mode buf)))
 982         (while (and this-mode (not (memq this-mode modes)))
 983           (push this-mode modes)
 984           (setq this-mode (and include-parents
 985                                (get this-mode 'derived-mode-parent))))))
 986     (mapcar #'symbol-name modes)))
 987
 988
 989 ;;; Extra operation definitions
 990
 991 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 992 (define-ibuffer-filter mode
 993   "Toggle current view to buffers with major mode QUALIFIER."
 994   (:description "major mode"
 995    :reader
 996    (let* ((buf (ibuffer-current-buffer))
 997           (default (if (and buf (buffer-live-p buf))
 998                        (symbol-name (buffer-local-value
 999                                      'major-mode buf)))))
1000      (intern
1001       (completing-read
1002        (if default
1003            (format "Filter by major mode (default %s): " default)
1004          "Filter by major mode: ")
1005        obarray
1006        #'(lambda (e)
1007            (string-match "-mode\\'" (symbol-name e)))
1008        t nil nil default))))
1009   (eq qualifier (buffer-local-value 'major-mode buf)))
1010
1011 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1012 (define-ibuffer-filter used-mode
1013   "Toggle current view to buffers with major mode QUALIFIER.
1014 Called interactively, this function allows selection of modes
1015 currently used by buffers."
1016   (:description "major mode in use"
1017    :reader
1018    (let* ((buf (ibuffer-current-buffer))
1019           (default (if (and buf (buffer-live-p buf))
1020                        (symbol-name (buffer-local-value
1021                                      'major-mode buf)))))
1022      (intern
1023       (completing-read
1024        (if default
1025            (format "Filter by major mode (default %s): " default)
1026          "Filter by major mode: ")
1027        (ibuffer-list-buffer-modes) nil t nil nil default))))
1028   (eq qualifier (buffer-local-value 'major-mode buf)))
1029
1030 ;;;###autoload (autoload 'ibuffer-filter-by-derived-mode "ibuf-ext")
1031 (define-ibuffer-filter derived-mode
1032     "Toggle current view to buffers whose major mode inherits from QUALIFIER."
1033   (:description "derived mode"
1034                 :reader
1035                 (intern
1036                  (completing-read "Filter by derived mode: "
1037                                   (ibuffer-list-buffer-modes t)
1038                                   nil t)))
1039   (with-current-buffer buf (derived-mode-p qualifier)))
1040
1041 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1042 (define-ibuffer-filter name
1043   "Toggle current view to buffers with name matching QUALIFIER."
1044   (:description "buffer name"
1045    :reader (read-from-minibuffer "Filter by name (regexp): "))
1046   (string-match qualifier (buffer-name buf)))
1047
1048 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1049 (define-ibuffer-filter filename
1050   "Toggle current view to buffers with filename matching QUALIFIER."
1051   (:description "filename"
1052    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1053   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1054     (string-match qualifier it)))
1055
1056 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1057 (define-ibuffer-filter size-gt
1058   "Toggle current view to buffers with size greater than QUALIFIER."
1059   (:description "size greater than"
1060    :reader
1061    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1062   (> (with-current-buffer buf (buffer-size))
1063      qualifier))
1064
1065 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1066 (define-ibuffer-filter size-lt
1067    "Toggle current view to buffers with size less than QUALIFIER."
1068   (:description "size less than"
1069    :reader
1070    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1071   (< (with-current-buffer buf (buffer-size))
1072      qualifier))
1073
1074 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1075 (define-ibuffer-filter content
1076    "Toggle current view to buffers whose contents match QUALIFIER."
1077   (:description "content"
1078    :reader (read-from-minibuffer "Filter by content (regexp): "))
1079   (with-current-buffer buf
1080     (save-excursion
1081       (goto-char (point-min))
1082       (re-search-forward qualifier nil t))))
1083
1084 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1085 (define-ibuffer-filter predicate
1086    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1087   (:description "predicate"
1088    :reader (read-minibuffer "Filter by predicate (form): "))
1089   (with-current-buffer buf
1090     (eval qualifier)))
1091
1092 ;;; Sorting
1093
1094 ;;;###autoload
1095 (defun ibuffer-toggle-sorting-mode ()
1096   "Toggle the current sorting mode.
1097 Default sorting modes are:
1098  Recency - the last time the buffer was viewed
1099  Name - the name of the buffer
1100  Major Mode - the name of the major mode of the buffer
1101  Size - the size of the buffer"
1102   (interactive)
1103   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1104     (add-to-list 'modes 'recency)
1105     (setq modes (sort modes 'string-lessp))
1106     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1107                     (car modes))))
1108       (setq ibuffer-sorting-mode next)
1109       (message "Sorting by %s" next)))
1110   (ibuffer-redisplay t))
1111
1112 ;;;###autoload
1113 (defun ibuffer-invert-sorting ()
1114   "Toggle whether or not sorting is in reverse order."
1115   (interactive)
1116   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1117   (message "Sorting order %s"
1118            (if ibuffer-sorting-reversep
1119                "reversed"
1120              "normal"))
1121   (ibuffer-redisplay t))
1122
1123 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1124 (define-ibuffer-sorter major-mode
1125   "Sort the buffers by major modes.
1126 Ordering is lexicographic."
1127   (:description "major mode")
1128   (string-lessp (downcase
1129                  (symbol-name (buffer-local-value 'major-mode (car a))))
1130                 (downcase
1131                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1132
1133 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1134 (define-ibuffer-sorter mode-name
1135   "Sort the buffers by their mode name.
1136 Ordering is lexicographic."
1137   (:description "major mode name")
1138   (string-lessp (downcase
1139                  (with-current-buffer
1140                      (car a)
1141                    (format-mode-line mode-name)))
1142                 (downcase
1143                  (with-current-buffer
1144                      (car b)
1145                    (format-mode-line mode-name)))))
1146
1147 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1148 (define-ibuffer-sorter alphabetic
1149   "Sort the buffers by their names.
1150 Ordering is lexicographic."
1151   (:description "buffer name")
1152   (string-lessp
1153    (buffer-name (car a))
1154    (buffer-name (car b))))
1155
1156 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1157 (define-ibuffer-sorter size
1158  "Sort the buffers by their size."
1159   (:description "size")
1160   (< (with-current-buffer (car a)
1161        (buffer-size))
1162      (with-current-buffer (car b)
1163        (buffer-size))))
1164
1165 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1166 (define-ibuffer-sorter filename/process
1167  "Sort the buffers by their file name/process name."
1168   (:description "file name")
1169   (string-lessp
1170    ;; FIXME: For now just compare the file name and the process name
1171    ;; (if it exists).  Is there a better way to do this?
1172    (or (buffer-file-name (car a))
1173        (let ((pr-a (get-buffer-process (car a))))
1174          (and (processp pr-a) (process-name pr-a))))
1175    (or (buffer-file-name (car b))
1176        (let ((pr-b (get-buffer-process (car b))))
1177          (and (processp pr-b) (process-name pr-b))))))
1178
1179 ;;; Functions to emulate bs.el
1180
1181 ;;;###autoload
1182 (defun ibuffer-bs-show ()
1183   "Emulate `bs-show' from the bs.el package."
1184   (interactive)
1185   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1186   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1187
1188 (defun ibuffer-bs-toggle-all ()
1189   "Emulate `bs-toggle-show-all' from the bs.el package."
1190   (interactive)
1191   (if ibuffer-filtering-qualifiers
1192       (ibuffer-pop-filter)
1193     (progn (ibuffer-push-filter '(filename . ".*"))
1194            (ibuffer-update nil t))))
1195
1196 ;;; Handy functions
1197
1198 ;;;###autoload
1199 (defun ibuffer-add-to-tmp-hide (regexp)
1200   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1201 This means that buffers whose name matches REGEXP will not be shown
1202 for this Ibuffer session."
1203   (interactive
1204    (list
1205     (read-from-minibuffer "Never show buffers matching: "
1206                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1207   (push regexp ibuffer-tmp-hide-regexps))
1208
1209 ;;;###autoload
1210 (defun ibuffer-add-to-tmp-show (regexp)
1211   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1212 This means that buffers whose name matches REGEXP will always be shown
1213 for this Ibuffer session."
1214   (interactive
1215    (list
1216     (read-from-minibuffer "Always show buffers matching: "
1217                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1218   (push regexp ibuffer-tmp-show-regexps))
1219
1220 ;;;###autoload
1221 (defun ibuffer-forward-next-marked (&optional count mark direction)
1222   "Move forward by COUNT marked buffers (default 1).
1223
1224 If MARK is non-nil, it should be a character denoting the type of mark
1225 to move by.  The default is `ibuffer-marked-char'.
1226
1227 If DIRECTION is non-nil, it should be an integer; negative integers
1228 mean move backwards, non-negative integers mean move forwards."
1229   (interactive "P")
1230   (unless count
1231     (setq count 1))
1232   (unless mark
1233     (setq mark ibuffer-marked-char))
1234   (unless direction
1235     (setq direction 1))
1236   ;; Skip the title
1237   (ibuffer-forward-line 0)
1238   (let ((opos (point)))
1239     (ibuffer-forward-line direction)
1240     (while (not (or (= (point) opos)
1241                     (eq (ibuffer-current-mark) mark)))
1242       (ibuffer-forward-line direction))
1243     (when (and (= (point) opos)
1244                (not (eq (ibuffer-current-mark) mark)))
1245       (error "No buffers with mark %c" mark))))
1246
1247 ;;;###autoload
1248 (defun ibuffer-backwards-next-marked (&optional count mark)
1249    "Move backwards by COUNT marked buffers (default 1).
1250
1251 If MARK is non-nil, it should be a character denoting the type of mark
1252 to move by.  The default is `ibuffer-marked-char'."
1253    (interactive "P")
1254    (ibuffer-forward-next-marked count mark -1))
1255
1256 ;;;###autoload
1257 (defun ibuffer-do-kill-lines ()
1258   "Hide all of the currently marked lines."
1259   (interactive)
1260   (if (= (ibuffer-count-marked-lines) 0)
1261       (message "No buffers marked; use 'm' to mark a buffer")
1262     (let ((count
1263            (ibuffer-map-marked-lines
1264             #'(lambda (_buf _mark)
1265                 'kill))))
1266       (message "Killed %s lines" count))))
1267
1268 ;;;###autoload
1269 (defun ibuffer-jump-to-buffer (name)
1270   "Move point to the buffer whose name is NAME.
1271
1272 If called interactively, prompt for a buffer name and go to the
1273 corresponding line in the Ibuffer buffer.  If said buffer is in a
1274 hidden group filter, open it.
1275
1276 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1277 visible buffers in the completion list.  Calling the command with
1278 a prefix argument reverses the meaning of that variable."
1279   (interactive (list
1280                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1281                   (when current-prefix-arg
1282                     (setq only-visible (not only-visible)))
1283                   (if only-visible
1284                       (let ((table (mapcar #'(lambda (x)
1285                                                (buffer-name (car x)))
1286                                            (ibuffer-current-state-list))))
1287                         (when (null table)
1288                           (error "No buffers!"))
1289                         (completing-read "Jump to buffer: "
1290                                          table nil t))
1291                     (read-buffer "Jump to buffer: " nil t)))))
1292   (when (not (string= "" name))
1293     (let (buf-point)
1294       ;; Blindly search for our buffer: it is very likely that it is
1295       ;; not in a hidden filter group.
1296       (ibuffer-map-lines #'(lambda (buf _marks)
1297                              (when (string= (buffer-name buf) name)
1298                                (setq buf-point (point))
1299                                nil))
1300                          t nil)
1301       (when (and
1302              (null buf-point)
1303              (not (null ibuffer-hidden-filter-groups)))
1304         ;; We did not find our buffer.  It must be in a hidden filter
1305         ;; group, so go through all hidden filter groups to find it.
1306         (catch 'found
1307           (dolist (group ibuffer-hidden-filter-groups)
1308             (ibuffer-jump-to-filter-group group)
1309             (ibuffer-toggle-filter-group)
1310             (ibuffer-map-lines #'(lambda (buf _marks)
1311                                    (when (string= (buffer-name buf) name)
1312                                      (setq buf-point (point))
1313                                      nil))
1314                                t group)
1315             (if buf-point
1316                 (throw 'found nil)
1317               (ibuffer-toggle-filter-group)))))
1318       (if (null buf-point)
1319           ;; Still not found even though we expanded all hidden filter
1320           ;; groups: that must be because it's hidden by predicate:
1321           ;; we won't bother trying to display it.
1322           (error "No buffer with name %s" name)
1323         (goto-char buf-point)))))
1324
1325 (declare-function diff-sentinel "diff"
1326                   (code &optional old-temp-file new-temp-file))
1327
1328 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1329   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1330         (tempfile (make-temp-file "buffer-content-")))
1331     (when bufferfile
1332       (unwind-protect
1333           (progn
1334             (with-current-buffer buffer
1335               (write-region nil nil tempfile nil 'nomessage))
1336             (let* ((old (expand-file-name bufferfile))
1337                    (new (expand-file-name tempfile))
1338                    (oldtmp (file-local-copy old))
1339                    (newtmp (file-local-copy new))
1340                    (switches diff-switches)
1341                    (command
1342                     (mapconcat
1343                      'identity
1344                      `(,diff-command
1345                        ;; Use explicitly specified switches
1346                        ,@(if (listp switches) switches (list switches))
1347                        ,@(if (or old new)
1348                              (list "-L" (shell-quote-argument old)
1349                                    "-L" (shell-quote-argument
1350                                          (format "Buffer %s" (buffer-name buffer)))))
1351                        ,(shell-quote-argument (or oldtmp old))
1352                        ,(shell-quote-argument (or newtmp new)))
1353                      " ")))
1354               (let ((inhibit-read-only t))
1355                 (insert command "\n")
1356                 (diff-sentinel
1357                  (call-process shell-file-name nil
1358                                (current-buffer) nil
1359                                shell-command-switch command))
1360                 (insert "\n")))))
1361       (sit-for 0)
1362       (when (file-exists-p tempfile)
1363         (delete-file tempfile)))))
1364
1365 ;;;###autoload
1366 (defun ibuffer-diff-with-file ()
1367   "View the differences between marked buffers and their associated files.
1368 If no buffers are marked, use buffer at point.
1369 This requires the external program \"diff\" to be in your `exec-path'."
1370   (interactive)
1371   (require 'diff)
1372   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1373     (when (null marked-bufs)
1374       (setq marked-bufs (list (ibuffer-current-buffer t))))
1375     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1376       (setq buffer-read-only nil)
1377       (buffer-disable-undo (current-buffer))
1378       (erase-buffer)
1379       (buffer-enable-undo (current-buffer))
1380       (diff-mode)
1381       (dolist (buf marked-bufs)
1382         (unless (buffer-live-p buf)
1383           (error "Buffer %s has been killed" buf))
1384         (ibuffer-diff-buffer-with-file-1 buf))
1385       (setq buffer-read-only t)))
1386   (switch-to-buffer "*Ibuffer Diff*"))
1387
1388 ;;;###autoload
1389 (defun ibuffer-copy-filename-as-kill (&optional arg)
1390   "Copy filenames of marked buffers into the kill ring.
1391
1392 The names are separated by a space.
1393 If a buffer has no filename, it is ignored.
1394
1395 With no prefix arg, use the filename sans its directory of each marked file.
1396 With a zero prefix arg, use the complete filename of each marked file.
1397 With \\[universal-argument], use the filename of each marked file relative
1398 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1399
1400 You can then feed the file name(s) to other commands with \\[yank]."
1401   (interactive "p")
1402   (if (zerop (ibuffer-count-marked-lines))
1403       (message "No buffers marked; use 'm' to mark a buffer")
1404     (let ((ibuffer-copy-filename-as-kill-result "")
1405           (type (cond ((zerop arg)
1406                        'full)
1407                       ((= arg 4)
1408                        'relative)
1409                       (t
1410                        'name))))
1411       (ibuffer-map-marked-lines
1412        #'(lambda (buf _mark)
1413            (setq ibuffer-copy-filename-as-kill-result
1414                  (concat ibuffer-copy-filename-as-kill-result
1415                          (let ((name (buffer-file-name buf)))
1416                            (if name
1417                                (case type
1418                                  (full
1419                                   name)
1420                                  (relative
1421                                   (file-relative-name
1422                                    name (or ibuffer-default-directory
1423                                             default-directory)))
1424                                  (t
1425                                   (file-name-nondirectory name)))
1426                              ""))
1427                          " "))))
1428       (kill-new ibuffer-copy-filename-as-kill-result))))
1429
1430 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1431   (let ((count
1432          (ibuffer-map-lines
1433           #'(lambda (buf _mark)
1434               (when (funcall func buf)
1435                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1436                                         ibuffer-marked-char))
1437                 t))
1438           nil
1439           group)))
1440     (ibuffer-redisplay t)
1441     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1442       (message "Marked %s buffers" count))))
1443
1444 ;;;###autoload
1445 (defun ibuffer-mark-by-name-regexp (regexp)
1446   "Mark all buffers whose name matches REGEXP."
1447   (interactive "sMark by name (regexp): ")
1448   (ibuffer-mark-on-buffer
1449    #'(lambda (buf)
1450        (string-match regexp (buffer-name buf)))))
1451
1452 ;;;###autoload
1453 (defun ibuffer-mark-by-mode-regexp (regexp)
1454   "Mark all buffers whose major mode matches REGEXP."
1455   (interactive "sMark by major mode (regexp): ")
1456   (ibuffer-mark-on-buffer
1457    #'(lambda (buf)
1458        (with-current-buffer buf
1459          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1460
1461 ;;;###autoload
1462 (defun ibuffer-mark-by-file-name-regexp (regexp)
1463   "Mark all buffers whose file name matches REGEXP."
1464   (interactive "sMark by file name (regexp): ")
1465   (ibuffer-mark-on-buffer
1466    #'(lambda (buf)
1467        (let ((name (or (buffer-file-name buf)
1468                        (with-current-buffer buf
1469                          (and
1470                           (boundp 'dired-directory)
1471                           (stringp dired-directory)
1472                           dired-directory)))))
1473          (when name
1474            (string-match regexp name))))))
1475
1476 ;;;###autoload
1477 (defun ibuffer-mark-by-mode (mode)
1478   "Mark all buffers whose major mode equals MODE."
1479   (interactive
1480    (let* ((buf (ibuffer-current-buffer))
1481           (default (if (and buf (buffer-live-p buf))
1482                        (symbol-name (buffer-local-value
1483                                      'major-mode buf)))))
1484      (list (intern
1485             (completing-read
1486              (if default
1487                  (format "Mark by major mode (default %s): " default)
1488                "Mark by major mode: ")
1489              (ibuffer-list-buffer-modes) nil t nil nil default)))))
1490   (ibuffer-mark-on-buffer
1491    #'(lambda (buf)
1492        (eq (buffer-local-value 'major-mode buf) mode))))
1493
1494 ;;;###autoload
1495 (defun ibuffer-mark-modified-buffers ()
1496   "Mark all modified buffers."
1497   (interactive)
1498   (ibuffer-mark-on-buffer
1499    #'(lambda (buf) (buffer-modified-p buf))))
1500
1501 ;;;###autoload
1502 (defun ibuffer-mark-unsaved-buffers ()
1503   "Mark all modified buffers that have an associated file."
1504   (interactive)
1505   (ibuffer-mark-on-buffer
1506    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1507                         (buffer-modified-p buf)))))
1508
1509 ;;;###autoload
1510 (defun ibuffer-mark-dissociated-buffers ()
1511   "Mark all buffers whose associated file does not exist."
1512   (interactive)
1513   (ibuffer-mark-on-buffer
1514    #'(lambda (buf)
1515        (with-current-buffer buf
1516          (or
1517           (and buffer-file-name
1518                (not (file-exists-p buffer-file-name)))
1519           (and (eq major-mode 'dired-mode)
1520                (boundp 'dired-directory)
1521                (stringp dired-directory)
1522                (not (file-exists-p (file-name-directory dired-directory)))))))))
1523
1524 ;;;###autoload
1525 (defun ibuffer-mark-help-buffers ()
1526   "Mark buffers like *Help*, *Apropos*, *Info*."
1527   (interactive)
1528   (ibuffer-mark-on-buffer
1529    #'(lambda (buf)
1530        (with-current-buffer buf
1531          (memq major-mode ibuffer-help-buffer-modes)))))
1532
1533 ;;;###autoload
1534 (defun ibuffer-mark-compressed-file-buffers ()
1535   "Mark buffers whose associated file is compressed."
1536   (interactive)
1537   (ibuffer-mark-on-buffer
1538    #'(lambda (buf)
1539        (with-current-buffer buf
1540          (and buffer-file-name
1541               (string-match ibuffer-compressed-file-name-regexp
1542                            buffer-file-name))))))
1543
1544 ;;;###autoload
1545 (defun ibuffer-mark-old-buffers ()
1546   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1547   (interactive)
1548   (ibuffer-mark-on-buffer
1549    #'(lambda (buf)
1550        (with-current-buffer buf
1551          ;; hacked from midnight.el
1552          (when buffer-display-time
1553            (let* ((tm (current-time))
1554                   (now (+ (* (float (ash 1 16)) (car tm))
1555                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1556                   (then (+ (* (float (ash 1 16))
1557                               (car buffer-display-time))
1558                            (float (cadr buffer-display-time))
1559                            (* 0.0000001 (caddr buffer-display-time)))))
1560              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1561
1562 ;;;###autoload
1563 (defun ibuffer-mark-special-buffers ()
1564   "Mark all buffers whose name begins and ends with '*'."
1565   (interactive)
1566   (ibuffer-mark-on-buffer
1567    #'(lambda (buf) (string-match "^\\*.+\\*$"
1568                                  (buffer-name buf)))))
1569
1570 ;;;###autoload
1571 (defun ibuffer-mark-read-only-buffers ()
1572   "Mark all read-only buffers."
1573   (interactive)
1574   (ibuffer-mark-on-buffer
1575    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1576
1577 ;;;###autoload
1578 (defun ibuffer-mark-dired-buffers ()
1579   "Mark all `dired' buffers."
1580   (interactive)
1581   (ibuffer-mark-on-buffer
1582    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1583
1584 ;;;###autoload
1585 (defun ibuffer-do-occur (regexp &optional nlines)
1586   "View lines which match REGEXP in all marked buffers.
1587 Optional argument NLINES says how many lines of context to display: it
1588 defaults to one."
1589   (interactive (occur-read-primary-args))
1590   (if (or (not (integerp nlines))
1591           (< nlines 0))
1592       (setq nlines 0))
1593   (when (zerop (ibuffer-count-marked-lines))
1594     (ibuffer-set-mark ibuffer-marked-char))
1595   (let ((ibuffer-do-occur-bufs nil))
1596     ;; Accumulate a list of marked buffers
1597     (ibuffer-map-marked-lines
1598      #'(lambda (buf _mark)
1599          (push buf ibuffer-do-occur-bufs)))
1600     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1601
1602 (provide 'ibuf-ext)
1603
1604 ;; Local Variables:
1605 ;; generated-autoload-file: "ibuffer.el"
1606 ;; End:
1607
1608 ;;; ibuf-ext.el ends here