lisp/button.el

   1 ;;; button.el --- clickable buttons
   2 ;;
   3 ;; Copyright (C) 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Miles Bader <miles@gnu.org>
   7 ;; Keywords: extensions
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15 ;;
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20 ;;
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package defines functions for inserting and manipulating
  29 ;; clickable buttons in Emacs buffers, such as might be used for help
  30 ;; hyperlinks, etc.
  31 ;;
  32 ;; In some ways it duplicates functionality also offered by the
  33 ;; `widget' package, but the button package has the advantage that it
  34 ;; is (1) much faster, (2) much smaller, and (3) much, much, simpler
  35 ;; (the code, that is, not the interface).
  36 ;;
  37 ;; Buttons can either use overlays, in which case the button is
  38 ;; represented by the overlay itself, or text-properties, in which case
  39 ;; the button is represented by a marker or buffer-position pointing
  40 ;; somewhere in the button.  In the latter case, no markers into the
  41 ;; buffer are retained, which is important for speed if there are are
  42 ;; extremely large numbers of buttons.
  43 ;;
  44 ;; Using `define-button-type' to define default properties for buttons
  45 ;; is not necessary, but it is is encouraged, since doing so makes the
  46 ;; resulting code clearer and more efficient.
  47 ;;
  48
  49 ;;; Code:
  50
  51 \f
  52 ;; Globals
  53
  54 ;; Use color for the MS-DOS port because it doesn't support underline.
  55 ;; FIXME if MS-DOS correctly answers the (supports) question, it need
  56 ;; no longer be a special case.
  57 (defface button '((((type pc) (class color))
  58                    (:foreground "lightblue"))
  59                   (((supports :underline t)) :underline t)
  60                   (t (:foreground "lightblue")))
  61   "Default face used for buttons."
  62   :group 'basic-faces)
  63
  64 (defvar button-map
  65   (let ((map (make-sparse-keymap)))
  66     ;; The following definition needs to avoid using escape sequences that
  67     ;; might get converted to ^M when building loaddefs.el
  68     (define-key map [(control ?m)] 'push-button)
  69     (define-key map [mouse-2] 'push-button)
  70     map)
  71   "Keymap used by buttons.")
  72
  73 (defvar button-buffer-map
  74   (let ((map (make-sparse-keymap)))
  75     (define-key map [?\t] 'forward-button)
  76     (define-key map "\e\t" 'backward-button)
  77     (define-key map [backtab] 'backward-button)
  78     map)
  79   "Keymap useful for buffers containing buttons.
  80 Mode-specific keymaps may want to use this as their parent keymap.")
  81
  82 ;; Default properties for buttons
  83 (put 'default-button 'face 'button)
  84 (put 'default-button 'mouse-face 'highlight)
  85 (put 'default-button 'keymap button-map)
  86 (put 'default-button 'type 'button)
  87 ;; action may be either a function to call, or a marker to go to
  88 (put 'default-button 'action 'ignore)
  89 (put 'default-button 'help-echo "mouse-2, RET: Push this button")
  90 ;; Make overlay buttons go away if their underlying text is deleted.
  91 (put 'default-button 'evaporate t)
  92 ;; Prevent insertions adjacent to the text-property buttons from
  93 ;; inheriting its properties.
  94 (put 'default-button 'rear-nonsticky t)
  95
  96 ;; A `category-symbol' property for the default button type
  97 (put 'button 'button-category-symbol 'default-button)
  98
  99 \f
 100 ;; Button types (which can be used to hold default properties for buttons)
 101
 102 ;; Because button-type properties are inherited by buttons using the
 103 ;; special `category' property (implemented by both overlays and
 104 ;; text-properties), we need to store them on a symbol to which the
 105 ;; `category' properties can point.  Instead of using the symbol that's
 106 ;; the name of each button-type, however, we use a separate symbol (with
 107 ;; `-button' appended, and uninterned) to store the properties.  This is
 108 ;; to avoid name clashes.
 109
 110 ;; [this is an internal function]
 111 (defsubst button-category-symbol (type)
 112   "Return the symbol used by button-type TYPE to store properties.
 113 Buttons inherit them by setting their `category' property to that symbol."
 114   (or (get type 'button-category-symbol)
 115       (error "Unknown button type `%s'" type)))
 116
 117 (defun define-button-type (name &rest properties)
 118   "Define a `button type' called NAME (a symbol).
 119 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 120 specifying properties to use as defaults for buttons with this type
 121 \(a button's type may be set by giving it a `type' property when
 122 creating the button, using the :type keyword argument).
 123
 124 In addition, the keyword argument :supertype may be used to specify a
 125 button-type from which NAME inherits its default property values
 126 \(however, the inheritance happens only when NAME is defined; subsequent
 127 changes to a supertype are not reflected in its subtypes)."
 128   (let ((catsym (make-symbol (concat (symbol-name name) "-button")))
 129         (super-catsym
 130          (button-category-symbol
 131           (or (plist-get properties 'supertype)
 132               (plist-get properties :supertype)
 133               'button))))
 134     ;; Provide a link so that it's easy to find the real symbol.
 135     (put name 'button-category-symbol catsym)
 136     ;; Initialize NAME's properties using the global defaults.
 137     (let ((default-props (symbol-plist super-catsym)))
 138       (while default-props
 139         (put catsym (pop default-props) (pop default-props))))
 140     ;; Add NAME as the `type' property, which will then be returned as
 141     ;; the type property of individual buttons.
 142     (put catsym 'type name)
 143     ;; Add the properties in PROPERTIES to the real symbol.
 144     (while properties
 145       (let ((prop (pop properties)))
 146         (when (eq prop :supertype)
 147           (setq prop 'supertype))
 148         (put catsym prop (pop properties))))
 149     ;; Make sure there's a `supertype' property
 150     (unless (get catsym 'supertype)
 151       (put catsym 'supertype 'button))
 152     name))
 153
 154 (defun button-type-put (type prop val)
 155   "Set the button-type TYPE's PROP property to VAL."
 156   (put (button-category-symbol type) prop val))
 157
 158 (defun button-type-get (type prop)
 159   "Get the property of button-type TYPE named PROP."
 160   (get (button-category-symbol type) prop))
 161
 162 (defun button-type-subtype-p (type supertype)
 163   "Return t if button-type TYPE is a subtype of SUPERTYPE."
 164   (or (eq type supertype)
 165       (and type
 166            (button-type-subtype-p (button-type-get type 'supertype)
 167                                   supertype))))
 168
 169 \f
 170 ;; Button properties and other attributes
 171
 172 (defun button-start (button)
 173   "Return the position at which BUTTON starts."
 174   (if (overlayp button)
 175       (overlay-start button)
 176     ;; Must be a text-property button.
 177     (or (previous-single-property-change (1+ button) 'button)
 178         (point-min))))
 179
 180 (defun button-end (button)
 181   "Return the position at which BUTTON ends."
 182   (if (overlayp button)
 183       (overlay-end button)
 184     ;; Must be a text-property button.
 185     (or (next-single-property-change button 'button)
 186         (point-max))))
 187
 188 (defun button-get (button prop)
 189   "Get the property of button BUTTON named PROP."
 190   (if (overlayp button)
 191       (overlay-get button prop)
 192     ;; Must be a text-property button.
 193     (get-text-property button prop)))
 194
 195 (defun button-put (button prop val)
 196   "Set BUTTON's PROP property to VAL."
 197   ;; Treat some properties specially.
 198   (cond ((memq prop '(type :type))
 199          ;; We translate a `type' property a `category' property, since
 200          ;; that's what's actually used by overlays/text-properties for
 201          ;; inheriting properties.
 202          (setq prop 'category)
 203          (setq val (button-category-symbol val)))
 204         ((eq prop 'category)
 205          ;; Disallow updating the `category' property directly.
 206          (error "Button `category' property may not be set directly")))
 207   ;; Add the property.
 208   (if (overlayp button)
 209       (overlay-put button prop val)
 210     ;; Must be a text-property button.
 211     (put-text-property
 212      (or (previous-single-property-change (1+ button) 'button)
 213          (point-min))
 214      (or (next-single-property-change button 'button)
 215          (point-max))
 216      prop val)))
 217
 218 (defsubst button-activate (button &optional use-mouse-action)
 219   "Call BUTTON's action property.
 220 If USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
 221 instead of its normal action; if the button has no mouse-action,
 222 the normal action is used instead."
 223   (let ((action (or (and use-mouse-action (button-get button 'mouse-action))
 224                     (button-get button 'action))))
 225     (if (markerp action)
 226         (save-selected-window
 227           (select-window (display-buffer (marker-buffer action)))
 228           (goto-char action)
 229           (recenter 0))
 230       (funcall action button))))
 231
 232 (defun button-label (button)
 233   "Return BUTTON's text label."
 234   (buffer-substring-no-properties (button-start button) (button-end button)))
 235
 236 (defsubst button-type (button)
 237   "Return BUTTON's button-type."
 238   (button-get button 'type))
 239
 240 (defun button-has-type-p (button type)
 241   "Return t if BUTTON has button-type TYPE, or one of TYPE's subtypes."
 242   (button-type-subtype-p (button-get button 'type) type))
 243
 244 \f
 245 ;; Creating overlay buttons
 246
 247 (defun make-button (beg end &rest properties)
 248   "Make a button from BEG to END in the current buffer.
 249 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 250 specifying properties to add to the button.
 251 In addition, the keyword argument :type may be used to specify a
 252 button-type from which to inherit other properties; see
 253 `define-button-type'.
 254
 255 Also see `make-text-button', `insert-button'."
 256   (let ((overlay (make-overlay beg end nil t nil)))
 257     (while properties
 258       (button-put overlay (pop properties) (pop properties)))
 259     ;; Put a pointer to the button in the overlay, so it's easy to get
 260     ;; when we don't actually have a reference to the overlay.
 261     (overlay-put overlay 'button overlay)
 262     ;; If the user didn't specify a type, use the default.
 263     (unless (overlay-get overlay 'category)
 264       (overlay-put overlay 'category 'default-button))
 265     ;; OVERLAY is the button, so return it
 266     overlay))
 267
 268 (defun insert-button (label &rest properties)
 269   "Insert a button with the label LABEL.
 270 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 271 specifying properties to add to the button.
 272 In addition, the keyword argument :type may be used to specify a
 273 button-type from which to inherit other properties; see
 274 `define-button-type'.
 275
 276 Also see `insert-text-button', `make-button'."
 277   (apply #'make-button
 278          (prog1 (point) (insert label))
 279          (point)
 280          properties))
 281
 282 \f
 283 ;; Creating text-property buttons
 284
 285 (defun make-text-button (beg end &rest properties)
 286   "Make a button from BEG to END in the current buffer.
 287 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 288 specifying properties to add to the button.
 289 In addition, the keyword argument :type may be used to specify a
 290 button-type from which to inherit other properties; see
 291 `define-button-type'.
 292
 293 This function is like `make-button', except that the button is actually
 294 part of the text instead of being a property of the buffer.  Creating
 295 large numbers of buttons can also be somewhat faster using
 296 `make-text-button'.
 297
 298 Also see `insert-text-button'."
 299   (let ((type-entry
 300          (or (plist-member properties 'type)
 301              (plist-member properties :type))))
 302     ;; Disallow setting the `category' property directly.
 303     (when (plist-get properties 'category)
 304       (error "Button `category' property may not be set directly"))
 305     (if (null type-entry)
 306         ;; The user didn't specify a `type' property, use the default.
 307         (setq properties (cons 'category (cons 'default-button properties)))
 308       ;; The user did specify a `type' property.  Translate it into a
 309       ;; `category' property, which is what's actually used by
 310       ;; text-properties for inheritance.
 311       (setcar type-entry 'category)
 312       (setcar (cdr type-entry)
 313               (button-category-symbol (car (cdr type-entry))))))
 314   ;; Now add all the text properties at once
 315   (add-text-properties beg end
 316                        ;; Each button should have a non-eq `button'
 317                        ;; property so that next-single-property-change can
 318                        ;; detect boundaries reliably.
 319                        (cons 'button (cons (list t) properties)))
 320   ;; Return something that can be used to get at the button.
 321   beg)
 322
 323 (defun insert-text-button (label &rest properties)
 324   "Insert a button with the label LABEL.
 325 The remaining arguments form a sequence of PROPERTY VALUE pairs,
 326 specifying properties to add to the button.
 327 In addition, the keyword argument :type may be used to specify a
 328 button-type from which to inherit other properties; see
 329 `define-button-type'.
 330
 331 This function is like `insert-button', except that the button is
 332 actually part of the text instead of being a property of the buffer.
 333 Creating large numbers of buttons can also be somewhat faster using
 334 `insert-text-button'.
 335
 336 Also see `make-text-button'."
 337   (apply #'make-text-button
 338          (prog1 (point) (insert label))
 339          (point)
 340          properties))
 341
 342 \f
 343 ;; Finding buttons in a buffer
 344
 345 (defun button-at (pos)
 346   "Return the button at position POS in the current buffer, or nil."
 347   (let ((button (get-char-property pos 'button)))
 348     (if (or (overlayp button) (null button))
 349         button
 350       ;; Must be a text-property button; return a marker pointing to it.
 351       (copy-marker pos t))))
 352
 353 (defun next-button (pos &optional count-current)
 354   "Return the next button after position POS in the current buffer.
 355 If COUNT-CURRENT is non-nil, count any button at POS in the search,
 356 instead of starting at the next button."
 357     (unless count-current
 358       ;; Search for the next button boundary.
 359       (setq pos (next-single-char-property-change pos 'button)))
 360     (and (< pos (point-max))
 361          (or (button-at pos)
 362              ;; We must have originally been on a button, and are now in
 363              ;; the inter-button space.  Recurse to find a button.
 364              (next-button pos))))
 365
 366 (defun previous-button (pos &optional count-current)
 367   "Return the previous button before position POS in the current buffer.
 368 If COUNT-CURRENT is non-nil, count any button at POS in the search,
 369 instead of starting at the next button."
 370   (let ((button (button-at pos)))
 371     (if button
 372         (if count-current
 373             button
 374           ;; We started out on a button, so move to its start and look
 375           ;; for the previous button boundary.
 376           (setq pos (previous-single-char-property-change
 377                      (button-start button) 'button))
 378           (let ((new-button (button-at pos)))
 379             (if new-button
 380                 ;; We are in a button again; this can happen if there
 381                 ;; are adjacent buttons (or at bob).
 382                 (unless (= pos (button-start button)) new-button)
 383               ;; We are now in the space between buttons.
 384               (previous-button pos))))
 385       ;; We started out in the space between buttons.
 386       (setq pos (previous-single-char-property-change pos 'button))
 387       (or (button-at pos)
 388           (and (> pos (point-min))
 389                (button-at (1- pos)))))))
 390
 391 \f
 392 ;; User commands
 393
 394 (defun push-button (&optional pos use-mouse-action)
 395   "Perform the action specified by a button at location POS.
 396 POS may be either a buffer position or a mouse-event.  If
 397 USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
 398 instead of its normal action; if the button has no mouse-action,
 399 the normal action is used instead.  The action may be either a
 400 function to call or a marker to display.
 401 POS defaults to point, except when `push-button' is invoked
 402 interactively as the result of a mouse-event, in which case, the
 403 mouse event is used.
 404 If there's no button at POS, do nothing and return nil, otherwise
 405 return t."
 406   (interactive
 407    (list (if (integerp last-command-event) (point) last-command-event)))
 408   (if (and (not (integerp pos)) (eventp pos))
 409       ;; POS is a mouse event; switch to the proper window/buffer
 410       (let ((posn (event-start pos)))
 411         (with-current-buffer (window-buffer (posn-window posn))
 412           (push-button (posn-point posn) t)))
 413     ;; POS is just normal position
 414     (let ((button (button-at (or pos (point)))))
 415       (if (not button)
 416           nil
 417         (button-activate button use-mouse-action)
 418         t))))
 419
 420 (defun forward-button (n &optional wrap display-message)
 421   "Move to the Nth next button, or Nth previous button if N is negative.
 422 If N is 0, move to the start of any button at point.
 423 If WRAP is non-nil, moving past either end of the buffer continues from the
 424 other end.
 425 If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
 426 Any button with a non-nil `skip' property is skipped over.
 427 Returns the button found."
 428   (interactive "p\nd\nd")
 429   (let (button)
 430     (if (zerop n)
 431         ;; Move to start of current button
 432         (if (setq button (button-at (point)))
 433             (goto-char (button-start button)))
 434       ;; Move to Nth next button
 435       (let ((iterator (if (> n 0) #'next-button #'previous-button))
 436             (wrap-start (if (> n 0) (point-min) (point-max))))
 437         (setq n (abs n))
 438         (setq button t)                 ; just to start the loop
 439         (while (and (> n 0) button)
 440           (setq button (funcall iterator (point)))
 441           (when (and (not button) wrap)
 442             (setq button (funcall iterator wrap-start t)))
 443           (when button
 444             (goto-char (button-start button))
 445             (unless (button-get button 'skip)
 446               (setq n (1- n)))))))
 447     (if (null button)
 448         (error (if wrap "No buttons!" "No more buttons"))
 449       (let ((msg (and display-message (button-get button 'help-echo))))
 450         (when msg
 451           (message "%s" msg)))
 452       button)))
 453
 454 (defun backward-button (n &optional wrap display-message)
 455   "Move to the Nth previous button, or Nth next button if N is negative.
 456 If N is 0, move to the start of any button at point.
 457 If WRAP is non-nil, moving past either end of the buffer continues from the
 458 other end.
 459 If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
 460 Any button with a non-nil `skip' property is skipped over.
 461 Returns the button found."
 462   (interactive "p\nd\nd")
 463   (forward-button (- n) wrap display-message))
 464
 465
 466 (provide 'button)
 467
 468 ;; arch-tag: 5f2c7627-413b-4097-b282-630f89d9c5e9
 469 ;;; button.el ends here