lisp/smerge-mode.el

   1 ;;; smerge-mode.el --- Minor mode to resolve diff3 conflicts
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   7 ;; Keywords: tools revision-control merge diff3 cvs conflict
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Provides a lightweight alternative to emerge/ediff.
  29 ;; To use it, simply add to your .emacs the following lines:
  30 ;;
  31 ;;   (autoload 'smerge-mode "smerge-mode" nil t)
  32 ;;
  33 ;; you can even have it turned on automatically with the following
  34 ;; piece of code in your .emacs:
  35 ;;
  36 ;;   (defun sm-try-smerge ()
  37 ;;     (save-excursion
  38 ;;       (goto-char (point-min))
  39 ;;       (when (re-search-forward "^<<<<<<< " nil t)
  40 ;;         (smerge-mode 1))))
  41 ;;   (add-hook 'find-file-hook 'sm-try-smerge t)
  42
  43 ;;; Todo:
  44
  45 ;; - if requested, ask the user whether he wants to call ediff right away
  46
  47 ;;; Code:
  48
  49 (eval-when-compile (require 'cl))
  50
  51
  52 ;;; The real definition comes later.
  53 (defvar smerge-mode)
  54
  55 (defgroup smerge ()
  56   "Minor mode to highlight and resolve diff3 conflicts."
  57   :group 'tools
  58   :prefix "smerge-")
  59
  60 (defcustom smerge-diff-buffer-name "*vc-diff*"
  61   "Buffer name to use for displaying diffs."
  62   :group 'smerge
  63   :type '(choice
  64           (const "*vc-diff*")
  65           (const "*cvs-diff*")
  66           (const "*smerge-diff*")
  67           string))
  68
  69 (defcustom smerge-diff-switches
  70   (append '("-d" "-b")
  71           (if (listp diff-switches) diff-switches (list diff-switches)))
  72   "A list of strings specifying switches to be passed to diff.
  73 Used in `smerge-diff-base-mine' and related functions."
  74   :group 'smerge
  75   :type '(repeat string))
  76
  77 (defcustom smerge-auto-leave t
  78   "Non-nil means to leave `smerge-mode' when the last conflict is resolved."
  79   :group 'smerge
  80   :type 'boolean)
  81
  82 (defface smerge-mine
  83   '((((min-colors 88) (background light))
  84      (:foreground "blue1"))
  85     (((background light))
  86      (:foreground "blue"))
  87     (((min-colors 88) (background dark))
  88      (:foreground "cyan1"))
  89     (((background dark))
  90      (:foreground "cyan")))
  91   "Face for your code."
  92   :group 'smerge)
  93 ;; backward-compatibility alias
  94 (put 'smerge-mine-face 'face-alias 'smerge-mine)
  95 (defvar smerge-mine-face 'smerge-mine)
  96
  97 (defface smerge-other
  98   '((((background light))
  99      (:foreground "darkgreen"))
 100     (((background dark))
 101      (:foreground "lightgreen")))
 102   "Face for the other code."
 103   :group 'smerge)
 104 ;; backward-compatibility alias
 105 (put 'smerge-other-face 'face-alias 'smerge-other)
 106 (defvar smerge-other-face 'smerge-other)
 107
 108 (defface smerge-base
 109   '((((min-colors 88) (background light))
 110      (:foreground "red1"))
 111     (((background light))
 112      (:foreground "red"))
 113     (((background dark))
 114      (:foreground "orange")))
 115   "Face for the base code."
 116   :group 'smerge)
 117 ;; backward-compatibility alias
 118 (put 'smerge-base-face 'face-alias 'smerge-base)
 119 (defvar smerge-base-face 'smerge-base)
 120
 121 (defface smerge-markers
 122   '((((background light))
 123      (:background "grey85"))
 124     (((background dark))
 125      (:background "grey30")))
 126   "Face for the conflict markers."
 127   :group 'smerge)
 128 ;; backward-compatibility alias
 129 (put 'smerge-markers-face 'face-alias 'smerge-markers)
 130 (defvar smerge-markers-face 'smerge-markers)
 131
 132 (defface smerge-refined-change
 133   '((t :background "yellow"))
 134   "Face used for char-based changes shown by `smerge-refine'."
 135   :group 'smerge)
 136
 137 (easy-mmode-defmap smerge-basic-map
 138   `(("n" . smerge-next)
 139     ("p" . smerge-prev)
 140     ("r" . smerge-resolve)
 141     ("a" . smerge-keep-all)
 142     ("b" . smerge-keep-base)
 143     ("o" . smerge-keep-other)
 144     ("m" . smerge-keep-mine)
 145     ("E" . smerge-ediff)
 146     ("C" . smerge-combine-with-next)
 147     ("R" . smerge-refine)
 148     ("\C-m" . smerge-keep-current)
 149     ("=" . ,(make-sparse-keymap "Diff"))
 150     ("=<" "base-mine" . smerge-diff-base-mine)
 151     ("=>" "base-other" . smerge-diff-base-other)
 152     ("==" "mine-other" . smerge-diff-mine-other))
 153   "The base keymap for `smerge-mode'.")
 154
 155 (defcustom smerge-command-prefix "\C-c^"
 156   "Prefix for `smerge-mode' commands."
 157   :group 'smerge
 158   :type '(choice (string "\e") (string "\C-c^") (string "") string))
 159
 160 (easy-mmode-defmap smerge-mode-map
 161   `((,smerge-command-prefix . ,smerge-basic-map))
 162   "Keymap for `smerge-mode'.")
 163
 164 (defvar smerge-check-cache nil)
 165 (make-variable-buffer-local 'smerge-check-cache)
 166 (defun smerge-check (n)
 167   (condition-case nil
 168       (let ((state (cons (point) (buffer-modified-tick))))
 169         (unless (equal (cdr smerge-check-cache) state)
 170           (smerge-match-conflict)
 171           (setq smerge-check-cache (cons (match-data) state)))
 172         (nth (* 2 n) (car smerge-check-cache)))
 173     (error nil)))
 174
 175 (easy-menu-define smerge-mode-menu smerge-mode-map
 176   "Menu for `smerge-mode'."
 177   '("SMerge"
 178     ["Next" smerge-next :help "Go to next conflict"]
 179     ["Previous" smerge-prev :help "Go to previous conflict"]
 180     "--"
 181     ["Keep All" smerge-keep-all :help "Keep all three versions"
 182      :active (smerge-check 1)]
 183     ["Keep Current" smerge-keep-current :help "Use current (at point) version"
 184      :active (and (smerge-check 1) (> (smerge-get-current) 0))]
 185     "--"
 186     ["Revert to Base" smerge-keep-base :help "Revert to base version"
 187      :active (smerge-check 2)]
 188     ["Keep Other" smerge-keep-other :help "Keep `other' version"
 189      :active (smerge-check 3)]
 190     ["Keep Yours" smerge-keep-mine :help "Keep your version"
 191      :active (smerge-check 1)]
 192     "--"
 193     ["Diff Base/Mine" smerge-diff-base-mine
 194      :help "Diff `base' and `mine' for current conflict"
 195      :active (smerge-check 2)]
 196     ["Diff Base/Other" smerge-diff-base-other
 197      :help "Diff `base' and `other' for current conflict"
 198      :active (smerge-check 2)]
 199     ["Diff Mine/Other" smerge-diff-mine-other
 200      :help "Diff `mine' and `other' for current conflict"
 201      :active (smerge-check 1)]
 202     "--"
 203     ["Invoke Ediff" smerge-ediff
 204      :help "Use Ediff to resolve the conflicts"
 205      :active (smerge-check 1)]
 206     ["Auto Resolve" smerge-resolve
 207      :help "Try auto-resolution heuristics"
 208      :active (smerge-check 1)]
 209     ["Combine" smerge-combine-with-next
 210      :help "Combine current conflict with next"
 211      :active (smerge-check 1)]
 212     ))
 213
 214 (easy-menu-define smerge-context-menu nil
 215   "Context menu for mine area in `smerge-mode'."
 216   '(nil
 217     ["Keep Current" smerge-keep-current :help "Use current (at point) version"]
 218     ["Kill Current" smerge-kill-current :help "Remove current (at point) version"]
 219     ["Keep All" smerge-keep-all :help "Keep all three versions"]
 220     "---"
 221     ["More..." (popup-menu smerge-mode-menu) :help "Show full SMerge mode menu"]
 222     ))
 223
 224 (defconst smerge-font-lock-keywords
 225   '((smerge-find-conflict
 226      (1 smerge-mine-face prepend t)
 227      (2 smerge-base-face prepend t)
 228      (3 smerge-other-face prepend t)
 229      ;; FIXME: `keep' doesn't work right with syntactic fontification.
 230      (0 smerge-markers-face keep)
 231      (4 nil t t)
 232      (5 nil t t)))
 233   "Font lock patterns for `smerge-mode'.")
 234
 235 (defconst smerge-begin-re "^<<<<<<< \\(.*\\)\n")
 236 (defconst smerge-end-re "^>>>>>>> .*\n")
 237 (defconst smerge-base-re "^||||||| .*\n")
 238 (defconst smerge-other-re "^=======\n")
 239
 240 (defvar smerge-conflict-style nil
 241   "Keep track of which style of conflict is in use.
 242 Can be nil if the style is undecided, or else:
 243 - `diff3-E'
 244 - `diff3-A'")
 245
 246 ;; Compiler pacifiers
 247 (defvar font-lock-mode)
 248 (defvar font-lock-keywords)
 249
 250 ;;;;
 251 ;;;; Actual code
 252 ;;;;
 253
 254 ;; Define smerge-next and smerge-prev
 255 (easy-mmode-define-navigation smerge smerge-begin-re "conflict")
 256
 257 (defconst smerge-match-names ["conflict" "mine" "base" "other"])
 258
 259 (defun smerge-ensure-match (n)
 260   (unless (match-end n)
 261     (error "No `%s'" (aref smerge-match-names n))))
 262
 263 (defun smerge-auto-leave ()
 264   (when (and smerge-auto-leave
 265              (save-excursion (goto-char (point-min))
 266                              (not (re-search-forward smerge-begin-re nil t))))
 267     (when (and (listp buffer-undo-list) smerge-mode)
 268       (push (list 'apply 'smerge-mode 1) buffer-undo-list))
 269     (smerge-mode -1)))
 270
 271
 272 (defun smerge-keep-all ()
 273   "Concatenate all versions."
 274   (interactive)
 275   (smerge-match-conflict)
 276   (let ((mb2 (or (match-beginning 2) (point-max)))
 277         (me2 (or (match-end 2) (point-min))))
 278     (delete-region (match-end 3) (match-end 0))
 279     (delete-region (max me2 (match-end 1)) (match-beginning 3))
 280     (if (and (match-end 2) (/= (match-end 1) (match-end 3)))
 281         (delete-region (match-end 1) (match-beginning 2)))
 282     (delete-region (match-beginning 0) (min (match-beginning 1) mb2))
 283     (smerge-auto-leave)))
 284
 285 (defun smerge-keep-n (n)
 286   (smerge-remove-props (match-beginning 0) (match-end 0))
 287   ;; We used to use replace-match, but that did not preserve markers so well.
 288   (delete-region (match-end n) (match-end 0))
 289   (delete-region (match-beginning 0) (match-beginning n)))
 290
 291 (defun smerge-combine-with-next ()
 292   "Combine the current conflict with the next one."
 293   (interactive)
 294   (smerge-match-conflict)
 295   (let ((ends nil))
 296     (dolist (i '(3 2 1 0))
 297       (push (if (match-end i) (copy-marker (match-end i) t)) ends))
 298     (setq ends (apply 'vector ends))
 299     (goto-char (aref ends 0))
 300     (if (not (re-search-forward smerge-begin-re nil t))
 301         (error "No next conflict")
 302       (smerge-match-conflict)
 303       (let ((match-data (mapcar (lambda (m) (if m (copy-marker m)))
 304                                 (match-data))))
 305         ;; First copy the in-between text in each alternative.
 306         (dolist (i '(1 2 3))
 307           (when (aref ends i)
 308             (goto-char (aref ends i))
 309             (insert-buffer-substring (current-buffer)
 310                                      (aref ends 0) (car match-data))))
 311         (delete-region (aref ends 0) (car match-data))
 312         ;; Then move the second conflict's alternatives into the first.
 313         (dolist (i '(1 2 3))
 314           (set-match-data match-data)
 315           (when (and (aref ends i) (match-end i))
 316             (goto-char (aref ends i))
 317             (insert-buffer-substring (current-buffer)
 318                                      (match-beginning i) (match-end i))))
 319         (delete-region (car match-data) (cadr match-data))
 320         ;; Free the markers.
 321         (dolist (m match-data) (if m (move-marker m nil)))
 322         (mapc (lambda (m) (if m (move-marker m nil))) ends)))))
 323
 324 (defvar smerge-resolve-function
 325   (lambda () (error "Don't know how to resolve"))
 326   "Mode-specific merge function.
 327 The function is called with zero or one argument (non-nil if the resolution
 328 function should only apply safe heuristics) and with the match data set
 329 according to `smerge-match-conflict'.")
 330 (add-to-list 'debug-ignored-errors "Don't know how to resolve")
 331
 332 (defvar smerge-text-properties
 333   `(help-echo "merge conflict: mouse-3 shows a menu"
 334     ;; mouse-face highlight
 335     keymap (keymap (down-mouse-3 . smerge-popup-context-menu))))
 336
 337 (defun smerge-remove-props (beg end)
 338   (remove-overlays beg end 'smerge 'refine)
 339   (remove-overlays beg end 'smerge 'conflict)
 340   ;; Now that we use overlays rather than text-properties, this function
 341   ;; does not cause refontification any more.  It can be seen very clearly
 342   ;; in buffers where jit-lock-contextually is not t, in which case deleting
 343   ;; the "<<<<<<< foobar" leading line leaves the rest of the conflict
 344   ;; highlighted as if it were still a valid conflict.  Note that in many
 345   ;; important cases (such as the previous example) we're actually called
 346   ;; during font-locking so inhibit-modification-hooks is non-nil, so we
 347   ;; can't just modify the buffer and expect font-lock to be triggered as in:
 348   ;; (put-text-property beg end 'smerge-force-highlighting nil)
 349   (let ((modified (buffer-modified-p)))
 350     (remove-text-properties beg end '(fontified nil))
 351     (restore-buffer-modified-p modified)))
 352
 353 (defun smerge-popup-context-menu (event)
 354   "Pop up the Smerge mode context menu under mouse."
 355   (interactive "e")
 356   (if (and smerge-mode
 357            (save-excursion (posn-set-point (event-end event)) (smerge-check 1)))
 358       (progn
 359         (posn-set-point (event-end event))
 360         (smerge-match-conflict)
 361         (let ((i (smerge-get-current))
 362               o)
 363           (if (<= i 0)
 364               ;; Out of range
 365               (popup-menu smerge-mode-menu)
 366             ;; Install overlay.
 367             (setq o (make-overlay (match-beginning i) (match-end i)))
 368             (unwind-protect
 369                 (progn
 370                   (overlay-put o 'face 'highlight)
 371                   (sit-for 0)           ;Display the new highlighting.
 372                   (popup-menu smerge-context-menu))
 373               ;; Delete overlay.
 374               (delete-overlay o)))))
 375     ;; There's no conflict at point, the text-props are just obsolete.
 376     (save-excursion
 377       (let ((beg (re-search-backward smerge-end-re nil t))
 378             (end (re-search-forward smerge-begin-re nil t)))
 379         (smerge-remove-props (or beg (point-min)) (or end (point-max)))
 380         (push event unread-command-events)))))
 381
 382 (defun smerge-resolve (&optional safe)
 383   "Resolve the conflict at point intelligently.
 384 This relies on mode-specific knowledge and thus only works in
 385 some major modes.  Uses `smerge-resolve-function' to do the actual work."
 386   (interactive)
 387   (smerge-match-conflict)
 388   (smerge-remove-props (match-beginning 0) (match-end 0))
 389   (cond
 390    ;; Trivial diff3 -A non-conflicts.
 391    ((and (eq (match-end 1) (match-end 3))
 392          (eq (match-beginning 1) (match-beginning 3)))
 393     (smerge-keep-n 3))
 394    ;; Mode-specific conflict resolution.
 395    ((condition-case nil
 396         (atomic-change-group
 397           (if safe
 398               (funcall smerge-resolve-function safe)
 399             (funcall smerge-resolve-function))
 400           t)
 401       (error nil))
 402     ;; Nothing to do: the resolution function has done it already.
 403     nil)
 404    ;; FIXME: Add "if [ diff -b MINE OTHER ]; then select OTHER; fi"
 405    ((and (match-end 2)
 406          ;; FIXME: Add "diff -b BASE MINE | patch OTHER".
 407          ;; FIXME: Add "diff -b BASE OTHER | patch MINE".
 408          nil)
 409     )
 410    ((and (not (match-end 2))
 411          ;; FIXME: Add "diff -b"-based refinement.
 412          nil)
 413     )
 414    (t
 415     (error "Don't know how to resolve")))
 416   (smerge-auto-leave))
 417
 418 (defun smerge-resolve-all ()
 419   "Perform automatic resolution on all conflicts."
 420   (interactive)
 421   (save-excursion
 422     (goto-char (point-min))
 423     (while (re-search-forward smerge-begin-re nil t)
 424       (condition-case nil
 425           (progn
 426             (smerge-match-conflict)
 427             (smerge-resolve 'safe))
 428         (error nil)))))
 429
 430 (defun smerge-batch-resolve ()
 431   ;; command-line-args-left is what is left of the command line.
 432   (if (not noninteractive)
 433       (error "`smerge-batch-resolve' is to be used only with -batch"))
 434   (while command-line-args-left
 435     (let ((file (pop command-line-args-left)))
 436       (message "Resolving conflicts in %s..." file)
 437       (when (file-readable-p file)
 438         (with-current-buffer (find-file-noselect file)
 439           (smerge-resolve-all)
 440           (save-buffer)
 441           (kill-buffer (current-buffer)))))))
 442
 443 (defun smerge-keep-base ()
 444   "Revert to the base version."
 445   (interactive)
 446   (smerge-match-conflict)
 447   (smerge-ensure-match 2)
 448   (smerge-keep-n 2)
 449   (smerge-auto-leave))
 450
 451 (defun smerge-keep-other ()
 452   "Use \"other\" version."
 453   (interactive)
 454   (smerge-match-conflict)
 455   ;;(smerge-ensure-match 3)
 456   (smerge-keep-n 3)
 457   (smerge-auto-leave))
 458
 459 (defun smerge-keep-mine ()
 460   "Keep your version."
 461   (interactive)
 462   (smerge-match-conflict)
 463   ;;(smerge-ensure-match 1)
 464   (smerge-keep-n 1)
 465   (smerge-auto-leave))
 466
 467 (defun smerge-get-current ()
 468   (let ((i 3))
 469     (while (or (not (match-end i))
 470                (< (point) (match-beginning i))
 471                (>= (point) (match-end i)))
 472       (decf i))
 473     i))
 474
 475 (defun smerge-keep-current ()
 476   "Use the current (under the cursor) version."
 477   (interactive)
 478   (smerge-match-conflict)
 479   (let ((i (smerge-get-current)))
 480     (if (<= i 0) (error "Not inside a version")
 481       (smerge-keep-n i)
 482       (smerge-auto-leave))))
 483
 484 (defun smerge-kill-current ()
 485   "Remove the current (under the cursor) version."
 486   (interactive)
 487   (smerge-match-conflict)
 488   (let ((i (smerge-get-current)))
 489     (if (<= i 0) (error "Not inside a version")
 490       (let ((left nil))
 491         (dolist (n '(3 2 1))
 492           (if (and (match-end n) (/= (match-end n) (match-end i)))
 493               (push n left)))
 494         (if (and (cdr left)
 495                  (/= (match-end (car left)) (match-end (cadr left))))
 496             (ding)                      ;We don't know how to do that.
 497           (smerge-keep-n (car left))
 498           (smerge-auto-leave))))))
 499
 500 (defun smerge-diff-base-mine ()
 501   "Diff 'base' and 'mine' version in current conflict region."
 502   (interactive)
 503   (smerge-diff 2 1))
 504
 505 (defun smerge-diff-base-other ()
 506   "Diff 'base' and 'other' version in current conflict region."
 507   (interactive)
 508   (smerge-diff 2 3))
 509
 510 (defun smerge-diff-mine-other ()
 511   "Diff 'mine' and 'other' version in current conflict region."
 512   (interactive)
 513   (smerge-diff 1 3))
 514
 515 (defun smerge-match-conflict ()
 516   "Get info about the conflict.  Puts the info in the `match-data'.
 517 The submatches contain:
 518  0:  the whole conflict.
 519  1:  your code.
 520  2:  the base code.
 521  3:  other code.
 522 An error is raised if not inside a conflict."
 523   (save-excursion
 524     (condition-case nil
 525         (let* ((orig-point (point))
 526
 527                (_ (forward-line 1))
 528                (_ (re-search-backward smerge-begin-re))
 529
 530                (start (match-beginning 0))
 531                (mine-start (match-end 0))
 532                (filename (or (match-string 1) ""))
 533
 534                (_ (re-search-forward smerge-end-re))
 535                (_ (assert (< orig-point (match-end 0))))
 536
 537                (other-end (match-beginning 0))
 538                (end (match-end 0))
 539
 540                (_ (re-search-backward smerge-other-re start))
 541
 542                (mine-end (match-beginning 0))
 543                (other-start (match-end 0))
 544
 545                base-start base-end)
 546
 547           ;; handle the various conflict styles
 548           (cond
 549            ((save-excursion
 550               (goto-char mine-start)
 551               (re-search-forward smerge-begin-re end t))
 552             ;; There's a nested conflict and we're after the the beginning
 553             ;; of the outer one but before the beginning of the inner one.
 554             ;; Of course, maybe this is not a nested conflict but in that
 555             ;; case it can only be something nastier that we don't know how
 556             ;; to handle, so may as well arbitrarily decide to treat it as
 557             ;; a nested conflict.  --Stef
 558             (error "There is a nested conflict"))
 559
 560            ((re-search-backward smerge-base-re start t)
 561             ;; a 3-parts conflict
 562             (set (make-local-variable 'smerge-conflict-style) 'diff3-A)
 563             (setq base-end mine-end)
 564             (setq mine-end (match-beginning 0))
 565             (setq base-start (match-end 0)))
 566
 567            ((string= filename (file-name-nondirectory
 568                                (or buffer-file-name "")))
 569             ;; a 2-parts conflict
 570             (set (make-local-variable 'smerge-conflict-style) 'diff3-E))
 571
 572            ((and (not base-start)
 573                  (or (eq smerge-conflict-style 'diff3-A)
 574                      (equal filename "ANCESTOR")
 575                      (string-match "\\`[.0-9]+\\'" filename)))
 576             ;; a same-diff conflict
 577             (setq base-start mine-start)
 578             (setq base-end   mine-end)
 579             (setq mine-start other-start)
 580             (setq mine-end   other-end)))
 581
 582           (store-match-data (list start end
 583                                   mine-start mine-end
 584                                   base-start base-end
 585                                   other-start other-end
 586                                   (when base-start (1- base-start)) base-start
 587                                   (1- other-start) other-start))
 588           t)
 589       (search-failed (error "Point not in conflict region")))))
 590
 591 (add-to-list 'debug-ignored-errors "Point not in conflict region")
 592
 593 (defun smerge-conflict-overlay (pos)
 594   "Return the conflict overlay at POS if any."
 595   (let ((ols (overlays-at pos))
 596         conflict)
 597     (dolist (ol ols)
 598       (if (and (eq (overlay-get ol 'smerge) 'conflict)
 599                (> (overlay-end ol) pos))
 600           (setq conflict ol)))
 601     conflict))
 602
 603 (defun smerge-find-conflict (&optional limit)
 604   "Find and match a conflict region.  Intended as a font-lock MATCHER.
 605 The submatches are the same as in `smerge-match-conflict'.
 606 Returns non-nil if a match is found between point and LIMIT.
 607 Point is moved to the end of the conflict."
 608   (let ((found nil)
 609         (pos (point))
 610         conflict)
 611     ;; First check to see if point is already inside a conflict, using
 612     ;; the conflict overlays.
 613     (while (and (not found) (setq conflict (smerge-conflict-overlay pos)))
 614       ;; Check the overlay's validity and kill it if it's out of date.
 615       (condition-case nil
 616           (progn
 617             (goto-char (overlay-start conflict))
 618             (smerge-match-conflict)
 619             (goto-char (match-end 0))
 620             (if (<= (point) pos)
 621                 (error "Matching backward!")
 622               (setq found t)))
 623         (error (smerge-remove-props
 624                 (overlay-start conflict) (overlay-end conflict))
 625                (goto-char pos))))
 626     ;; If we're not already inside a conflict, look for the next conflict
 627     ;; and add/update its overlay.
 628     (while (and (not found) (re-search-forward smerge-begin-re limit t))
 629       (condition-case nil
 630           (progn
 631             (smerge-match-conflict)
 632             (goto-char (match-end 0))
 633             (let ((conflict (smerge-conflict-overlay (1- (point)))))
 634               (if conflict
 635                   ;; Update its location, just in case it got messed up.
 636                   (move-overlay conflict (match-beginning 0) (match-end 0))
 637                 (setq conflict (make-overlay (match-beginning 0) (match-end 0)
 638                                              nil 'front-advance nil))
 639                 (overlay-put conflict 'evaporate t)
 640                 (overlay-put conflict 'smerge 'conflict)
 641                 (let ((props smerge-text-properties))
 642                   (while props
 643                     (overlay-put conflict (pop props) (pop props))))))
 644             (setq found t))
 645         (error nil)))
 646     found))
 647
 648 (defun smerge-refine-chopup-region (beg end file)
 649   "Chopup the region into small elements, one per line."
 650   ;; ediff chops up into words, where the definition of a word is
 651   ;; customizable.  Instead we here keep only one char per line.
 652   ;; The advantages are that there's nothing to configure, that we get very
 653   ;; fine results, and that it's trivial to map the line numbers in the
 654   ;; output of diff back into buffer positions.  The disadvantage is that it
 655   ;; can take more time to compute the diff and that the result is sometimes
 656   ;; too fine.  I'm not too concerned about the slowdown because conflicts
 657   ;; are usually significantly smaller than the whole file.  As for the
 658   ;; problem of too-fine-refinement, I have found it to be unimportant
 659   ;; especially when you consider the cases where the fine-grain is just
 660   ;; what you want.
 661   (let ((buf (current-buffer)))
 662     (with-temp-buffer
 663       (insert-buffer-substring buf beg end)
 664       (goto-char (point-min))
 665       (while (not (eobp))
 666         (forward-char 1)
 667         (unless (eq (char-before) ?\n) (insert ?\n)))
 668       (let ((coding-system-for-write 'emacs-mule))
 669         (write-region (point-min) (point-max) file nil 'nomessage)))))
 670
 671 (defun smerge-refine-highlight-change (buf beg match-num1 match-num2)
 672   (let* ((startline (string-to-number (match-string match-num1)))
 673          (ol (make-overlay
 674               (+ beg startline -1)
 675               (+ beg (if (match-end match-num2)
 676                          (string-to-number (match-string match-num2))
 677                        startline))
 678               buf
 679               'front-advance nil)))
 680     (overlay-put ol 'smerge 'refine)
 681     (overlay-put ol 'evaporate t)
 682     (overlay-put ol 'face 'smerge-refined-change)))
 683
 684
 685 (defun smerge-refine ()
 686   "Highlight the parts of the conflict that are different."
 687   (interactive)
 688   ;; FIXME: make it work with 3-way conflicts.
 689   (smerge-match-conflict)
 690   (remove-overlays (match-beginning 0) (match-end 0) 'smerge 'refine)
 691   (smerge-ensure-match 1)
 692   (smerge-ensure-match 3)
 693   (let ((buf (current-buffer))
 694         ;; Read them before the match-data gets clobbered.
 695         (beg1 (match-beginning 1)) (end1 (match-end 1))
 696         (beg2 (match-beginning 3)) (end2 (match-end 3))
 697         (file1 (make-temp-file "smerge1"))
 698         (file2 (make-temp-file "smerge2")))
 699
 700     ;; Chop up regions into smaller elements and save into files.
 701     (smerge-refine-chopup-region beg1 end1 file1)
 702     (smerge-refine-chopup-region beg2 end2 file2)
 703
 704     ;; Call diff on those files.
 705     (unwind-protect
 706         (with-temp-buffer
 707           (let ((coding-system-for-read 'emacs-mule))
 708             ;; Don't forget -a to make sure diff treats it as a text file
 709             ;; even if it contains \0 and such.
 710             (call-process diff-command nil t nil "-a" file1 file2))
 711           ;; Process diff's output.
 712           (goto-char (point-min))
 713           (while (not (eobp))
 714             (if (not (looking-at "\\([0-9]+\\)\\(?:,\\([0-9]+\\)\\)?\\([acd]\\)\\([0-9]+\\)\\(?:,\\([0-9]+\\)\\)?$"))
 715                 (error "Unexpected patch hunk header: %s"
 716                        (buffer-substring (point) (line-end-position)))
 717               (let ((op (char-after (match-beginning 3))))
 718                 (when (memq op '(?d ?c))
 719                   (smerge-refine-highlight-change buf beg1 1 2))
 720                 (when (memq op '(?a ?c))
 721                   (smerge-refine-highlight-change buf beg2 4 5)))
 722               (forward-line 1)                            ;Skip hunk header.
 723               (and (re-search-forward "^[0-9]" nil 'move) ;Skip hunk body.
 724                    (goto-char (match-beginning 0))))))
 725       (delete-file file1)
 726       (delete-file file2))))
 727
 728 (defun smerge-diff (n1 n2)
 729   (smerge-match-conflict)
 730   (smerge-ensure-match n1)
 731   (smerge-ensure-match n2)
 732   (let ((name1 (aref smerge-match-names n1))
 733         (name2 (aref smerge-match-names n2))
 734         ;; Read them before the match-data gets clobbered.
 735         (beg1 (match-beginning n1))
 736         (end1 (match-end n1))
 737         (beg2 (match-beginning n2))
 738         (end2 (match-end n2))
 739         (file1 (make-temp-file "smerge1"))
 740         (file2 (make-temp-file "smerge2"))
 741         (dir default-directory)
 742         (file (if buffer-file-name (file-relative-name buffer-file-name)))
 743         ;; We would want to use `emacs-mule-unix' for read&write, but we
 744         ;; bump into problems with the coding-system used by diff to write
 745         ;; the file names and the time stamps in the header.
 746         ;; `buffer-file-coding-system' is not always correct either, but if
 747         ;; the OS/user uses only one coding-system, then it works.
 748         (coding-system-for-read buffer-file-coding-system))
 749     (write-region beg1 end1 file1 nil 'nomessage)
 750     (write-region beg2 end2 file2 nil 'nomessage)
 751     (unwind-protect
 752         (with-current-buffer (get-buffer-create smerge-diff-buffer-name)
 753           (setq default-directory dir)
 754           (let ((inhibit-read-only t))
 755             (erase-buffer)
 756             (let ((status
 757                    (apply 'call-process diff-command nil t nil
 758                           (append smerge-diff-switches
 759                                   (list "-L" (concat name1 "/" file)
 760                                         "-L" (concat name2 "/" file)
 761                                         file1 file2)))))
 762               (if (eq status 0) (insert "No differences found.\n"))))
 763           (goto-char (point-min))
 764           (diff-mode)
 765           (display-buffer (current-buffer) t))
 766       (delete-file file1)
 767       (delete-file file2))))
 768
 769 ;; compiler pacifiers
 770 (defvar smerge-ediff-windows)
 771 (defvar smerge-ediff-buf)
 772 (defvar ediff-buffer-A)
 773 (defvar ediff-buffer-B)
 774 (defvar ediff-buffer-C)
 775 (defvar ediff-ancestor-buffer)
 776 (defvar ediff-quit-hook)
 777
 778 ;;;###autoload
 779 (defun smerge-ediff (&optional name-mine name-other name-base)
 780   "Invoke ediff to resolve the conflicts.
 781 NAME-MINE, NAME-OTHER, and NAME-BASE, if non-nil, are used for the
 782 buffer names."
 783   (interactive)
 784   (let* ((buf (current-buffer))
 785          (mode major-mode)
 786          ;;(ediff-default-variant 'default-B)
 787          (config (current-window-configuration))
 788          (filename (file-name-nondirectory buffer-file-name))
 789          (mine (generate-new-buffer
 790                 (or name-mine (concat "*" filename " MINE*"))))
 791          (other (generate-new-buffer
 792                  (or name-other (concat "*" filename " OTHER*"))))
 793          base)
 794     (with-current-buffer mine
 795       (buffer-disable-undo)
 796       (insert-buffer-substring buf)
 797       (goto-char (point-min))
 798       (while (smerge-find-conflict)
 799         (when (match-beginning 2) (setq base t))
 800         (smerge-keep-n 1))
 801       (buffer-enable-undo)
 802       (set-buffer-modified-p nil)
 803       (funcall mode))
 804
 805     (with-current-buffer other
 806       (buffer-disable-undo)
 807       (insert-buffer-substring buf)
 808       (goto-char (point-min))
 809       (while (smerge-find-conflict)
 810         (smerge-keep-n 3))
 811       (buffer-enable-undo)
 812       (set-buffer-modified-p nil)
 813       (funcall mode))
 814
 815     (when base
 816       (setq base (generate-new-buffer
 817                   (or name-base (concat "*" filename " BASE*"))))
 818       (with-current-buffer base
 819         (buffer-disable-undo)
 820         (insert-buffer-substring buf)
 821         (goto-char (point-min))
 822         (while (smerge-find-conflict)
 823           (if (match-end 2)
 824               (smerge-keep-n 2)
 825             (delete-region (match-beginning 0) (match-end 0))))
 826         (buffer-enable-undo)
 827         (set-buffer-modified-p nil)
 828         (funcall mode)))
 829
 830     ;; the rest of the code is inspired from vc.el
 831     ;; Fire up ediff.
 832     (set-buffer
 833      (if base
 834          (ediff-merge-buffers-with-ancestor mine other base)
 835           ;; nil 'ediff-merge-revisions-with-ancestor buffer-file-name)
 836        (ediff-merge-buffers mine other)))
 837         ;; nil 'ediff-merge-revisions buffer-file-name)))
 838
 839     ;; Ediff is now set up, and we are in the control buffer.
 840     ;; Do a few further adjustments and take precautions for exit.
 841     (set (make-local-variable 'smerge-ediff-windows) config)
 842     (set (make-local-variable 'smerge-ediff-buf) buf)
 843     (set (make-local-variable 'ediff-quit-hook)
 844          (lambda ()
 845            (let ((buffer-A ediff-buffer-A)
 846                  (buffer-B ediff-buffer-B)
 847                  (buffer-C ediff-buffer-C)
 848                  (buffer-Ancestor ediff-ancestor-buffer)
 849                  (buf smerge-ediff-buf)
 850                  (windows smerge-ediff-windows))
 851              (ediff-cleanup-mess)
 852              (with-current-buffer buf
 853                (erase-buffer)
 854                (insert-buffer-substring buffer-C)
 855                (kill-buffer buffer-A)
 856                (kill-buffer buffer-B)
 857                (kill-buffer buffer-C)
 858                (when (bufferp buffer-Ancestor) (kill-buffer buffer-Ancestor))
 859                (set-window-configuration windows)
 860                (message "Conflict resolution finished; you may save the buffer")))))
 861     (message "Please resolve conflicts now; exit ediff when done")))
 862
 863
 864 (defconst smerge-parsep-re
 865   (concat smerge-begin-re "\\|" smerge-end-re "\\|"
 866           smerge-base-re "\\|" smerge-other-re "\\|"))
 867
 868 ;;;###autoload
 869 (define-minor-mode smerge-mode
 870   "Minor mode to simplify editing output from the diff3 program.
 871 \\{smerge-mode-map}"
 872   :group 'smerge :lighter " SMerge"
 873   (when (and (boundp 'font-lock-mode) font-lock-mode)
 874     (save-excursion
 875       (if smerge-mode
 876           (font-lock-add-keywords nil smerge-font-lock-keywords 'append)
 877         (font-lock-remove-keywords nil smerge-font-lock-keywords))
 878       (goto-char (point-min))
 879       (while (smerge-find-conflict)
 880         (save-excursion
 881           (font-lock-fontify-region (match-beginning 0) (match-end 0) nil)))))
 882   (if (string-match (regexp-quote smerge-parsep-re) paragraph-separate)
 883       (unless smerge-mode
 884         (set (make-local-variable 'paragraph-separate)
 885              (replace-match "" t t paragraph-separate)))
 886     (when smerge-mode
 887         (set (make-local-variable 'paragraph-separate)
 888              (concat smerge-parsep-re paragraph-separate))))
 889   (unless smerge-mode
 890     (smerge-remove-props (point-min) (point-max))))
 891
 892
 893 (provide 'smerge-mode)
 894
 895 ;; arch-tag: 605c8d1e-e43d-4943-a6f3-1bcc4333e690
 896 ;;; smerge-mode.el ends here