lisp/gnus/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2
   3 ;; Copyright (C) 1997-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (require 'gnus)
  28 (require 'gnus-sum)
  29 (require 'message)
  30 (require 'gnus-msg)
  31 (require 'nndraft)
  32 (require 'gnus-agent)
  33 (eval-when-compile (require 'cl))
  34 (eval-when-compile
  35   (when (featurep 'xemacs)
  36     (require 'easy-mmode))) ; for `define-minor-mode'
  37
  38 ;;; Draft minor mode
  39
  40 (defvar gnus-draft-mode-map
  41   (let ((map (make-sparse-keymap)))
  42     (gnus-define-keys map
  43      "Dt" gnus-draft-toggle-sending
  44      "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  45      "De" gnus-draft-edit-message
  46      "Ds" gnus-draft-send-message
  47      "DS" gnus-draft-send-all-messages)
  48     map))
  49
  50 (defun gnus-draft-make-menu-bar ()
  51   (unless (boundp 'gnus-draft-menu)
  52     (easy-menu-define
  53      gnus-draft-menu gnus-draft-mode-map ""
  54      '("Drafts"
  55        ["Toggle whether to send" gnus-draft-toggle-sending t]
  56        ["Edit" gnus-draft-edit-message t]
  57        ["Send selected message(s)" gnus-draft-send-message t]
  58        ["Send all messages" gnus-draft-send-all-messages t]
  59        ["Delete draft" gnus-summary-delete-article t]))))
  60
  61 (define-minor-mode gnus-draft-mode
  62   "Minor mode for providing a draft summary buffers.
  63
  64 \\{gnus-draft-mode-map}"
  65   :lighter " Draft" :keymap gnus-draft-mode-map
  66   (cond
  67    ((not (derived-mode-p 'gnus-summary-mode)) (setq gnus-draft-mode nil))
  68    (gnus-draft-mode
  69     ;; Set up the menu.
  70     (when (gnus-visual-p 'draft-menu 'menu)
  71       (gnus-draft-make-menu-bar))
  72     (add-hook 'gnus-summary-prepare-exit-hook 'gnus-draft-clear-marks t t))))
  73
  74 ;;; Commands
  75
  76 (defun gnus-draft-toggle-sending (article)
  77   "Toggle whether to send an article or not."
  78   (interactive (list (gnus-summary-article-number)))
  79   (if (gnus-draft-article-sendable-p article)
  80       (progn
  81         (push article gnus-newsgroup-unsendable)
  82         (gnus-summary-mark-article article gnus-unsendable-mark))
  83     (setq gnus-newsgroup-unsendable
  84           (delq article gnus-newsgroup-unsendable))
  85     (gnus-summary-mark-article article gnus-unread-mark))
  86   (gnus-summary-position-point))
  87
  88 (defun gnus-draft-edit-message ()
  89   "Enter a mail/post buffer to edit and send the draft."
  90   (interactive)
  91   (let ((article (gnus-summary-article-number))
  92         (group gnus-newsgroup-name))
  93     (gnus-draft-check-draft-articles (list article))
  94     (gnus-summary-mark-as-read article gnus-canceled-mark)
  95     (gnus-draft-setup article group t)
  96     (set-buffer-modified-p t)
  97     (save-excursion
  98       (save-restriction
  99         (message-narrow-to-headers)
 100         (message-remove-header "date")))
 101     (let ((message-draft-headers
 102            (delq 'Date (copy-sequence message-draft-headers))))
 103       (save-buffer))
 104     (let ((gnus-verbose-backends nil))
 105       (gnus-request-expire-articles (list article) group t))
 106     (push
 107      `((lambda ()
 108          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 109            (save-excursion
 110              (set-buffer ,gnus-summary-buffer)
 111              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 112      message-send-actions)))
 113
 114 (defun gnus-draft-send-message (&optional n)
 115   "Send the current draft(s).
 116 Obeys the standard process/prefix convention."
 117   (interactive "P")
 118   (let* ((articles (gnus-summary-work-articles n))
 119          (total (length articles))
 120          article)
 121     (gnus-draft-check-draft-articles articles)
 122     (while (setq article (pop articles))
 123       (gnus-summary-remove-process-mark article)
 124       (unless (memq article gnus-newsgroup-unsendable)
 125         (let ((message-sending-message
 126                (format "Sending message %d of %d..."
 127                        (- total (length articles)) total)))
 128           (gnus-draft-send article gnus-newsgroup-name t))
 129         (gnus-summary-mark-article article gnus-canceled-mark)))))
 130
 131 (defun gnus-draft-send (article &optional group interactive)
 132   "Send message ARTICLE."
 133   (let* ((is-queue (or (not group)
 134                        (equal group "nndraft:queue")))
 135          (message-syntax-checks (if interactive message-syntax-checks
 136                                   'dont-check-for-anything-just-trust-me))
 137          (message-hidden-headers nil)
 138          (message-inhibit-body-encoding (or is-queue
 139                                             message-inhibit-body-encoding))
 140          (message-send-hook (and (not is-queue)
 141                                  message-send-hook))
 142          (message-setup-hook (and (not is-queue)
 143                                   message-setup-hook))
 144          (gnus-message-setup-hook (and (not is-queue)
 145                                        gnus-message-setup-hook))
 146          (message-signature (and (not is-queue)
 147                                  message-signature))
 148          (gnus-agent-queue-mail (and (not is-queue)
 149                                      gnus-agent-queue-mail))
 150          (rfc2047-encode-encoded-words nil)
 151          type method move-to)
 152     (gnus-draft-setup article (or group "nndraft:queue") nil 'dont-pop)
 153     ;; We read the meta-information that says how and where
 154     ;; this message is to be sent.
 155     (save-restriction
 156       (message-narrow-to-headers)
 157       (when (re-search-forward
 158              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 159                      ":") nil t)
 160         (skip-syntax-forward "-")
 161         (setq move-to (buffer-substring (point) (point-at-eol)))
 162         (message-remove-header gnus-agent-target-move-group-header))
 163       (goto-char (point-min))
 164       (when (re-search-forward
 165              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 166              nil t)
 167         (setq type (ignore-errors (read (current-buffer)))
 168               method (ignore-errors (read (current-buffer))))
 169         (message-remove-header gnus-agent-meta-information-header)))
 170     ;; Let Agent restore any GCC lines and have message.el perform them.
 171     (gnus-agent-restore-gcc)
 172     ;; Then we send it.  If we have no meta-information, we just send
 173     ;; it and let Message figure out how.
 174     (when (and (or (null method)
 175                    (gnus-server-opened method)
 176                    (gnus-open-server method))
 177                (if type
 178                    (let ((message-this-is-news (eq type 'news))
 179                          (message-this-is-mail (eq type 'mail))
 180                          (gnus-post-method method)
 181                          (message-post-method method))
 182                      (if move-to
 183                          (gnus-inews-do-gcc move-to)
 184                        (message-send-and-exit)))
 185                  (if move-to
 186                      (gnus-inews-do-gcc move-to)
 187                    (message-send-and-exit))))
 188       (let ((gnus-verbose-backends nil))
 189         (gnus-request-expire-articles
 190          (list article) (or group "nndraft:queue") t)))))
 191
 192 (defun gnus-draft-send-all-messages ()
 193   "Send all the sendable drafts."
 194   (interactive)
 195   (when (or
 196          gnus-expert-user
 197          (gnus-y-or-n-p
 198           "Send all drafts? "))
 199     (gnus-uu-mark-buffer)
 200     (gnus-draft-send-message)))
 201
 202 (defun gnus-group-send-queue ()
 203   "Send all sendable articles from the queue group."
 204   (interactive)
 205   (when (or gnus-plugged
 206             (not gnus-agent-prompt-send-queue)
 207             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 208     (gnus-activate-group "nndraft:queue")
 209     (save-excursion
 210       (let* ((articles (nndraft-articles))
 211              (unsendable (gnus-uncompress-range
 212                           (cdr (assq 'unsend
 213                                      (gnus-info-marks
 214                                       (gnus-get-info "nndraft:queue"))))))
 215              (gnus-posting-styles nil)
 216              message-send-mail-partially-limit
 217              (total (length articles))
 218              article)
 219         (while (setq article (pop articles))
 220           (unless (memq article unsendable)
 221             (let ((message-sending-message
 222                    (format "Sending message %d of %d..."
 223                            (- total (length articles)) total)))
 224               (gnus-draft-send article))))))
 225     (gnus-group-refresh-group "nndraft:queue")))
 226
 227 ;;;###autoload
 228 (defun gnus-draft-reminder ()
 229   "Reminder user if there are unsent drafts."
 230   (interactive)
 231   (if (gnus-alive-p)
 232       (let (active)
 233         (catch 'continue
 234           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 235             (setq active (gnus-activate-group group))
 236             (if (and active (>= (cdr active) (car active)))
 237                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 238                     (throw 'continue t)
 239                   (error "Stop!"))))))))
 240
 241 (defcustom gnus-draft-setup-hook nil
 242   "Hook run after setting up a draft buffer."
 243   :group 'gnus-message
 244   :version "23.1" ;; No Gnus
 245   :type 'hook)
 246
 247
 248 (defun gnus-draft-setup (narticle group &optional restore dont-pop)
 249   "Setup a mail draft buffer.
 250 If DONT-POP is nil, display the buffer after setting it up."
 251   (let (ga)
 252     (gnus-setup-message 'forward
 253       (let ((article narticle))
 254         (message-mail nil nil nil nil
 255                       (if dont-pop
 256                           (lambda (buf) (set-buffer (get-buffer-create buf)))))
 257         (let ((inhibit-read-only t))
 258           (erase-buffer))
 259         (if (not (gnus-request-restore-buffer article group))
 260             (error "Couldn't restore the article")
 261           (when (and restore
 262                      (equal group "nndraft:queue"))
 263             (mime-to-mml))
 264           ;; Insert the separator.
 265           (goto-char (point-min))
 266           (search-forward "\n\n")
 267           (forward-char -1)
 268           (save-restriction
 269             (narrow-to-region (point-min) (point))
 270             (setq ga
 271                   (message-fetch-field gnus-draft-meta-information-header)))
 272           (insert mail-header-separator)
 273           (forward-line 1)
 274           (message-set-auto-save-file-name))))
 275     (gnus-backlog-remove-article group narticle)
 276     (when (and ga
 277                (ignore-errors (setq ga (car (read-from-string ga)))))
 278       (setq gnus-newsgroup-name
 279             (if (equal (car ga) "") nil (car ga)))
 280       (gnus-configure-posting-styles)
 281       (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 282       (setq message-post-method
 283             `(lambda (arg)
 284                (gnus-post-method arg ,(car ga))))
 285       (unless (equal (cadr ga) "")
 286         (dolist (article (cdr ga))
 287           (message-add-action
 288            `(progn
 289               (gnus-add-mark ,(car ga) 'replied ,article)
 290               (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 291                                                            'add '(reply)))))
 292            'send))))
 293     (run-hooks 'gnus-draft-setup-hook)))
 294
 295 (defun gnus-draft-article-sendable-p (article)
 296   "Say whether ARTICLE is sendable."
 297   (not (memq article gnus-newsgroup-unsendable)))
 298
 299 (defun gnus-draft-check-draft-articles (articles)
 300   "Check whether the draft articles ARTICLES are under edit."
 301   (when (equal gnus-newsgroup-name "nndraft:drafts")
 302     (let ((buffers (buffer-list))
 303           file buffs buff)
 304       (save-current-buffer
 305         (while (and articles
 306                     (not buff))
 307           (setq file (nndraft-article-filename (pop articles))
 308                 buffs buffers)
 309           (while buffs
 310             (set-buffer (setq buff (pop buffs)))
 311             (if (and buffer-file-name
 312                      (equal (file-remote-p file)
 313                             (file-remote-p buffer-file-name))
 314                      (string-equal (file-truename buffer-file-name)
 315                                    (file-truename file))
 316                      (buffer-modified-p))
 317                 (setq buffs nil)
 318               (setq buff nil)))))
 319       (when buff
 320         (let* ((window (get-buffer-window buff t))
 321                (frame (and window (window-frame window))))
 322           (if frame
 323               (gnus-select-frame-set-input-focus frame)
 324             (pop-to-buffer buff t)))
 325         (error "The draft %s is under edit" file)))))
 326
 327 (defun gnus-draft-clear-marks ()
 328   (setq gnus-newsgroup-reads nil
 329         gnus-newsgroup-marked nil
 330         gnus-newsgroup-unreads (nndraft-articles)))
 331
 332 (provide 'gnus-draft)
 333
 334 ;;; gnus-draft.el ends here