lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (C) 1994-1996, 2001-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Maintainer: FSF
   7 ;; Keywords: faces, i18n, Unicode, multilingual
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Describe-Text Mode.
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'quail))
  31 (require 'help-mode)
  32
  33 ;;; Describe-Text Utilities.
  34
  35 (defun describe-text-widget (widget)
  36   "Insert text to describe WIDGET in the current buffer."
  37   (insert-text-button
  38    (symbol-name (if (symbolp widget) widget (car widget)))
  39    'action `(lambda (&rest ignore)
  40               (widget-browse ',widget))
  41    'help-echo "mouse-2, RET: browse this widget")
  42   (insert " ")
  43   (insert-text-button
  44    "(widget)Top" 'type 'help-info 'help-args '("(widget)Top")))
  45
  46 (defun describe-text-sexp (sexp)
  47   "Insert a short description of SEXP in the current buffer."
  48   (let ((pp (condition-case signal
  49                 (pp-to-string sexp)
  50               (error (prin1-to-string signal)))))
  51     (when (string-match-p "\n\\'" pp)
  52       (setq pp (substring pp 0 (1- (length pp)))))
  53
  54     (if (and (not (string-match-p "\n" pp))
  55              (<= (length pp) (- (window-width) (current-column))))
  56         (insert pp)
  57       (insert-text-button
  58        "[Show]" 'action `(lambda (&rest ignore)
  59                            (with-output-to-temp-buffer
  60                                "*Pp Eval Output*"
  61                              (princ ',pp)))
  62        'help-echo "mouse-2, RET: pretty print value in another buffer"))))
  63
  64 (defun describe-property-list (properties)
  65   "Insert a description of PROPERTIES in the current buffer.
  66 PROPERTIES should be a list of overlay or text properties.
  67 The `category', `face' and `font-lock-face' properties are made
  68 into help buttons that call `describe-text-category' or
  69 `describe-face' when pushed."
  70   ;; Sort the properties by the size of their value.
  71   (dolist (elt (sort (let (ret)
  72                        (while properties
  73                          (push (list (pop properties) (pop properties)) ret))
  74                        ret)
  75                      (lambda (a b) (string< (prin1-to-string (nth 0 a) t)
  76                                             (prin1-to-string (nth 0 b) t)))))
  77     (let ((key (nth 0 elt))
  78           (value (nth 1 elt)))
  79       (insert (propertize (format "  %-20s " key)
  80                           'face 'help-argument-name))
  81       (cond ((eq key 'category)
  82              (insert-text-button
  83               (symbol-name value)
  84               'action `(lambda (&rest ignore)
  85                          (describe-text-category ',value))
  86               'follow-link t
  87               'help-echo "mouse-2, RET: describe this category"))
  88             ((memq key '(face font-lock-face mouse-face))
  89              (insert-text-button
  90               (format "%S" value)
  91               'type 'help-face 'help-args (list value)))
  92             ((widgetp value)
  93              (describe-text-widget value))
  94             (t
  95              (describe-text-sexp value))))
  96     (insert "\n")))
  97 \f
  98 ;;; Describe-Text Commands.
  99
 100 (defun describe-text-category (category)
 101   "Describe a text property category."
 102   (interactive "SCategory: ")
 103   (help-setup-xref (list #'describe-text-category category)
 104                    (called-interactively-p 'interactive))
 105   (with-help-window (help-buffer)
 106     (with-current-buffer standard-output
 107       (insert "Category " (format "%S" category) ":\n\n")
 108       (describe-property-list (symbol-plist category))
 109       (goto-char (point-min)))))
 110
 111 ;;;###autoload
 112 (defun describe-text-properties (pos &optional output-buffer buffer)
 113   "Describe widgets, buttons, overlays, and text properties at POS.
 114 POS is taken to be in BUFFER or in current buffer if nil.
 115 Interactively, describe them for the character after point.
 116 If optional second argument OUTPUT-BUFFER is non-nil,
 117 insert the output into that buffer, and don't initialize or clear it
 118 otherwise."
 119   (interactive "d")
 120   (let ((src-buf (current-buffer)))
 121     (if buffer (set-buffer buffer) (setq buffer (current-buffer)))
 122   (if (>= pos (point-max))
 123       (error "No character follows specified position"))
 124   (if output-buffer
 125       (describe-text-properties-1 pos output-buffer)
 126     (if (not (or (text-properties-at pos) (overlays-at pos)))
 127         (message "This is plain text.")
 128         (with-temp-buffer
 129             (setq output-buffer (current-buffer))
 130             (insert "Text content at position " (format "%d" pos) ":\n\n")
 131           (set-buffer buffer)
 132           (describe-text-properties-1 pos output-buffer)
 133           (set-buffer src-buf)
 134           (help-setup-xref (list 'describe-text-properties pos nil buffer)
 135                            (called-interactively-p 'interactive))
 136           (with-help-window (help-buffer)
 137             (with-current-buffer standard-output
 138               (buffer-swap-text output-buffer)
 139               (goto-char (point-min)))))))))
 140
 141 (defun describe-text-properties-1 (pos output-buffer)
 142   (let* ((properties (text-properties-at pos))
 143          (overlays (overlays-at pos))
 144          (wid-field (get-char-property pos 'field))
 145          (wid-button (get-char-property pos 'button))
 146          (wid-doc (get-char-property pos 'widget-doc))
 147          ;; If button.el is not loaded, we have no buttons in the text.
 148          (button (and (fboundp 'button-at) (button-at pos)))
 149          (button-type (and button (button-type button)))
 150          (button-label (and button (button-label button)))
 151          (widget (or wid-field wid-button wid-doc)))
 152     (with-current-buffer output-buffer
 153       ;; Widgets
 154       (when (widgetp widget)
 155         (newline)
 156         (insert (cond (wid-field "This is an editable text area")
 157                       (wid-button "This is an active area")
 158                       (wid-doc "This is documentation text")))
 159         (insert " of a ")
 160         (describe-text-widget widget)
 161         (insert ".\n\n"))
 162       ;; Buttons
 163       (when (and button (not (widgetp wid-button)))
 164         (newline)
 165         (insert "Here is a `" (format "%S" button-type)
 166                 "' button labeled `" button-label "'.\n\n"))
 167       ;; Overlays
 168       (when overlays
 169         (newline)
 170         (if (eq (length overlays) 1)
 171             (insert "There is an overlay here:\n")
 172           (insert "There are " (format "%d" (length overlays))
 173                          " overlays here:\n"))
 174         (dolist (overlay overlays)
 175           (insert " From " (format "%d" (overlay-start overlay))
 176                          " to " (format "%d" (overlay-end overlay)) "\n")
 177           (describe-property-list (overlay-properties overlay)))
 178         (insert "\n"))
 179       ;; Text properties
 180       (when properties
 181         (newline)
 182         (insert "There are text properties here:\n")
 183         (describe-property-list properties)))))
 184 \f
 185 (defcustom describe-char-unidata-list
 186   '(name old-name general-category decomposition)
 187   "List of Unicode-based character property names shown by `describe-char'."
 188   :group 'mule
 189   :version "23.1"
 190   :type '(choice (const :tag "All properties" t)
 191           (set
 192            (const :tag "Unicode name" name)
 193            (const :tag "Unicode old name" old-name)
 194            (const :tag "Unicode general category " general-category)
 195            (const :tag "Unicode canonical combining class"
 196                   canonical-combining-class)
 197            (const :tag "Unicode bidi class" bidi-class)
 198            (const :tag "Unicode decomposition mapping" decomposition)
 199            (const :tag "Unicode decimal digit value" decimal-digit-value)
 200            (const :tag "Unicode digit value" digit-value)
 201            (const :tag "Unicode numeric value" numeric-value)
 202            (const :tag "Unicode mirrored" mirrored)
 203            (const :tag "Unicode ISO 10646 comment" iso-10646-comment)
 204            (const :tag "Unicode simple uppercase mapping" uppercase)
 205            (const :tag "Unicode simple lowercase mapping" lowercase)
 206            (const :tag "Unicode simple titlecase mapping" titlecase))))
 207
 208 (defcustom describe-char-unicodedata-file nil
 209   "Location of Unicode data file.
 210 This is the UnicodeData.txt file from the Unicode Consortium, used for
 211 diagnostics.  If it is non-nil `describe-char' will print data
 212 looked up from it.  This facility is mostly of use to people doing
 213 multilingual development.
 214
 215 This is a fairly large file, not typically present on GNU systems.
 216 At the time of writing it is at the URL
 217 `http://www.unicode.org/Public/UNIDATA/UnicodeData.txt'."
 218   :group 'mule
 219   :version "22.1"
 220   :type '(choice (const :tag "None" nil)
 221                  file))
 222
 223 (defun describe-char-unicode-data (char)
 224   "Return a list of Unicode data for Unicode CHAR.
 225 Each element is a list of a property description and the property value.
 226 The list is null if CHAR isn't found in `describe-char-unicodedata-file'.
 227 This function is semi-obsolete.  Use `get-char-code-property'."
 228   (when describe-char-unicodedata-file
 229     (unless (file-exists-p describe-char-unicodedata-file)
 230       (error "`unicodedata-file' %s not found" describe-char-unicodedata-file))
 231     (with-current-buffer (get-buffer-create " *Unicode Data*")
 232       (when (zerop (buffer-size))
 233         ;; Don't use -literally in case of DOS line endings.
 234         (insert-file-contents describe-char-unicodedata-file))
 235       (goto-char (point-min))
 236       (let ((hex (format "%04X" char))
 237             found first last)
 238         (if (re-search-forward (concat "^" hex) nil t)
 239             (setq found t)
 240           ;; It's not listed explicitly.  Look for ranges, e.g. CJK
 241           ;; ideographs, and check whether it's in one of them.
 242           (while (and (re-search-forward "^\\([^;]+\\);[^;]+First>;" nil t)
 243                       (>= char (setq first
 244                                      (string-to-number (match-string 1) 16)))
 245                       (progn
 246                         (forward-line 1)
 247                         (looking-at "^\\([^;]+\\);[^;]+Last>;")
 248                         (> char
 249                            (setq last
 250                                  (string-to-number (match-string 1) 16))))))
 251           (if (and (>= char first)
 252                    (<= char last))
 253               (setq found t)))
 254         (if found
 255             (let ((fields (mapcar (lambda (elt)
 256                                     (if (> (length elt) 0)
 257                                         elt))
 258                                   (cdr (split-string
 259                                         (buffer-substring
 260                                          (line-beginning-position)
 261                                          (line-end-position))
 262                                         ";")))))
 263               ;; The length depends on whether the last field was empty.
 264               (unless (or (= 13 (length fields))
 265                           (= 14 (length fields)))
 266                 (error "Invalid contents in %s" describe-char-unicodedata-file))
 267               ;; The field names and values lists are slightly
 268               ;; modified from Mule-UCS unidata.el.
 269               (list
 270                (list "Name" (let ((name (nth 0 fields)))
 271                               ;; Check for <..., First>, <..., Last>
 272                               (if (string-match "\\`\\(<[^,]+\\)," name)
 273                                   (concat (match-string 1 name) ">")
 274                                 name)))
 275                (list "Category"
 276                      (let ((val (nth 1 fields)))
 277                        (or (char-code-property-description
 278                             'general-category (intern val))
 279                            val)))
 280                (list "Combining class"
 281                      (let ((val (nth 1 fields)))
 282                        (or (char-code-property-description
 283                             'canonical-combining-class (intern val))
 284                            val)))
 285                (list "Bidi category"
 286                      (let ((val (nth 1 fields)))
 287                        (or (char-code-property-description
 288                             'bidi-class (intern val))
 289                            val)))
 290                (list
 291                 "Decomposition"
 292                 (if (nth 4 fields)
 293                     (let* ((parts (split-string (nth 4 fields)))
 294                            (info (car parts)))
 295                       (if (string-match "\\`<\\(.+\\)>\\'" info)
 296                           (setq info (match-string 1 info))
 297                         (setq info nil))
 298                       (if info (setq parts (cdr parts)))
 299                       (setq parts (mapconcat
 300                                    (lambda (arg)
 301                                      (string (string-to-number arg 16)))
 302                                    parts " "))
 303                       (concat info (if info " ") parts))))
 304                (list "Decimal digit value"
 305                      (nth 5 fields))
 306                (list "Digit value"
 307                      (nth 6 fields))
 308                (list "Numeric value"
 309                      (nth 7 fields))
 310                (list "Mirrored"
 311                      (if (equal "Y" (nth 8 fields))
 312                          "yes"))
 313                (list "Old name" (nth 9 fields))
 314                (list "ISO 10646 comment" (nth 10 fields))
 315                (list "Uppercase" (and (nth 11 fields)
 316                                       (string (string-to-number
 317                                                (nth 11 fields) 16))))
 318                (list "Lowercase" (and (nth 12 fields)
 319                                       (string (string-to-number
 320                                                (nth 12 fields) 16))))
 321                (list "Titlecase" (and (nth 13 fields)
 322                                       (string (string-to-number
 323                                                (nth 13 fields) 16)))))))))))
 324
 325 ;; Not defined on builds without X, but behind display-graphic-p.
 326 (declare-function internal-char-font "fontset.c" (position &optional ch))
 327
 328 ;; Return information about how CHAR is displayed at the buffer
 329 ;; position POS.  If the selected frame is on a graphic display,
 330 ;; return a string "FONT-DRIVER:FONT-NAME (GLYPH-CODE)" where:
 331 ;;   FONT-DRIVER is the font-driver name,
 332 ;;   FONT-NAME is the font name,
 333 ;;   GLYPH-CODE is a hexadigit string representing the glyph-ID.
 334 ;; Otherwise, return a string describing the terminal codes for the
 335 ;; character.
 336 (defun describe-char-display (pos char)
 337   (if (display-graphic-p (selected-frame))
 338       (let ((char-font-info (internal-char-font pos char)))
 339         (if char-font-info
 340             (let ((type (font-get (car char-font-info) :type))
 341                   (name (font-xlfd-name (car char-font-info)))
 342                   (code (cdr char-font-info)))
 343                (if (integerp code)
 344                    (format "%s:%s (#x%02X)" type name code)
 345                  (format "%s:%s (#x%04X%04X)"
 346                          type name (car code) (cdr code))))))
 347     (let* ((charset (get-text-property pos 'charset))
 348            (coding (or (terminal-coding-system) 'us-ascii))
 349            (encoded (encode-coding-char char coding charset)))
 350       (if encoded
 351           (encoded-string-description encoded coding)))))
 352
 353 \f
 354 ;; Return a string of CH with composition for padding on both sides.
 355 ;; It is displayed without overlapping with the left/right columns.
 356 (defsubst describe-char-padded-string (ch)
 357   (if (internal-char-font nil ch)
 358       (compose-string (string ch) 0 1 (format "\t%c\t" ch))
 359     (string ch)))
 360
 361 ;; Return a nicely formatted list of categories; extended category
 362 ;; description is added to the category name as a tooltip
 363 (defsubst describe-char-categories (category-set)
 364   (let ((mnemonics (category-set-mnemonics category-set)))
 365     (unless (eq mnemonics "")
 366       (list (mapconcat
 367              (lambda (x)
 368                (let* ((c (category-docstring x))
 369                       (doc (if (string-match "\\`\\(.*?\\)\n" c)
 370                                (propertize (match-string 1 c)
 371                                            'help-echo
 372                                            (substring c (1+ (match-end 1))))
 373                              c)))
 374                  (format "%c:%s" x doc)))
 375              mnemonics ", ")))))
 376
 377 ;;;###autoload
 378 (defun describe-char (pos &optional buffer)
 379   "Describe position POS (interactively, point) and the char after POS.
 380 POS is taken to be in BUFFER, or the current buffer if BUFFER is nil.
 381 The information is displayed in buffer `*Help*'.
 382
 383 The position information includes POS; the total size of BUFFER; the
 384 region limits, if narrowed; the column number; and the horizontal
 385 scroll amount, if the buffer is horizontally scrolled.
 386
 387 The character information includes the character code; charset and
 388 code points in it; syntax; category; how the character is encoded in
 389 BUFFER and in BUFFER's file; character composition information (if
 390 relevant); the font and font glyphs used to display the character;
 391 the character's canonical name and other properties defined by the
 392 Unicode Data Base; and widgets, buttons, overlays, and text properties
 393 relevant to POS."
 394   (interactive "d")
 395   (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 396   (let ((src-buf (current-buffer)))
 397     (set-buffer buffer)
 398     (if (>= pos (point-max))
 399         (error "No character follows specified position"))
 400     (let* ((char (char-after pos))
 401            (eight-bit-p (and (not enable-multibyte-characters) (>= char 128)))
 402            (charset (if eight-bit-p 'eight-bit
 403                       (or (get-text-property pos 'charset)
 404                           (char-charset char))))
 405            (composition (find-composition pos nil nil t))
 406            (component-chars nil)
 407            (display-table (or (window-display-table)
 408                               buffer-display-table
 409                               standard-display-table))
 410            (disp-vector (and display-table (aref display-table char)))
 411            (multibyte-p enable-multibyte-characters)
 412            (overlays (mapcar (lambda (o) (overlay-properties o))
 413                              (overlays-at pos)))
 414            (char-description (if (not multibyte-p)
 415                                  (single-key-description char)
 416                                (if (< char 128)
 417                                    (single-key-description char)
 418                                  (string-to-multibyte
 419                                   (char-to-string char)))))
 420            (text-props-desc
 421             (let ((tmp-buf (generate-new-buffer " *text-props*")))
 422               (unwind-protect
 423                   (progn
 424                     (describe-text-properties pos tmp-buf)
 425                     (with-current-buffer tmp-buf (buffer-string)))
 426                 (kill-buffer tmp-buf))))
 427            item-list max-width code)
 428
 429       (if multibyte-p
 430           (or (setq code (encode-char char charset))
 431               (setq charset (char-charset char)
 432                     code (encode-char char charset)))
 433         (setq code char))
 434       (cond
 435        ;; Append a PDF character to directional embeddings and
 436        ;; overrides, to prevent potential messup of the following
 437        ;; text.
 438        ((memq char '(?\x202a ?\x202b ?\x202d ?\x202e))
 439         (setq char-description
 440               (concat char-description
 441                       (propertize (string ?\x202c) 'invisible t))))
 442        ;; Append a LRM character to any strong character to avoid
 443        ;; messing up the numerical codepoint.
 444        ((memq (get-char-code-property char 'bidi-class) '(R AL))
 445         (setq char-description
 446               (concat char-description
 447                       (propertize (string ?\x200e) 'invisible t)))))
 448       (when composition
 449         ;; When the composition is trivial (i.e. composed only with the
 450         ;; current character itself without any alternate characters),
 451         ;; we don't show the composition information.  Otherwise, store
 452         ;; two descriptive strings in the first two elements of
 453         ;; COMPOSITION.
 454         (or (catch 'tag
 455               (let ((from (car composition))
 456                     (to (nth 1 composition))
 457                     (components (nth 2 composition))
 458                     ch)
 459                 (if (and (vectorp components) (vectorp (aref components 0)))
 460                     (let ((idx (- pos from))
 461                           (nglyphs (lgstring-glyph-len components))
 462                           (i 0) j glyph glyph-from)
 463                       ;; COMPONENTS is a gstring.  Find a grapheme
 464                       ;; cluster containing the current character.
 465                       (while (and (< i nglyphs)
 466                                   (setq glyph (lgstring-glyph components i))
 467                                   (< (lglyph-to glyph) idx))
 468                         (setq i (1+ i)))
 469                       (if (or (not glyph) (= i nglyphs))
 470                           ;; The composition is broken.
 471                           (throw 'tag nil))
 472                       (setq glyph-from (lglyph-from glyph)
 473                             to (+ from (lglyph-to glyph) 1)
 474                             from (+ from glyph-from)
 475                             j i)
 476                       (while (and (< j nglyphs)
 477                                   (setq glyph (lgstring-glyph components j))
 478                                   (= (lglyph-from glyph) glyph-from))
 479                         (setq j (1+ j)))
 480                       (if (and (= to (1+ from))
 481                                (= i (1- j))
 482                                (setq glyph (lgstring-glyph components i))
 483                                (= char (lglyph-char glyph)))
 484                           ;; The composition is trivial.
 485                           (throw 'tag nil))
 486                       (nconc composition (list i (1- j))))
 487                   (dotimes (i (length components))
 488                     (if (integerp (setq ch (aref components i)))
 489                         (push (cons ch (describe-char-display pos ch))
 490                               component-chars)))
 491                   (setq component-chars (nreverse component-chars)))
 492                 (if (< from pos)
 493                     (if (< (1+ pos) to)
 494                         (setcar composition
 495                                 (concat
 496                                  " with the surrounding characters \""
 497                                  (mapconcat 'describe-char-padded-string
 498                                             (buffer-substring from pos) "")
 499                                  "\" and \""
 500                                  (mapconcat 'describe-char-padded-string
 501                                             (buffer-substring (1+ pos) to) "")
 502                                  "\""))
 503                       (setcar composition
 504                               (concat
 505                                " with the preceding character(s) \""
 506                                (mapconcat 'describe-char-padded-string
 507                                           (buffer-substring from pos) "")
 508                                "\"")))
 509                   (if (< (1+ pos) to)
 510                       (setcar composition
 511                               (concat
 512                                " with the following character(s) \""
 513                                (mapconcat 'describe-char-padded-string
 514                                           (buffer-substring (1+ pos) to) "")
 515                                "\""))
 516                     (setcar composition nil)))
 517                 (setcar (cdr composition)
 518                         (format "composed to form \"%s\" (see below)"
 519                                 (buffer-substring from to)))))
 520             (setq composition nil)))
 521
 522       (setq item-list
 523             `(("position"
 524                ,(let* ((beg      (point-min))
 525                        (end      (point-max))
 526                        (total    (buffer-size))
 527                        (percent  (if (> total 50000) ; Avoid overflow multiplying by 100
 528                                      (/ (+ (/ total 200) (1- pos))  (max (/ total 100) 1))
 529                                    (/ (+ (/ total 2) (* 100 (1- pos)))  (max total 1))))
 530                        (hscroll  (if (= (window-hscroll) 0)
 531                                      ""
 532                                    (format ", Hscroll: %d" (window-hscroll))))
 533                        (col      (current-column)))
 534                   (if (or (/= beg 1)  (/= end (1+ total)))
 535                       (format "%d of %d (%d%%), restriction: <%d-%d>, column: %d%s"
 536                               pos total percent col beg end hscroll)
 537                     (if (= pos end)
 538                         (format "%d of %d (EOB), column: %d%s" pos total col hscroll)
 539                       (format "%d of %d (%d%%), column: %d%s"
 540                               pos total percent col hscroll)))))
 541               ("character"
 542                ,(format "%s (displayed as %s) (codepoint %d, #o%o, #x%x)"
 543                         char-description
 544                         (apply 'propertize char-description
 545                                (text-properties-at pos))
 546                         char char char))
 547               ("preferred charset"
 548                ,`(insert-text-button
 549                   ,(symbol-name charset)
 550                   'type 'help-character-set 'help-args '(,charset))
 551                ,(format "(%s)" (charset-description charset)))
 552               ("code point in charset"
 553                ,(let ((str (if (integerp code)
 554                                (format (if (< code 256) "0x%02X" "0x%04X")
 555                                        code)
 556                              (format "0x%04X%04X" (car code) (cdr code)))))
 557                   (if (<= (charset-dimension charset) 2)
 558                       `(insert-text-button
 559                         ,str
 560                         'action (lambda (&rest ignore)
 561                                   (list-charset-chars ',charset)
 562                                   (with-selected-window
 563                                       (get-buffer-window "*Character List*" 0)
 564                                     (goto-char (point-min))
 565                                     (forward-line 2) ;Skip the header.
 566                                     (let ((case-fold-search nil))
 567                                       (if (search-forward
 568                                            ,(char-to-string char) nil t)
 569                                           (goto-char (match-beginning 0))))))
 570                         'follow-link t
 571                         'help-echo
 572                         "mouse-2, RET: show this character in its character set")
 573                     str)))
 574               ("syntax"
 575                ,(let ((syntax (syntax-after pos)))
 576                   (with-temp-buffer
 577                     (internal-describe-syntax-value syntax)
 578                     (buffer-string))))
 579               ("category"
 580                ,@(if (not eight-bit-p)
 581                      (let ((category-set (char-category-set char)))
 582                        (if category-set
 583                            (describe-char-categories category-set)
 584                          '("-- none --")))))
 585               ("to input"
 586                ,@(if (not eight-bit-p)
 587                      (let ((key-list (and (eq input-method-function
 588                                               'quail-input-method)
 589                                           (quail-find-key char))))
 590                        (if (consp key-list)
 591                            (list "type"
 592                                  (concat "\""
 593                                          (mapconcat 'identity
 594                                                     key-list "\" or \"")
 595                                          "\"")
 596                                  "with"
 597                                  `(insert-text-button
 598                                    ,current-input-method
 599                                    'type 'help-input-method
 600                                    'help-args '(,current-input-method)))))))
 601               ("buffer code"
 602                ,(if multibyte-p
 603                     (encoded-string-description
 604                      (string-as-unibyte (char-to-string char)) nil)
 605                   (format "#x%02X" char)))
 606               ("file code"
 607                ,@(if multibyte-p
 608                      (let* ((coding buffer-file-coding-system)
 609                             (encoded (encode-coding-char char coding charset)))
 610                        (if encoded
 611                            (list (encoded-string-description encoded coding)
 612                                  (format "(encoded by coding system %S)"
 613                                          coding))
 614                          (list "not encodable by coding system"
 615                                (symbol-name coding))))
 616                    (list (format "#x%02X" char))))
 617               ("display"
 618                ,(cond
 619                  (disp-vector
 620                   (setq disp-vector (copy-sequence disp-vector))
 621                   (dotimes (i (length disp-vector))
 622                     (aset disp-vector i
 623                           (cons (aref disp-vector i)
 624                                 (describe-char-display
 625                                  pos (glyph-char (aref disp-vector i))))))
 626                   (format "by display table entry [%s] (see below)"
 627                           (mapconcat
 628                            (lambda (x)
 629                              (format "?%c" (glyph-char (car x))))
 630                            disp-vector " ")))
 631                  (composition
 632                   (cadr composition))
 633                  (t
 634                   (let ((display (describe-char-display pos char)))
 635                     (if (display-graphic-p (selected-frame))
 636                         (if display
 637                             (concat "by this font (glyph code)\n    " display)
 638                           "no font available")
 639                       (if display
 640                           (format "terminal code %s" display)
 641                         "not encodable for terminal"))))))
 642               ,@(let ((face
 643                        (if (not (or disp-vector composition))
 644                            (cond
 645                             ((and show-trailing-whitespace
 646                                   (save-excursion (goto-char pos)
 647                                                   (looking-at-p "[ \t]+$")))
 648                              'trailing-whitespace)
 649                             ((and nobreak-char-display char (eq char '#xa0))
 650                              'nobreak-space)
 651                             ((and nobreak-char-display char
 652                                   (memq char '(#xad #x2010 #x2011)))
 653                              'escape-glyph)
 654                             ((and (< char 32) (not (memq char '(9 10))))
 655                              'escape-glyph)))))
 656                   (if face (list (list "hardcoded face"
 657                                        `(insert-text-button
 658                                          ,(symbol-name face)
 659                                          'type 'help-face
 660                                          'help-args '(,face))))))
 661               ,@(if (not eight-bit-p)
 662                     (let ((unicodedata (describe-char-unicode-data char)))
 663                       (if unicodedata
 664                           (cons (list "Unicode data" "") unicodedata))))))
 665       (setq max-width (apply 'max (mapcar (lambda (x)
 666                                             (if (cadr x) (length (car x)) 0))
 667                                           item-list)))
 668       (set-buffer src-buf)
 669       (help-setup-xref (list 'describe-char pos buffer)
 670                        (called-interactively-p 'interactive))
 671       (with-help-window (help-buffer)
 672         (with-current-buffer standard-output
 673           (set-buffer-multibyte multibyte-p)
 674           (let ((formatter (format "%%%ds:" max-width)))
 675             (dolist (elt item-list)
 676               (when (cadr elt)
 677                 (insert (format formatter (car elt)))
 678                 (dolist (clm (cdr elt))
 679                   (if (eq (car-safe clm) 'insert-text-button)
 680                       (progn (insert " ") (eval clm))
 681                     (when (>= (+ (current-column)
 682                                  (or (string-match-p "\n" clm)
 683                                      (string-width clm))
 684                                  1)
 685                               (window-width))
 686                       (insert "\n")
 687                       (indent-to (1+ max-width)))
 688                     (unless (zerop (length clm))
 689                       (insert " " clm))))
 690                 (insert "\n"))))
 691
 692           (when overlays
 693             (save-excursion
 694               (goto-char (point-min))
 695               (re-search-forward "character:[ \t\n]+")
 696               (let ((end (+ (point) (length char-description))))
 697                 (mapc (lambda (props)
 698                         (let ((o (make-overlay (point) end)))
 699                           (while props
 700                             (overlay-put o (car props) (nth 1 props))
 701                             (setq props (cddr props)))))
 702                       overlays))))
 703
 704           (when disp-vector
 705             (insert
 706              "\nThe display table entry is displayed by ")
 707             (if (display-graphic-p (selected-frame))
 708                 (progn
 709                   (insert "these fonts (glyph codes):\n")
 710                   (dotimes (i (length disp-vector))
 711                     (insert (glyph-char (car (aref disp-vector i))) ?:
 712                             (propertize " " 'display '(space :align-to 5))
 713                             (or (cdr (aref disp-vector i)) "-- no font --")
 714                             "\n")
 715                     (let ((face (glyph-face (car (aref disp-vector i)))))
 716                       (when face
 717                         (insert (propertize " " 'display '(space :align-to 5))
 718                                 "face: ")
 719                         (insert (concat "`" (symbol-name face) "'"))
 720                         (insert "\n")))))
 721               (insert "these terminal codes:\n")
 722               (dotimes (i (length disp-vector))
 723                 (insert (car (aref disp-vector i))
 724                         (propertize " " 'display '(space :align-to 5))
 725                         (or (cdr (aref disp-vector i)) "-- not encodable --")
 726                         "\n"))))
 727
 728           (when composition
 729             (insert "\nComposed")
 730             (if (car composition)
 731                 (insert (car composition)))
 732             (if (and (vectorp (nth 2 composition))
 733                      (vectorp (aref (nth 2 composition) 0)))
 734                 (let* ((gstring (nth 2 composition))
 735                        (font (lgstring-font gstring))
 736                        (from (nth 3 composition))
 737                        (to (nth 4 composition))
 738                        glyph)
 739                   (if (fontp font)
 740                       (progn
 741                         (insert " using this font:\n  "
 742                                 (symbol-name (font-get font :type))
 743                                 ?:
 744                                 (aref (query-font font) 0)
 745                                 "\nby these glyphs:\n")
 746                         (while (and (<= from to)
 747                                     (setq glyph (lgstring-glyph gstring from)))
 748                           (insert (format "  %S\n" glyph))
 749                           (setq from (1+ from))))
 750                     (insert " by these characters:\n")
 751                     (while (and (<= from to)
 752                                 (setq glyph (lgstring-glyph gstring from)))
 753                       (insert (format " %c (#x%d)\n"
 754                                       (lglyph-char glyph) (lglyph-char glyph)))
 755                       (setq from (1+ from)))))
 756               (insert " by the rule:\n\t(")
 757               (let ((first t))
 758                 (mapc (lambda (x)
 759                         (if first (setq first nil)
 760                           (insert " "))
 761                         (if (consp x) (insert (format "%S" x))
 762                           (if (= x ?\t) (insert (single-key-description x))
 763                             (insert ??)
 764                             (insert (describe-char-padded-string x)))))
 765                       (nth 2 composition)))
 766               (insert  ")\nThe component character(s) are displayed by ")
 767               (if (display-graphic-p (selected-frame))
 768                   (progn
 769                     (insert "these fonts (glyph codes):")
 770                     (dolist (elt component-chars)
 771                       (if (/= (car elt) ?\t)
 772                           (insert "\n "
 773                                   (describe-char-padded-string (car elt))
 774                                   ?:
 775                                   (propertize " "
 776                                               'display '(space :align-to 5))
 777                                   (or (cdr elt) "-- no font --")))))
 778                 (insert "these terminal codes:")
 779                 (dolist (elt component-chars)
 780                   (insert "\n  " (car elt) ":"
 781                           (propertize " " 'display '(space :align-to 4))
 782                           (or (cdr elt) "-- not encodable --"))))
 783               (insert "\nSee the variable `reference-point-alist' for "
 784                       "the meaning of the rule.\n")))
 785
 786           (unless eight-bit-p
 787             (insert (if (not describe-char-unidata-list)
 788                         "\nCharacter code properties are not shown: "
 789                       "\nCharacter code properties: "))
 790             (insert-text-button
 791              "customize what to show"
 792              'action (lambda (&rest _ignore)
 793                        (customize-variable
 794                         'describe-char-unidata-list))
 795              'follow-link t)
 796             (insert "\n")
 797             (dolist (elt (if (eq describe-char-unidata-list t)
 798                              (nreverse (mapcar 'car char-code-property-alist))
 799                            describe-char-unidata-list))
 800               (let ((val (get-char-code-property char elt))
 801                     description)
 802                 (when val
 803                   (setq description (char-code-property-description elt val))
 804                   (insert (if description
 805                               (format "  %s: %s (%s)\n" elt val description)
 806                             (format "  %s: %s\n" elt val)))))))
 807
 808           (if text-props-desc (insert text-props-desc))
 809           (toggle-read-only 1))))))
 810
 811 (define-obsolete-function-alias 'describe-char-after 'describe-char "22.1")
 812
 813 (provide 'descr-text)
 814
 815 ;;; descr-text.el ends here