lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994-1996, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action `(lambda (&rest ignore)
  40               (widget-browse ',widget))
  41    'help-echo "mouse-2, RET: browse this widget")
  42   (insert " ")
  43   (insert-text-button
  44    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  45
  46 (defun describe-text-sexp (sexp)
  47   "Insert a short description of SEXP in the current buffer."
  48   (let ((pp (condition-case signal
  49                 (pp-to-string sexp)
  50               (error (prin1-to-string signal)))))
  51     (when (string-match-p "\n\\'" pp)
  52       (setq pp (substring pp 0 (1- (length pp)))))
  53
  54     (if (and (not (string-match-p "\n" pp))
  55              (<= (length pp) (- (window-width) (current-column))))
  56         (insert pp)
  57       (insert-text-button
  58        "[Show]" 'action `(lambda (&rest ignore)
  59                            (with-output-to-temp-buffer
  60                                "*Pp Eval Output*"
  61                              (princ ',pp)))
  62        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  63
  64 (defun describe-property-list (properties)
  65   "Insert a description of PROPERTIES in the current buffer.
  66 PROPERTIES should be a list of overlay or text properties.
  67 The `category', `face' and `font-lock-face' properties are made
  68 into help buttons that call `describe-text-category' or
  69 `describe-face' when pushed."
  70   ;; Sort the properties by the size of their value.
  71   (dolist (elt (sort (let (ret)
  72                        (while properties
  73                          (push (list (pop properties) (pop properties)) ret))
  74                        ret)
  75                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  76                                             (prin1-to-string (nth 0 b) t)))))
  77     (let ((key (nth 0 elt))
  78           (value (nth 1 elt)))
  79       (insert (propertize (format "  %-20s " key)
  80                           'face 'help-argument-name))
  81       (cond ((eq key 'category)
  82              (insert-text-button
  83               (symbol-name value)
  84               'action `(lambda (&rest ignore)
  85                          (describe-text-category ',value))
  86               'follow-link t
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category)
 104                    (called-interactively-p 'interactive))
 105   (with-help-window (help-buffer)
 106     (with-current-buffer standard-output
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer buffer)
 113   "Describe widgets, buttons, overlays, and text properties at POS.
 114 POS is taken to be in BUFFER or in current buffer if nil.
 115 Interactively, describe them for the character after point.
 116 If optional second argument OUTPUT-BUFFER is non-nil,
 117 insert the output into that buffer, and don't initialize or clear it
 118 otherwise."
 119   (interactive "d")
 120   (let ((src-buf (current-buffer)))
 121     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 122   (if (>= pos (point-max))
 123       (error "No character follows specified position"))
 124   (if output-buffer
 125       (describe-text-properties-1 pos output-buffer)
 126     (if (not (or (text-properties-at pos) (overlays-at pos)))
 127         (message "This is plain text.")
 128         (with-temp-buffer
 129             (setq output-buffer (current-buffer))
 130             (insert "Text content at position " (format "%d" pos) ":\n\n")
 131           (set-buffer buffer)
 132           (describe-text-properties-1 pos output-buffer)
 133           (set-buffer src-buf)
 134           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 135                            (called-interactively-p 'interactive))
 136           (with-help-window (help-buffer)
 137             (with-current-buffer standard-output
 138               (buffer-swap-text output-buffer)
 139               (goto-char (point-min)))))))))
 140
 141 (defun describe-text-properties-1 (pos output-buffer)
 142   (let* ((properties (text-properties-at pos))
 143          (overlays (overlays-in pos (1+ pos)))
 144          (wid-field (get-char-property pos 'field))
 145          (wid-button (get-char-property pos 'button))
 146          (wid-doc (get-char-property pos 'widget-doc))
 147          ;; If button.el is not loaded, we have no buttons in the text.
 148          (button (and (fboundp 'button-at) (button-at pos)))
 149          (button-type (and button (button-type button)))
 150          (button-label (and button (button-label button)))
 151          (widget (or wid-field wid-button wid-doc)))
 152     (with-current-buffer output-buffer
 153       ;; Widgets
 154       (when (widgetp widget)
 155         (newline)
 156         (insert (cond (wid-field "This is an editable text area")
 157                       (wid-button "This is an active area")
 158                       (wid-doc "This is documentation text")))
 159         (insert " of a ")
 160         (describe-text-widget widget)
 161         (insert ".\n\n"))
 162       ;; Buttons
 163       (when (and button (not (widgetp wid-button)))
 164         (newline)
 165         (insert "Here is a `" (format "%S" button-type)
 166                 "' button labeled `" button-label "'.\n\n"))
 167       ;; Overlays
 168       (when overlays
 169         (newline)
 170         (if (eq (length overlays) 1)
 171             (insert "There is an overlay here:\n")
 172           (insert "There are " (format "%d" (length overlays))
 173                          " overlays here:\n"))
 174         (dolist (overlay overlays)
 175           (insert " From " (format "%d" (overlay-start overlay))
 176                          " to " (format "%d" (overlay-end overlay)) "\n")
 177           (describe-property-list (overlay-properties overlay)))
 178         (insert "\n"))
 179       ;; Text properties
 180       (when properties
 181         (newline)
 182         (insert "There are text properties here:\n")
 183         (describe-property-list properties)))))
 184 \f
 185 (defcustom describe-char-unidata-list
 186   '(name old-name general-category decomposition)
 187   "List of Unicode-based character property names shown by `describe-char'."
 188   :group 'mule
 189   :version "23.1"
 190   :type '(choice (const :tag "All properties" t)
 191           (set
 192            (const :tag "Unicode name" name)
 193            (const :tag "Unicode old name" old-name)
 194            (const :tag "Unicode general category " general-category)
 195            (const :tag "Unicode canonical combining class"
 196                   canonical-combining-class)
 197            (const :tag "Unicode bidi class" bidi-class)
 198            (const :tag "Unicode decomposition mapping" decomposition)
 199            (const :tag "Unicode decimal digit value" decimal-digit-value)
 200            (const :tag "Unicode digit value" digit-value)
 201            (const :tag "Unicode numeric value" numeric-value)
 202            (const :tag "Unicode mirrored" mirrored)
 203            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 204            (const :tag "Unicode simple uppercase mapping" uppercase)
 205            (const :tag "Unicode simple lowercase mapping" lowercase)
 206            (const :tag "Unicode simple titlecase mapping" titlecase))))
 207
 208 (defcustom describe-char-unicodedata-file nil
 209   "Location of Unicode data file.
 210 This is the UnicodeData.txt file from the Unicode Consortium, used for
 211 diagnostics.  If it is non-nil `describe-char' will print data
 212 looked up from it.  This facility is mostly of use to people doing
 213 multilingual development.
 214
 215 This is a fairly large file, not typically present on GNU systems.
 216 At the time of writing it is at the URL
 217 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 218   :group 'mule
 219   :version "22.1"
 220   :type '(choice (const :tag "None" nil)
 221                  file))
 222
 223 (defun describe-char-unicode-data (char)
 224   "Return a list of Unicode data for Unicode CHAR.
 225 Each element is a list of a property description and the property value.
 226 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 227 This function is semi-obsolete.  Use `get-char-code-property'."
 228   (when describe-char-unicodedata-file
 229     (unless (file-exists-p describe-char-unicodedata-file)
 230       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 231     (with-current-buffer (get-buffer-create " *Unicode Data*")
 232       (when (zerop (buffer-size))
 233         ;; Don't use -literally in case of DOS line endings.
 234         (insert-file-contents describe-char-unicodedata-file))
 235       (goto-char (point-min))
 236       (let ((hex (format "%04X" char))
 237             found first last)
 238         (if (re-search-forward (concat "^" hex) nil t)
 239             (setq found t)
 240           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 241           ;; ideographs, and check whether it's in one of them.
 242           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 243                       (>= char (setq first
 244                                      (string-to-number (match-string 1) 16)))
 245                       (progn
 246                         (forward-line 1)
 247                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 248                         (> char
 249                            (setq last
 250                                  (string-to-number (match-string 1) 16))))))
 251           (if (and (>= char first)
 252                    (<= char last))
 253               (setq found t)))
 254         (if found
 255             (let ((fields (mapcar (lambda (elt)
 256                                     (if (> (length elt) 0)
 257                                         elt))
 258                                   (cdr (split-string
 259                                         (buffer-substring
 260                                          (line-beginning-position)
 261                                          (line-end-position))
 262                                         ";")))))
 263               ;; The length depends on whether the last field was empty.
 264               (unless (or (= 13 (length fields))
 265                           (= 14 (length fields)))
 266                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 267               ;; The field names and values lists are slightly
 268               ;; modified from Mule-UCS unidata.el.
 269               (list
 270                (list "Name" (let ((name (nth 0 fields)))
 271                               ;; Check for <..., First>, <..., Last>
 272                               (if (string-match "\\`\\(<[^,]+\\)," name)
 273                                   (concat (match-string 1 name) ">")
 274                                 name)))
 275                (list "Category"
 276                      (let ((val (nth 1 fields)))
 277                        (or (char-code-property-description
 278                             'general-category (intern val))
 279                            val)))
 280                (list "Combining class"
 281                      (let ((val (nth 1 fields)))
 282                        (or (char-code-property-description
 283                             'canonical-combining-class (intern val))
 284                            val)))
 285                (list "Bidi category"
 286                      (let ((val (nth 1 fields)))
 287                        (or (char-code-property-description
 288                             'bidi-class (intern val))
 289                            val)))
 290                (list
 291                 "Decomposition"
 292                 (if (nth 4 fields)
 293                     (let* ((parts (split-string (nth 4 fields)))
 294                            (info (car parts)))
 295                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 296                           (setq info (match-string 1 info))
 297                         (setq info nil))
 298                       (if info (setq parts (cdr parts)))
 299                       (setq parts (mapconcat
 300                                    (lambda (arg)
 301                                      (string (string-to-number arg 16)))
 302                                    parts " "))
 303                       (concat info (if info " ") parts))))
 304                (list "Decimal digit value"
 305                      (nth 5 fields))
 306                (list "Digit value"
 307                      (nth 6 fields))
 308                (list "Numeric value"
 309                      (nth 7 fields))
 310                (list "Mirrored"
 311                      (if (equal "Y" (nth 8 fields))
 312                          "yes"))
 313                (list "Old name" (nth 9 fields))
 314                (list "ISO 10646 comment" (nth 10 fields))
 315                (list "Uppercase" (and (nth 11 fields)
 316                                       (string (string-to-number
 317                                                (nth 11 fields) 16))))
 318                (list "Lowercase" (and (nth 12 fields)
 319                                       (string (string-to-number
 320                                                (nth 12 fields) 16))))
 321                (list "Titlecase" (and (nth 13 fields)
 322                                       (string (string-to-number
 323                                                (nth 13 fields) 16)))))))))))
 324
 325 ;; Not defined on builds without X, but behind display-graphic-p.
 326 (declare-function internal-char-font "fontset.c" (position &optional ch))
 327
 328 ;; Return information about how CHAR is displayed at the buffer
 329 ;; position POS.  If the selected frame is on a graphic display,
 330 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 331 ;;   FONT-DRIVER is the font-driver name,
 332 ;;   FONT-NAME is the font name,
 333 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 334 ;; Otherwise, return a string describing the terminal codes for the
 335 ;; character.
 336 (defun describe-char-display (pos char)
 337   (if (display-graphic-p (selected-frame))
 338       (let ((char-font-info (internal-char-font pos char)))
 339         (if char-font-info
 340             (let ((type (font-get (car char-font-info) :type))
 341                   (name (font-xlfd-name (car char-font-info)))
 342                   (code (cdr char-font-info)))
 343                (if (integerp code)
 344                    (format "%s:%s (#x%02X)" type name code)
 345                  (format "%s:%s (#x%04X%04X)"
 346                          type name (car code) (cdr code))))))
 347     (let* ((charset (get-text-property pos 'charset))
 348            (coding (or (terminal-coding-system) 'us-ascii))
 349            (encoded (encode-coding-char char coding charset)))
 350       (if encoded
 351           (encoded-string-description encoded coding)))))
 352
 353 \f
 354 ;; Return a string of CH with composition for padding on both sides.
 355 ;; It is displayed without overlapping with the left/right columns.
 356 (defsubst describe-char-padded-string (ch)
 357   (if (and (display-multi-font-p)
 358            (internal-char-font nil ch))
 359       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 360     (string ch)))
 361
 362 ;; Return a nicely formatted list of categories; extended category
 363 ;; description is added to the category name as a tooltip
 364 (defsubst describe-char-categories (category-set)
 365   (let ((mnemonics (category-set-mnemonics category-set)))
 366     (unless (eq mnemonics "")
 367       (list (mapconcat
 368              (lambda (x)
 369                (let* ((c (category-docstring x))
 370                       (doc (if (string-match "\\`\\(.*?\\)\n" c)
 371                                (propertize (match-string 1 c)
 372                                            'help-echo
 373                                            (substring c (1+ (match-end 1))))
 374                              c)))
 375                  (format "%c:%s" x doc)))
 376              mnemonics ", ")))))
 377
 378 ;;;###autoload
 379 (defun describe-char (pos &optional buffer)
 380   "Describe position POS (interactively, point) and the char after POS.
 381 POS is taken to be in BUFFER, or the current buffer if BUFFER is nil.
 382 The information is displayed in buffer `*Help*'.
 383
 384 The position information includes POS; the total size of BUFFER; the
 385 region limits, if narrowed; the column number; and the horizontal
 386 scroll amount, if the buffer is horizontally scrolled.
 387
 388 The character information includes the character code; charset and
 389 code points in it; syntax; category; how the character is encoded in
 390 BUFFER and in BUFFER's file; character composition information (if
 391 relevant); the font and font glyphs used to display the character;
 392 the character's canonical name and other properties defined by the
 393 Unicode Data Base; and widgets, buttons, overlays, and text properties
 394 relevant to POS."
 395   (interactive "d")
 396   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 397   (let ((src-buf (current-buffer)))
 398     (set-buffer buffer)
 399     (if (>= pos (point-max))
 400         (error "No character follows specified position"))
 401     (let* ((char (char-after pos))
 402            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 403            (charset (if eight-bit-p 'eight-bit
 404                       (or (get-text-property pos 'charset)
 405                           (char-charset char))))
 406            (composition (find-composition pos nil nil t))
 407            (component-chars nil)
 408            (display-table (or (window-display-table)
 409                               buffer-display-table
 410                               standard-display-table))
 411            (disp-vector (and display-table (aref display-table char)))
 412            (multibyte-p enable-multibyte-characters)
 413            (overlays (mapcar (lambda (o) (overlay-properties o))
 414                              (overlays-at pos)))
 415            (char-description (if (not multibyte-p)
 416                                  (single-key-description char)
 417                                (if (< char 128)
 418                                    (single-key-description char)
 419                                  (string-to-multibyte
 420                                   (char-to-string char)))))
 421            (text-props-desc
 422             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 423               (unwind-protect
 424                   (progn
 425                     (describe-text-properties pos tmp-buf)
 426                     (with-current-buffer tmp-buf (buffer-string)))
 427                 (kill-buffer tmp-buf))))
 428            item-list max-width code)
 429
 430       (if multibyte-p
 431           (or (setq code (encode-char char charset))
 432               (setq charset (char-charset char)
 433                     code (encode-char char charset)))
 434         (setq code char))
 435       (cond
 436        ;; Append a PDF character to directional embeddings and
 437        ;; overrides, to prevent potential messup of the following
 438        ;; text.
 439        ((memq char '(?\x202a ?\x202b ?\x202d ?\x202e))
 440         (setq char-description
 441               (concat char-description
 442                       (propertize (string ?\x202c) 'invisible t))))
 443        ;; Append a LRM character to any strong character to avoid
 444        ;; messing up the numerical codepoint.
 445        ((memq (get-char-code-property char 'bidi-class) '(R AL))
 446         (setq char-description
 447               (concat char-description
 448                       (propertize (string ?\x200e) 'invisible t)))))
 449       (when composition
 450         ;; When the composition is trivial (i.e. composed only with the
 451         ;; current character itself without any alternate characters),
 452         ;; we don't show the composition information.  Otherwise, store
 453         ;; two descriptive strings in the first two elements of
 454         ;; COMPOSITION.
 455         (or (catch 'tag
 456               (let ((from (car composition))
 457                     (to (nth 1 composition))
 458                     (components (nth 2 composition))
 459                     ch)
 460                 (if (and (vectorp components) (vectorp (aref components 0)))
 461                     (let ((idx (- pos from))
 462                           (nglyphs (lgstring-glyph-len components))
 463                           (i 0) j glyph glyph-from)
 464                       ;; COMPONENTS is a gstring.  Find a grapheme
 465                       ;; cluster containing the current character.
 466                       (while (and (< i nglyphs)
 467                                   (setq glyph (lgstring-glyph components i))
 468                                   (< (lglyph-to glyph) idx))
 469                         (setq i (1+ i)))
 470                       (if (or (not glyph) (= i nglyphs))
 471                           ;; The composition is broken.
 472                           (throw 'tag nil))
 473                       (setq glyph-from (lglyph-from glyph)
 474                             to (+ from (lglyph-to glyph) 1)
 475                             from (+ from glyph-from)
 476                             j i)
 477                       (while (and (< j nglyphs)
 478                                   (setq glyph (lgstring-glyph components j))
 479                                   (= (lglyph-from glyph) glyph-from))
 480                         (setq j (1+ j)))
 481                       (if (and (= to (1+ from))
 482                                (= i (1- j))
 483                                (setq glyph (lgstring-glyph components i))
 484                                (= char (lglyph-char glyph)))
 485                           ;; The composition is trivial.
 486                           (throw 'tag nil))
 487                       (nconc composition (list i (1- j))))
 488                   (dotimes (i (length components))
 489                     (if (integerp (setq ch (aref components i)))
 490                         (push (cons ch (describe-char-display pos ch))
 491                               component-chars)))
 492                   (setq component-chars (nreverse component-chars)))
 493                 (if (< from pos)
 494                     (if (< (1+ pos) to)
 495                         (setcar composition
 496                                 (concat
 497                                  " with the surrounding characters \""
 498                                  (mapconcat 'describe-char-padded-string
 499                                             (buffer-substring from pos) "")
 500                                  "\" and \""
 501                                  (mapconcat 'describe-char-padded-string
 502                                             (buffer-substring (1+ pos) to) "")
 503                                  "\""))
 504                       (setcar composition
 505                               (concat
 506                                " with the preceding character(s) \""
 507                                (mapconcat 'describe-char-padded-string
 508                                           (buffer-substring from pos) "")
 509                                "\"")))
 510                   (if (< (1+ pos) to)
 511                       (setcar composition
 512                               (concat
 513                                " with the following character(s) \""
 514                                (mapconcat 'describe-char-padded-string
 515                                           (buffer-substring (1+ pos) to) "")
 516                                "\""))
 517                     (setcar composition nil)))
 518                 (setcar (cdr composition)
 519                         (format "composed to form \"%s\" (see below)"
 520                                 (buffer-substring from to)))))
 521             (setq composition nil)))
 522
 523       (setq item-list
 524             `(("position"
 525                ,(let* ((beg      (point-min))
 526                        (end      (point-max))
 527                        (total    (buffer-size))
 528                        (percent  (if (> total 50000) ; Avoid overflow multiplying by 100
 529                                      (/ (+ (/ total 200) (1- pos))  (max (/ total 100) 1))
 530                                    (/ (+ (/ total 2) (* 100 (1- pos)))  (max total 1))))
 531                        (hscroll  (if (= (window-hscroll) 0)
 532                                      ""
 533                                    (format ", Hscroll: %d" (window-hscroll))))
 534                        (col      (current-column)))
 535                   (if (or (/= beg 1)  (/= end (1+ total)))
 536                       (format "%d of %d (%d%%), restriction: <%d-%d>, column: %d%s"
 537                               pos total percent beg end col hscroll)
 538                     (if (= pos end)
 539                         (format "%d of %d (EOB), column: %d%s" pos total col hscroll)
 540                       (format "%d of %d (%d%%), column: %d%s"
 541                               pos total percent col hscroll)))))
 542               ("character"
 543                ,(format "%s (displayed as %s) (codepoint %d, #o%o, #x%x)"
 544                         char-description
 545                         (apply 'propertize char-description
 546                                (text-properties-at pos))
 547                         char char char))
 548               ("preferred charset"
 549                ,`(insert-text-button
 550                   ,(symbol-name charset)
 551                   'type 'help-character-set 'help-args '(,charset))
 552                ,(format "(%s)" (charset-description charset)))
 553               ("code point in charset"
 554                ,(let ((str (if (integerp code)
 555                                (format (if (< code 256) "0x%02X" "0x%04X")
 556                                        code)
 557                              (format "0x%04X%04X" (car code) (cdr code)))))
 558                   (if (<= (charset-dimension charset) 2)
 559                       `(insert-text-button
 560                         ,str
 561                         'action (lambda (&rest ignore)
 562                                   (list-charset-chars ',charset)
 563                                   (with-selected-window
 564                                       (get-buffer-window "*Character List*" 0)
 565                                     (goto-char (point-min))
 566                                     (forward-line 2) ;Skip the header.
 567                                     (let ((case-fold-search nil))
 568                                       (if (search-forward
 569                                            ,(char-to-string char) nil t)
 570                                           (goto-char (match-beginning 0))))))
 571                         'follow-link t
 572                         'help-echo
 573                         "mouse-2, RET: show this character in its character set")
 574                     str)))
 575               ("syntax"
 576                ,(let ((syntax (syntax-after pos)))
 577                   (with-temp-buffer
 578                     (internal-describe-syntax-value syntax)
 579                     (buffer-string))))
 580               ("category"
 581                ,@(if (not eight-bit-p)
 582                      (let ((category-set (char-category-set char)))
 583                        (if category-set
 584                            (describe-char-categories category-set)
 585                          '("-- none --")))))
 586               ("to input"
 587                ,@(if (not eight-bit-p)
 588                      (let ((key-list (and (eq input-method-function
 589                                               'quail-input-method)
 590                                           (quail-find-key char))))
 591                        (if (consp key-list)
 592                            (list "type"
 593                                  (concat "\""
 594                                          (mapconcat 'identity
 595                                                     key-list "\" or \"")
 596                                          "\"")
 597                                  "with"
 598                                  `(insert-text-button
 599                                    ,current-input-method
 600                                    'type 'help-input-method
 601                                    'help-args '(,current-input-method))
 602                                  "input method")
 603                          (list
 604                           "type \"C-x 8 RET HEX-CODEPOINT\" or \"C-x 8 RET NAME\"")))))
 605               ("buffer code"
 606                ,(if multibyte-p
 607                     (encoded-string-description
 608                      (string-as-unibyte (char-to-string char)) nil)
 609                   (format "#x%02X" char)))
 610               ("file code"
 611                ,@(if multibyte-p
 612                      (let* ((coding buffer-file-coding-system)
 613                             (encoded (encode-coding-char char coding charset)))
 614                        (if encoded
 615                            (list (encoded-string-description encoded coding)
 616                                  (format "(encoded by coding system %S)"
 617                                          coding))
 618                          (list "not encodable by coding system"
 619                                (symbol-name coding))))
 620                    (list (format "#x%02X" char))))
 621               ("display"
 622                ,(cond
 623                  (disp-vector
 624                   (setq disp-vector (copy-sequence disp-vector))
 625                   (dotimes (i (length disp-vector))
 626                     (aset disp-vector i
 627                           (cons (aref disp-vector i)
 628                                 (describe-char-display
 629                                  pos (glyph-char (aref disp-vector i))))))
 630                   (format "by display table entry [%s] (see below)"
 631                           (mapconcat
 632                            (lambda (x)
 633                              (format "?%c" (glyph-char (car x))))
 634                            disp-vector " ")))
 635                  (composition
 636                   (cadr composition))
 637                  (t
 638                   (let ((display (describe-char-display pos char)))
 639                     (if (display-graphic-p (selected-frame))
 640                         (if display
 641                             (concat "by this font (glyph code)\n    " display)
 642                           "no font available")
 643                       (if display
 644                           (format "terminal code %s" display)
 645                         "not encodable for terminal"))))))
 646               ,@(let ((face
 647                        (if (not (or disp-vector composition))
 648                            (cond
 649                             ((and show-trailing-whitespace
 650                                   (save-excursion (goto-char pos)
 651                                                   (looking-at-p "[ \t]+$")))
 652                              'trailing-whitespace)
 653                             ((and nobreak-char-display char (eq char '#xa0))
 654                              'nobreak-space)
 655                             ((and nobreak-char-display char
 656                                   (memq char '(#xad #x2010 #x2011)))
 657                              'escape-glyph)
 658                             ((and (< char 32) (not (memq char '(9 10))))
 659                              'escape-glyph)))))
 660                   (if face (list (list "hardcoded face"
 661                                        `(insert-text-button
 662                                          ,(symbol-name face)
 663                                          'type 'help-face
 664                                          'help-args '(,face))))))
 665               ,@(if (not eight-bit-p)
 666                     (let ((unicodedata (describe-char-unicode-data char)))
 667                       (if unicodedata
 668                           (cons (list "Unicode data" "") unicodedata))))))
 669       (setq max-width (apply 'max (mapcar (lambda (x)
 670                                             (if (cadr x) (length (car x)) 0))
 671                                           item-list)))
 672       (set-buffer src-buf)
 673       (help-setup-xref (list 'describe-char pos buffer)
 674                        (called-interactively-p 'interactive))
 675       (with-help-window (help-buffer)
 676         (with-current-buffer standard-output
 677           (set-buffer-multibyte multibyte-p)
 678           (let ((formatter (format "%%%ds:" max-width)))
 679             (dolist (elt item-list)
 680               (when (cadr elt)
 681                 (insert (format formatter (car elt)))
 682                 (dolist (clm (cdr elt))
 683                   (cond ((eq (car-safe clm) 'insert-text-button)
 684                          (insert " ")
 685                          (eval clm))
 686                         ((not (zerop (length clm)))
 687                          (insert " " clm))))
 688                 (insert "\n"))))
 689
 690           (when overlays
 691             (save-excursion
 692               (goto-char (point-min))
 693               (re-search-forward "(displayed as ")
 694               (let ((end (+ (point) (length char-description))))
 695                 (mapc (lambda (props)
 696                         (let ((o (make-overlay (point) end)))
 697                           (while props
 698                             (overlay-put o (car props) (nth 1 props))
 699                             (setq props (cddr props)))))
 700                       overlays))))
 701
 702           (when disp-vector
 703             (insert
 704              "\nThe display table entry is displayed by ")
 705             (if (display-graphic-p (selected-frame))
 706                 (progn
 707                   (insert "these fonts (glyph codes):\n")
 708                   (dotimes (i (length disp-vector))
 709                     (insert (glyph-char (car (aref disp-vector i))) ?:
 710                             (propertize " " 'display '(space :align-to 5))
 711                             (or (cdr (aref disp-vector i)) "-- no font --")
 712                             "\n")
 713                     (let ((face (glyph-face (car (aref disp-vector i)))))
 714                       (when face
 715                         (insert (propertize " " 'display '(space :align-to 5))
 716                                 "face: ")
 717                         (insert (concat "`" (symbol-name face) "'"))
 718                         (insert "\n")))))
 719               (insert "these terminal codes:\n")
 720               (dotimes (i (length disp-vector))
 721                 (insert (car (aref disp-vector i))
 722                         (propertize " " 'display '(space :align-to 5))
 723                         (or (cdr (aref disp-vector i)) "-- not encodable --")
 724                         "\n"))))
 725
 726           (when composition
 727             (insert "\nComposed")
 728             (if (car composition)
 729                 (insert (car composition)))
 730             (if (and (vectorp (nth 2 composition))
 731                      (vectorp (aref (nth 2 composition) 0)))
 732                 (let* ((gstring (nth 2 composition))
 733                        (font (lgstring-font gstring))
 734                        (from (nth 3 composition))
 735                        (to (nth 4 composition))
 736                        glyph)
 737                   (if (fontp font)
 738                       (progn
 739                         (insert " using this font:\n  "
 740                                 (symbol-name (font-get font :type))
 741                                 ?:
 742                                 (aref (query-font font) 0)
 743                                 "\nby these glyphs:\n")
 744                         (while (and (<= from to)
 745                                     (setq glyph (lgstring-glyph gstring from)))
 746                           (insert (format "  %S\n" glyph))
 747                           (setq from (1+ from))))
 748                     (insert " by these characters:\n")
 749                     (while (and (<= from to)
 750                                 (setq glyph (lgstring-glyph gstring from)))
 751                       (insert (format " %c (#x%d)\n"
 752                                       (lglyph-char glyph) (lglyph-char glyph)))
 753                       (setq from (1+ from)))))
 754               (insert " by the rule:\n\t(")
 755               (let ((first t))
 756                 (mapc (lambda (x)
 757                         (if first (setq first nil)
 758                           (insert " "))
 759                         (if (consp x) (insert (format "%S" x))
 760                           (if (= x ?\t) (insert (single-key-description x))
 761                             (insert ??)
 762                             (insert (describe-char-padded-string x)))))
 763                       (nth 2 composition)))
 764               (insert  ")\nThe component character(s) are displayed by ")
 765               (if (display-graphic-p (selected-frame))
 766                   (progn
 767                     (insert "these fonts (glyph codes):")
 768                     (dolist (elt component-chars)
 769                       (if (/= (car elt) ?\t)
 770                           (insert "\n "
 771                                   (describe-char-padded-string (car elt))
 772                                   ?:
 773                                   (propertize " "
 774                                               'display '(space :align-to 5))
 775                                   (or (cdr elt) "-- no font --")))))
 776                 (insert "these terminal codes:")
 777                 (dolist (elt component-chars)
 778                   (insert "\n  " (car elt) ":"
 779                           (propertize " " 'display '(space :align-to 4))
 780                           (or (cdr elt) "-- not encodable --"))))
 781               (insert "\nSee the variable `reference-point-alist' for "
 782                       "the meaning of the rule.\n")))
 783
 784           (unless eight-bit-p
 785             (insert (if (not describe-char-unidata-list)
 786                         "\nCharacter code properties are not shown: "
 787                       "\nCharacter code properties: "))
 788             (insert-text-button
 789              "customize what to show"
 790              'action (lambda (&rest _ignore)
 791                        (customize-variable
 792                         'describe-char-unidata-list))
 793              'follow-link t)
 794             (insert "\n")
 795             (dolist (elt (if (eq describe-char-unidata-list t)
 796                              (nreverse (mapcar 'car char-code-property-alist))
 797                            describe-char-unidata-list))
 798               (let ((val (get-char-code-property char elt))
 799                     description)
 800                 (when val
 801                   (setq description (char-code-property-description elt val))
 802                   (insert (if description
 803                               (format "  %s: %s (%s)\n" elt val description)
 804                             (format "  %s: %s\n" elt val)))))))
 805
 806           (if text-props-desc (insert text-props-desc))
 807           (setq buffer-read-only t))))))
 808
 809 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 810
 811 (provide 'descr-text)
 812
 813 ;;; descr-text.el ends here