lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30
  31 (defgroup image ()
  32   "Image support."
  33   :group 'multimedia)
  34
  35
  36 (defconst image-type-header-regexps
  37   '(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  38     ("\\`P[1-6]" . pbm)
  39     ("\\`GIF8" . gif)
  40     ("\\`\211PNG\r\n" . png)
  41     ("\\`[\t\n\r ]*#define" . xbm)
  42     ("\\`\\(MM\0\\*\\|II\\*\0\\)" . tiff)
  43     ("\\`[\t\n\r ]*%!PS" . postscript)
  44     ("\\`\xff\xd8" . (image-jpeg-p . jpeg)))
  45   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  46 When the first bytes of an image file match REGEXP, it is assumed to
  47 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  48 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  49 with one argument, a string containing the image data.  If PREDICATE returns
  50 a non-nil value, TYPE is the image's type.")
  51
  52 (defconst image-type-file-name-regexps
  53   '(("\\.png\\'" . png)
  54     ("\\.gif\\'" . gif)
  55     ("\\.jpe?g\\'" . jpeg)
  56     ("\\.bmp\\'" . bmp)
  57     ("\\.xpm\\'" . xpm)
  58     ("\\.pbm\\'" . pbm)
  59     ("\\.xbm\\'" . xbm)
  60     ("\\.ps\\'" . postscript)
  61     ("\\.tiff?\\'" . tiff))
  62   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  63 When the name of an image file match REGEXP, it is assumed to
  64 be of image type IMAGE-TYPE.")
  65
  66
  67 (defvar image-load-path nil
  68   "List of locations in which to search for image files.
  69 If an element is a string, it defines a directory to search.
  70 If an element is a variable symbol whose value is a string, that
  71 value defines a directory to search.
  72 If an element is a variable symbol whose value is a list, the
  73 value is used as a list of directories to search.")
  74
  75 (eval-at-startup
  76  (setq image-load-path
  77        (list (file-name-as-directory (expand-file-name "images" data-directory))
  78              'data-directory 'load-path)))
  79
  80
  81 (defun image-load-path-for-library (library image &optional path no-error)
  82   "Return a suitable search path for images used by LIBRARY.
  83
  84 It searches for IMAGE in `image-load-path' (excluding
  85 \"`data-directory'/images\") and `load-path', followed by a path
  86 suitable for LIBRARY, which includes \"../../etc/images\" and
  87 \"../etc/images\" relative to the library file itself, and then
  88 in \"`data-directory'/images\".
  89
  90 Then this function returns a list of directories which contains
  91 first the directory in which IMAGE was found, followed by the
  92 value of `load-path'. If PATH is given, it is used instead of
  93 `load-path'.
  94
  95 If NO-ERROR is non-nil and a suitable path can't be found, don't
  96 signal an error. Instead, return a list of directories as before,
  97 except that nil appears in place of the image directory.
  98
  99 Here is an example that uses a common idiom to provide
 100 compatibility with versions of Emacs that lack the variable
 101 `image-load-path':
 102
 103     ;; Shush compiler.
 104     (defvar image-load-path)
 105
 106     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 107            (image-load-path (cons (car load-path)
 108                                   (when (boundp 'image-load-path)
 109                                     image-load-path))))
 110       (mh-tool-bar-folder-buttons-init))"
 111   (unless library (error "No library specified"))
 112   (unless image   (error "No image specified"))
 113   (let (image-directory image-directory-load-path)
 114     ;; Check for images in image-load-path or load-path.
 115     (let ((img image)
 116           (dir (or
 117                 ;; Images in image-load-path.
 118                 (image-search-load-path image)
 119                 ;; Images in load-path.
 120                 (locate-library image)))
 121           parent)
 122       ;; Since the image might be in a nested directory (for
 123       ;; example, mail/attach.pbm), adjust `image-directory'
 124       ;; accordingly.
 125       (when dir
 126         (setq dir (file-name-directory dir))
 127         (while (setq parent (file-name-directory img))
 128           (setq img (directory-file-name parent)
 129                 dir (expand-file-name "../" dir))))
 130       (setq image-directory-load-path dir))
 131
 132     ;; If `image-directory-load-path' isn't Emacs' image directory,
 133     ;; it's probably a user preference, so use it. Then use a
 134     ;; relative setting if possible; otherwise, use
 135     ;; `image-directory-load-path'.
 136     (cond
 137      ;; User-modified image-load-path?
 138      ((and image-directory-load-path
 139            (not (equal image-directory-load-path
 140                        (file-name-as-directory
 141                         (expand-file-name "images" data-directory)))))
 142       (setq image-directory image-directory-load-path))
 143      ;; Try relative setting.
 144      ((let (library-name d1ei d2ei)
 145         ;; First, find library in the load-path.
 146         (setq library-name (locate-library library))
 147         (if (not library-name)
 148             (error "Cannot find library %s in load-path" library))
 149         ;; And then set image-directory relative to that.
 150         (setq
 151          ;; Go down 2 levels.
 152          d2ei (file-name-as-directory
 153                (expand-file-name
 154                 (concat (file-name-directory library-name) "../../etc/images")))
 155          ;; Go down 1 level.
 156          d1ei (file-name-as-directory
 157                (expand-file-name
 158                 (concat (file-name-directory library-name) "../etc/images"))))
 159         (setq image-directory
 160               ;; Set it to nil if image is not found.
 161               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 162                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 163      ;; Use Emacs' image directory.
 164      (image-directory-load-path
 165       (setq image-directory image-directory-load-path))
 166      (no-error
 167       (message "Could not find image %s for library %s" image library))
 168      (t
 169       (error "Could not find image %s for library %s" image library)))
 170
 171     ;; Return an augmented `path' or `load-path'.
 172     (nconc (list image-directory)
 173            (delete image-directory (copy-sequence (or path load-path))))))
 174
 175
 176 (defun image-jpeg-p (data)
 177   "Value is non-nil if DATA, a string, consists of JFIF image data.
 178 We accept the tag Exif because that is the same format."
 179   (when (string-match "\\`\xff\xd8" data)
 180     (catch 'jfif
 181       (let ((len (length data)) (i 2))
 182         (while (< i len)
 183           (when (/= (aref data i) #xff)
 184             (throw 'jfif nil))
 185           (setq i (1+ i))
 186           (when (>= (+ i 2) len)
 187             (throw 'jfif nil))
 188           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 189                            (aref data (+ i 2))))
 190                 (code (aref data i)))
 191             (when (and (>= code #xe0) (<= code #xef))
 192               ;; APP0 LEN1 LEN2 "JFIF\0"
 193               (throw 'jfif
 194                      (string-match "JFIF\\|Exif"
 195                                    (substring data i (min (+ i nbytes) len)))))
 196             (setq i (+ i 1 nbytes))))))))
 197
 198
 199 ;;;###autoload
 200 (defun image-type-from-data (data)
 201   "Determine the image type from image data DATA.
 202 Value is a symbol specifying the image type or nil if type cannot
 203 be determined."
 204   (let ((types image-type-header-regexps)
 205         type)
 206     (while types
 207       (let ((regexp (car (car types)))
 208             (image-type (cdr (car types))))
 209         (if (or (and (symbolp image-type)
 210                      (string-match regexp data))
 211                 (and (consp image-type)
 212                      (funcall (car image-type) data)
 213                      (setq image-type (cdr image-type))))
 214             (setq type image-type
 215                   types nil)
 216           (setq types (cdr types)))))
 217     type))
 218
 219
 220 ;;;###autoload
 221 (defun image-type-from-buffer ()
 222   "Determine the image type from data in the current buffer.
 223 Value is a symbol specifying the image type or nil if type cannot
 224 be determined."
 225   (let ((types image-type-header-regexps)
 226         type
 227         (opoint (point)))
 228     (goto-char (point-min))
 229     (while types
 230       (let ((regexp (car (car types)))
 231             (image-type (cdr (car types)))
 232             data)
 233         (if (or (and (symbolp image-type)
 234                      (looking-at regexp))
 235                 (and (consp image-type)
 236                      (funcall (car image-type)
 237                               (or data
 238                                   (setq data
 239                                         (buffer-substring
 240                                          (point-min)
 241                                          (min (point-max)
 242                                               (+ (point-min) 256))))))
 243                      (setq image-type (cdr image-type))))
 244             (setq type image-type
 245                   types nil)
 246           (setq types (cdr types)))))
 247     (goto-char opoint)
 248     type))
 249
 250
 251 ;;;###autoload
 252 (defun image-type-from-file-header (file)
 253   "Determine the type of image file FILE from its first few bytes.
 254 Value is a symbol specifying the image type, or nil if type cannot
 255 be determined."
 256   (unless (or (file-readable-p file)
 257               (file-name-absolute-p file))
 258     (setq file (image-search-load-path file)))
 259   (and file
 260        (file-readable-p file)
 261        (with-temp-buffer
 262          (set-buffer-multibyte nil)
 263          (insert-file-contents-literally file nil 0 256)
 264          (image-type-from-buffer))))
 265
 266
 267 ;;;###autoload
 268 (defun image-type-from-file-name (file)
 269   "Determine the type of image file FILE from its name.
 270 Value is a symbol specifying the image type, or nil if type cannot
 271 be determined."
 272   (let ((types image-type-file-name-regexps)
 273         type)
 274     (while types
 275       (if (string-match (car (car types)) file)
 276           (setq type (cdr (car types))
 277                 types nil)
 278         (setq types (cdr types))))
 279     type))
 280
 281
 282 ;;;###autoload
 283 (defun image-type (file-or-data &optional type data-p)
 284   "Determine and return image type.
 285 FILE-OR-DATA is an image file name or image data.
 286 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 287 or nil, try to determine the image type from its first few bytes
 288 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 289 use its file extension as image type.
 290 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data."
 291   (when (and (not data-p) (not (stringp file-or-data)))
 292     (error "Invalid image file name `%s'" file-or-data))
 293   (cond ((null data-p)
 294          ;; FILE-OR-DATA is a file name.
 295          (unless (or type
 296                      (setq type (image-type-from-file-header file-or-data)))
 297            (let ((extension (file-name-extension file-or-data)))
 298              (unless extension
 299                (error "Cannot determine image type"))
 300              (setq type (intern extension)))))
 301         (t
 302          ;; FILE-OR-DATA contains image data.
 303          (unless type
 304            (setq type (image-type-from-data file-or-data)))))
 305   (unless type
 306     (error "Cannot determine image type"))
 307   (unless (symbolp type)
 308     (error "Invalid image type `%s'" type))
 309   type)
 310
 311 ;;;###autoload
 312 (defun image-type-available-p (type)
 313   "Return non-nil if image type TYPE is available.
 314 Image types are symbols like `xbm' or `jpeg'."
 315   (and (fboundp 'init-image-library)
 316        (init-image-library type image-library-alist)))
 317
 318
 319 ;;;###autoload
 320 (defun create-image (file-or-data &optional type data-p &rest props)
 321   "Create an image.
 322 FILE-OR-DATA is an image file name or image data.
 323 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 324 or nil, try to determine the image type from its first few bytes
 325 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 326 use its file extension as image type.
 327 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 328 Optional PROPS are additional image attributes to assign to the image,
 329 like, e.g. `:mask MASK'.
 330 Value is the image created, or nil if images of type TYPE are not supported.
 331
 332 Images should not be larger than specified by `max-image-size'."
 333   (setq type (image-type file-or-data type data-p))
 334   (when (image-type-available-p type)
 335     (append (list 'image :type type (if data-p :data :file) file-or-data)
 336             props)))
 337
 338
 339 ;;;###autoload
 340 (defun put-image (image pos &optional string area)
 341   "Put image IMAGE in front of POS in the current buffer.
 342 IMAGE must be an image created with `create-image' or `defimage'.
 343 IMAGE is displayed by putting an overlay into the current buffer with a
 344 `before-string' STRING that has a `display' property whose value is the
 345 image.  STRING is defaulted if you omit it.
 346 POS may be an integer or marker.
 347 AREA is where to display the image.  AREA nil or omitted means
 348 display it in the text area, a value of `left-margin' means
 349 display it in the left marginal area, a value of `right-margin'
 350 means display it in the right marginal area."
 351   (unless string (setq string "x"))
 352   (let ((buffer (current-buffer)))
 353     (unless (eq (car-safe image) 'image)
 354       (error "Not an image: %s" image))
 355     (unless (or (null area) (memq area '(left-margin right-margin)))
 356       (error "Invalid area %s" area))
 357     (setq string (copy-sequence string))
 358     (let ((overlay (make-overlay pos pos buffer))
 359           (prop (if (null area) image (list (list 'margin area) image))))
 360       (put-text-property 0 (length string) 'display prop string)
 361       (overlay-put overlay 'put-image t)
 362       (overlay-put overlay 'before-string string))))
 363
 364
 365 ;;;###autoload
 366 (defun insert-image (image &optional string area slice)
 367   "Insert IMAGE into current buffer at point.
 368 IMAGE is displayed by inserting STRING into the current buffer
 369 with a `display' property whose value is the image.  STRING is
 370 defaulted if you omit it.
 371 AREA is where to display the image.  AREA nil or omitted means
 372 display it in the text area, a value of `left-margin' means
 373 display it in the left marginal area, a value of `right-margin'
 374 means display it in the right marginal area.
 375 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 376 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 377 specifying the X and Y positions and WIDTH and HEIGHT of image area
 378 to insert.  A float value 0.0 - 1.0 means relative to the width or
 379 height of the image; integer values are taken as pixel values."
 380   ;; Use a space as least likely to cause trouble when it's a hidden
 381   ;; character in the buffer.
 382   (unless string (setq string " "))
 383   (unless (eq (car-safe image) 'image)
 384     (error "Not an image: %s" image))
 385   (unless (or (null area) (memq area '(left-margin right-margin)))
 386     (error "Invalid area %s" area))
 387   (if area
 388       (setq image (list (list 'margin area) image))
 389     ;; Cons up a new spec equal but not eq to `image' so that
 390     ;; inserting it twice in a row (adjacently) displays two copies of
 391     ;; the image.  Don't try to avoid this by looking at the display
 392     ;; properties on either side so that we DTRT more often with
 393     ;; cut-and-paste.  (Yanking killed image text next to another copy
 394     ;; of it loses anyway.)
 395     (setq image (cons 'image (cdr image))))
 396   (let ((start (point)))
 397     (insert string)
 398     (add-text-properties start (point)
 399                          `(display ,(if slice
 400                                         (list (cons 'slice slice) image)
 401                                       image) rear-nonsticky (display)))))
 402
 403
 404 ;;;###autoload
 405 (defun insert-sliced-image (image &optional string area rows cols)
 406   "Insert IMAGE into current buffer at point.
 407 IMAGE is displayed by inserting STRING into the current buffer
 408 with a `display' property whose value is the image.  STRING is
 409 defaulted if you omit it.
 410 AREA is where to display the image.  AREA nil or omitted means
 411 display it in the text area, a value of `left-margin' means
 412 display it in the left marginal area, a value of `right-margin'
 413 means display it in the right marginal area.
 414 The image is automatically split into ROW x COLS slices."
 415   (unless string (setq string " "))
 416   (unless (eq (car-safe image) 'image)
 417     (error "Not an image: %s" image))
 418   (unless (or (null area) (memq area '(left-margin right-margin)))
 419     (error "Invalid area %s" area))
 420   (if area
 421       (setq image (list (list 'margin area) image))
 422     ;; Cons up a new spec equal but not eq to `image' so that
 423     ;; inserting it twice in a row (adjacently) displays two copies of
 424     ;; the image.  Don't try to avoid this by looking at the display
 425     ;; properties on either side so that we DTRT more often with
 426     ;; cut-and-paste.  (Yanking killed image text next to another copy
 427     ;; of it loses anyway.)
 428     (setq image (cons 'image (cdr image))))
 429   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 430          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 431     (while (< y 1.0)
 432       (while (< x 1.0)
 433         (let ((start (point)))
 434           (insert string)
 435           (add-text-properties start (point)
 436                                `(display ,(list (list 'slice x y dx dy) image)
 437                                          rear-nonsticky (display)))
 438           (setq x (+ x dx))))
 439       (setq x 0.0
 440             y (+ y dy))
 441       (insert (propertize "\n" 'line-height t)))))
 442
 443
 444
 445 ;;;###autoload
 446 (defun remove-images (start end &optional buffer)
 447   "Remove images between START and END in BUFFER.
 448 Remove only images that were put in BUFFER with calls to `put-image'.
 449 BUFFER nil or omitted means use the current buffer."
 450   (unless buffer
 451     (setq buffer (current-buffer)))
 452   (let ((overlays (overlays-in start end)))
 453     (while overlays
 454       (let ((overlay (car overlays)))
 455         (when (overlay-get overlay 'put-image)
 456           (delete-overlay overlay)))
 457       (setq overlays (cdr overlays)))))
 458
 459 (defun image-search-load-path (file &optional path)
 460   (unless path
 461     (setq path image-load-path))
 462   (let (element found filename)
 463     (while (and (not found) (consp path))
 464       (setq element (car path))
 465       (cond
 466        ((stringp element)
 467         (setq found
 468               (file-readable-p
 469                (setq filename (expand-file-name file element)))))
 470        ((and (symbolp element) (boundp element))
 471         (setq element (symbol-value element))
 472         (cond
 473          ((stringp element)
 474           (setq found
 475                 (file-readable-p
 476                  (setq filename (expand-file-name file element)))))
 477          ((consp element)
 478           (if (setq filename (image-search-load-path file element))
 479               (setq found t))))))
 480       (setq path (cdr path)))
 481     (if found filename)))
 482
 483 ;;;###autoload
 484 (defun find-image (specs)
 485   "Find an image, choosing one of a list of image specifications.
 486
 487 SPECS is a list of image specifications.
 488
 489 Each image specification in SPECS is a property list.  The contents of
 490 a specification are image type dependent.  All specifications must at
 491 least contain the properties `:type TYPE' and either `:file FILE' or
 492 `:data DATA', where TYPE is a symbol specifying the image type,
 493 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 494 string containing the actual image data.  The specification whose TYPE
 495 is supported, and FILE exists, is used to construct the image
 496 specification to be returned.  Return nil if no specification is
 497 satisfied.
 498
 499 The image is looked for in `image-load-path'.
 500
 501 Image files should not be larger than specified by `max-image-size'."
 502   (let (image)
 503     (while (and specs (null image))
 504       (let* ((spec (car specs))
 505              (type (plist-get spec :type))
 506              (data (plist-get spec :data))
 507              (file (plist-get spec :file))
 508              found)
 509         (when (image-type-available-p type)
 510           (cond ((stringp file)
 511                  (if (setq found (image-search-load-path file))
 512                      (setq image
 513                            (cons 'image (plist-put (copy-sequence spec)
 514                                                    :file found)))))
 515                 ((not (null data))
 516                  (setq image (cons 'image spec)))))
 517         (setq specs (cdr specs))))
 518     image))
 519
 520
 521 ;;;###autoload
 522 (defmacro defimage (symbol specs &optional doc)
 523   "Define SYMBOL as an image.
 524
 525 SPECS is a list of image specifications.  DOC is an optional
 526 documentation string.
 527
 528 Each image specification in SPECS is a property list.  The contents of
 529 a specification are image type dependent.  All specifications must at
 530 least contain the properties `:type TYPE' and either `:file FILE' or
 531 `:data DATA', where TYPE is a symbol specifying the image type,
 532 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 533 string containing the actual image data.  The first image
 534 specification whose TYPE is supported, and FILE exists, is used to
 535 define SYMBOL.
 536
 537 Example:
 538
 539    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 540                          (:type xbm :file \"~/test1.xbm\")))"
 541   (declare (doc-string 3))
 542   `(defvar ,symbol (find-image ',specs) ,doc))
 543
 544
 545 (provide 'image)
 546
 547 ;; arch-tag: 8e76a07b-eb48-4f3e-a7a0-1a7ba9f096b3
 548 ;;; image.el ends here