lisp/progmodes/executable.el

   1 ;;; executable.el --- base functionality for executable interpreter scripts -*- byte-compile-dynamic: t -*-
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 2000 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Pfeiffer <occitan@esperanto.org>
   6 ;; Keywords: languages, unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; executable.el is used by certain major modes to insert a suitable
  28 ;; #! line at the beginning of the file, if the file does not already
  29 ;; have one.
  30
  31 ;; Unless it has a magic number, a Unix file with executable mode is passed to
  32 ;; a new instance of the running shell (or to a Bourne shell if a csh is
  33 ;; running and the file starts with `:').  Only a shell can start such a file,
  34 ;; exec() cannot, which is why it is important to have a magic number in every
  35 ;; executable script.  Such a magic number is made up by the characters `#!'
  36 ;; the filename of an interpreter (in COFF, ELF or somesuch format) and one
  37 ;; optional argument.
  38
  39 ;; This library is for certain major modes like sh-, awk-, perl-, tcl- or
  40 ;; makefile-mode to insert or update a suitable #! line at the beginning of
  41 ;; the file, if the file does not already have one and the file is not a
  42 ;; default file of that interpreter (like .profile or makefile).  It also
  43 ;; makes the file executable if it wasn't, as soon as it's saved.
  44
  45 ;; It also allows debugging scripts, with an adaptation of compile, as far
  46 ;; as interpreters give out meaningful error messages.
  47
  48 ;; Modes that use this should nconc `executable-map' to the end of their own
  49 ;; keymap and `executable-font-lock-keywords' to the end of their own font
  50 ;; lock keywords.  Their mode-setting commands should call
  51 ;; `executable-set-magic'.
  52
  53 ;;; Code:
  54
  55 (defgroup executable nil
  56   "Base functionality for executable interpreter scripts"
  57   :group 'processes)
  58
  59 ;; This used to default to `other', but that doesn't seem to have any
  60 ;; significance.  fx 2000-02-11.
  61 (defcustom executable-insert t          ; 'other
  62   "*Non-nil means offer to add a magic number to a file.
  63 This takes effect when you switch to certain major modes,
  64 including Shell-script mode (`sh-mode').
  65 When you type \\[executable-set-magic], it always offers to add or
  66 update the magic number."
  67 ;;;   :type '(choice (const :tag "off" nil)
  68 ;;;              (const :tag "on" t)
  69 ;;;              symbol)
  70   :type 'boolean
  71   :group 'executable)
  72
  73
  74 (defcustom executable-query 'function
  75   "*If non-nil, ask user before changing an existing magic number.
  76 When this is `function', only ask when called non-interactively."
  77   :type '(choice (const :tag "Don't Ask" nil)
  78                  (const :tag "Ask when non-interactive" function)
  79                  (other :tag "Ask" t))
  80   :group 'executable)
  81
  82
  83 (defcustom executable-magicless-file-regexp "/[Mm]akefile$\\|/\\.\\(z?profile\\|bash_profile\\|z?login\\|bash_login\\|z?logout\\|bash_logout\\|.+shrc\\|esrc\\|rcrc\\|[kz]shenv\\)$"
  84   "*On files with this kind of name no magic is inserted or changed."
  85   :type 'regexp
  86   :group 'executable)
  87
  88
  89 (defcustom executable-prefix "#! "
  90   "*Interpreter magic number prefix inserted when there was no magic number."
  91   :type 'string
  92   :group 'executable)
  93
  94
  95 (defcustom executable-chmod 73
  96   "*After saving, if the file is not executable, set this mode.
  97 This mode passed to `set-file-modes' is taken absolutely when negative, or
  98 relative to the files existing modes.  Do nothing if this is nil.
  99 Typical values are 73 (+x) or -493 (rwxr-xr-x)."
 100   :type '(choice integer
 101                  (const nil))
 102   :group 'executable)
 103
 104
 105 (defvar executable-command nil)
 106
 107 (defcustom executable-self-display "tail"
 108   "*Command you use with argument `+2' to make text files self-display.
 109 Note that the like of `more' doesn't work too well under Emacs \\[shell]."
 110   :type 'string
 111   :group 'executable)
 112
 113
 114 (defvar executable-font-lock-keywords
 115   '(("\\`#!.*/\\([^ \t\n]+\\)" 1 font-lock-keyword-face t))
 116   "*Rules for highlighting executable scripts' magic number.
 117 This can be included in `font-lock-keywords' by modes that call `executable'.")
 118
 119
 120 (defvar executable-error-regexp-alist
 121   '(;; /bin/xyz: syntax error at line 14: `(' unexpected
 122     ;; /bin/xyz[5]: syntax error at line 8 : ``' unmatched
 123     ("^\\(.*[^[/]\\)\\(\\[[0-9]+\\]\\)?: .* error .* line \\([0-9]+\\)" 1 3)
 124     ;; /bin/xyz[27]: ehco:  not found
 125     ("^\\(.*[^/]\\)\\[\\([0-9]+\\)\\]: .*: " 1 2)
 126     ;; /bin/xyz: syntax error near unexpected token `)'
 127     ;; /bin/xyz: /bin/xyz: line 2: `)'
 128     ("^\\(.*[^/]\\): [^0-9\n]+\n\\1: \\1: line \\([0-9]+\\):" 1 2)
 129     ;; /usr/bin/awk: syntax error at line 5 of file /bin/xyz
 130     (" error .* line \\([0-9]+\\) of file \\(.+\\)$" 2 1)
 131     ;; /usr/bin/awk: calling undefined function toto
 132     ;;  input record number 3, file awktestdata
 133     ;;  source line 4 of file /bin/xyz
 134     ("^[^ ].+\n\\( .+\n\\)* line \\([0-9]+\\) of file \\(.+\\)$" 3 2)
 135     ;; makefile:1: *** target pattern contains no `%'.  Stop.
 136     ("^\\(.+\\):\\([0-9]+\\): " 1 2))
 137   "Alist of regexps used to match script errors.
 138 See `compilation-error-regexp-alist'.")
 139
 140 ;; The C function openp slightly modified would do the trick fine
 141 (defvar executable-binary-suffixes
 142   (if (memq system-type '(ms-dos windows-nt))
 143       '(".exe" ".com" ".bat" ".cmd" ".btm" "")
 144     '("")))
 145
 146 ;;;###autoload
 147 (defun executable-find (command)
 148   "Search for COMMAND in exec-path and return the absolute file name.
 149 Return nil if COMMAND is not found anywhere in `exec-path'."
 150   (let ((list exec-path)
 151         file)
 152     (while list
 153       (setq list
 154             (if (and (setq file (expand-file-name command (car list)))
 155                      (let ((suffixes executable-binary-suffixes)
 156                            candidate)
 157                        (while suffixes
 158                          (setq candidate (concat file (car suffixes)))
 159                          (if (and (file-executable-p candidate)
 160                                   (not (file-directory-p candidate)))
 161                              (setq suffixes nil)
 162                            (setq suffixes (cdr suffixes))
 163                            (setq candidate nil)))
 164                        (setq file candidate)))
 165                 nil
 166               (setq file nil)
 167               (cdr list))))
 168     file))
 169
 170 (defun executable-chmod ()
 171   "This gets called after saving a file to assure that it be executable.
 172 You can set the absolute or relative mode in variable `executable-chmod' for
 173 non-executable files."
 174   (and executable-chmod
 175        buffer-file-name
 176        (or (file-executable-p buffer-file-name)
 177            (set-file-modes buffer-file-name
 178                            (if (< executable-chmod 0)
 179                                (- executable-chmod)
 180                              (logior executable-chmod
 181                                      (file-modes buffer-file-name)))))))
 182
 183
 184 (defun executable-interpret (command)
 185   "Run script with user-specified args, and collect output in a buffer.
 186 While script runs asynchronously, you can use the \\[next-error] command
 187 to find the next error."
 188   (interactive (list (read-string "Run script: "
 189                                   (or executable-command
 190                                       buffer-file-name))))
 191   (require 'compile)
 192   (save-some-buffers (not compilation-ask-about-save))
 193   (make-local-variable 'executable-command)
 194   (compile-internal (setq executable-command command)
 195                     "No more errors." "Interpretation"
 196                     ;; Give it a simpler regexp to match.
 197                     nil executable-error-regexp-alist))
 198
 199
 200
 201 ;;;###autoload
 202 (defun executable-set-magic (interpreter &optional argument
 203                                          no-query-flag insert-flag)
 204   "Set this buffer's interpreter to INTERPRETER with optional ARGUMENT.
 205 The variables `executable-magicless-file-regexp', `executable-prefix',
 206 `executable-insert', `executable-query' and `executable-chmod' control
 207 when and how magic numbers are inserted or replaced and scripts made
 208 executable."
 209   (interactive
 210    (let* ((name (read-string "Name or file name of interpreter: "))
 211           (arg (read-string (format "Argument for %s: " name))))
 212      (list name arg (eq executable-query 'function) t)))
 213
 214   (setq interpreter (if (file-name-absolute-p interpreter)
 215                         interpreter
 216                       (or (executable-find interpreter)
 217                           (error "Interpreter %s not recognized"
 218                                  interpreter))))
 219
 220   (setq argument (concat (if (string-match "\\`/:" interpreter)
 221                              (replace-match "" nil nil interpreter)
 222                            interpreter)
 223                          (and argument (string< "" argument) " ")
 224                          argument))
 225
 226   (or buffer-read-only
 227       (if buffer-file-name
 228           (string-match executable-magicless-file-regexp
 229                         buffer-file-name))
 230       (not (or insert-flag executable-insert))
 231       (> (point-min) 1)
 232       (save-excursion
 233         (let ((point (point-marker))
 234               (buffer-modified-p (buffer-modified-p)))
 235           (goto-char (point-min))
 236           (make-local-hook 'after-save-hook)
 237           (add-hook 'after-save-hook 'executable-chmod nil t)
 238           (if (looking-at "#![ \t]*\\(.*\\)$")
 239               (and (goto-char (match-beginning 1))
 240                    ;; If the line ends in a space,
 241                    ;; don't offer to change it.
 242                    (not (= (char-after (1- (match-end 1))) ?\ ))
 243                    (not (string= argument
 244                                  (buffer-substring (point) (match-end 1))))
 245                    (if (or (not executable-query) no-query-flag
 246                            (save-window-excursion
 247                              ;; Make buffer visible before question.
 248                              (switch-to-buffer (current-buffer))
 249                              (y-or-n-p (concat "Replace magic number by `"
 250                                                executable-prefix argument "'? "))))
 251                        (progn
 252                          (replace-match argument t t nil 1)
 253                          (message "Magic number changed to `%s'"
 254                                   (concat executable-prefix argument)))))
 255             (insert executable-prefix argument ?\n)
 256             (message "Magic number changed to `%s'"
 257                      (concat executable-prefix argument)))
 258 ;;;       (or insert-flag
 259 ;;;           (eq executable-insert t)
 260 ;;;           (set-buffer-modified-p buffer-modified-p))
 261           )))
 262     interpreter)
 263
 264
 265
 266 ;;;###autoload
 267 (defun executable-self-display ()
 268   "Turn a text file into a self-displaying Un*x command.
 269 The magic number of such a command displays all lines but itself."
 270   (interactive)
 271   (if (eq this-command 'executable-self-display)
 272       (setq this-command 'executable-set-magic))
 273   (executable-set-magic executable-self-display "+2"))
 274
 275 ;;;###autoload
 276 (defun executable-make-buffer-file-executable-if-script-p ()
 277   "Make file executable according to umask if not already executable.
 278 If file already has any execute bits set at all, do not change existing
 279 file modes."
 280   (and (>= (buffer-size) 2)
 281        (save-restriction
 282          (widen)
 283          (string= "#!" (buffer-substring 1 3)))
 284        (let* ((current-mode (file-modes (buffer-file-name)))
 285               (add-mode (logand ?\111 (default-file-modes))))
 286          (or (/= (logand ?\111 current-mode) 0)
 287              (zerop add-mode)
 288              (set-file-modes (buffer-file-name)
 289                              (logior current-mode add-mode))))))
 290
 291 (provide 'executable)
 292
 293 ;;; executable.el ends here