lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33
  34 (defconst image-type-header-regexps
  35   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  36     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  37     ("\\`GIF8[79]a" . gif)
  38     ("\\`\x89PNG\r\n\x1a\n" . png)
  39     ("\\`[\t\n\r ]*#define \\([a-z0-9]+\\)_width [0-9]+\n\
  40 #define \\1_height [0-9]+\n\
  41 static char \\1_bits" . xbm)
  42     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  43     ("\\`[\t\n\r ]*%!PS" . postscript)
  44     ("\\`\xff\xd8" . (image-jpeg-p . jpeg))
  45     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  46              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  47         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  48                 comment-re "*"
  49                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  50                 "[Ss][Vv][Gg]"))
  51      . svg)
  52     )
  53   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  54 When the first bytes of an image file match REGEXP, it is assumed to
  55 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  56 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  57 with one argument, a string containing the image data.  If PREDICATE returns
  58 a non-nil value, TYPE is the image's type.")
  59
  60 (defconst image-type-file-name-regexps
  61   '(("\\.png\\'" . png)
  62     ("\\.gif\\'" . gif)
  63     ("\\.jpe?g\\'" . jpeg)
  64     ("\\.bmp\\'" . bmp)
  65     ("\\.xpm\\'" . xpm)
  66     ("\\.pbm\\'" . pbm)
  67     ("\\.xbm\\'" . xbm)
  68     ("\\.ps\\'" . postscript)
  69     ("\\.tiff?\\'" . tiff)
  70     ("\\.svgz?\\'" . svg)
  71     )
  72   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  73 When the name of an image file match REGEXP, it is assumed to
  74 be of image type IMAGE-TYPE.")
  75
  76 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  77 ;; of content autodetection.  Their contents are just C code, so it is
  78 ;; easy to generate false matches.
  79 (defvar image-type-auto-detectable
  80   '((pbm . t)
  81     (xbm . nil)
  82     (bmp . maybe)
  83     (gif . maybe)
  84     (png . maybe)
  85     (xpm . nil)
  86     (jpeg . maybe)
  87     (tiff . maybe)
  88     (svg . maybe)
  89     (postscript . nil))
  90   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  91 \(See `image-type-auto-detected-p').
  92
  93 AUTODETECT can be
  94  - t      always auto-detect.
  95  - nil    never auto-detect.
  96  - maybe  auto-detect only if the image type is available
  97             (see `image-type-available-p').")
  98
  99 (defvar image-load-path nil
 100   "List of locations in which to search for image files.
 101 If an element is a string, it defines a directory to search.
 102 If an element is a variable symbol whose value is a string, that
 103 value defines a directory to search.
 104 If an element is a variable symbol whose value is a list, the
 105 value is used as a list of directories to search.")
 106
 107 (eval-at-startup
 108  (setq image-load-path
 109        (list (file-name-as-directory (expand-file-name "images" data-directory))
 110              'data-directory 'load-path)))
 111
 112
 113 (defun image-load-path-for-library (library image &optional path no-error)
 114   "Return a suitable search path for images used by LIBRARY.
 115
 116 It searches for IMAGE in `image-load-path' (excluding
 117 \"`data-directory'/images\") and `load-path', followed by a path
 118 suitable for LIBRARY, which includes \"../../etc/images\" and
 119 \"../etc/images\" relative to the library file itself, and then
 120 in \"`data-directory'/images\".
 121
 122 Then this function returns a list of directories which contains
 123 first the directory in which IMAGE was found, followed by the
 124 value of `load-path'. If PATH is given, it is used instead of
 125 `load-path'.
 126
 127 If NO-ERROR is non-nil and a suitable path can't be found, don't
 128 signal an error. Instead, return a list of directories as before,
 129 except that nil appears in place of the image directory.
 130
 131 Here is an example that uses a common idiom to provide
 132 compatibility with versions of Emacs that lack the variable
 133 `image-load-path':
 134
 135     ;; Shush compiler.
 136     (defvar image-load-path)
 137
 138     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 139            (image-load-path (cons (car load-path)
 140                                   (when (boundp 'image-load-path)
 141                                     image-load-path))))
 142       (mh-tool-bar-folder-buttons-init))"
 143   (unless library (error "No library specified"))
 144   (unless image   (error "No image specified"))
 145   (let (image-directory image-directory-load-path)
 146     ;; Check for images in image-load-path or load-path.
 147     (let ((img image)
 148           (dir (or
 149                 ;; Images in image-load-path.
 150                 (image-search-load-path image)
 151                 ;; Images in load-path.
 152                 (locate-library image)))
 153           parent)
 154       ;; Since the image might be in a nested directory (for
 155       ;; example, mail/attach.pbm), adjust `image-directory'
 156       ;; accordingly.
 157       (when dir
 158         (setq dir (file-name-directory dir))
 159         (while (setq parent (file-name-directory img))
 160           (setq img (directory-file-name parent)
 161                 dir (expand-file-name "../" dir))))
 162       (setq image-directory-load-path dir))
 163
 164     ;; If `image-directory-load-path' isn't Emacs' image directory,
 165     ;; it's probably a user preference, so use it. Then use a
 166     ;; relative setting if possible; otherwise, use
 167     ;; `image-directory-load-path'.
 168     (cond
 169      ;; User-modified image-load-path?
 170      ((and image-directory-load-path
 171            (not (equal image-directory-load-path
 172                        (file-name-as-directory
 173                         (expand-file-name "images" data-directory)))))
 174       (setq image-directory image-directory-load-path))
 175      ;; Try relative setting.
 176      ((let (library-name d1ei d2ei)
 177         ;; First, find library in the load-path.
 178         (setq library-name (locate-library library))
 179         (if (not library-name)
 180             (error "Cannot find library %s in load-path" library))
 181         ;; And then set image-directory relative to that.
 182         (setq
 183          ;; Go down 2 levels.
 184          d2ei (file-name-as-directory
 185                (expand-file-name
 186                 (concat (file-name-directory library-name) "../../etc/images")))
 187          ;; Go down 1 level.
 188          d1ei (file-name-as-directory
 189                (expand-file-name
 190                 (concat (file-name-directory library-name) "../etc/images"))))
 191         (setq image-directory
 192               ;; Set it to nil if image is not found.
 193               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 194                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 195      ;; Use Emacs' image directory.
 196      (image-directory-load-path
 197       (setq image-directory image-directory-load-path))
 198      (no-error
 199       (message "Could not find image %s for library %s" image library))
 200      (t
 201       (error "Could not find image %s for library %s" image library)))
 202
 203     ;; Return an augmented `path' or `load-path'.
 204     (nconc (list image-directory)
 205            (delete image-directory (copy-sequence (or path load-path))))))
 206
 207
 208 (defun image-jpeg-p (data)
 209   "Value is non-nil if DATA, a string, consists of JFIF image data.
 210 We accept the tag Exif because that is the same format."
 211   (when (string-match "\\`\xff\xd8" data)
 212     (catch 'jfif
 213       (let ((len (length data)) (i 2))
 214         (while (< i len)
 215           (when (/= (aref data i) #xff)
 216             (throw 'jfif nil))
 217           (setq i (1+ i))
 218           (when (>= (+ i 2) len)
 219             (throw 'jfif nil))
 220           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 221                            (aref data (+ i 2))))
 222                 (code (aref data i)))
 223             (when (and (>= code #xe0) (<= code #xef))
 224               ;; APP0 LEN1 LEN2 "JFIF\0"
 225               (throw 'jfif
 226                      (string-match "JFIF\\|Exif"
 227                                    (substring data i (min (+ i nbytes) len)))))
 228             (setq i (+ i 1 nbytes))))))))
 229
 230
 231 ;;;###autoload
 232 (defun image-type-from-data (data)
 233   "Determine the image type from image data DATA.
 234 Value is a symbol specifying the image type or nil if type cannot
 235 be determined."
 236   (let ((types image-type-header-regexps)
 237         type)
 238     (while types
 239       (let ((regexp (car (car types)))
 240             (image-type (cdr (car types))))
 241         (if (or (and (symbolp image-type)
 242                      (string-match regexp data))
 243                 (and (consp image-type)
 244                      (funcall (car image-type) data)
 245                      (setq image-type (cdr image-type))))
 246             (setq type image-type
 247                   types nil)
 248           (setq types (cdr types)))))
 249     type))
 250
 251
 252 ;;;###autoload
 253 (defun image-type-from-buffer ()
 254   "Determine the image type from data in the current buffer.
 255 Value is a symbol specifying the image type or nil if type cannot
 256 be determined."
 257   (let ((types image-type-header-regexps)
 258         type
 259         (opoint (point)))
 260     (goto-char (point-min))
 261     (while types
 262       (let ((regexp (car (car types)))
 263             (image-type (cdr (car types)))
 264             data)
 265         (if (or (and (symbolp image-type)
 266                      (looking-at regexp))
 267                 (and (consp image-type)
 268                      (funcall (car image-type)
 269                               (or data
 270                                   (setq data
 271                                         (buffer-substring
 272                                          (point-min)
 273                                          (min (point-max)
 274                                               (+ (point-min) 256))))))
 275                      (setq image-type (cdr image-type))))
 276             (setq type image-type
 277                   types nil)
 278           (setq types (cdr types)))))
 279     (goto-char opoint)
 280     type))
 281
 282
 283 ;;;###autoload
 284 (defun image-type-from-file-header (file)
 285   "Determine the type of image file FILE from its first few bytes.
 286 Value is a symbol specifying the image type, or nil if type cannot
 287 be determined."
 288   (unless (or (file-readable-p file)
 289               (file-name-absolute-p file))
 290     (setq file (image-search-load-path file)))
 291   (and file
 292        (file-readable-p file)
 293        (with-temp-buffer
 294          (set-buffer-multibyte nil)
 295          (insert-file-contents-literally file nil 0 256)
 296          (image-type-from-buffer))))
 297
 298
 299 ;;;###autoload
 300 (defun image-type-from-file-name (file)
 301   "Determine the type of image file FILE from its name.
 302 Value is a symbol specifying the image type, or nil if type cannot
 303 be determined."
 304   (assoc-default file image-type-file-name-regexps 'string-match))
 305
 306
 307 ;;;###autoload
 308 (defun image-type (source &optional type data-p)
 309   "Determine and return image type.
 310 SOURCE is an image file name or image data.
 311 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 312 or nil, try to determine the image type from its first few bytes
 313 of image data.  If that doesn't work, and SOURCE is a file name,
 314 use its file extension as image type.
 315 Optional DATA-P non-nil means SOURCE is a string containing image data."
 316   (when (and (not data-p) (not (stringp source)))
 317     (error "Invalid image file name `%s'" source))
 318   (unless type
 319     (setq type (if data-p
 320                    (image-type-from-data source)
 321                  (or (image-type-from-file-header source)
 322                      (image-type-from-file-name source))))
 323     (or type (error "Cannot determine image type")))
 324   (or (memq type (and (boundp 'image-types) image-types))
 325       (error "Invalid image type `%s'" type))
 326   type)
 327
 328
 329 ;;;###autoload
 330 (defun image-type-available-p (type)
 331   "Return non-nil if image type TYPE is available.
 332 Image types are symbols like `xbm' or `jpeg'."
 333   (and (fboundp 'init-image-library)
 334        (init-image-library type image-library-alist)))
 335
 336
 337 ;;;###autoload
 338 (defun image-type-auto-detected-p ()
 339   "Return t if the current buffer contains an auto-detectable image.
 340 This function is intended to be used from `magic-fallback-mode-alist'.
 341
 342 The buffer is considered to contain an auto-detectable image if
 343 its beginning matches an image type in `image-type-header-regexps',
 344 and that image type is present in `image-type-auto-detectable' with a
 345 non-nil value.  If that value is non-nil, but not t, then the image type
 346 must be available."
 347   (let* ((type (image-type-from-buffer))
 348          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 349     (and auto
 350          (or (eq auto t) (image-type-available-p type)))))
 351
 352
 353 ;;;###autoload
 354 (defun create-image (file-or-data &optional type data-p &rest props)
 355   "Create an image.
 356 FILE-OR-DATA is an image file name or image data.
 357 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 358 or nil, try to determine the image type from its first few bytes
 359 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 360 use its file extension as image type.
 361 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 362 Optional PROPS are additional image attributes to assign to the image,
 363 like, e.g. `:mask MASK'.
 364 Value is the image created, or nil if images of type TYPE are not supported.
 365
 366 Images should not be larger than specified by `max-image-size'.
 367
 368 Image file names that are not absolute are searched for in the
 369 \"images\" sub-directory of `data-directory' and
 370 `x-bitmap-file-path' (in that order)."
 371   ;; It is x_find_image_file in image.c that sets the search path.
 372   (setq type (image-type file-or-data type data-p))
 373   (when (image-type-available-p type)
 374     (append (list 'image :type type (if data-p :data :file) file-or-data)
 375             props)))
 376
 377
 378 ;;;###autoload
 379 (defun put-image (image pos &optional string area)
 380   "Put image IMAGE in front of POS in the current buffer.
 381 IMAGE must be an image created with `create-image' or `defimage'.
 382 IMAGE is displayed by putting an overlay into the current buffer with a
 383 `before-string' STRING that has a `display' property whose value is the
 384 image.  STRING is defaulted if you omit it.
 385 POS may be an integer or marker.
 386 AREA is where to display the image.  AREA nil or omitted means
 387 display it in the text area, a value of `left-margin' means
 388 display it in the left marginal area, a value of `right-margin'
 389 means display it in the right marginal area."
 390   (unless string (setq string "x"))
 391   (let ((buffer (current-buffer)))
 392     (unless (eq (car-safe image) 'image)
 393       (error "Not an image: %s" image))
 394     (unless (or (null area) (memq area '(left-margin right-margin)))
 395       (error "Invalid area %s" area))
 396     (setq string (copy-sequence string))
 397     (let ((overlay (make-overlay pos pos buffer))
 398           (prop (if (null area) image (list (list 'margin area) image))))
 399       (put-text-property 0 (length string) 'display prop string)
 400       (overlay-put overlay 'put-image t)
 401       (overlay-put overlay 'before-string string))))
 402
 403
 404 ;;;###autoload
 405 (defun insert-image (image &optional string area slice)
 406   "Insert IMAGE into current buffer at point.
 407 IMAGE is displayed by inserting STRING into the current buffer
 408 with a `display' property whose value is the image.  STRING is
 409 defaulted if you omit it.
 410 AREA is where to display the image.  AREA nil or omitted means
 411 display it in the text area, a value of `left-margin' means
 412 display it in the left marginal area, a value of `right-margin'
 413 means display it in the right marginal area.
 414 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 415 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 416 specifying the X and Y positions and WIDTH and HEIGHT of image area
 417 to insert.  A float value 0.0 - 1.0 means relative to the width or
 418 height of the image; integer values are taken as pixel values."
 419   ;; Use a space as least likely to cause trouble when it's a hidden
 420   ;; character in the buffer.
 421   (unless string (setq string " "))
 422   (unless (eq (car-safe image) 'image)
 423     (error "Not an image: %s" image))
 424   (unless (or (null area) (memq area '(left-margin right-margin)))
 425     (error "Invalid area %s" area))
 426   (if area
 427       (setq image (list (list 'margin area) image))
 428     ;; Cons up a new spec equal but not eq to `image' so that
 429     ;; inserting it twice in a row (adjacently) displays two copies of
 430     ;; the image.  Don't try to avoid this by looking at the display
 431     ;; properties on either side so that we DTRT more often with
 432     ;; cut-and-paste.  (Yanking killed image text next to another copy
 433     ;; of it loses anyway.)
 434     (setq image (cons 'image (cdr image))))
 435   (let ((start (point)))
 436     (insert string)
 437     (add-text-properties start (point)
 438                          `(display ,(if slice
 439                                         (list (cons 'slice slice) image)
 440                                       image) rear-nonsticky (display)))))
 441
 442
 443 ;;;###autoload
 444 (defun insert-sliced-image (image &optional string area rows cols)
 445   "Insert IMAGE into current buffer at point.
 446 IMAGE is displayed by inserting STRING into the current buffer
 447 with a `display' property whose value is the image.  STRING is
 448 defaulted if you omit it.
 449 AREA is where to display the image.  AREA nil or omitted means
 450 display it in the text area, a value of `left-margin' means
 451 display it in the left marginal area, a value of `right-margin'
 452 means display it in the right marginal area.
 453 The image is automatically split into ROW x COLS slices."
 454   (unless string (setq string " "))
 455   (unless (eq (car-safe image) 'image)
 456     (error "Not an image: %s" image))
 457   (unless (or (null area) (memq area '(left-margin right-margin)))
 458     (error "Invalid area %s" area))
 459   (if area
 460       (setq image (list (list 'margin area) image))
 461     ;; Cons up a new spec equal but not eq to `image' so that
 462     ;; inserting it twice in a row (adjacently) displays two copies of
 463     ;; the image.  Don't try to avoid this by looking at the display
 464     ;; properties on either side so that we DTRT more often with
 465     ;; cut-and-paste.  (Yanking killed image text next to another copy
 466     ;; of it loses anyway.)
 467     (setq image (cons 'image (cdr image))))
 468   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 469          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 470     (while (< y 1.0)
 471       (while (< x 1.0)
 472         (let ((start (point)))
 473           (insert string)
 474           (add-text-properties start (point)
 475                                `(display ,(list (list 'slice x y dx dy) image)
 476                                          rear-nonsticky (display)))
 477           (setq x (+ x dx))))
 478       (setq x 0.0
 479             y (+ y dy))
 480       (insert (propertize "\n" 'line-height t)))))
 481
 482
 483
 484 ;;;###autoload
 485 (defun remove-images (start end &optional buffer)
 486   "Remove images between START and END in BUFFER.
 487 Remove only images that were put in BUFFER with calls to `put-image'.
 488 BUFFER nil or omitted means use the current buffer."
 489   (unless buffer
 490     (setq buffer (current-buffer)))
 491   (let ((overlays (overlays-in start end)))
 492     (while overlays
 493       (let ((overlay (car overlays)))
 494         (when (overlay-get overlay 'put-image)
 495           (delete-overlay overlay)))
 496       (setq overlays (cdr overlays)))))
 497
 498 (defun image-search-load-path (file &optional path)
 499   (unless path
 500     (setq path image-load-path))
 501   (let (element found filename)
 502     (while (and (not found) (consp path))
 503       (setq element (car path))
 504       (cond
 505        ((stringp element)
 506         (setq found
 507               (file-readable-p
 508                (setq filename (expand-file-name file element)))))
 509        ((and (symbolp element) (boundp element))
 510         (setq element (symbol-value element))
 511         (cond
 512          ((stringp element)
 513           (setq found
 514                 (file-readable-p
 515                  (setq filename (expand-file-name file element)))))
 516          ((consp element)
 517           (if (setq filename (image-search-load-path file element))
 518               (setq found t))))))
 519       (setq path (cdr path)))
 520     (if found filename)))
 521
 522 ;;;###autoload
 523 (defun find-image (specs)
 524   "Find an image, choosing one of a list of image specifications.
 525
 526 SPECS is a list of image specifications.
 527
 528 Each image specification in SPECS is a property list.  The contents of
 529 a specification are image type dependent.  All specifications must at
 530 least contain the properties `:type TYPE' and either `:file FILE' or
 531 `:data DATA', where TYPE is a symbol specifying the image type,
 532 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 533 string containing the actual image data.  The specification whose TYPE
 534 is supported, and FILE exists, is used to construct the image
 535 specification to be returned.  Return nil if no specification is
 536 satisfied.
 537
 538 The image is looked for in `image-load-path'.
 539
 540 Image files should not be larger than specified by `max-image-size'."
 541   (let (image)
 542     (while (and specs (null image))
 543       (let* ((spec (car specs))
 544              (type (plist-get spec :type))
 545              (data (plist-get spec :data))
 546              (file (plist-get spec :file))
 547              found)
 548         (when (image-type-available-p type)
 549           (cond ((stringp file)
 550                  (if (setq found (image-search-load-path file))
 551                      (setq image
 552                            (cons 'image (plist-put (copy-sequence spec)
 553                                                    :file found)))))
 554                 ((not (null data))
 555                  (setq image (cons 'image spec)))))
 556         (setq specs (cdr specs))))
 557     image))
 558
 559
 560 ;;;###autoload
 561 (defmacro defimage (symbol specs &optional doc)
 562   "Define SYMBOL as an image.
 563
 564 SPECS is a list of image specifications.  DOC is an optional
 565 documentation string.
 566
 567 Each image specification in SPECS is a property list.  The contents of
 568 a specification are image type dependent.  All specifications must at
 569 least contain the properties `:type TYPE' and either `:file FILE' or
 570 `:data DATA', where TYPE is a symbol specifying the image type,
 571 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 572 string containing the actual image data.  The first image
 573 specification whose TYPE is supported, and FILE exists, is used to
 574 define SYMBOL.
 575
 576 Example:
 577
 578    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 579                          (:type xbm :file \"~/test1.xbm\")))"
 580   (declare (doc-string 3))
 581   `(defvar ,symbol (find-image ',specs) ,doc))
 582
 583
 584 (provide 'image)
 585
 586 ;; arch-tag: 8e76a07b-eb48-4f3e-a7a0-1a7ba9f096b3
 587 ;;; image.el ends here