lisp/vc-sccs.el

   1 ;;; vc-sccs.el --- support for SCCS version-control
   2
   3 ;; Copyright (C) 1992,93,94,95,96,97,98,99,2000,2001 Free Software Foundation, Inc.
   4
   5 ;; Author:     FSF (see vc.el for full credits)
   6 ;; Maintainer: Andre Spiegel <spiegel@gnu.org>
   7
   8 ;; $Id: vc-sccs.el,v 1.10 2001/03/10 10:51:22 spiegel Exp $
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile
  32   (require 'vc))
  33
  34 ;;;
  35 ;;; Customization options
  36 ;;;
  37
  38 (defcustom vc-sccs-register-switches nil
  39   "*Extra switches for registering a file in SCCS.
  40 A string or list of strings passed to the checkin program by
  41 \\[vc-sccs-register]."
  42   :type '(choice (const :tag "None" nil)
  43                  (string :tag "Argument String")
  44                  (repeat :tag "Argument List"
  45                          :value ("")
  46                          string))
  47   :version "21.1"
  48   :group 'vc)
  49
  50 (defcustom vc-sccs-diff-switches nil
  51   "*A string or list of strings specifying extra switches for `vcdiff',
  52 the diff utility used for SCCS under VC."
  53     :type '(choice (const :tag "None" nil)
  54                  (string :tag "Argument String")
  55                  (repeat :tag "Argument List"
  56                          :value ("")
  57                          string))
  58   :version "21.1"
  59   :group 'vc)
  60
  61 (defcustom vc-sccs-header (or (cdr (assoc 'SCCS vc-header-alist)) '("%W%"))
  62   "*Header keywords to be inserted by `vc-insert-headers'."
  63   :type '(repeat string)
  64   :group 'vc)
  65
  66 ;;;###autoload
  67 (defcustom vc-sccs-master-templates
  68   '("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir)
  69   "*Where to look for SCCS master files.
  70 For a description of possible values, see `vc-check-master-templates'."
  71   :type '(choice (const :tag "Use standard SCCS file names"
  72                         ("%sSCCS/s.%s" "%ss.%s" vc-sccs-search-project-dir))
  73                  (repeat :tag "User-specified"
  74                          (choice string
  75                                  function)))
  76   :version "21.1"
  77   :group 'vc)
  78
  79 \f
  80 ;;;
  81 ;;; Internal variables
  82 ;;;
  83
  84 (defconst vc-sccs-name-assoc-file "VC-names")
  85
  86 \f
  87 ;;;
  88 ;;; State-querying functions
  89 ;;;
  90
  91 ;;;###autoload
  92 (progn (defun vc-sccs-registered (f) (vc-default-registered 'SCCS f)))
  93
  94 (defun vc-sccs-state (file)
  95   "SCCS-specific function to compute the version control state."
  96   (with-temp-buffer
  97     (if (vc-insert-file (vc-sccs-lock-file file))
  98         (let* ((locks (vc-sccs-parse-locks))
  99                (workfile-version (vc-workfile-version file))
 100                (locking-user (cdr (assoc workfile-version locks))))
 101           (if (not locking-user)
 102               (if (vc-workfile-unchanged-p file)
 103                   'up-to-date
 104                 'unlocked-changes)
 105             (if (string= locking-user (vc-user-login-name))
 106                 'edited
 107               locking-user)))
 108       'up-to-date)))
 109
 110 (defun vc-sccs-state-heuristic (file)
 111   "SCCS-specific state heuristic."
 112   (if (not (vc-mistrust-permissions file))
 113       ;;   This implementation assumes that any file which is under version
 114       ;; control and has -rw-r--r-- is locked by its owner.  This is true
 115       ;; for both RCS and SCCS, which keep unlocked files at -r--r--r--.
 116       ;; We have to be careful not to exclude files with execute bits on;
 117       ;; scripts can be under version control too.  Also, we must ignore the
 118       ;; group-read and other-read bits, since paranoid users turn them off.
 119       (let* ((attributes (file-attributes file))
 120              (owner-uid  (nth 2 attributes))
 121              (permissions (nth 8 attributes)))
 122         (if (string-match ".r-..-..-." permissions)
 123             'up-to-date
 124           (if (string-match ".rw..-..-." permissions)
 125               (if (file-ownership-preserved-p file)
 126                   'edited
 127                 (vc-user-login-name owner-uid))
 128           ;; Strange permissions.
 129           ;; Fall through to real state computation.
 130           (vc-sccs-state file)))
 131     (vc-sccs-state file))))
 132
 133 (defun vc-sccs-workfile-version (file)
 134   "SCCS-specific version of `vc-workfile-version'."
 135   (with-temp-buffer
 136     (vc-insert-file (vc-name file) "^\001e")
 137     (vc-parse-buffer "^\001d D \\([^ ]+\\)" 1)))
 138
 139 (defun vc-sccs-checkout-model (file)
 140   "SCCS-specific version of `vc-checkout-model'."
 141   'locking)
 142
 143 (defun vc-sccs-workfile-unchanged-p (file)
 144   "SCCS-specific implementation of vc-workfile-unchanged-p."
 145   (zerop (apply 'vc-do-command nil 1 "vcdiff" (vc-name file)
 146                 (list "--brief" "-q"
 147                       (concat "-r" (vc-workfile-version file))))))
 148
 149 \f
 150 ;;;
 151 ;;; State-changing functions
 152 ;;;
 153
 154 (defun vc-sccs-register (file &optional rev comment)
 155   "Register FILE into the SCCS version-control system.
 156 REV is the optional revision number for the file.  COMMENT can be used
 157 to provide an initial description of FILE.
 158
 159 `vc-register-switches' and `vc-sccs-register-switches' are passed to
 160 the SCCS command (in that order).
 161
 162 Automatically retrieve a read-only version of the file with keywords
 163 expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
 164     (let* ((switches (list
 165                      (if (stringp vc-register-switches)
 166                          (list vc-register-switches)
 167                        vc-register-switches)
 168                      (if (stringp vc-sccs-register-switches)
 169                          (list vc-sccs-register-switches)
 170                        vc-sccs-register-switches)))
 171            (dirname (or (file-name-directory file) ""))
 172            (basename (file-name-nondirectory file))
 173            (project-file (vc-sccs-search-project-dir dirname basename)))
 174       (let ((vc-name
 175              (or project-file
 176                  (format (car vc-sccs-master-templates) dirname basename)))|)
 177         (apply 'vc-do-command nil 0 "admin" vc-name
 178                (and rev (concat "-r" rev))
 179                "-fb"
 180                (concat "-i" (file-relative-name file))
 181                (and comment (concat "-y" comment))
 182                switches))
 183       (delete-file file)
 184       (if vc-keep-workfiles
 185           (vc-do-command nil 0 "get" (vc-name file)))))
 186
 187 (defun vc-sccs-responsible-p (file)
 188   "Return non-nil if SCCS thinks it would be responsible for registering FILE."
 189   ;; TODO: check for all the patterns in vc-sccs-master-templates
 190   (or (file-directory-p (expand-file-name "SCCS" (file-name-directory file)))
 191       (stringp (vc-sccs-search-project-dir (or (file-name-directory file) "")
 192                                            (file-name-nondirectory file)))))
 193
 194 (defun vc-sccs-checkin (file rev comment)
 195   "SCCS-specific version of `vc-backend-checkin'."
 196   (let ((switches (if (stringp vc-checkin-switches)
 197                       (list vc-checkin-switches)
 198                     vc-checkin-switches)))
 199     (apply 'vc-do-command nil 0 "delta" (vc-name file)
 200            (if rev (concat "-r" rev))
 201            (concat "-y" comment)
 202            switches)
 203     (if vc-keep-workfiles
 204         (vc-do-command nil 0 "get" (vc-name file)))))
 205
 206 (defun vc-sccs-checkout (file &optional editable rev workfile)
 207   "Retrieve a copy of a saved version of SCCS controlled FILE into a WORKFILE.
 208 EDITABLE non-nil means that the file should be writable and
 209 locked.  REV is the revision to check out into WORKFILE."
 210   (let ((filename (or workfile file))
 211         (file-buffer (get-file-buffer file))
 212         switches)
 213     (message "Checking out %s..." filename)
 214     (save-excursion
 215       ;; Change buffers to get local value of vc-checkout-switches.
 216       (if file-buffer (set-buffer file-buffer))
 217       (setq switches (if (stringp vc-checkout-switches)
 218                          (list vc-checkout-switches)
 219                        vc-checkout-switches))
 220       ;; Save this buffer's default-directory
 221       ;; and use save-excursion to make sure it is restored
 222       ;; in the same buffer it was saved in.
 223       (let ((default-directory default-directory))
 224         (save-excursion
 225           ;; Adjust the default-directory so that the check-out creates
 226           ;; the file in the right place.
 227           (setq default-directory (file-name-directory filename))
 228
 229           (and rev (string= rev "") (setq rev nil))
 230           (if workfile
 231               ;; Some SCCS implementations allow checking out directly to a
 232               ;; file using the -G option, but then some don't so use the
 233               ;; least common denominator approach and use the -p option
 234               ;; ala RCS.
 235               (let ((vc-modes (logior (file-modes (vc-name file))
 236                                       (if editable 128 0)))
 237                     (failed t))
 238                 (unwind-protect
 239                     (progn
 240                       (let ((coding-system-for-read 'no-conversion)
 241                             (coding-system-for-write 'no-conversion))
 242                         (with-temp-file filename
 243                           (apply 'vc-do-command
 244                                  (current-buffer) 0 "get" (vc-name file)
 245                                  "-s" ;; suppress diagnostic output
 246                                  (if editable "-e")
 247                                  "-p"
 248                                  (and rev
 249                                       (concat "-r"
 250                                               (vc-sccs-lookup-triple file rev)))
 251                                  switches)))
 252                       (set-file-modes filename
 253                                       (logior (file-modes (vc-name file))
 254                                               (if editable 128 0)))
 255                       (setq failed nil))
 256                   (and failed (file-exists-p filename)
 257                        (delete-file filename))))
 258             (apply 'vc-do-command nil 0 "get" (vc-name file)
 259                    (if editable "-e")
 260                    (and rev (concat "-r" (vc-sccs-lookup-triple file rev)))
 261                    switches)))))
 262     (message "Checking out %s...done" filename)))
 263
 264 (defun vc-sccs-revert (file)
 265   "Revert FILE to the version it was based on."
 266   (vc-do-command nil 0 "unget" (vc-name file))
 267   (vc-do-command nil 0 "get" (vc-name file))
 268   ;; Checking out explicit versions is not supported under SCCS, yet.
 269   ;; We always "revert" to the latest version; therefore
 270   ;; vc-workfile-version is cleared here so that it gets recomputed.
 271   (vc-file-setprop file 'vc-workfile-version nil))
 272
 273 (defun vc-sccs-cancel-version (file editable)
 274   "Undo the most recent checkin of FILE.
 275 EDITABLE non-nil means previous version should be locked."
 276   (vc-do-command nil 0 "rmdel"
 277                  (vc-name file)
 278                  (concat "-r" (vc-workfile-version file)))
 279   (vc-do-command nil 0 "get"
 280                  (vc-name file)
 281                  (if editable "-e")))
 282
 283 (defun vc-sccs-steal-lock (file &optional rev)
 284   "Steal the lock on the current workfile for FILE and revision REV."
 285   (vc-do-command nil 0 "unget" (vc-name file) "-n" (if rev (concat "-r" rev)))
 286   (vc-do-command nil 0 "get" (vc-name file) "-g" (if rev (concat "-r" rev))))
 287
 288 \f
 289 ;;;
 290 ;;; History functions
 291 ;;;
 292
 293 (defun vc-sccs-print-log (file)
 294   "Get change log associated with FILE."
 295   (vc-do-command nil 0 "prs" (vc-name file)))
 296
 297 (defun vc-sccs-logentry-check ()
 298   "Check that the log entry in the current buffer is acceptable for SCCS."
 299   (when (>= (buffer-size) 512)
 300     (goto-char 512)
 301     (error "Log must be less than 512 characters; point is now at pos 512")))
 302
 303 (defun vc-sccs-diff (file &optional oldvers newvers)
 304   "Get a difference report using SCCS between two versions of FILE."
 305   (setq oldvers (vc-sccs-lookup-triple file oldvers))
 306   (setq newvers (vc-sccs-lookup-triple file newvers))
 307   (apply 'vc-do-command "*vc-diff*" 1 "vcdiff" (vc-name file)
 308          (append (list "-q"
 309                        (and oldvers (concat "-r" oldvers))
 310                        (and newvers (concat "-r" newvers)))
 311                  (vc-diff-switches-list sccs))))
 312
 313 \f
 314 ;;;
 315 ;;; Snapshot system
 316 ;;;
 317
 318 (defun vc-sccs-assign-name (file name)
 319   "Assign to FILE's latest version a given NAME."
 320   (vc-sccs-add-triple name file (vc-workfile-version file)))
 321
 322 \f
 323 ;;;
 324 ;;; Miscellaneous
 325 ;;;
 326
 327 (defun vc-sccs-check-headers ()
 328   "Check if the current file has any headers in it."
 329   (save-excursion
 330     (goto-char (point-min))
 331     (re-search-forward  "%[A-Z]%" nil t)))
 332
 333 (defun vc-sccs-rename-file (old new)
 334   ;; Move the master file (using vc-rcs-master-templates).
 335   (vc-rename-master (vc-name old) new vc-sccs-master-templates)
 336   ;; Update the snapshot file.
 337   (with-current-buffer
 338       (find-file-noselect
 339        (expand-file-name vc-sccs-name-assoc-file
 340                          (file-name-directory (vc-name old))))
 341     (goto-char (point-min))
 342     ;; (replace-regexp (concat ":" (regexp-quote old) "$") (concat ":" new))
 343     (while (re-search-forward (concat ":" (regexp-quote old) "$") nil t)
 344       (replace-match (concat ":" new) nil nil))
 345     (basic-save-buffer)
 346     (kill-buffer (current-buffer))))
 347
 348 \f
 349 ;;;
 350 ;;; Internal functions
 351 ;;;
 352
 353 ;; This function is wrapped with `progn' so that the autoload cookie
 354 ;; copies the whole function itself into loaddefs.el rather than just placing
 355 ;; a (autoload 'vc-sccs-search-project-dir "vc-sccs") which would not
 356 ;; help us avoid loading vc-sccs.
 357 ;;;###autoload
 358 (progn (defun vc-sccs-search-project-dir (dirname basename)
 359   "Return the name of a master file in the SCCS project directory.
 360 Does not check whether the file exists but returns nil if it does not
 361 find any project directory."
 362   (let ((project-dir (getenv "PROJECTDIR")) dirs dir)
 363     (when project-dir
 364       (if (file-name-absolute-p project-dir)
 365           (setq dirs '("SCCS" ""))
 366         (setq dirs '("src/SCCS" "src" "source/SCCS" "source"))
 367         (setq project-dir (expand-file-name (concat "~" project-dir))))
 368       (while (and (not dir) dirs)
 369         (setq dir (expand-file-name (car dirs) project-dir))
 370         (unless (file-directory-p dir)
 371           (setq dir nil)
 372           (setq dirs (cdr dirs))))
 373       (and dir (expand-file-name (concat "s." basename) dir))))))
 374
 375 (defun vc-sccs-lock-file (file)
 376   "Generate lock file name corresponding to FILE."
 377   (let ((master (vc-name file)))
 378     (and
 379      master
 380      (string-match "\\(.*/\\)\\(s\\.\\)\\(.*\\)" master)
 381      (replace-match "p." t t master 2))))
 382
 383 (defun vc-sccs-parse-locks ()
 384   "Parse SCCS locks in current buffer.
 385 The result is a list of the form ((VERSION . USER) (VERSION . USER) ...)."
 386   (let (master-locks)
 387     (goto-char (point-min))
 388     (while (re-search-forward "^\\([0-9.]+\\) [0-9.]+ \\([^ ]+\\) .*\n?"
 389                               nil t)
 390       (setq master-locks
 391             (cons (cons (match-string 1) (match-string 2)) master-locks)))
 392     ;; FIXME: is it really necessary to reverse ?
 393     (nreverse master-locks)))
 394
 395 (defun vc-sccs-add-triple (name file rev)
 396   (with-current-buffer
 397       (find-file-noselect
 398        (expand-file-name vc-sccs-name-assoc-file
 399                          (file-name-directory (vc-name file))))
 400     (goto-char (point-max))
 401     (insert name "\t:\t" file "\t" rev "\n")
 402     (basic-save-buffer)
 403     (kill-buffer (current-buffer))))
 404
 405 (defun vc-sccs-lookup-triple (file name)
 406   "Return the numeric version corresponding to a named snapshot of FILE.
 407 If NAME is nil or a version number string it's just passed through."
 408   (if (or (null name)
 409           (let ((firstchar (aref name 0)))
 410             (and (>= firstchar ?0) (<= firstchar ?9))))
 411       name
 412     (with-temp-buffer
 413       (vc-insert-file
 414        (expand-file-name vc-sccs-name-assoc-file
 415                          (file-name-directory (vc-name file))))
 416       (vc-parse-buffer (concat name "\t:\t" file "\t\\(.+\\)") 1))))
 417
 418 (provide 'vc-sccs)
 419
 420 ;;; vc-sccs.el ends here
 421
 422
 423