| blob | 7fd45c879beb788b11290e5c2dd39a4babc714e2 |
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to
22 dnl the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
24 AC_PREREQ(2.8)dnl
25 AC_INIT(src/lisp.h)
26 AC_CONFIG_HEADER(src/config.h:src/config.in)
28 lispdir='${datadir}/emacs/${version}/lisp'
29 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
30 '${datadir}/emacs/site-lisp'
31 lisppath='${locallisppath}:${lispdir}'
32 etcdir='${datadir}/emacs/${version}/etc'
33 lockdir='${sharedstatedir}/emacs/lock'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
37 AC_ARG_WITH(gcc,
38 [ --with-gcc use GCC to compile Emacs])
39 AC_ARG_WITH(pop,
40 [ --with-pop support POP for mail retrieval],
41 [AC_DEFINE(MAIL_USE_POP)])
42 AC_ARG_WITH(kerberos,
43 [ --with-kerberos support Kerberos-authenticated POP],
44 [AC_DEFINE(KERBEROS)])
45 AC_ARG_WITH(hesiod,
46 [ --with-hesiod support Hesiod to get the POP server host],
47 [AC_DEFINE(HESIOD)])
48 dnl This should be the last --with option, because --with-x is
49 dnl added later on when we find the path of X, and it's best to
50 dnl keep them together visually.
51 AC_ARG_WITH(x-toolkit,
52 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif)],
53 [ case "${withval}" in
54 y | ye | yes ) val=athena ;;
55 n | no ) val=no ;;
56 l | lu | luc | luci | lucid ) val=lucid ;;
57 a | at | ath | athe | athen | athena ) val=athena ;;
58 m | mo | mot | moti | motif ) val=motif ;;
59 dnl These don't currently work.
60 dnl o | op | ope | open | open- | open-l | open-lo \
61 dnl | open-loo | open-look ) val=open-look ;;
62 * )
63 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
64 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
65 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
66 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
67 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
68 ;;
69 esac
70 with_x_toolkit=$val
71 ])
73 #### Make srcdir absolute, if it isn't already. It's important to
74 #### avoid running the path through pwd unnecessary, since pwd can
75 #### give you automounter prefixes, which can go away. We do all this
76 #### so Emacs can find its files when run uninstalled.
77 case "${srcdir}" in
78 /* ) ;;
79 . )
80 ## We may be able to use the $PWD environment variable to make this
81 ## absolute. But sometimes PWD is inaccurate.
82 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
83 CDPATH=
84 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
85 then
86 srcdir="$PWD"
87 else
88 srcdir="`(cd ${srcdir}; pwd)`"
89 fi
90 ;;
91 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
92 esac
94 #### Check if the source directory already has a configured system in it.
95 if test `pwd` != `(cd ${srcdir} && pwd)` \
96 && test -f "${srcdir}/src/config.h" ; then
97 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
98 as a build directory right now; it has been configured in its own
99 right. To configure in another directory as well, you MUST
100 use GNU make. If you do not have GNU make, then you must
101 now do \`make distclean' in ${srcdir},
102 and then run $0 again.])
104 changequote(, )dnl
105 extrasub='/^VPATH[ ]*=/c\
106 changequote([, ])dnl
107 vpath %.c $(srcdir)\
108 vpath %.h $(srcdir)\
109 vpath %.y $(srcdir)\
110 vpath %.l $(srcdir)\
111 vpath %.s $(srcdir)\
112 vpath %.in $(srcdir)'
113 fi
115 #### Given the configuration name, set machfile and opsysfile to the
116 #### names of the m/*.h and s/*.h files we should use.
118 ### Canonicalize the configuration name.
120 AC_CANONICAL_HOST
121 canonical=$host
122 configuration=$host_alias
124 changequote(, )dnl
126 ### If you add support for a new configuration, add code to this
127 ### switch statement to recognize your configuration name and select
128 ### the appropriate operating system and machine description files.
130 ### You would hope that you could choose an m/*.h file pretty much
131 ### based on the machine portion of the configuration name, and an s-
132 ### file based on the operating system portion. However, it turns out
133 ### that each m/*.h file is pretty manufacturer-specific - for
134 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
135 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
136 ### machines. So we basically have to have a special case for each
137 ### configuration name.
138 ###
139 ### As far as handling version numbers on operating systems is
140 ### concerned, make sure things will fail in a fixable way. If
141 ### /etc/MACHINES doesn't say anything about version numbers, be
142 ### prepared to handle anything reasonably. If version numbers
143 ### matter, be sure /etc/MACHINES says something about it.
144 ###
145 ### Eric Raymond says we should accept strings like "sysvr4" to mean
146 ### "System V Release 4"; he writes, "The old convention encouraged
147 ### confusion between `system' and `release' levels'."
149 machine='' opsys='' unported=no
150 case "${canonical}" in
152 ## NetBSD ports
153 *-*-netbsd* )
154 opsys=netbsd
155 case "${canonical}" in
156 i[345]86-*-netbsd*) machine=intel386 ;;
157 m68k-*-netbsd*)
158 # This is somewhat bogus.
159 machine=hp9000s300 ;;
160 mips-*-netbsd*) machine=pmax ;;
161 ns32k-*-netbsd*) machine=ns32000 ;;
162 sparc-*-netbsd*) machine=sparc ;;
163 esac
164 ;;
166 ## Acorn RISCiX:
167 arm-acorn-riscix1.1* )
168 machine=acorn opsys=riscix1-1
169 ;;
170 arm-acorn-riscix1.2* | arm-acorn-riscix )
171 machine=acorn opsys=riscix1-2
172 ;;
174 ## Alliant machines
175 ## Strictly speaking, we need the version of the alliant operating
176 ## system to choose the right machine file, but currently the
177 ## configuration name doesn't tell us enough to choose the right
178 ## one; we need to give alliants their own operating system name to
179 ## do this right. When someone cares, they can help us.
180 fx80-alliant-* )
181 machine=alliant4 opsys=bsd4-2
182 ;;
183 i860-alliant-* )
184 machine=alliant-2800 opsys=bsd4-3
185 ;;
187 ## Alpha (DEC) machines.
188 alpha-dec-osf* )
189 machine=alpha opsys=osf1
190 ;;
192 alpha-*-linux* | alpha-*-lignux* )
193 machine=alpha opsys=lignux
194 ;;
196 ## Altos 3068
197 m68*-altos-sysv* )
198 machine=altos opsys=usg5-2
199 ;;
201 ## Amdahl UTS
202 580-amdahl-sysv* )
203 machine=amdahl opsys=usg5-2-2
204 ;;
206 ## Apollo, Domain/OS
207 m68*-apollo-* )
208 machine=apollo opsys=bsd4-3
209 ;;
211 ## AT&T 3b2, 3b5, 3b15, 3b20
212 we32k-att-sysv* )
213 machine=att3b opsys=usg5-2-2
214 ;;
216 ## AT&T 3b1 - The Mighty Unix PC!
217 m68*-att-sysv* )
218 machine=7300 opsys=usg5-2-2
219 ;;
221 ## Bull dpx20
222 rs6000-bull-bosx* )
223 machine=ibmrs6000 opsys=aix3-2
224 ;;
226 ## Bull dpx2
227 m68*-bull-sysv3* )
228 machine=dpx2 opsys=usg5-3
229 ;;
231 ## Bull sps7
232 m68*-bull-sysv2* )
233 machine=sps7 opsys=usg5-2
234 ;;
236 ## CCI 5/32, 6/32 -- see "Tahoe".
238 ## Celerity
239 ## I don't know what configuration name to use for this; config.sub
240 ## doesn't seem to know anything about it. Hey, Celerity users, get
241 ## in touch with us!
242 celerity-celerity-bsd* )
243 machine=celerity opsys=bsd4-2
244 ;;
246 ## Clipper
247 ## What operating systems does this chip run that Emacs has been
248 ## tested on?
249 clipper-* )
250 machine=clipper
251 ## We'll use the catch-all code at the bottom to guess the
252 ## operating system.
253 ;;
255 ## Convex
256 *-convex-bsd* | *-convex-convexos* )
257 machine=convex opsys=bsd4-3
258 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
259 NON_GNU_CPP="cc -E -P"
260 ;;
262 ## Cubix QBx/386
263 i[345]86-cubix-sysv* )
264 machine=intel386 opsys=usg5-3
265 ;;
267 ## Cydra 5
268 cydra*-cydrome-sysv* )
269 machine=cydra5 opsys=usg5-3
270 ;;
272 ## Data General AViiON Machines
273 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
274 machine=aviion opsys=dgux5-4r3
275 ;;
276 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
277 machine=aviion opsys=dgux5-4r2
278 ;;
279 m88k-dg-dgux* )
280 machine=aviion opsys=dgux
281 ;;
283 ## DECstations
284 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
285 machine=pmax opsys=bsd4-2
286 ;;
287 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
288 machine=pmax opsys=bsd4-3
289 ;;
290 mips-dec-ultrix* )
291 machine=pmax opsys=ultrix4-3
292 ;;
293 mips-dec-osf* )
294 machine=pmax opsys=osf1
295 ;;
296 mips-dec-mach_bsd4.3* )
297 machine=pmax opsys=mach-bsd4-3
298 ;;
300 ## Motorola Delta machines
301 m68k-motorola-sysv* | m68000-motorola-sysv* )
302 machine=delta opsys=usg5-3
303 if test -z "`type gnucc | grep 'not found'`"
304 then
305 if test -s /etc/167config
306 then CC="gnucc -m68040"
307 else CC="gnucc -m68881"
308 fi
309 else
310 if test -z "`type gcc | grep 'not found'`"
311 then CC=gcc
312 else CC=cc
313 fi
314 fi
315 ;;
316 m88k-motorola-sysv4* )
317 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
318 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
319 # I hope there are not other 4.0 versions for this machine
320 # which really need usg5-4 instead.
321 machine=delta88k opsys=usg5-4-2
322 ;;
323 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
324 machine=delta88k opsys=usg5-3
325 ;;
327 ## Dual machines
328 m68*-dual-sysv* )
329 machine=dual opsys=usg5-2
330 ;;
331 m68*-dual-uniplus* )
332 machine=dual opsys=unipl5-2
333 ;;
335 ## Elxsi 6400
336 elxsi-elxsi-sysv* )
337 machine=elxsi opsys=usg5-2
338 ;;
340 ## Encore machines
341 ns16k-encore-bsd* )
342 machine=ns16000 opsys=umax
343 ;;
345 ## The GEC 93 - apparently, this port isn't really finished yet.
347 ## Gould Power Node and NP1
348 pn-gould-bsd4.2* )
349 machine=gould opsys=bsd4-2
350 ;;
351 pn-gould-bsd4.3* )
352 machine=gould opsys=bsd4-3
353 ;;
354 np1-gould-bsd* )
355 machine=gould-np1 opsys=bsd4-3
356 ;;
358 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
359 ## as far as Emacs is concerned).
360 m88k-harris-cxux* )
361 # Build needs to be different on 7.0 and later releases
362 case "`uname -r`" in
363 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
364 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
365 esac
366 NON_GNU_CPP="/lib/cpp"
367 ;;
368 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
369 m68k-harris-cxux* )
370 machine=nh3000 opsys=cxux
371 ;;
372 ## Harris power pc NightHawk running Power UNIX (Series 6000)
373 powerpc-harris-powerunix )
374 machine=nh6000 opsys=powerunix
375 NON_GNU_CPP="cc -Xo -E -P"
376 ;;
378 ## Honeywell XPS100
379 xps*-honeywell-sysv* )
380 machine=xps100 opsys=usg5-2
381 ;;
383 ## HP 9000 series 200 or 300
384 m68*-hp-bsd* )
385 machine=hp9000s300 opsys=bsd4-3
386 ;;
387 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
388 m68*-hp-hpux* )
389 case "`uname -r`" in
390 ## Someone's system reports A.B8.05 for this.
391 ## I wonder what other possibilities there are.
392 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
393 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
394 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
395 *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
396 *) machine=hp9000s300 opsys=hpux ;;
397 esac
398 ;;
400 ## HP 9000 series 700 and 800, running HP/UX
401 hppa*-hp-hpux7* )
402 machine=hp800 opsys=hpux
403 ;;
404 hppa*-hp-hpux8* )
405 machine=hp800 opsys=hpux8
406 ;;
407 hppa*-hp-hpux9shr* )
408 machine=hp800 opsys=hpux9shr
409 ;;
410 hppa*-hp-hpux9* )
411 machine=hp800 opsys=hpux9
412 ;;
413 hppa*-hp-hpux10* )
414 machine=hp800 opsys=hpux10
415 ;;
417 ## HP 9000 series 700 and 800, running HP/UX
418 hppa*-hp-hpux* )
419 ## Cross-compilation? Nah!
420 case "`uname -r`" in
421 ## Someone's system reports A.B8.05 for this.
422 ## I wonder what other possibilities there are.
423 *.B8.* ) machine=hp800 opsys=hpux8 ;;
424 *.08.* ) machine=hp800 opsys=hpux8 ;;
425 *.09.* ) machine=hp800 opsys=hpux9 ;;
426 *) machine=hp800 opsys=hpux ;;
427 esac
428 ;;
429 hppa-*-nextstep* )
430 machine=hp800 opsys=nextstep
431 ;;
433 ## Orion machines
434 orion-orion-bsd* )
435 machine=orion opsys=bsd4-2
436 ;;
437 clipper-orion-bsd* )
438 machine=orion105 opsys=bsd4-2
439 ;;
441 ## IBM machines
442 i[345]86-ibm-aix1.1* )
443 machine=ibmps2-aix opsys=usg5-2-2
444 ;;
445 i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
446 machine=ibmps2-aix opsys=usg5-3
447 ;;
448 i370-ibm-aix*)
449 machine=ibm370aix opsys=usg5-3
450 ;;
451 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
452 machine=ibmrs6000 opsys=aix3-1
453 ;;
454 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
455 machine=ibmrs6000 opsys=aix3-2-5
456 ;;
457 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
458 machine=ibmrs6000 opsys=aix4-1
459 ;;
460 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
461 machine=ibmrs6000 opsys=aix4
462 ;;
463 rs6000-ibm-aix* | powerpc-ibm-aix* )
464 machine=ibmrs6000 opsys=aix3-2
465 ;;
466 romp-ibm-bsd4.3* )
467 machine=ibmrt opsys=bsd4-3
468 ;;
469 romp-ibm-bsd4.2* )
470 machine=ibmrt opsys=bsd4-2
471 ;;
472 romp-ibm-aos4.3* )
473 machine=ibmrt opsys=bsd4-3
474 ;;
475 romp-ibm-aos4.2* )
476 machine=ibmrt opsys=bsd4-2
477 ;;
478 romp-ibm-aos* )
479 machine=ibmrt opsys=bsd4-3
480 ;;
481 romp-ibm-bsd* )
482 machine=ibmrt opsys=bsd4-3
483 ;;
484 romp-ibm-aix* )
485 machine=ibmrt-aix opsys=usg5-2-2
486 ;;
488 ## Integrated Solutions `Optimum V'
489 m68*-isi-bsd4.2* )
490 machine=isi-ov opsys=bsd4-2
491 ;;
492 m68*-isi-bsd4.3* )
493 machine=isi-ov opsys=bsd4-3
494 ;;
496 ## Intel 386 machines where we do care about the manufacturer
497 i[345]86-intsys-sysv* )
498 machine=is386 opsys=usg5-2-2
499 ;;
501 ## Prime EXL
502 i[345]86-prime-sysv* )
503 machine=i386 opsys=usg5-3
504 ;;
506 ## Sequent Symmetry running Dynix
507 i[345]86-sequent-bsd* )
508 machine=symmetry opsys=bsd4-3
509 ;;
511 ## Sequent Symmetry running DYNIX/ptx
512 ## Use the old cpp rather than the newer ANSI one.
513 i[345]86-sequent-ptx* )
514 machine=sequent-ptx opsys=ptx
515 NON_GNU_CPP="/lib/cpp"
516 ;;
518 ## Unspecified sysv on an ncr machine defaults to svr4.2.
519 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
520 i[345]86-ncr-sysv* )
521 machine=ncr386 opsys=usg5-4-2
522 ;;
524 ## Intel Paragon OSF/1
525 i860-intel-osf1* )
526 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
527 ;;
529 ## Intel 860
530 i860-*-sysv4* )
531 machine=i860 opsys=usg5-4
532 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
533 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
534 ;;
536 ## Masscomp machines
537 m68*-masscomp-rtu* )
538 machine=masscomp opsys=rtu
539 ;;
541 ## Megatest machines
542 m68*-megatest-bsd* )
543 machine=mega68 opsys=bsd4-2
544 ;;
546 ## Workstations sold by MIPS
547 ## This is not necessarily all workstations using the MIPS processor -
548 ## Irises are produced by SGI, and DECstations by DEC.
550 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
551 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
552 ## it gives for choosing between the alternatives seems to be "Use
553 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
554 ## the BSD world." I'll assume that these are instructions for
555 ## handling two odd situations, and that every other situation
556 ## should use mips.h and usg5-2-2, they being listed first.
557 mips-mips-usg* )
558 machine=mips4
559 ## Fall through to the general code at the bottom to decide on the OS.
560 ;;
561 mips-mips-riscos4* )
562 machine=mips4 opsys=bsd4-3
563 NON_GNU_CC="cc -systype bsd43"
564 NON_GNU_CPP="cc -systype bsd43 -E"
565 ;;
566 mips-mips-riscos5* )
567 machine=mips4 opsys=riscos5
568 NON_GNU_CC="cc -systype bsd43"
569 NON_GNU_CPP="cc -systype bsd43 -E"
570 ;;
571 mips-mips-bsd* )
572 machine=mips opsys=bsd4-3
573 ;;
574 mips-mips-* )
575 machine=mips opsys=usg5-2-2
576 ;;
578 ## NeXT
579 m68*-next-* | m68k-*-nextstep* )
580 machine=m68k opsys=nextstep
581 ;;
583 ## The complete machine from National Semiconductor
584 ns32k-ns-genix* )
585 machine=ns32000 opsys=usg5-2
586 ;;
588 ## NCR machines
589 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
590 machine=tower32 opsys=usg5-2-2
591 ;;
592 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
593 machine=tower32v3 opsys=usg5-3
594 ;;
596 ## Nixdorf Targon 31
597 m68*-nixdorf-sysv* )
598 machine=targon31 opsys=usg5-2-2
599 ;;
601 ## Nu (TI or LMI)
602 m68*-nu-sysv* )
603 machine=nu opsys=usg5-2
604 ;;
606 ## Plexus
607 m68*-plexus-sysv* )
608 machine=plexus opsys=usg5-2
609 ;;
611 ## Pyramid machines
612 ## I don't really have any idea what sort of processor the Pyramid has,
613 ## so I'm assuming it is its own architecture.
614 pyramid-pyramid-bsd* )
615 machine=pyramid opsys=bsd4-2
616 ;;
618 ## Sequent Balance
619 ns32k-sequent-bsd4.2* )
620 machine=sequent opsys=bsd4-2
621 ;;
622 ns32k-sequent-bsd4.3* )
623 machine=sequent opsys=bsd4-3
624 ;;
626 ## Siemens Nixdorf
627 mips-siemens-sysv* | mips-sni-sysv*)
628 machine=mips-siemens opsys=usg5-4
629 NON_GNU_CC=/usr/ccs/bin/cc
630 NON_GNU_CPP=/usr/ccs/lib/cpp
631 ;;
633 ## Silicon Graphics machines
634 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
635 m68*-sgi-iris3.5* )
636 machine=irist opsys=iris3-5
637 ;;
638 m68*-sgi-iris3.6* | m68*-sgi-iris*)
639 machine=irist opsys=iris3-6
640 ;;
641 ## Iris 4D
642 mips-sgi-irix3* )
643 machine=iris4d opsys=irix3-3
644 ;;
645 mips-sgi-irix4* )
646 machine=iris4d opsys=irix4-0
647 ;;
648 mips-sgi-irix6* )
649 machine=iris4d opsys=irix6-0 NON_GNU_CPP=/lib/cpp
650 ;;
651 mips-sgi-irix5.[01]* )
652 machine=iris4d opsys=irix5-0
653 ;;
654 mips-sgi-irix5* | mips-sgi-irix* )
655 machine=iris4d opsys=irix5-2
656 ;;
658 ## SONY machines
659 m68*-sony-bsd4.2* )
660 machine=news opsys=bsd4-2
661 ;;
662 m68*-sony-bsd4.3* )
663 machine=news opsys=bsd4-3
664 ;;
665 m68*-sony-newsos3* | m68*-sony-news3*)
666 machine=news opsys=bsd4-3
667 ;;
668 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
669 machine=news-risc opsys=bsd4-3
670 ;;
671 mips-sony-news* )
672 machine=news-risc opsys=newsos5
673 ;;
675 ## Stride
676 m68*-stride-sysv* )
677 machine=stride opsys=usg5-2
678 ;;
680 ## Suns
681 sparc-*-linux* | sparc-*-lignux* )
682 machine=sparc opsys=lignux
683 ;;
685 *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
686 | i[345]86-*-solaris2* | i[345]86-*-sunos5* | powerpc*-*-solaris2* \
687 | rs6000-*-solaris2*)
688 case "${canonical}" in
689 m68*-sunos1* ) machine=sun1 ;;
690 m68*-sunos2* ) machine=sun2 ;;
691 m68* ) machine=sun3 ;;
692 i[345]86-sun-sunos[34]* ) machine=sun386 ;;
693 i[345]86-*-* ) machine=intel386 ;;
694 powerpc* | rs6000* ) machine=rs6000 ;;
695 sparc* ) machine=sparc ;;
696 * ) unported=yes ;;
697 esac
698 case "${canonical}" in
699 ## The Sun386 didn't get past 4.0.
700 i[345]86-*-sunos4 ) opsys=sunos4-0 ;;
701 *-sunos4.0* ) opsys=sunos4-0 ;;
702 *-sunos4.1.[3-9]* | *-sunos4shr*)
703 opsys=sunos4shr
704 NON_GNU_CPP=/usr/lib/cpp
705 ;;
706 *-sunos4.1.[3-9]*-noshare )
707 opsys=sunos4-1-3
708 NON_GNU_CPP=/usr/lib/cpp
709 NON_GCC_TEST_OPTIONS=-Bstatic
710 GCC_TEST_OPTIONS=-static
711 ;;
712 *-sunos4* | *-sunos )
713 opsys=sunos4-1
714 NON_GCC_TEST_OPTIONS=-Bstatic
715 GCC_TEST_OPTIONS=-static
716 ;;
717 *-sunos5.3* | *-solaris2.3* )
718 opsys=sol2-3
719 NON_GNU_CPP=/usr/ccs/lib/cpp
720 ;;
721 *-sunos5.4* | *-solaris2.4* )
722 opsys=sol2-4
723 NON_GNU_CPP=/usr/ccs/lib/cpp
724 RANLIB="ar -ts"
725 ;;
726 *-sunos5.5* | *-solaris2.5* )
727 opsys=sol2-5
728 NON_GNU_CPP=/usr/ccs/lib/cpp
729 RANLIB="ar -ts"
730 ;;
731 *-sunos5* | *-solaris* )
732 opsys=sol2-4
733 NON_GNU_CPP=/usr/ccs/lib/cpp
734 ;;
735 * ) opsys=bsd4-2 ;;
736 esac
737 ## Watch out for a compiler that we know will not work.
738 case "${canonical}" in
739 *-solaris* | *-sunos5* )
740 if [ "x$CC" = x/usr/ucb/cc ]; then
741 ## /usr/ucb/cc doesn't work;
742 ## we should find some other compiler that does work.
743 unset CC
744 fi
745 ;;
746 *) ;;
747 esac
748 ;;
749 sparc-*-nextstep* )
750 machine=sparc opsys=nextstep
751 ;;
753 ## Tadpole 68k
754 m68*-tadpole-sysv* )
755 machine=tad68k opsys=usg5-3
756 ;;
758 ## Tahoe machines
759 tahoe-tahoe-bsd4.2* )
760 machine=tahoe opsys=bsd4-2
761 ;;
762 tahoe-tahoe-bsd4.3* )
763 machine=tahoe opsys=bsd4-3
764 ;;
766 ## Tandem Integrity S2
767 mips-tandem-sysv* )
768 machine=tandem-s2 opsys=usg5-3
769 ;;
771 ## Tektronix XD88
772 m88k-tektronix-sysv3* )
773 machine=tekxd88 opsys=usg5-3
774 ;;
776 ## Tektronix 16000 box (6130?)
777 ns16k-tektronix-bsd* )
778 machine=ns16000 opsys=bsd4-2
779 ;;
780 ## Tektronix 4300
781 ## src/m/tek4300.h hints that this is a m68k machine.
782 m68*-tektronix-bsd* )
783 machine=tek4300 opsys=bsd4-3
784 ;;
786 ## Titan P2 or P3
787 ## We seem to have lost the machine-description file titan.h!
788 titan-titan-sysv* )
789 machine=titan opsys=usg5-3
790 ;;
792 ## Ustation E30 (SS5E)
793 m68*-unisys-uniplus* )
794 machine=ustation opsystem=unipl5-2
795 ;;
797 ## Vaxen.
798 vax-dec-* )
799 machine=vax
800 case "${canonical}" in
801 *-bsd4.1* ) opsys=bsd4-1 ;;
802 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
803 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
804 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
805 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
806 *-vms* ) opsys=vms ;;
807 * ) unported=yes
808 esac
809 ;;
811 ## Whitechapel MG1
812 ns16k-whitechapel-* )
813 machine=mg1
814 ## We don't know what sort of OS runs on these; we'll let the
815 ## operating system guessing code below try.
816 ;;
818 ## Wicat
819 m68*-wicat-sysv* )
820 machine=wicat opsys=usg5-2
821 ;;
823 ## Intel 386 machines where we don't care about the manufacturer
824 i[345]86-*-* )
825 machine=intel386
826 case "${canonical}" in
827 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
828 *-isc2.2* ) opsys=isc2-2 ;;
829 *-isc4.0* ) opsys=isc4-0 ;;
830 *-isc4.* ) opsys=isc4-1
831 GCC_TEST_OPTIONS=-posix
832 NON_GCC_TEST_OPTIONS=-Xp
833 ;;
834 *-isc* ) opsys=isc3-0 ;;
835 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
836 *-esix* ) opsys=esix ;;
837 *-xenix* ) opsys=xenix ;;
838 *-linux* | *-lignux* ) opsys=lignux ;;
839 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
840 *-bsd386* | *-bsdi1* ) opsys=bsd386 ;;
841 *-bsdi2* ) opsys=bsdos2 ;;
842 *-386bsd* ) opsys=386bsd ;;
843 *-freebsd* ) opsys=freebsd ;;
844 *-nextstep* ) opsys=nextstep ;;
845 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
846 esac
847 ;;
849 ## Lignux/68k
850 m68k-*-linux* | m68k-*-lignux* )
851 machine=m68k opsys=lignux
852 ;;
854 * )
855 unported=yes
856 ;;
857 esac
859 ### If the code above didn't choose an operating system, just choose
860 ### an operating system based on the configuration name. You really
861 ### only want to use this when you have no idea what the right
862 ### operating system is; if you know what operating systems a machine
863 ### runs, it's cleaner to make it explicit in the case statement
864 ### above.
865 if test x"${opsys}" = x; then
866 case "${canonical}" in
867 *-gnu* ) opsys=gnu ;;
868 *-bsd4.[01] ) opsys=bsd4-1 ;;
869 *-bsd4.2 ) opsys=bsd4-2 ;;
870 *-bsd4.3 ) opsys=bsd4-3 ;;
871 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
872 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
873 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
874 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
875 *-sysv4.1* | *-sysvr4.1* )
876 NON_GNU_CPP=/usr/lib/cpp
877 opsys=usg5-4 ;;
878 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
879 if [ x$NON_GNU_CPP = x ]; then
880 if [ -f /usr/ccs/lib/cpp ]; then
881 NON_GNU_CPP=/usr/ccs/lib/cpp
882 else
883 NON_GNU_CPP=/lib/cpp
884 fi
885 fi
886 opsys=usg5-4-2 ;;
887 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
888 * )
889 unported=yes
890 ;;
891 esac
892 fi
894 if test "x$RANLIB" = x; then
895 RANLIB=ranlib
896 fi
898 changequote([, ])dnl
900 if test $unported = yes; then
901 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
902 Check \`etc/MACHINES' for recognized configuration names.])
903 fi
905 machfile="m/${machine}.h"
906 opsysfile="s/${opsys}.h"
909 #### Choose a compiler.
910 test -n "$CC" && cc_specified=yes
912 # Save the value of CFLAGS that the user specified.
913 SPECIFIED_CFLAGS="$CFLAGS"
915 case ${with_gcc} in
916 "yes" ) CC="gcc" GCC=yes ;;
917 "no" ) : ${CC=cc} ;;
918 * ) AC_PROG_CC
919 esac
921 # On Suns, sometimes $CPP names a directory.
922 if test -n "$CPP" && test -d "$CPP"; then
923 CPP=
924 fi
926 #### Some systems specify a CPP to use unless we are using GCC.
927 #### Now that we know whether we are using GCC, we can decide whether
928 #### to use that one.
929 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
930 then
931 CPP="$NON_GNU_CPP"
932 fi
934 #### Some systems specify a CC to use unless we are using GCC.
935 #### Now that we know whether we are using GCC, we can decide whether
936 #### to use that one.
937 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
938 test x$cc_specified != xyes
939 then
940 CC="$NON_GNU_CC"
941 fi
943 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
944 then
945 CC="$CC $GCC_TEST_OPTIONS"
946 fi
948 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
949 then
950 CC="$CC $NON_GCC_TEST_OPTIONS"
951 fi
953 #### Some other nice autoconf tests. If you add a test here which
954 #### should make an entry in src/config.h, don't forget to add an
955 #### #undef clause to src/config.h.in for autoconf to modify.
957 dnl checks for programs
958 AC_PROG_LN_S
959 AC_PROG_CPP
960 AC_PROG_INSTALL
961 AC_PROG_YACC
963 dnl checks for Unix variants
964 AC_AIX
966 dnl checks for header files
967 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h linux/version.h)
968 AC_HEADER_STDC
969 AC_HEADER_TIME
970 AC_DECL_SYS_SIGLIST
972 dnl Some systems have utime.h but don't declare the struct anyplace.
973 AC_MSG_CHECKING(for struct utimbuf)
974 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
975 #include <sys/time.h>
976 #include <time.h>
977 #else
978 #ifdef HAVE_SYS_TIME_H
979 #include <sys/time.h>
980 #else
981 #include <time.h>
982 #endif
983 #endif
984 #ifdef HAVE_UTIME_H
985 #include <utime.h>
986 #endif], [static struct utimbuf x; x.actime = x.modtime;],
987 [AC_MSG_RESULT(yes)
988 AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
989 AC_MSG_RESULT(no))
991 dnl checks for typedefs
992 AC_TYPE_SIGNAL
994 AC_MSG_CHECKING(for struct timeval)
995 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
996 #include <sys/time.h>
997 #include <time.h>
998 #else
999 #ifdef HAVE_SYS_TIME_H
1000 #include <sys/time.h>
1001 #else
1002 #include <time.h>
1003 #endif
1004 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1005 [AC_MSG_RESULT(yes)
1006 HAVE_TIMEVAL=yes
1007 AC_DEFINE(HAVE_TIMEVAL)],
1008 [AC_MSG_RESULT(no)
1009 HAVE_TIMEVAL=no])
1011 dnl checks for structure members
1012 AC_STRUCT_TM
1013 AC_STRUCT_TIMEZONE
1015 dnl checks for compiler characteristics
1016 AC_C_CONST
1018 dnl check for Make feature
1019 AC_PROG_MAKE_SET
1021 dnl checks for operating system services
1022 AC_SYS_LONG_FILE_NAMES
1024 #### Choose a window system.
1026 AC_PATH_X
1027 if test "$no_x" = yes; then
1028 window_system=none
1029 else
1030 window_system=x11
1031 fi
1033 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1034 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1035 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1036 fi
1037 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1038 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1039 fi
1041 if test x"${x_includes}" = x; then
1042 bitmapdir=/usr/include/X11/bitmaps
1043 else
1044 # accumulate include directories that have X11 bitmap subdirectories
1045 bmd_acc="dummyval"
1046 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1047 if test -d "${bmd}/X11/bitmaps"; then
1048 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1049 elif test -d "${bmd}/bitmaps"; then
1050 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1051 fi
1052 done
1053 if test ${bmd_acc} != "dummyval"; then
1054 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1055 fi
1056 fi
1058 case "${window_system}" in
1059 x11 )
1060 HAVE_X_WINDOWS=yes
1061 HAVE_X11=yes
1062 case "${with_x_toolkit}" in
1063 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1064 motif ) USE_X_TOOLKIT=MOTIF ;;
1065 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1066 no ) USE_X_TOOLKIT=none ;;
1067 dnl If user did not say whether to use a toolkit,
1068 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1069 * ) USE_X_TOOLKIT=maybe ;;
1070 esac
1071 ;;
1072 none )
1073 HAVE_X_WINDOWS=no
1074 HAVE_X11=no
1075 USE_X_TOOLKIT=none
1076 ;;
1077 esac
1079 ### If we're using X11, we should use the X menu package.
1080 HAVE_MENUS=no
1081 case ${HAVE_X11} in
1082 yes ) HAVE_MENUS=yes ;;
1083 esac
1085 if test "${opsys}" = "hpux9"; then
1086 case "${x_libraries}" in
1087 *X11R4* )
1088 opsysfile="s/hpux9-x11r4.h"
1089 ;;
1090 esac
1091 fi
1093 if test "${opsys}" = "hpux9shr"; then
1094 case "${x_libraries}" in
1095 *X11R4* )
1096 opsysfile="s/hpux9shxr4.h"
1097 ;;
1098 esac
1099 fi
1101 #### Extract some information from the operating system and machine files.
1103 AC_CHECKING([the machine- and system-dependent files to find out
1104 - which libraries the lib-src programs will want, and
1105 - whether the GNU malloc routines are usable])
1107 ### First figure out CFLAGS (which we use for running the compiler here)
1108 ### and REAL_CFLAGS (which we use for real compilation).
1109 ### The two are the same except on a few systems, where they are made
1110 ### different to work around various lossages. For example,
1111 ### GCC 2.5 on Lignux needs them to be different because it treats -g
1112 ### as implying static linking.
1114 ### If the CFLAGS env var is specified, we use that value
1115 ### instead of the default.
1117 ### It's not important that this name contain the PID; you can't run
1118 ### two configures in the same directory and have anything work
1119 ### anyway.
1120 tempcname="conftest.c"
1122 echo '
1123 #include "'${srcdir}'/src/'${opsysfile}'"
1124 #include "'${srcdir}'/src/'${machfile}'"
1125 #ifndef LIBS_MACHINE
1126 #define LIBS_MACHINE
1127 #endif
1128 #ifndef LIBS_SYSTEM
1129 #define LIBS_SYSTEM
1130 #endif
1131 #ifndef C_SWITCH_SYSTEM
1132 #define C_SWITCH_SYSTEM
1133 #endif
1134 #ifndef C_SWITCH_MACHINE
1135 #define C_SWITCH_MACHINE
1136 #endif
1137 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1138 configure___ c_switch_system=C_SWITCH_SYSTEM
1139 configure___ c_switch_machine=C_SWITCH_MACHINE
1141 #ifndef LIB_X11_LIB
1142 #define LIB_X11_LIB -lX11
1143 #endif
1145 #ifndef LIBX11_MACHINE
1146 #define LIBX11_MACHINE
1147 #endif
1149 #ifndef LIBX11_SYSTEM
1150 #define LIBX11_SYSTEM
1151 #endif
1152 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1154 #ifdef UNEXEC
1155 configure___ unexec=UNEXEC
1156 #else
1157 configure___ unexec=unexec.o
1158 #endif
1160 #ifdef SYSTEM_MALLOC
1161 configure___ system_malloc=yes
1162 #else
1163 configure___ system_malloc=no
1164 #endif
1166 #ifndef C_DEBUG_SWITCH
1167 #define C_DEBUG_SWITCH -g
1168 #endif
1170 #ifndef C_OPTIMIZE_SWITCH
1171 #define C_OPTIMIZE_SWITCH -O
1172 #endif
1174 #ifdef THIS_IS_CONFIGURE
1176 /* Get the CFLAGS for tests in configure. */
1177 #ifdef __GNUC__
1178 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1179 #else
1180 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1181 #endif
1183 #else /* not THIS_IS_CONFIGURE */
1185 /* Get the CFLAGS for real compilation. */
1186 #ifdef __GNUC__
1187 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1188 #else
1189 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1190 #endif
1192 #endif /* not THIS_IS_CONFIGURE */
1193 ' > ${tempcname}
1195 # The value of CPP is a quoted variable reference, so we need to do this
1196 # to get its actual value...
1197 CPP=`eval "echo $CPP"`
1198 changequote(, )dnl
1199 eval `${CPP} -Isrc ${tempcname} \
1200 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1201 if test "x$SPECIFIED_CFLAGS" = x; then
1202 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1203 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1204 else
1205 REAL_CFLAGS="$CFLAGS"
1206 fi
1207 changequote([, ])dnl
1208 rm ${tempcname}
1210 ### Compute the unexec source name from the object name.
1211 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1213 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1214 # Assume not, until told otherwise.
1215 GNU_MALLOC=yes
1216 if test "${system_malloc}" = "yes"; then
1217 GNU_MALLOC=no
1218 GNU_MALLOC_reason="
1219 (The GNU allocators don't work with this system configuration.)"
1220 fi
1222 if test x"${REL_ALLOC}" = x; then
1223 REL_ALLOC=${GNU_MALLOC}
1224 fi
1226 LISP_FLOAT_TYPE=yes
1229 #### Add the libraries to LIBS and check for some functions.
1231 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1232 LIBS="$libsrc_libs $LIBS"
1234 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1235 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1236 AC_CHECK_LIB(dnet, dnet_ntoa)
1237 dnl This causes -lresolv to get used in subsequent tests,
1238 dnl which causes failures on some systems such as HPUX 9.
1239 dnl AC_CHECK_LIB(resolv, gethostbyname)
1241 dnl FIXME replace main with a function we actually want from this library.
1242 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1244 AC_CHECK_LIB(pthreads, cma_open)
1246 AC_MSG_CHECKING(for XFree86)
1247 if test -d /usr/X386/include; then
1248 HAVE_XFREE386=yes
1249 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1250 else
1251 HAVE_XFREE386=no
1252 fi
1253 AC_MSG_RESULT($HAVE_XFREE386)
1255 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1256 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1258 if test "${HAVE_X11}" = "yes"; then
1259 DEFS="$C_SWITCH_X_SITE $DEFS"
1260 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1261 LIBS="$LIBX $LIBS"
1262 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1264 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1265 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1266 # but it's more convenient here to set LD_RUN_PATH
1267 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1268 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1269 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1270 export LD_RUN_PATH
1271 fi
1273 if test "${opsys}" = "lignux"; then
1274 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1275 AC_TRY_LINK([],
1276 [XOpenDisplay ("foo");],
1277 [xlinux_first_failure=no],
1278 [xlinux_first_failure=yes])
1279 if test "${xlinux_first_failure}" = "yes"; then
1280 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1281 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1282 OLD_CPPFLAGS="$CPPFLAGS"
1283 OLD_LIBS="$LIBS"
1284 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1285 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1286 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1287 LIBS="$LIBS -b i486-linuxaout"
1288 AC_TRY_LINK([],
1289 [XOpenDisplay ("foo");],
1290 [xlinux_second_failure=no],
1291 [xlinux_second_failure=yes])
1292 if test "${xlinux_second_failure}" = "yes"; then
1293 # If we get the same failure with -b, there is no use adding -b.
1294 # So take it out. This plays safe.
1295 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1296 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1297 CPPFLAGS="$OLD_CPPFLAGS"
1298 LIBS="$OLD_LIBS"
1299 AC_MSG_RESULT(no)
1300 else
1301 AC_MSG_RESULT(yes)
1302 fi
1303 else
1304 AC_MSG_RESULT(no)
1305 fi
1306 fi
1308 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1309 XScreenNumberOfScreen XSetWMProtocols)
1310 fi
1312 if test "${window_system}" = "x11"; then
1313 AC_MSG_CHECKING(X11 version 6)
1314 AC_TRY_LINK([#include <X11/Xlib.h>],
1315 [#if XlibSpecificationRelease < 6
1316 fail;
1317 #endif
1318 ], [AC_MSG_RESULT(6 or newer)
1319 AC_DEFINE(HAVE_X11R6)],
1320 [AC_MSG_RESULT(before 6)])
1321 fi
1323 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1324 AC_MSG_CHECKING(X11 version 5)
1325 AC_TRY_LINK([#include <X11/Xlib.h>],
1326 [#if XlibSpecificationRelease < 5
1327 fail;
1328 #endif
1329 ], [AC_MSG_RESULT(5 or newer; use toolkit by default)
1330 USE_X_TOOLKIT=LUCID
1331 AC_DEFINE(HAVE_X11R5)],
1332 [AC_MSG_RESULT(before 5; do not use toolkit by default)
1333 USE_X_TOOLKIT=none])
1334 fi
1336 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1338 if test "${USE_X_TOOLKIT}" != "none"; then
1339 AC_MSG_CHECKING(X11 toolkit version)
1340 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1341 [#if XtSpecificationRelease < 6
1342 fail;
1343 #endif
1344 ], [AC_MSG_RESULT(6 or newer)
1345 HAVE_X11XTR6=yes
1346 AC_DEFINE(HAVE_X11XTR6)],
1347 [AC_MSG_RESULT(before 6)
1348 HAVE_X11XTR6=no])
1350 dnl If using toolkit, check whether libXmu.a exists.
1351 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1352 OLDLIBS="$LIBS"
1353 if test x$HAVE_X11XTR6 = xyes; then
1354 LIBS="-lXt -lSM -lICE $LIBS"
1355 else
1356 LIBS="-lXt $LIBS"
1357 fi
1358 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1359 LIBS="$OLDLIBS"
1360 fi
1362 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1363 AC_MSG_CHECKING(whether netdb declares h_errno)
1364 AC_TRY_LINK([#include <netdb.h>],
1365 [return h_errno;],
1366 [AC_MSG_RESULT(yes)
1367 AC_DEFINE(HAVE_H_ERRNO)],
1368 [AC_MSG_RESULT(no)])
1370 AC_FUNC_ALLOCA
1372 # fmod, logb, and frexp are found in -lm on most systems.
1373 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1374 AC_CHECK_LIB(m, sqrt)
1376 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1377 random lrand48 bcopy bcmp logb frexp fmod ftime res_init setsid \
1378 strerror fpathconf select mktime eaccess getpagesize tzset setlocale)
1380 # Check this now, so that we will NOT find the above functions in ncurses.
1381 # That is because we have not set up to link ncurses in lib-src.
1382 # It's better to believe a function is not available
1383 # than to expect to find it in ncurses.
1384 AC_CHECK_LIB(ncurses, tparm)
1386 AC_MSG_CHECKING(whether localtime caches TZ)
1387 AC_CACHE_VAL(emacs_cv_localtime_cache,
1388 [if test x$ac_cv_func_tzset = xyes; then
1389 AC_TRY_RUN([#include <time.h>
1390 #if STDC_HEADERS
1391 # include <stdlib.h>
1392 #endif
1393 extern char **environ;
1394 unset_TZ ()
1395 {
1396 char **from, **to;
1397 for (to = from = environ; (*to = *from); from++)
1398 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1399 to++;
1400 }
1401 main()
1402 {
1403 time_t now = time ((time_t *) 0);
1404 int hour_GMT0, hour_unset;
1405 if (putenv ("TZ=GMT0") != 0)
1406 exit (1);
1407 hour_GMT0 = localtime (&now)->tm_hour;
1408 unset_TZ ();
1409 hour_unset = localtime (&now)->tm_hour;
1410 if (putenv ("TZ=PST8") != 0)
1411 exit (1);
1412 if (localtime (&now)->tm_hour == hour_GMT0)
1413 exit (1);
1414 unset_TZ ();
1415 if (localtime (&now)->tm_hour != hour_unset)
1416 exit (1);
1417 exit (0);
1418 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1419 [# If we have tzset, assume the worst when cross-compiling.
1420 emacs_cv_localtime_cache=yes])
1421 else
1422 # If we lack tzset, report that localtime does not cache TZ,
1423 # since we can't invalidate the cache if we don't have tzset.
1424 emacs_cv_localtime_cache=no
1425 fi])dnl
1426 AC_MSG_RESULT($emacs_cv_localtime_cache)
1427 if test $emacs_cv_localtime_cache = yes; then
1428 AC_DEFINE(LOCALTIME_CACHE)
1429 fi
1431 if test "x$HAVE_TIMEVAL" = xyes; then
1432 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1433 AC_TRY_LINK([
1434 #ifdef TIME_WITH_SYS_TIME
1435 #include <sys/time.h>
1436 #include <time.h>
1437 #else
1438 #ifdef HAVE_SYS_TIME_H
1439 #include <sys/time.h>
1440 #else
1441 #include <time.h>
1442 #endif
1443 #endif
1444 ],
1445 [
1446 struct timeval time;
1447 struct timezone dummy;
1448 gettimeofday (&time, &dummy);
1449 ],
1450 [AC_MSG_RESULT(no)],
1451 [AC_MSG_RESULT(yes)
1452 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1453 fi
1455 ok_so_far=yes
1456 AC_CHECK_FUNC(socket, , ok_so_far=no)
1457 if test $ok_so_far = yes; then
1458 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1459 fi
1460 if test $ok_so_far = yes; then
1461 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1462 fi
1463 if test $ok_so_far = yes; then
1464 AC_DEFINE(HAVE_INET_SOCKETS)
1465 fi
1467 if test -f /usr/lpp/X11/bin/smt.exp; then
1468 AC_DEFINE(HAVE_AIX_SMT_EXP)
1469 fi
1471 # Set up the CFLAGS for real compilation, so we can substitute it.
1472 CFLAGS="$REAL_CFLAGS"
1474 changequote(, )dnl
1475 #### Find out which version of Emacs this is.
1476 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
1477 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1478 changequote([, ])dnl
1479 if test x"${version}" = x; then
1480 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1481 fi
1483 ### Specify what sort of things we'll be editing into Makefile and config.h.
1484 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1485 AC_SUBST(version)
1486 AC_SUBST(configuration)
1487 AC_SUBST(canonical)
1488 AC_SUBST(srcdir)
1489 AC_SUBST(prefix)
1490 AC_SUBST(exec_prefix)
1491 AC_SUBST(bindir)
1492 AC_SUBST(datadir)
1493 AC_SUBST(sharedstatedir)
1494 AC_SUBST(libexecdir)
1495 AC_SUBST(mandir)
1496 AC_SUBST(infodir)
1497 AC_SUBST(lispdir)
1498 AC_SUBST(locallisppath)
1499 AC_SUBST(lisppath)
1500 AC_SUBST(etcdir)
1501 AC_SUBST(lockdir)
1502 AC_SUBST(archlibdir)
1503 AC_SUBST(docdir)
1504 AC_SUBST(bitmapdir)
1505 AC_SUBST(c_switch_system)
1506 AC_SUBST(c_switch_machine)
1507 AC_SUBST(LD_SWITCH_X_SITE)
1508 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1509 AC_SUBST(C_SWITCH_X_SITE)
1510 AC_SUBST(CFLAGS)
1511 AC_SUBST(X_TOOLKIT_TYPE)
1512 AC_SUBST(machfile)
1513 AC_SUBST(opsysfile)
1514 AC_SUBST(RANLIB)
1516 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
1517 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1518 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
1519 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1520 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1521 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1522 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
1523 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
1525 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1526 AC_DEFINE(HAVE_X_WINDOWS)
1527 fi
1528 if test "${USE_X_TOOLKIT}" != "none" ; then
1529 AC_DEFINE(USE_X_TOOLKIT)
1530 fi
1531 if test "${HAVE_X11}" = "yes" ; then
1532 AC_DEFINE(HAVE_X11)
1533 fi
1534 if test "${HAVE_XFREE386}" = "yes" ; then
1535 AC_DEFINE(HAVE_XFREE386)
1536 fi
1537 if test "${HAVE_MENUS}" = "yes" ; then
1538 AC_DEFINE(HAVE_MENUS)
1539 fi
1540 if test "${GNU_MALLOC}" = "yes" ; then
1541 AC_DEFINE(GNU_MALLOC)
1542 fi
1543 if test "${REL_ALLOC}" = "yes" ; then
1544 AC_DEFINE(REL_ALLOC)
1545 fi
1546 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1547 AC_DEFINE(LISP_FLOAT_TYPE)
1548 fi
1550 #### Report on what we decided to do.
1551 echo "
1552 Configured for \`${canonical}'.
1554 Where should the build process find the source code? ${srcdir}
1555 What operating system and machine description files should Emacs use?
1556 \`${opsysfile}' and \`${machfile}'
1557 What compiler should emacs be built with? ${CC} ${CFLAGS}
1558 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
1559 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
1560 What window system should Emacs use? ${window_system}
1561 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
1563 if test -n "${x_includes}"; then
1564 echo " Where do we find X Windows header files? ${x_includes}"
1565 else
1566 echo " Where do we find X Windows header files? Standard dirs"
1567 fi
1568 if test -n "${x_libraries}"; then
1569 echo " Where do we find X Windows libraries? ${x_libraries}"
1570 else
1571 echo " Where do we find X Windows libraries? Standard dirs"
1572 fi
1574 echo
1576 # Remove any trailing slashes in these variables.
1577 changequote(, )dnl
1578 test "${prefix}" != NONE &&
1579 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1580 test "${exec_prefix}" != NONE &&
1581 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1582 changequote([, ])dnl
1584 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1585 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1587 ### Make the necessary directories, if they don't exist.
1588 for dir in cpp etc ; do
1589 test -d ${dir} || mkdir ${dir}
1590 done
1592 # Build src/Makefile from ${srcdir}/src/Makefile.c
1593 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1594 # This must be done after src/config.h is built, since we rely on that file.
1596 changequote(, )dnl The horror, the horror.
1597 # Now get this: Some word that is part of the ${srcdir} directory name
1598 # or the ${configuration} value might, just might, happen to be an
1599 # identifier like `sun4' or `i386' or something, and be predefined by
1600 # the C preprocessor to some helpful value like 1, or maybe the empty
1601 # string. Needless to say consequent macro substitutions are less
1602 # than conducive to the makefile finding the correct directory.
1603 undefs="`echo $top_srcdir $configuration $canonical |
1604 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
1605 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1606 `"
1607 changequote([, ])dnl
1609 echo creating lib-src/Makefile
1610 ( cd lib-src
1611 rm -f junk.c junk1.c junk2.c
1612 sed -e '/start of cpp stuff/q' \
1613 < Makefile.c > junk1.c
1614 sed -e '1,/start of cpp stuff/d'\
1615 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1616 < Makefile.c > junk.c
1617 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1618 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1619 cat junk1.c junk2.c > Makefile.new
1620 rm -f junk.c junk1.c junk2.c
1621 chmod 444 Makefile.new
1622 mv -f Makefile.new Makefile
1623 )
1625 echo creating src/Makefile
1626 ( cd src
1627 rm -f junk.c junk1.c junk2.c
1628 sed -e '/start of cpp stuff/q' \
1629 < Makefile.c > junk1.c
1630 sed -e '1,/start of cpp stuff/d'\
1631 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1632 < Makefile.c > junk.c
1633 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1634 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1635 cat junk1.c junk2.c > Makefile.new
1636 rm -f junk.c junk1.c junk2.c
1637 chmod 444 Makefile.new
1638 mv -f Makefile.new Makefile
1639 )
1641 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1642 echo creating src/.gdbinit
1643 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1644 fi
1646 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])