lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: mouse, terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Enable mouse support when running inside an xterm.
  29
  30 ;; This is actually useful when you are running X11 locally, but is
  31 ;; working on remote machine over a modem line or through a gateway.
  32
  33 ;; It works by translating xterm escape codes into generic emacs mouse
  34 ;; events so it should work with any package that uses the mouse.
  35
  36 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  37 ;; functionality, it is still available by holding down the SHIFT key
  38 ;; when you press the mouse button.
  39
  40 ;;; Todo:
  41
  42 ;; Support multi-click -- somehow.
  43
  44 ;;; Code:
  45
  46 ;; XXX Perhaps this should be terminal-local instead. --lorentey
  47 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  48
  49 (defvar xterm-mouse-last)
  50
  51 ;; Mouse events symbols must have an 'event-kind property with
  52 ;; the value 'mouse-click.
  53 (dolist (event-type '(mouse-1 mouse-2 mouse-3))
  54   (put event-type 'event-kind 'mouse-click))
  55
  56 (defun xterm-mouse-translate (event)
  57   "Read a click and release event from XTerm."
  58   (save-excursion
  59     (save-window-excursion
  60       (deactivate-mark)
  61       (let* ((xterm-mouse-last)
  62              (down (xterm-mouse-event))
  63              (down-command (nth 0 down))
  64              (down-data (nth 1 down))
  65              (down-where (nth 1 down-data))
  66              (down-binding (key-binding (if (symbolp down-where)
  67                                             (vector down-where down-command)
  68                                           (vector down-command))))
  69              (is-click (string-match "^mouse" (symbol-name (car down)))))
  70
  71         (unless is-click
  72           (unless (and (eq (read-char) ?\e)
  73                        (eq (read-char) ?\[)
  74                        (eq (read-char) ?M))
  75             (error "Unexpected escape sequence from XTerm")))
  76
  77         (let* ((click (if is-click down (xterm-mouse-event)))
  78                (click-command (nth 0 click))
  79                (click-data (nth 1 click))
  80                (click-where (nth 1 click-data)))
  81           (if (memq down-binding '(nil ignore))
  82               (if (and (symbolp click-where)
  83                        (consp click-where))
  84                   (vector (list click-where click-data) click)
  85                 (vector click))
  86             (setq unread-command-events
  87                   (if (eq down-where click-where)
  88                       (list click)
  89                     (list
  90                      ;; Cheat `mouse-drag-region' with move event.
  91                      (list 'mouse-movement click-data)
  92                      ;; Generate a drag event.
  93                      (if (symbolp down-where)
  94                          0
  95                        (list (intern (format "drag-mouse-%d"
  96                                              (+ 1 xterm-mouse-last)))
  97                              down-data click-data)))))
  98             (if (and (symbolp down-where)
  99                      (consp down-where))
 100                 (vector (list down-where down-data) down)
 101               (vector down))))))))
 102
 103 ;; These two variables have been converted to terminal parameters.
 104 ;;
 105 ;;(defvar xterm-mouse-x 0
 106 ;;  "Position of last xterm mouse event relative to the frame.")
 107 ;;
 108 ;;(defvar xterm-mouse-y 0
 109 ;;  "Position of last xterm mouse event relative to the frame.")
 110
 111 ;; Indicator for the xterm-mouse mode.
 112
 113 (defun xterm-mouse-position-function (pos)
 114   "Bound to `mouse-position-function' in XTerm mouse mode."
 115   (when (terminal-parameter nil 'xterm-mouse-x)
 116     (setcdr pos (cons (terminal-parameter nil 'xterm-mouse-x)
 117                       (terminal-parameter nil 'xterm-mouse-y))))
 118   pos)
 119
 120 ;; read xterm sequences above ascii 127 (#x7f)
 121 (defun xterm-mouse-event-read ()
 122   (let ((c (read-char)))
 123     (if (< c 0)
 124         (+ c #x8000000 128)
 125       c)))
 126
 127 (defun xterm-mouse-event ()
 128   "Convert XTerm mouse event to Emacs mouse event."
 129   (let* ((type (- (xterm-mouse-event-read) #o40))
 130          (x (- (xterm-mouse-event-read) #o40 1))
 131          (y (- (xterm-mouse-event-read) #o40 1))
 132          (mouse (intern
 133                  ;; For buttons > 3, the release-event looks
 134                  ;; differently (see xc/programs/xterm/button.c,
 135                  ;; function EditorButton), and there seems to come in
 136                  ;; a release-event only, no down-event.
 137                  (cond ((>= type 64)
 138                         (format "mouse-%d" (- type 60)))
 139                        ((= type 3)
 140                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 141                        (t
 142                         (setq xterm-mouse-last type)
 143                         (format "down-mouse-%d" (+ 1 type))))))
 144          (w (window-at x y))
 145          (ltrb (window-edges w))
 146          (left (nth 0 ltrb))
 147          (top (nth 1 ltrb)))
 148
 149     (set-terminal-parameter nil 'xterm-mouse-x x)
 150     (set-terminal-parameter nil 'xterm-mouse-y y)
 151     (setq
 152      last-input-event
 153      (if w
 154          (list mouse (posn-at-x-y (- x left) (- y top) w t))
 155        (list mouse
 156              (append (list nil 'menu-bar) (nthcdr 2 (posn-at-x-y x y w t))))))))
 157
 158 ;;;###autoload
 159 (define-minor-mode xterm-mouse-mode
 160   "Toggle XTerm mouse mode.
 161 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 162
 163 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 164 This works in terminal emulators compatible with xterm.  It only
 165 works for simple uses of the mouse.  Basically, only non-modified
 166 single clicks are supported.  When turned on, the normal xterm
 167 mouse functionality for such clicks is still available by holding
 168 down the SHIFT key while pressing the mouse button."
 169   :global t :group 'mouse
 170   (if xterm-mouse-mode
 171       ;; Turn it on
 172       (progn
 173         (setq mouse-position-function #'xterm-mouse-position-function)
 174         (turn-on-xterm-mouse-tracking))
 175     ;; Turn it off
 176     (turn-off-xterm-mouse-tracking 'force)
 177     (setq mouse-position-function nil)))
 178
 179 (defun turn-on-xterm-mouse-tracking ()
 180   "Enable Emacs mouse tracking in xterm."
 181   (dolist (f (frame-list))
 182     (when (eq t (frame-live-p f))
 183       (with-selected-frame f
 184         (when xterm-mouse-mode
 185           (send-string-to-terminal "\e[?1000h"))))))
 186
 187 (defun turn-off-xterm-mouse-tracking (&optional force)
 188   "Disable Emacs mouse tracking in xterm."
 189   (dolist (f (frame-list))
 190     (when (eq t (frame-live-p f))
 191       (with-selected-frame f
 192         (when (or force xterm-mouse-mode)
 193           (send-string-to-terminal "\e[?1000l"))))))
 194
 195 (defun turn-on-xterm-mouse-tracking-on-terminal (terminal)
 196   "Enable xterm mouse tracking on TERMINAL."
 197   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal)))
 198     (send-string-to-terminal "\e[?1000h" terminal)))
 199
 200 (defun turn-off-xterm-mouse-tracking-on-terminal (terminal)
 201   "Disable xterm mouse tracking on TERMINAL."
 202   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal)))
 203     (send-string-to-terminal "\e[?1000l" terminal)))
 204
 205 (defun xterm-mouse-handle-delete-frame (frame)
 206   "Turn off xterm mouse tracking if FRAME is the last frame on its device."
 207   (when (and (eq t (frame-live-p frame))
 208              (<= 1 (length (frames-on-display-list (frame-terminal frame)))))
 209     (turn-off-xterm-mouse-tracking-on-terminal frame)))
 210
 211 ;; Frame creation and deletion.
 212 (add-hook 'after-make-frame-functions 'turn-on-xterm-mouse-tracking-on-terminal)
 213 (add-hook 'delete-frame-functions 'xterm-mouse-handle-delete-frame)
 214
 215 ;; Restore normal mouse behaviour outside Emacs.
 216 (add-hook 'suspend-tty-functions 'turn-off-xterm-mouse-tracking-on-terminal)
 217 (add-hook 'resume-tty-functions 'turn-on-xterm-mouse-tracking-on-terminal)
 218 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 219 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 220 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 221
 222 (provide 'xt-mouse)
 223
 224 ;;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 225 ;;; xt-mouse.el ends here