etc/ETAGS.EBNF

   1 EBNF (Extended Backus Normal Form) description of the format of the tags
   2 file created by etags.c and interpreted by etags.el
   3
   4 Productions created from current behaviour to aid extensions
   5 Francesco Potorti` <pot@gnu.org> 2002
   6 ================================================================
   7
   8 FF ::= #x0c                                /* tag section starter */
   9
  10 LF ::= #x0a                                /* line terminator */
  11
  12 DEL ::= #x7f                               /* pattern terminator */
  13
  14 SOH ::= #x01                               /* name terminator */
  15
  16 regchar ::= [^#x0a#x0c#x7f]                /* regular character */
  17
  18 regstring ::= { regchar }                  /* regular string */
  19
  20 unsint ::= [0-9] { [0-9] }                 /* non-negative integer */
  21
  22
  23
  24 tagfile ::= { tagsection }                 /* a tags file */
  25
  26 tagsection ::= FF LF ( includesec | regularsec ) LF
  27
  28 includesec ::= filename ",include" [ LF fileprop ]
  29
  30 regularsec ::= filename "," [ unsint ] [ LF fileprop ] { LF tag }
  31
  32 filename ::= regchar regstring             /* a file name */
  33
  34 fileprop ::= "(" regstring ")"             /* an elisp alist */
  35
  36 tag ::= directtag | patterntag
  37
  38 directtag ::= DEL realposition             /* no pattern */
  39
  40 patterntag ::= pattern DEL [ tagname SOH ] position
  41
  42 pattern ::= regstring                      /* a tag pattern */
  43
  44 tagname ::= regchar regstring              /* a tag name */
  45
  46 position ::= realposition | ","            /* charpos,linepos */
  47
  48 realposition ::= "," unsint | unsint "," | unsint "," unsint