lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes.
   2 ;;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 ;; PUBLIC: define a new major mode which inherits from an existing one.
  95
  96 ;;;###autoload
  97 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
  98   "Create a new mode as a variant of an existing mode.
  99
 100 The arguments to this command are as follow:
 101
 102 CHILD:     the name of the command for the derived mode.
 103 PARENT:    the name of the command for the parent mode (e.g. `text-mode').
 104 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 105 DOCSTRING: an optional documentation string--if you do not supply one,
 106            the function will attempt to invent something useful.
 107 BODY:      forms to execute just before running the
 108            hooks for the new mode.
 109
 110 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 111
 112   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 113
 114 You could then make new key bindings for `LaTeX-thesis-mode-map'
 115 without changing regular LaTeX mode.  In this example, BODY is empty,
 116 and DOCSTRING is generated by default.
 117
 118 On a more complicated level, the following command uses `sgml-mode' as
 119 the parent, and then sets the variable `case-fold-search' to nil:
 120
 121   (define-derived-mode article-mode sgml-mode \"Article\"
 122     \"Major mode for editing technical articles.\"
 123     (setq case-fold-search nil))
 124
 125 Note that if the documentation string had been left out, it would have
 126 been generated automatically, with a reference to the keymap."
 127
 128   (when (and docstring (not (stringp docstring)))
 129     ;; Some trickiness, since what appears to be the docstring may really be
 130     ;; the first element of the body.
 131     (push docstring body)
 132     (setq docstring nil))
 133
 134   (unless parent (setq parent 'fundamental-mode))
 135
 136   (let ((map (derived-mode-map-name child))
 137         (syntax (derived-mode-syntax-table-name child))
 138         (abbrev (derived-mode-abbrev-table-name child))
 139         (hook (derived-mode-hook-name child))
 140         (docstring (derived-mode-make-docstring parent child docstring)))
 141
 142     `(progn
 143        (defvar ,map (make-sparse-keymap))
 144        (defvar ,syntax (make-char-table 'syntax-table nil))
 145        (defvar ,abbrev)
 146        (define-abbrev-table ',abbrev nil)
 147        (put ',child 'derived-mode-parent ',parent)
 148
 149        (defun ,child ()
 150          ,docstring
 151          (interactive)
 152                                         ; Run the parent.
 153          ;; (combine-run-hooks
 154
 155           (,parent)
 156                                         ; Identify special modes.
 157           (if (get (quote ,parent) 'special)
 158               (put (quote ,child) 'special t))
 159                                         ; Identify the child mode.
 160           (setq major-mode (quote ,child))
 161           (setq mode-name ,name)
 162                                         ; Set up maps and tables.
 163           (unless (keymap-parent ,map)
 164             (set-keymap-parent ,map (current-local-map)))
 165           (let ((parent (char-table-parent ,syntax)))
 166             (unless (and parent (not (eq parent (standard-syntax-table))))
 167               (set-char-table-parent ,syntax (syntax-table))))
 168           (when local-abbrev-table
 169             (mapatoms
 170              (lambda (symbol)
 171                (or (intern-soft (symbol-name symbol) ,abbrev)
 172                    (define-abbrev ,abbrev (symbol-name symbol)
 173                      (symbol-value symbol) (symbol-function symbol))))
 174              local-abbrev-table))
 175
 176           (use-local-map ,map)
 177           (set-syntax-table ,syntax)
 178           (setq local-abbrev-table ,abbrev)
 179                                         ; Splice in the body (if any).
 180           ,@body
 181           ;; )
 182                                         ; Run the hooks, if any.
 183          (run-hooks ',hook)))))
 184
 185 ;; PUBLIC: find if the current mode derives from another.
 186
 187 (defun derived-mode-p (&rest modes)
 188   "Non-nil if the current major mode is derived from one of MODES.
 189 Uses the `derived-mode-parent' property of the symbol to trace backwards."
 190   (let ((parent major-mode))
 191     (while (and (not (memq parent modes))
 192                 (setq parent (get parent 'derived-mode-parent))))
 193     parent))
 194
 195 ;; PUBLIC: find the ultimate class of a derived mode.
 196
 197 (defun derived-mode-class (mode)
 198   "Find the class of a major MODE.
 199 A mode's class is the first ancestor which is NOT a derived mode.
 200 Use the `derived-mode-parent' property of the symbol to trace backwards.
 201 Since major-modes might derive from each other and from `fundamental-mode',
 202 this function is not very useful.  Use `derived-mode-p' instead."
 203   (while (get mode 'derived-mode-parent)
 204     (setq mode (get mode 'derived-mode-parent)))
 205   mode)
 206
 207 \f
 208 ;;; PRIVATE
 209
 210 (defsubst derived-mode-hook-name (mode)
 211   "Construct the mode hook name based on mode name MODE."
 212   (intern (concat (symbol-name mode) "-hook")))
 213
 214 (defsubst derived-mode-map-name (mode)
 215   "Construct a map name based on a MODE name."
 216   (intern (concat (symbol-name mode) "-map")))
 217
 218 (defsubst derived-mode-syntax-table-name (mode)
 219   "Construct a syntax-table name based on a MODE name."
 220   (intern (concat (symbol-name mode) "-syntax-table")))
 221
 222 (defsubst derived-mode-abbrev-table-name (mode)
 223   "Construct an abbrev-table name based on a MODE name."
 224   (intern (concat (symbol-name mode) "-abbrev-table")))
 225
 226 (defun derived-mode-make-docstring (parent child &optional docstring)
 227   "Construct a docstring for a new mode if none is provided."
 228
 229   (let ((map (derived-mode-map-name child))
 230         (syntax (derived-mode-syntax-table-name child))
 231         (abbrev (derived-mode-abbrev-table-name child))
 232         (hook (derived-mode-hook-name child)))
 233
 234     (unless (stringp docstring)
 235       ;; Use a default docstring.
 236       (setq docstring
 237             (format "Major mode derived from `%s' by `define-derived-mode'.
 238 It inherits all of the parent's attributes, but has its own keymap,
 239 abbrev table and syntax table:
 240
 241   `%s', `%s' and `%s'
 242
 243 which more-or-less shadow %s's corresponding tables."
 244                     parent map abbrev syntax parent)))
 245
 246     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 247       ;; Make sure the docstring mentions the mode's hook
 248       (setq docstring
 249             (concat docstring
 250                     (if (eq parent 'fundamental-mode)
 251                         "\n\nThis mode "
 252                       (concat
 253                        "\n\nIn addition to any hooks its parent mode "
 254                        (if (string-match (regexp-quote (format "`%s'" parent))
 255                                          docstring) nil
 256                          (format "`%s' " parent))
 257                        "might have run,\nthis mode "))
 258                     (format "runs the hook `%s'" hook)
 259                     ", as the final step\nduring initialization.")))
 260
 261     (unless (string-match "\\\\[{[]" docstring)
 262       ;; And don't forget to put the mode's keymap
 263       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 264
 265     docstring))
 266
 267 \f
 268 ;;; OBSOLETE
 269 ;; The functions below are only provided for backward compatibility with
 270 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 271
 272 (defsubst derived-mode-setup-function-name (mode)
 273   "Construct a setup-function name based on a MODE name."
 274   (intern (concat (symbol-name mode) "-setup")))
 275
 276 \f
 277 ;; Utility functions for defining a derived mode.
 278
 279 ;;;###autoload
 280 (defun derived-mode-init-mode-variables (mode)
 281   "Initialise variables for a new MODE.
 282 Right now, if they don't already exist, set up a blank keymap, an
 283 empty syntax table, and an empty abbrev table -- these will be merged
 284 the first time the mode is used."
 285
 286   (if (boundp (derived-mode-map-name mode))
 287       t
 288     (eval `(defvar ,(derived-mode-map-name mode)
 289                (make-sparse-keymap)
 290                ,(format "Keymap for %s." mode)))
 291     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 292
 293   (if (boundp (derived-mode-syntax-table-name mode))
 294       t
 295     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 296              ;; Make a syntax table which doesn't specify anything
 297              ;; for any char.  Valid data will be merged in by
 298              ;; derived-mode-merge-syntax-tables.
 299              (make-char-table 'syntax-table nil)
 300              ,(format "Syntax table for %s." mode)))
 301     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 302
 303   (if (boundp (derived-mode-abbrev-table-name mode))
 304       t
 305     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 306              (progn
 307                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 308                (make-abbrev-table))
 309              ,(format "Abbrev table for %s." mode)))))
 310 \f
 311 ;; Utility functions for running a derived mode.
 312
 313 (defun derived-mode-set-keymap (mode)
 314   "Set the keymap of the new MODE, maybe merging with the parent."
 315   (let* ((map-name (derived-mode-map-name mode))
 316          (new-map (eval map-name))
 317          (old-map (current-local-map)))
 318     (and old-map
 319          (get map-name 'derived-mode-unmerged)
 320          (derived-mode-merge-keymaps old-map new-map))
 321     (put map-name 'derived-mode-unmerged nil)
 322     (use-local-map new-map)))
 323
 324 (defun derived-mode-set-syntax-table (mode)
 325   "Set the syntax table of the new MODE, maybe merging with the parent."
 326   (let* ((table-name (derived-mode-syntax-table-name mode))
 327          (old-table (syntax-table))
 328          (new-table (eval table-name)))
 329     (if (get table-name 'derived-mode-unmerged)
 330         (derived-mode-merge-syntax-tables old-table new-table))
 331     (put table-name 'derived-mode-unmerged nil)
 332     (set-syntax-table new-table)))
 333
 334 (defun derived-mode-set-abbrev-table (mode)
 335   "Set the abbrev table for MODE if it exists.
 336 Always merge its parent into it, since the merge is non-destructive."
 337   (let* ((table-name (derived-mode-abbrev-table-name mode))
 338          (old-table local-abbrev-table)
 339          (new-table (eval table-name)))
 340     (derived-mode-merge-abbrev-tables old-table new-table)
 341     (setq local-abbrev-table new-table)))
 342
 343 ;;;(defun derived-mode-run-setup-function (mode)
 344 ;;;  "Run the setup function if it exists."
 345
 346 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 347 ;;;    (if (fboundp fname)
 348 ;;;     (funcall fname))))
 349
 350 (defun derived-mode-run-hooks (mode)
 351   "Run the mode hook for MODE."
 352   (let ((hooks-name (derived-mode-hook-name mode)))
 353     (if (boundp hooks-name)
 354         (run-hooks hooks-name))))
 355
 356 ;; Functions to merge maps and tables.
 357
 358 (defun derived-mode-merge-keymaps (old new)
 359   "Merge an OLD keymap into a NEW one.
 360 The old keymap is set to be the last cdr of the new one, so that there will
 361 be automatic inheritance."
 362   ;; ?? Can this just use `set-keymap-parent'?
 363   (let ((tail new))
 364     ;; Scan the NEW map for prefix keys.
 365     (while (consp tail)
 366       (and (consp (car tail))
 367            (let* ((key (vector (car (car tail))))
 368                   (subnew (lookup-key new key))
 369                   (subold (lookup-key old key)))
 370              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 371              (and (keymapp subnew) (keymapp subold)
 372                   (derived-mode-merge-keymaps subold subnew))))
 373       (and (vectorp (car tail))
 374            ;; Search a vector of ASCII char bindings for prefix keys.
 375            (let ((i (1- (length (car tail)))))
 376              (while (>= i 0)
 377                (let* ((key (vector i))
 378                       (subnew (lookup-key new key))
 379                       (subold (lookup-key old key)))
 380                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 381                  (and (keymapp subnew) (keymapp subold)
 382                       (derived-mode-merge-keymaps subold subnew)))
 383                (setq i (1- i)))))
 384       (setq tail (cdr tail))))
 385   (setcdr (nthcdr (1- (length new)) new) old))
 386
 387 (defun derived-mode-merge-syntax-tables (old new)
 388   "Merge an OLD syntax table into a NEW one.
 389 Where the new table already has an entry, nothing is copied from the old one."
 390   (set-char-table-parent new old))
 391
 392 ;; Merge an old abbrev table into a new one.
 393 ;; This function requires internal knowledge of how abbrev tables work,
 394 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 395 ;; as the value of the symbol, and the hook as the function definition.
 396 (defun derived-mode-merge-abbrev-tables (old new)
 397   (if old
 398       (mapatoms
 399        (lambda (symbol)
 400          (or (intern-soft (symbol-name symbol) new)
 401              (define-abbrev new (symbol-name symbol)
 402                (symbol-value symbol) (symbol-function symbol))))
 403        old)))
 404
 405 (provide 'derived)
 406
 407 ;;; derived.el ends here