lisp/which-func.el

   1 ;;; which-func.el --- Print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   6 ;;           (doesn't seem to be responsive any more)
   7 ;; Keywords: mode-line, imenu, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package prints name of function where your current point is
  29 ;; located in mode line. It assumes that you work with imenu package
  30 ;; and imenu--index-alist is up to date.
  31
  32 ;; KNOWN BUGS
  33 ;; ----------
  34 ;; Really this package shows not "function where the current point is
  35 ;; located now", but "nearest function which defined above the current
  36 ;; point". So if your current point is located after end of function
  37 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  38 ;; line.
  39 ;; - if two windows display the same buffer, both windows
  40 ;;   show the same `which-func' information.
  41
  42 ;; TODO LIST
  43 ;; ---------
  44 ;;     1. Dependence on imenu package should be removed.  Separate
  45 ;; function determination mechanism should be used to determine the end
  46 ;; of a function as well as the beginning of a function.
  47 ;;     2. This package should be realized with the help of overlay
  48 ;; properties instead of imenu--index-alist variable.
  49
  50 ;;; History:
  51
  52 ;; THANKS TO
  53 ;; ---------
  54 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  55 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  56 ;;     and toggling this  mode) have  been   borrowed from  his  package
  57 ;;     column.el
  58 ;; Peter Eisenhauer <pipe@fzi.de>
  59 ;;     Bug fixing in case nested indexes.
  60 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  61 ;;     Suggestion to use find-file-hooks for first imenu
  62 ;;     index building.
  63
  64 ;;; Code:
  65
  66 ;; Variables for customization
  67 ;; ---------------------------
  68 ;;
  69 (defvar which-func-unknown "???"
  70   "String to display in the mode line when current function is unknown.")
  71
  72 (defgroup which-func nil
  73   "Mode to display the current function name in the modeline."
  74   :group 'tools
  75   :version "20.3")
  76
  77 (defcustom which-func-modes
  78   '(emacs-lisp-mode c-mode c++-mode perl-mode cperl-mode makefile-mode
  79                     sh-mode fortran-mode)
  80   "List of major modes for which Which Function mode should be used.
  81 For other modes it is disabled.  If this is equal to t,
  82 then Which Function mode is enabled in any major mode that supports it."
  83   :group 'which-func
  84   :type '(choice (const :tag "All modes" t)
  85                  (repeat (symbol :tag "Major mode"))))
  86
  87 (defcustom which-func-non-auto-modes nil
  88   "List of major modes where Which Function mode is inactive till Imenu is used.
  89 This means that Which Function mode won't really do anything
  90 until you use Imenu, in these modes.  Note that files
  91 larger than `which-func-maxout' behave in this way too;
  92 Which Function mode doesn't do anything until you use Imenu."
  93   :group 'which-func
  94   :type '(repeat (symbol :tag "Major mode")))
  95
  96 (defcustom which-func-maxout 500000
  97   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  98 Zero means compute the Imenu menu regardless of size."
  99   :group 'which-func
 100   :type 'integer)
 101
 102 (defcustom which-func-format '("[" which-func-current "]")
 103   "Format for displaying the function in the mode line."
 104   :group 'which-func
 105   :type 'sexp)
 106
 107 (defvar which-func-cleanup-function nil
 108   "Function to transform a string before displaying it in the mode line.
 109 The function is called with one argument, the string to display.
 110 Its return value is displayed in the modeline.
 111 If nil, no function is called.  The default value is nil.
 112
 113 This feature can be useful if Imenu is set up to make more
 114 detailed entries (e.g., containing the argument list of a function),
 115 and you want to simplify them for the mode line
 116 \(e.g., removing the parameter list to just have the function name.)")
 117
 118 ;;; Code, nothing to customize below here
 119 ;;; -------------------------------------
 120 ;;;
 121 (require 'imenu)
 122
 123 (defvar which-func-current  which-func-unknown)
 124 (defvar which-func-previous which-func-unknown)
 125 (make-variable-buffer-local 'which-func-current)
 126 (make-variable-buffer-local 'which-func-previous)
 127
 128 (defvar which-func-mode nil
 129   "Non-nil means display current function name in mode line.
 130 This makes a difference only if `which-func-mode-global' is non-nil")
 131 (make-variable-buffer-local 'which-func-mode)
 132 ;;(put 'which-func-mode 'permanent-local t)
 133
 134 (add-hook 'find-file-hooks 'which-func-ff-hook t)
 135
 136 (defun which-func-ff-hook ()
 137   "File find hook for Which Function mode.
 138 It creates the Imenu index for the buffer, if necessary."
 139   (setq which-func-mode
 140         (and which-func-mode-global
 141              (or (eq which-func-modes t) (member major-mode which-func-modes))))
 142
 143   (condition-case nil
 144       (if (and which-func-mode
 145                (not (member major-mode which-func-non-auto-modes))
 146                (or (null which-func-maxout)
 147                    (< buffer-saved-size which-func-maxout)
 148                    (= which-func-maxout 0)))
 149           (setq imenu--index-alist
 150                 (save-excursion (funcall imenu-create-index-function))))
 151     (error
 152      (setq which-func-mode nil))))
 153
 154 (defun which-func-update ()
 155   ;; Update the string containing the current function.
 156   (when which-func-mode
 157     (condition-case info
 158         (progn
 159           (setq which-func-current (or (which-function) which-func-unknown))
 160           (unless (string= which-func-current which-func-previous)
 161             (force-mode-line-update)
 162             (setq which-func-previous which-func-current)))
 163       (error
 164        (which-func-mode -1)
 165        (error "Error in which-func-update: %s" info)))))
 166
 167 ;;;###autoload
 168 (defalias 'which-func-mode 'which-function-mode)
 169
 170 ;; This is the name people would normally expect.
 171 ;;;###autoload
 172 (define-minor-mode which-function-mode
 173   "Toggle Which Function mode, globally.
 174 When Which Function mode is enabled, the current function name is
 175 continuously displayed in the mode line, in certain major modes.
 176
 177 With prefix ARG, turn Which Function mode on iff arg is positive,
 178 and off otherwise."
 179   :global t :group 'which-func
 180   (if which-func-mode-global
 181       ;;Turn it on
 182       (progn
 183         (add-hook 'post-command-idle-hook 'which-func-update)
 184         (dolist (buf (buffer-list))
 185           (with-current-buffer buf
 186             (setq which-func-mode
 187                   (or (eq which-func-modes t)
 188                       (member major-mode which-func-modes))))))
 189     ;; Turn it off
 190     (remove-hook 'post-command-idle-hook 'which-func-update)
 191     (dolist (buf (buffer-list))
 192       (with-current-buffer buf (setq which-func-mode nil)))))
 193
 194 (defun which-function ()
 195   "Return current function name based on point.
 196 Uses `imenu--index-alist' or `add-log-current-defun-function'.
 197 If no function name is found, return nil."
 198   (let (name)
 199     ;; First try using imenu support.
 200     (when (and (boundp 'imenu--index-alist) imenu--index-alist)
 201       (let ((pair (car-safe imenu--index-alist))
 202             (rest (cdr-safe imenu--index-alist)))
 203         (while (and (or rest pair)
 204                     (or (not (number-or-marker-p (cdr pair)))
 205                         (> (point) (cdr pair))))
 206           (setq name (car pair))
 207           (setq pair (car-safe rest))
 208           (setq rest (cdr-safe rest)))))
 209     ;; Try using add-log support.
 210     (when (and (null name) (boundp 'add-log-current-defun-function)
 211                add-log-current-defun-function)
 212       (setq name (funcall add-log-current-defun-function)))
 213     ;; Filter the name if requested.
 214     (when name
 215       (if which-func-cleanup-function
 216           (funcall which-func-cleanup-function name)
 217         name))))
 218
 219 (provide 'which-func)
 220
 221 ;; which-func.el ends here