lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el.
   2
   3 ;; Copyright (C) 1988, 1994, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; Code:
  69
  70 (require 'scheme)
  71 (require 'comint)
  72
  73 ;;; INFERIOR SCHEME MODE STUFF
  74 ;;;============================================================================
  75
  76 (defvar inferior-scheme-mode-hook nil
  77   "*Hook for customising inferior-scheme mode.")
  78 (defvar inferior-scheme-mode-map nil)
  79
  80 (cond ((not inferior-scheme-mode-map)
  81        (setq inferior-scheme-mode-map
  82              (copy-keymap comint-mode-map))
  83        (define-key inferior-scheme-mode-map "\M-\C-x" ;gnu convention
  84                    'scheme-send-definition)
  85        (define-key inferior-scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp)
  86        (define-key inferior-scheme-mode-map "\C-c\C-l" 'scheme-load-file)
  87        (define-key inferior-scheme-mode-map "\C-c\C-k" 'scheme-compile-file)
  88        (scheme-mode-commands inferior-scheme-mode-map)))
  89
  90 ;; Install the process communication commands in the scheme-mode keymap.
  91 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
  92 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
  93 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
  94 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
  95 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
  96 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
  97 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
  98 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
  99 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 100 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 101 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 102
 103 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 104   (define-key map [separator-eval] '("--"))
 105   (define-key map [compile-file]
 106     '("Compile Scheme File" . scheme-compile-file))
 107   (define-key map [load-file]
 108     '("Load Scheme File" . scheme-load-file))
 109   (define-key map [switch]
 110     '("Switch to Scheme" . switch-to-scheme))
 111   (define-key map [com-def-go]
 112     '("Compile Definitiion & Go" . scheme-compile-definition-and-go))
 113   (define-key map [com-def]
 114     '("Compile Definitiion" . scheme-compile-definition))
 115   (define-key map [send-def-go]
 116     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 117   (define-key map [send-def]
 118     '("Evaluate Last Definition" . scheme-send-definition))
 119   (define-key map [send-region-go]
 120     '("Evaluate Region & Go" . scheme-send-region-and-go))
 121   (define-key map [send-region-go]
 122     '("Evaluate Region" . scheme-send-region))
 123   (define-key map [send-region]
 124     '("Evaluate Region" . scheme-send-region))
 125   (define-key map [send-sexp]
 126     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 127 )
 128
 129 (defvar scheme-buffer)
 130
 131 (defun inferior-scheme-mode ()
 132   "Major mode for interacting with an inferior Scheme process.
 133
 134 The following commands are available:
 135 \\{inferior-scheme-mode-map}
 136
 137 A Scheme process can be fired up with M-x run-scheme.
 138
 139 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 140 inferior-scheme-mode-hook (in that order).
 141
 142 You can send text to the inferior Scheme process from other buffers containing
 143 Scheme source.
 144     switch-to-scheme switches the current buffer to the Scheme process buffer.
 145     scheme-send-definition sends the current definition to the Scheme process.
 146     scheme-compile-definition compiles the current definition.
 147     scheme-send-region sends the current region to the Scheme process.
 148     scheme-compile-region compiles the current region.
 149
 150     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 151         scheme-send-region-and-go, and scheme-compile-region-and-go
 152         switch to the Scheme process buffer after sending their text.
 153 For information on running multiple processes in multiple buffers, see
 154 documentation for variable scheme-buffer.
 155
 156 Commands:
 157 Return after the end of the process' output sends the text from the
 158     end of process to point.
 159 Return before the end of the process' output copies the sexp ending at point
 160     to the end of the process' output, and sends it.
 161 Delete converts tabs to spaces as it moves back.
 162 Tab indents for Scheme; with argument, shifts rest
 163     of expression rigidly with the current line.
 164 C-M-q does Tab on each line starting within following expression.
 165 Paragraphs are separated only by blank lines.  Semicolons start comments.
 166 If you accidentally suspend your process, use \\[comint-continue-subjob]
 167 to continue it."
 168   (interactive)
 169   (comint-mode)
 170   ;; Customise in inferior-scheme-mode-hook
 171   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 172   (scheme-mode-variables)
 173   (setq major-mode 'inferior-scheme-mode)
 174   (setq mode-name "Inferior Scheme")
 175   (setq mode-line-process '(":%s"))
 176   (use-local-map inferior-scheme-mode-map)
 177   (setq comint-input-filter (function scheme-input-filter))
 178   (setq comint-get-old-input (function scheme-get-old-input))
 179   (run-hooks 'inferior-scheme-mode-hook))
 180
 181 (defvar inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 182   "*Input matching this regexp are not saved on the history list.
 183 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters.")
 184
 185 (defun scheme-input-filter (str)
 186   "Don't save anything matching inferior-scheme-filter-regexp"
 187   (not (string-match inferior-scheme-filter-regexp str)))
 188
 189 (defun scheme-get-old-input ()
 190   "Snarf the sexp ending at point"
 191   (save-excursion
 192     (let ((end (point)))
 193       (backward-sexp)
 194       (buffer-substring (point) end))))
 195
 196 (defun scheme-args-to-list (string)
 197   (let ((where (string-match "[ \t]" string)))
 198     (cond ((null where) (list string))
 199           ((not (= where 0))
 200            (cons (substring string 0 where)
 201                  (scheme-args-to-list (substring string (+ 1 where)
 202                                                  (length string)))))
 203           (t (let ((pos (string-match "[^ \t]" string)))
 204                (if (null pos)
 205                    nil
 206                  (scheme-args-to-list (substring string pos
 207                                                  (length string)))))))))
 208
 209 (defvar scheme-program-name "scheme"
 210   "*Program invoked by the run-scheme command")
 211
 212 ;;;###autoload
 213 (defun run-scheme (cmd)
 214   "Run an inferior Scheme process, input and output via buffer *scheme*.
 215 If there is a process already running in `*scheme*', switch to that buffer.
 216 With argument, allows you to edit the command line (default is value
 217 of `scheme-program-name').  Runs the hooks `inferior-scheme-mode-hook'
 218 \(after the `comint-mode-hook' is run).
 219 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 220
 221   (interactive (list (if current-prefix-arg
 222                          (read-string "Run Scheme: " scheme-program-name)
 223                          scheme-program-name)))
 224   (if (not (comint-check-proc "*scheme*"))
 225       (let ((cmdlist (scheme-args-to-list cmd)))
 226         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 227                            nil (cdr cmdlist)))
 228         (inferior-scheme-mode)))
 229   (setq scheme-program-name cmd)
 230   (setq scheme-buffer "*scheme*")
 231   (pop-to-buffer "*scheme*"))
 232 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 233
 234 (defun scheme-send-region (start end)
 235   "Send the current region to the inferior Scheme process."
 236   (interactive "r")
 237   (comint-send-region (scheme-proc) start end)
 238   (comint-send-string (scheme-proc) "\n"))
 239
 240 (defun scheme-send-definition ()
 241   "Send the current definition to the inferior Scheme process."
 242   (interactive)
 243   (save-excursion
 244    (end-of-defun)
 245    (let ((end (point)))
 246      (beginning-of-defun)
 247      (scheme-send-region (point) end))))
 248
 249 (defun scheme-send-last-sexp ()
 250   "Send the previous sexp to the inferior Scheme process."
 251   (interactive)
 252   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 253
 254 (defvar scheme-compile-exp-command "(compile '%s)"
 255   "*Template for issuing commands to compile arbitrary Scheme expressions.")
 256
 257 (defun scheme-compile-region (start end)
 258   "Compile the current region in the inferior Scheme process.
 259 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 260   (interactive "r")
 261   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 262                                             (format "(begin %s)"
 263                                                     (buffer-substring start end))))
 264   (comint-send-string (scheme-proc) "\n"))
 265
 266 (defun scheme-compile-definition ()
 267   "Compile the current definition in the inferior Scheme process."
 268   (interactive)
 269   (save-excursion
 270    (end-of-defun)
 271    (let ((end (point)))
 272      (beginning-of-defun)
 273      (scheme-compile-region (point) end))))
 274
 275 (defun switch-to-scheme (eob-p)
 276   "Switch to the scheme process buffer.
 277 With argument, positions cursor at end of buffer."
 278   (interactive "P")
 279   (if (get-buffer scheme-buffer)
 280       (pop-to-buffer scheme-buffer)
 281       (error "No current process buffer. See variable scheme-buffer."))
 282   (cond (eob-p
 283          (push-mark)
 284          (goto-char (point-max)))))
 285
 286 (defun scheme-send-region-and-go (start end)
 287   "Send the current region to the inferior Scheme process.
 288 Then switch to the process buffer."
 289   (interactive "r")
 290   (scheme-send-region start end)
 291   (switch-to-scheme t))
 292
 293 (defun scheme-send-definition-and-go ()
 294   "Send the current definition to the inferior Scheme.
 295 Then switch to the process buffer."
 296   (interactive)
 297   (scheme-send-definition)
 298   (switch-to-scheme t))
 299
 300 (defun scheme-compile-definition-and-go ()
 301   "Compile the current definition in the inferior Scheme.
 302 Then switch to the process buffer."
 303   (interactive)
 304   (scheme-compile-definition)
 305   (switch-to-scheme t))
 306
 307 (defun scheme-compile-region-and-go (start end)
 308   "Compile the current region in the inferior Scheme.
 309 Then switch to the process buffer."
 310   (interactive "r")
 311   (scheme-compile-region start end)
 312   (switch-to-scheme t))
 313
 314 (defvar scheme-source-modes '(scheme-mode)
 315   "*Used to determine if a buffer contains Scheme source code.
 316 If it's loaded into a buffer that is in one of these major modes, it's
 317 considered a scheme source file by scheme-load-file and scheme-compile-file.
 318 Used by these commands to determine defaults.")
 319
 320 (defvar scheme-prev-l/c-dir/file nil
 321   "Caches the last (directory . file) pair.
 322 Caches the last pair used in the last scheme-load-file or
 323 scheme-compile-file command. Used for determining the default in the
 324 next one.")
 325
 326 (defun scheme-load-file (file-name)
 327   "Load a Scheme file into the inferior Scheme process."
 328   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 329                                   scheme-source-modes t)) ; T because LOAD
 330                                                           ; needs an exact name
 331   (comint-check-source file-name) ; Check to see if buffer needs saved.
 332   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 333                                        (file-name-nondirectory file-name)))
 334   (comint-send-string (scheme-proc) (concat "(load \""
 335                                             file-name
 336                                             "\"\)\n")))
 337
 338 (defun scheme-compile-file (file-name)
 339   "Compile a Scheme file in the inferior Scheme process."
 340   (interactive (comint-get-source "Compile Scheme file: "
 341                                   scheme-prev-l/c-dir/file
 342                                   scheme-source-modes
 343                                   nil)) ; NIL because COMPILE doesn't
 344                                         ; need an exact name.
 345   (comint-check-source file-name) ; Check to see if buffer needs saved.
 346   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 347                                        (file-name-nondirectory file-name)))
 348   (comint-send-string (scheme-proc) (concat "(compile-file \""
 349                                             file-name
 350                                             "\"\)\n")))
 351
 352 \f
 353 (defvar scheme-buffer nil "*The current scheme process buffer.
 354
 355 MULTIPLE PROCESS SUPPORT
 356 ===========================================================================
 357 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 358 processes. To run multiple Scheme processes, you start the first up with
 359 \\[run-scheme]. It will be in a buffer named *scheme*. Rename this buffer
 360 with \\[rename-buffer]. You may now start up a new process with another
 361 \\[run-scheme]. It will be in a new buffer, named *scheme*. You can
 362 switch between the different process buffers with \\[switch-to-buffer].
 363
 364 Commands that send text from source buffers to Scheme processes --
 365 like scheme-send-definition or scheme-compile-region -- have to choose a
 366 process to send to, when you have more than one Scheme process around. This
 367 is determined by the global variable scheme-buffer. Suppose you
 368 have three inferior Schemes running:
 369     Buffer      Process
 370     foo         scheme
 371     bar         scheme<2>
 372     *scheme*    scheme<3>
 373 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 374 code, what process do you send it to?
 375
 376 - If you're in a process buffer (foo, bar, or *scheme*),
 377   you send it to that process.
 378 - If you're in some other buffer (e.g., a source file), you
 379   send it to the process attached to buffer scheme-buffer.
 380 This process selection is performed by function scheme-proc.
 381
 382 Whenever \\[run-scheme] fires up a new process, it resets scheme-buffer
 383 to be the new process's buffer. If you only run one process, this will
 384 do the right thing. If you run multiple processes, you can change
 385 scheme-buffer to another process buffer with \\[set-variable].
 386
 387 More sophisticated approaches are, of course, possible. If you find yourself
 388 needing to switch back and forth between multiple processes frequently,
 389 you may wish to consider ilisp.el, a larger, more sophisticated package
 390 for running inferior Lisp and Scheme processes. The approach taken here is
 391 for a minimal, simple implementation. Feel free to extend it.")
 392
 393 (defun scheme-proc ()
 394   "Returns the current scheme process. See variable scheme-buffer."
 395   (let ((proc (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 396                                       (current-buffer)
 397                                       scheme-buffer))))
 398     (or proc
 399         (error "No current process. See variable scheme-buffer"))))
 400
 401
 402 ;;; Do the user's customisation...
 403
 404 (defvar cmuscheme-load-hook nil
 405   "This hook is run when cmuscheme is loaded in.
 406 This is a good place to put keybindings.")
 407
 408 (run-hooks 'cmuscheme-load-hook)
 409
 410
 411 ;;; CHANGE LOG
 412 ;;; ===========================================================================
 413 ;;; 8/88 Olin
 414 ;;; Created.
 415 ;;;
 416 ;;; 2/15/89 Olin
 417 ;;; Removed -emacs flag from process invocation. It's only useful for
 418 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
 419 ;;; which messes things up royally. A bug.
 420 ;;;
 421 ;;; 5/22/90 Olin
 422 ;;; - Upgraded to use comint-send-string and comint-send-region.
 423 ;;; - run-scheme now offers to let you edit the command line if
 424 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
 425 ;;;   has been removed.
 426 ;;; - Explicit references to process "scheme" have been replaced with
 427 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
 428 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
 429 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
 430 ;;;   and friends, but interested hackers might find a useful application
 431 ;;;   of this facility.
 432 ;;;
 433 ;;; 3/12/90 Olin
 434 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
 435 ;;;   Tale suggested this.
 436
 437 (provide 'cmuscheme)
 438
 439 ;;; cmuscheme.el ends here