lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- Support the mouse when emacs run in an xterm.
   2
   3 ;; Copyright (C) 1994, 2000 Free Software Foundation
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: mouse, terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Enable mouse support when running inside an xterm or Linux console.
  28
  29 ;; This is actually useful when you are running X11 locally, but is
  30 ;; working on remote machine over a modem line or through a gateway.
  31
  32 ;; It works by translating xterm escape codes into generic emacs mouse
  33 ;; events so it should work with any package that uses the mouse.
  34
  35 ;; The xterm mouse escape codes are supposedly also supported by the
  36 ;; Linux console, but I have not been able to verify this.
  37
  38 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  39 ;; functionality, it is still available by holding down the SHIFT key
  40 ;; when you press the mouse button.
  41
  42 ;;; Todo:
  43
  44 ;; Support multi-click -- somehow.
  45
  46 ;; Clicking on the mode-line does not work, although it should.
  47
  48 ;;; Code:
  49
  50 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  51
  52 (defvar xterm-mouse-last)
  53
  54 (defun xterm-mouse-translate (event)
  55   "Read a click and release event from XTerm."
  56   (save-excursion
  57     (save-window-excursion
  58       (deactivate-mark)
  59       (let* ((xterm-mouse-last)
  60              (down (xterm-mouse-event))
  61              (down-command (nth 0 down))
  62              (down-data (nth 1 down))
  63              (down-where (nth 1 down-data))
  64              (down-binding (key-binding (if (symbolp down-where)
  65                                             (vector down-where down-command)
  66                                           (vector down-command)))))
  67         (or (and (eq (read-char) ?\e)
  68                  (eq (read-char) ?\[)
  69                  (eq (read-char) ?M))
  70             (error "Unexpected escape sequence from XTerm"))
  71         (let* ((click (xterm-mouse-event))
  72                (click-command (nth 0 click))
  73                (click-data (nth 1 click))
  74                (click-where (nth 1 click-data)))
  75           (if (memq down-binding '(nil ignore))
  76               (if (and (symbolp click-where)
  77                        (not (eq 'menu-bar click-where)))
  78                   (vector (list click-where click-data) click)
  79                 (vector click))
  80             (setq unread-command-events
  81                   (if (eq down-where click-where)
  82                       (list click)
  83                     (list
  84                      ;; Cheat `mouse-drag-region' with move event.
  85                      (list 'mouse-movement click-data)
  86                      ;; Generate a drag event.
  87                      (if (symbolp down-where)
  88                          0
  89                        (list (intern (format "drag-mouse-%d"
  90                                              (+ 1 xterm-mouse-last)))
  91                              down-data click-data))
  92                      )))
  93             (if (and (symbolp down-where)
  94                      (not (eq 'menu-bar down-where)))
  95                 (vector (list down-where down-data) down)
  96               (vector down))))))))
  97
  98 (defvar xterm-mouse-x 0
  99   "Position of last xterm mouse event relative to the frame.")
 100
 101 (defvar xterm-mouse-y 0
 102   "Position of last xterm mouse event relative to the frame.")
 103
 104 ;; Indicator for the xterm-mouse mode.
 105 (defvar xterm-mouse-mode nil)
 106
 107 (defun xterm-mouse-position-function (pos)
 108   "Bound to `mouse-position-function' in XTerm mouse mode."
 109   (setcdr pos (cons xterm-mouse-x xterm-mouse-y))
 110   pos)
 111
 112 (defun xterm-mouse-event ()
 113   "Convert XTerm mouse event to Emacs mouse event."
 114   (let* ((type (- (read-char) ? ))
 115          (x (- (read-char) ?  1))
 116          (y (- (read-char) ?  1))
 117          (point (cons x y))
 118          (window (window-at x y))
 119          (where (if window
 120                     (coordinates-in-window-p point window)
 121                   'menu-bar))
 122          (pos (if (consp where)
 123                   (progn
 124                     (select-window window)
 125                     (goto-char (window-start window))
 126                     (move-to-window-line  (cdr where))
 127                     (move-to-column (+ (car where) (current-column)
 128                                        (if (string-match "\\` \\*Minibuf"
 129                                                          (buffer-name))
 130                                            (- (minibuffer-prompt-width))
 131                                          0)
 132                                        (max 0 (1- (window-hscroll)))))
 133                     (point))
 134                 where))
 135          (mouse (intern (if (eq type 3)
 136                             (format "mouse-%d" (+ 1 xterm-mouse-last))
 137                           (setq xterm-mouse-last type)
 138                           (format "down-mouse-%d" (+ 1 type))))))
 139     (setq xterm-mouse-x x
 140           xterm-mouse-y y)
 141     (list mouse
 142           (list window pos point
 143                 (/ (nth 2 (current-time)) 1000)))))
 144
 145 (or (assq 'xterm-mouse-mode minor-mode-alist)
 146     (setq minor-mode-alist
 147           (cons '(xterm-mouse-mode (" Mouse")) minor-mode-alist)))
 148
 149 ;;;###autoload
 150 (defun xterm-mouse-mode (arg)
 151   "Toggle XTerm mouse mode.
 152 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 153
 154 Turn it on to use emacs mouse commands, and off to use xterm mouse commands."
 155   (interactive "P")
 156   (if (or (and (null arg) xterm-mouse-mode)
 157           (<= (prefix-numeric-value arg) 0))
 158       ;; Turn it off
 159       (if xterm-mouse-mode
 160           (progn
 161             (turn-off-xterm-mouse-tracking)
 162             (setq xterm-mouse-mode nil
 163                   mouse-position-function nil)
 164             (set-buffer-modified-p (buffer-modified-p))))
 165     ;;Turn it on
 166     (unless (or window-system xterm-mouse-mode)
 167       (setq xterm-mouse-mode t
 168             mouse-position-function #'xterm-mouse-position-function)
 169       (turn-on-xterm-mouse-tracking)
 170       (set-buffer-modified-p (buffer-modified-p)))))
 171
 172 (defun turn-on-xterm-mouse-tracking ()
 173   "Enable Emacs mouse tracking in xterm."
 174   (if xterm-mouse-mode
 175       (send-string-to-terminal "\e[?1000h")))
 176
 177 (defun turn-off-xterm-mouse-tracking ()
 178   "Disable disable Emacs mouse tracking in xterm."
 179   (if xterm-mouse-mode
 180       (send-string-to-terminal "\e[?1000l")))
 181
 182 ;; Restore normal mouse behaviour outside Emacs.
 183 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 184 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 185 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 186
 187 (provide 'xt-mouse)
 188
 189 ;;; xt-mouse.el ends here