lisp/mail/rmailkwd.el

   1 ;;; rmailkwd.el --- part of the "RMAIL" mail reader for Emacs
   2
   3 ;; Copyright (C) 1985, 1988, 1994, 2001 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; Global to all RMAIL buffers.  It exists primarily for the sake of
  30 ;; completion.  It is better to use strings with the label functions
  31 ;; and let them worry about making the label.
  32
  33 (defvar rmail-label-obarray (make-vector 47 0))
  34
  35 ;; Named list of symbols representing valid message attributes in RMAIL.
  36
  37 (defconst rmail-attributes
  38   (cons 'rmail-keywords
  39         (mapcar (function (lambda (s) (intern s rmail-label-obarray)))
  40                 '("deleted" "answered" "filed" "forwarded" "unseen" "edited"
  41                   "resent"))))
  42
  43 (defconst rmail-deleted-label (intern "deleted" rmail-label-obarray))
  44
  45 ;; Named list of symbols representing valid message keywords in RMAIL.
  46
  47 (defvar rmail-keywords)
  48 \f
  49 ;;;###autoload
  50 (defun rmail-add-label (string)
  51   "Add LABEL to labels associated with current RMAIL message.
  52 Completion is performed over known labels when reading."
  53   (interactive (list (rmail-read-label "Add label")))
  54   (rmail-set-label string t))
  55
  56 ;;;###autoload
  57 (defun rmail-kill-label (string)
  58   "Remove LABEL from labels associated with current RMAIL message.
  59 Completion is performed over known labels when reading."
  60   (interactive (list (rmail-read-label "Remove label")))
  61   (rmail-set-label string nil))
  62
  63 ;;;###autoload
  64 (defun rmail-read-label (prompt)
  65   (with-current-buffer rmail-buffer
  66     (if (not rmail-keywords) (rmail-parse-file-keywords))
  67     (let ((result
  68            (completing-read (concat prompt
  69                                     (if rmail-last-label
  70                                         (concat " (default "
  71                                                 (symbol-name rmail-last-label)
  72                                                 "): ")
  73                                       ": "))
  74                             rmail-label-obarray
  75                             nil
  76                             nil)))
  77       (if (string= result "")
  78           rmail-last-label
  79         (setq rmail-last-label (rmail-make-label result t))))))
  80
  81 (defun rmail-set-label (l state &optional n)
  82   (with-current-buffer rmail-buffer
  83     (rmail-maybe-set-message-counters)
  84     (if (not n) (setq n rmail-current-message))
  85     (aset rmail-summary-vector (1- n) nil)
  86     (let* ((attribute (rmail-attribute-p l))
  87            (keyword (and (not attribute)
  88                          (or (rmail-keyword-p l)
  89                              (rmail-install-keyword l))))
  90            (label (or attribute keyword)))
  91       (if label
  92           (let ((omax (- (buffer-size) (point-max)))
  93                 (omin (- (buffer-size) (point-min)))
  94                 (buffer-read-only nil)
  95                 (case-fold-search t))
  96             (unwind-protect
  97                 (save-excursion
  98                   (widen)
  99                   (goto-char (rmail-msgbeg n))
 100                   (forward-line 1)
 101                   (if (not (looking-at "[01],"))
 102                       nil
 103                     (let ((start (1+ (point)))
 104                           (bound))
 105                       (narrow-to-region (point) (progn (end-of-line) (point)))
 106                       (setq bound (point-max))
 107                       (search-backward ",," nil t)
 108                       (if attribute
 109                           (setq bound (1+ (point)))
 110                         (setq start (1+ (point))))
 111                       (goto-char start)
 112 ;                     (while (re-search-forward "[ \t]*,[ \t]*" nil t)
 113 ;                       (replace-match ","))
 114 ;                     (goto-char start)
 115                       (if (re-search-forward
 116                            (concat ", " (rmail-quote-label-name label) ",")
 117                            bound
 118                            'move)
 119                           (if (not state) (replace-match ","))
 120                         (if state (insert " " (symbol-name label) ",")))
 121                       (if (eq label rmail-deleted-label)
 122                           (rmail-set-message-deleted-p n state)))))
 123               (narrow-to-region (- (buffer-size) omin) (- (buffer-size) omax))
 124               (if (= n rmail-current-message) (rmail-display-labels))))))))
 125 \f
 126 ;; Commented functions aren't used by RMAIL but might be nice for user
 127 ;; packages that do stuff with RMAIL.  Note that rmail-message-labels-p
 128 ;; is in rmail.el now.
 129
 130 ;(defun rmail-message-label-p (label &optional n)
 131 ;  "Returns symbol if LABEL (attribute or keyword) on NTH or current message."
 132 ;  (rmail-message-labels-p (or n rmail-current-message) (regexp-quote label)))
 133
 134 ;(defun rmail-parse-message-labels (&optional n)
 135 ;  "Returns labels associated with NTH or current RMAIL message.
 136 ;The result is a list of two lists of strings.  The first is the
 137 ;message attributes and the second is the message keywords."
 138 ;  (let (atts keys)
 139 ;    (save-restriction
 140 ;      (widen)
 141 ;      (goto-char (rmail-msgbeg (or n rmail-current-message)))
 142 ;      (forward-line 1)
 143 ;      (or (looking-at "[01],") (error "Malformed label line"))
 144 ;      (forward-char 2)
 145 ;      (while (looking-at "[ \t]*\\([^ \t\n,]+\\),")
 146 ;       (setq atts (cons (buffer-substring (match-beginning 1) (match-end 1))
 147 ;                         atts))
 148 ;       (goto-char (match-end 0)))
 149 ;      (or (looking-at ",") (error "Malformed label line"))
 150 ;      (forward-char 1)
 151 ;      (while (looking-at "[ \t]*\\([^ \t\n,]+\\),")
 152 ;       (setq keys (cons (buffer-substring (match-beginning 1) (match-end 1))
 153 ;                        keys))
 154 ;       (goto-char (match-end 0)))
 155 ;      (or (looking-at "[ \t]*$") (error "Malformed label line"))
 156 ;      (list (nreverse atts) (nreverse keys)))))
 157
 158 (defun rmail-attribute-p (s)
 159   (let ((symbol (rmail-make-label s)))
 160     (if (memq symbol (cdr rmail-attributes)) symbol)))
 161
 162 (defun rmail-keyword-p (s)
 163   (let ((symbol (rmail-make-label s)))
 164     (if (memq symbol (cdr (rmail-keywords))) symbol)))
 165
 166 (defun rmail-make-label (s &optional forcep)
 167   (cond ((symbolp s) s)
 168         (forcep (intern (downcase s) rmail-label-obarray))
 169         (t  (intern-soft (downcase s) rmail-label-obarray))))
 170
 171 (defun rmail-force-make-label (s)
 172   (intern (downcase s) rmail-label-obarray))
 173
 174 (defun rmail-quote-label-name (label)
 175   (regexp-quote (symbol-name (rmail-make-label label t))))
 176 \f
 177 ;; Motion on messages with keywords.
 178
 179 ;;;###autoload
 180 (defun rmail-previous-labeled-message (n labels)
 181   "Show previous message with one of the labels LABELS.
 182 LABELS should be a comma-separated list of label names.
 183 If LABELS is empty, the last set of labels specified is used.
 184 With prefix argument N moves backward N messages with these labels."
 185   (interactive "p\nsMove to previous msg with labels: ")
 186   (rmail-next-labeled-message (- n) labels))
 187
 188 ;;;###autoload
 189 (defun rmail-next-labeled-message (n labels)
 190   "Show next message with one of the labels LABELS.
 191 LABELS should be a comma-separated list of label names.
 192 If LABELS is empty, the last set of labels specified is used.
 193 With prefix argument N moves forward N messages with these labels."
 194   (interactive "p\nsMove to next msg with labels: ")
 195   (if (string= labels "")
 196       (setq labels rmail-last-multi-labels))
 197   (or labels
 198       (error "No labels to find have been specified previously"))
 199   (set-buffer rmail-buffer)
 200   (setq rmail-last-multi-labels labels)
 201   (rmail-maybe-set-message-counters)
 202   (let ((lastwin rmail-current-message)
 203         (current rmail-current-message)
 204         (regexp (concat ", ?\\("
 205                         (mail-comma-list-regexp labels)
 206                         "\\),")))
 207     (save-restriction
 208       (widen)
 209       (while (and (> n 0) (< current rmail-total-messages))
 210         (setq current (1+ current))
 211         (if (rmail-message-labels-p current regexp)
 212             (setq lastwin current n (1- n))))
 213       (while (and (< n 0) (> current 1))
 214         (setq current (1- current))
 215         (if (rmail-message-labels-p current regexp)
 216             (setq lastwin current n (1+ n)))))
 217     (rmail-show-message lastwin)
 218     (if (< n 0)
 219         (message "No previous message with labels %s" labels))
 220     (if (> n 0)
 221         (message "No following message with labels %s" labels))))
 222 \f
 223 ;;; Manipulate the file's Labels option.
 224
 225 ;; Return a list of symbols for all
 226 ;; the keywords (labels) recorded in this file's Labels option.
 227 (defun rmail-keywords ()
 228   (or rmail-keywords (rmail-parse-file-keywords)))
 229
 230 ;; Set rmail-keywords to a list of symbols for all
 231 ;; the keywords (labels) recorded in this file's Labels option.
 232 (defun rmail-parse-file-keywords ()
 233   (save-restriction
 234     (save-excursion
 235       (widen)
 236       (goto-char 1)
 237       (setq rmail-keywords
 238             (if (search-forward "\nLabels:" (rmail-msgbeg 1) t)
 239                 (progn
 240                   (narrow-to-region (point) (progn (end-of-line) (point)))
 241                   (goto-char (point-min))
 242                   (cons 'rmail-keywords
 243                         (mapcar 'rmail-force-make-label
 244                                 (mail-parse-comma-list)))))))))
 245
 246 ;; Add WORD to the list in the file's Labels option.
 247 ;; Any keyword used for the first time needs this done.
 248 (defun rmail-install-keyword (word)
 249   (let ((keyword (rmail-make-label word t))
 250         (keywords (rmail-keywords)))
 251     (if (not (or (rmail-attribute-p keyword)
 252                  (rmail-keyword-p keyword)))
 253         (let ((omin (- (buffer-size) (point-min)))
 254               (omax (- (buffer-size) (point-max))))
 255           (unwind-protect
 256               (save-excursion
 257                 (widen)
 258                 (goto-char 1)
 259                 (let ((case-fold-search t)
 260                       (buffer-read-only nil))
 261                   (or (search-forward "\nLabels:" nil t)
 262                       (progn
 263                         (end-of-line)
 264                         (insert "\nLabels:")))
 265                   (delete-region (point) (progn (end-of-line) (point)))
 266                   (setcdr keywords (cons keyword (cdr keywords)))
 267                   (while (setq keywords (cdr keywords))
 268                     (insert (symbol-name (car keywords)) ","))
 269                   (delete-char -1)))
 270             (narrow-to-region (- (buffer-size) omin)
 271                               (- (buffer-size) omax)))))
 272     keyword))
 273
 274 ;;; arch-tag: b26b3392-99ca-4e1d-933a-dab59b04e9a8
 275 ;;; rmailkwd.el ends here