lisp/vc/vc-arch.el

   1 ;;; vc-arch.el --- VC backend for the Arch version-control system
   2
   3 ;; Copyright (C) 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7 ;; Package: vc
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The home page of the Arch version control system is at
  27 ;;
  28 ;;      http://www.gnuarch.org/
  29 ;;
  30 ;; This is derived from vc-mcvs.el as follows:
  31 ;; - cp vc-mcvs.el vc-arch.el and then M-% mcvs RET arch RET
  32 ;;
  33 ;; Then of course started the hacking.
  34 ;;
  35 ;; What has been partly tested:
  36 ;; - Open a file.
  37 ;; - C-x v =  without any prefix arg.
  38 ;; - C-x v v  to commit a change to a single file.
  39
  40 ;; Bugs:
  41
  42 ;; - *vc-log*'s initial content lacks the `Summary:' lines.
  43 ;; - All files under the tree are considered as "under Arch's control"
  44 ;;   without regards to =tagging-method and such.
  45 ;; - Files are always considered as `edited'.
  46 ;; - C-x v l does not work.
  47 ;; - C-x v i does not work.
  48 ;; - C-x v ~ does not work.
  49 ;; - C-x v u does not work.
  50 ;; - C-x v s does not work.
  51 ;; - C-x v r does not work.
  52 ;; - VC directory listings do not work.
  53 ;; - And more...
  54
  55 ;;; Code:
  56
  57 (eval-when-compile (require 'vc) (require 'cl))
  58
  59 ;;; Properties of the backend
  60
  61 (defun vc-arch-revision-granularity () 'repository)
  62 (defun vc-arch-checkout-model (files) 'implicit)
  63
  64 ;;;
  65 ;;; Customization options
  66 ;;;
  67
  68 (defgroup vc-arch nil
  69   "VC Arch backend."
  70   :version "24.1"
  71   :group 'vc)
  72
  73 ;; It seems Arch diff does not accept many options, so this is not
  74 ;; very useful.  It exists mainly so that the VC backends are all
  75 ;; consistent with regards to their treatment of diff switches.
  76 (defcustom vc-arch-diff-switches t
  77   "String or list of strings specifying switches for Arch diff under VC.
  78 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  79   :type '(choice (const :tag "Unspecified" nil)
  80                  (const :tag "None" t)
  81                  (string :tag "Argument String")
  82                  (repeat :tag "Argument List" :value ("") string))
  83   :version "23.1"
  84   :group 'vc-arch)
  85
  86 (define-obsolete-variable-alias 'vc-arch-command 'vc-arch-program "23.1")
  87
  88 (defcustom vc-arch-program
  89   (let ((candidates '("tla" "baz")))
  90     (while (and candidates (not (executable-find (car candidates))))
  91       (setq candidates (cdr candidates)))
  92     (or (car candidates) "tla"))
  93   "Name of the Arch executable."
  94   :type 'string
  95   :group 'vc-arch)
  96
  97 ;; Clear up the cache to force vc-call to check again and discover
  98 ;; new functions when we reload this file.
  99 (put 'Arch 'vc-functions nil)
 100
 101 ;;;###autoload (defun vc-arch-registered (file)
 102 ;;;###autoload   (if (vc-find-root file "{arch}/=tagging-method")
 103 ;;;###autoload       (progn
 104 ;;;###autoload         (load "vc-arch")
 105 ;;;###autoload         (vc-arch-registered file))))
 106
 107 (defun vc-arch-add-tagline ()
 108   "Add an `arch-tag' to the end of the current file."
 109   (interactive)
 110   (comment-normalize-vars)
 111   (goto-char (point-max))
 112   (forward-comment -1)
 113   (skip-chars-forward " \t\n")
 114   (cond
 115    ((not (bolp)) (insert "\n\n"))
 116    ((not (eq ?\n (char-before (1- (point))))) (insert "\n")))
 117   (let ((beg (point))
 118         (idfile (and buffer-file-name
 119                      (expand-file-name
 120                       (concat ".arch-ids/"
 121                               (file-name-nondirectory buffer-file-name)
 122                               ".id")
 123                       (file-name-directory buffer-file-name)))))
 124     (insert "arch-tag: ")
 125     (if (and idfile (file-exists-p idfile))
 126         ;; If the file is unreadable, we do want to get an error here.
 127         (progn
 128           (insert-file-contents idfile)
 129           (forward-line 1)
 130           (delete-file idfile))
 131       (condition-case nil
 132           (call-process "uuidgen" nil t)
 133         (file-error (insert (format "%s <%s> %s"
 134                                     (current-time-string)
 135                                     user-mail-address
 136                                     (+ (nth 2 (current-time))
 137                                        (buffer-size)))))))
 138     (comment-region beg (point))))
 139
 140 (defconst vc-arch-tagline-re "^\\W*arch-tag:[ \t]*\\(.*[^ \t\n]\\)")
 141
 142 (defmacro vc-with-current-file-buffer (file &rest body)
 143   (declare (indent 2) (debug t))
 144   `(let ((-kill-buf- nil)
 145          (-file- ,file))
 146      (with-current-buffer (or (find-buffer-visiting -file-)
 147                               (setq -kill-buf- (generate-new-buffer " temp")))
 148        ;; Avoid find-file-literally since it can do many undesirable extra
 149        ;; things (among which, call us back into an infinite loop).
 150        (if -kill-buf- (insert-file-contents -file-))
 151        (unwind-protect
 152            (progn ,@body)
 153          (if (buffer-live-p -kill-buf-) (kill-buffer -kill-buf-))))))
 154
 155 (defun vc-arch-file-source-p (file)
 156   "Can return nil, `maybe' or a non-nil value.
 157 Only the value `maybe' can be trusted :-(."
 158   ;; FIXME: Check the tag and name of parent dirs.
 159   (unless (string-match "\\`[,+]" (file-name-nondirectory file))
 160     (or (string-match "\\`{arch}/"
 161                       (file-relative-name file (vc-arch-root file)))
 162         (file-exists-p
 163          ;; Check the presence of an ID file.
 164          (expand-file-name
 165           (concat ".arch-ids/" (file-name-nondirectory file) ".id")
 166           (file-name-directory file)))
 167         ;; Check the presence of a tagline.
 168         (vc-with-current-file-buffer file
 169           (save-excursion
 170             (goto-char (point-max))
 171             (or (re-search-backward vc-arch-tagline-re (- (point) 1000) t)
 172                 (progn
 173                   (goto-char (point-min))
 174                   (re-search-forward vc-arch-tagline-re (+ (point) 1000) t)))))
 175         ;; FIXME: check =tagging-method to see whether untagged files might
 176         ;; be source or not.
 177         (with-current-buffer
 178             (find-file-noselect (expand-file-name "{arch}/=tagging-method"
 179                                                   (vc-arch-root file)))
 180           (let ((untagged-source t))    ;Default is `names'.
 181             (save-excursion
 182               (goto-char (point-min))
 183               (if (re-search-forward "^[ \t]*\\(\\(tagline\\|implicit\\|names\\)\\|explicit\\)" nil t)
 184                   (setq untagged-source (match-end 2)))
 185               (if (re-search-forward "^[ \t]*untagged-source[ \t]+\\(\\(source\\)\\|precious\\|backup\\|junk\\|unrecognized\\)" nil t)
 186                   (setq untagged-source (match-end 2))))
 187             (if untagged-source 'maybe))))))
 188
 189 (defun vc-arch-file-id (file)
 190   ;; Don't include the kind of ID this is because it seems to be too messy.
 191   (let ((idfile (expand-file-name
 192                  (concat ".arch-ids/" (file-name-nondirectory file) ".id")
 193                  (file-name-directory file))))
 194     (if (file-exists-p idfile)
 195         (with-temp-buffer
 196           (insert-file-contents idfile)
 197           (looking-at ".*[^ \n\t]")
 198           (match-string 0))
 199       (with-current-buffer (find-file-noselect file)
 200         (save-excursion
 201           (goto-char (point-max))
 202           (if (or (re-search-backward vc-arch-tagline-re (- (point) 1000) t)
 203                   (progn
 204                     (goto-char (point-min))
 205                     (re-search-forward vc-arch-tagline-re (+ (point) 1000) t)))
 206               (match-string 1)
 207             (concat "./" (file-relative-name file (vc-arch-root file)))))))))
 208
 209 (defun vc-arch-tagging-method (file)
 210   (with-current-buffer
 211       (find-file-noselect
 212        (expand-file-name "{arch}/=tagging-method" (vc-arch-root file)))
 213     (save-excursion
 214       (goto-char (point-min))
 215       (if (re-search-forward
 216            "^[ \t]*\\(tagline\\|implicit\\|names\\|explicit\\)" nil t)
 217           (intern (match-string 1))
 218         'names))))
 219
 220 (defun vc-arch-root (file)
 221   "Return the root directory of an Arch project, if any."
 222   (or (vc-file-getprop file 'arch-root)
 223       ;; Check the =tagging-method, in case someone naively manually
 224       ;; creates a {arch} directory somewhere.
 225       (let ((root (vc-find-root file "{arch}/=tagging-method")))
 226         (when root
 227           (vc-file-setprop
 228            file 'arch-root root)))))
 229
 230 (defun vc-arch-register (files &optional rev comment)
 231   (if rev (error "Explicit initial revision not supported for Arch"))
 232   (dolist (file files)
 233     (let ((tagmet (vc-arch-tagging-method file)))
 234       (if (and (memq tagmet '(tagline implicit)) comment-start)
 235           (with-current-buffer (find-file-noselect file)
 236             (if (buffer-modified-p)
 237                 (error "Save %s first" (buffer-name)))
 238             (vc-arch-add-tagline)
 239             (save-buffer)))))
 240   (vc-arch-command nil 0 files "add"))
 241
 242 (defun vc-arch-registered (file)
 243   ;; Don't seriously check whether it's source or not.  Checking would
 244   ;; require running TLA, so it's better to not do it, so it also works if
 245   ;; TLA is not installed.
 246   (and (vc-arch-root file)
 247        (vc-arch-file-source-p file)))
 248
 249 (defun vc-arch-default-version (file)
 250   (or (vc-file-getprop (vc-arch-root file) 'arch-default-version)
 251       (let* ((root (vc-arch-root file))
 252              (f (expand-file-name "{arch}/++default-version" root)))
 253         (if (file-readable-p f)
 254             (vc-file-setprop
 255              root 'arch-default-version
 256              (with-temp-buffer
 257                (insert-file-contents f)
 258                ;; Strip the terminating newline.
 259                (buffer-substring (point-min) (1- (point-max)))))))))
 260
 261 (defun vc-arch-workfile-unchanged-p (file)
 262   "Stub: arch workfiles are always considered to be in a changed state,"
 263   nil)
 264
 265 (defun vc-arch-state (file)
 266   ;; There's no checkout operation and merging is not done from VC
 267   ;; so the only operation that's state dependent that VC supports is commit
 268   ;; which is only activated if the file is `edited'.
 269   (let* ((root (vc-arch-root file))
 270          (ver (vc-arch-default-version file))
 271          (pat (concat "\\`" (subst-char-in-string ?/ ?% ver)))
 272          (dir (expand-file-name ",,inode-sigs/"
 273                                 (expand-file-name "{arch}" root)))
 274          (sigfile nil))
 275     (dolist (f (if (file-directory-p dir) (directory-files dir t pat)))
 276       (if (or (not sigfile) (file-newer-than-file-p f sigfile))
 277           (setq sigfile f)))
 278     (if (not sigfile)
 279         'edited                         ;We know nothing.
 280       (let ((id (vc-arch-file-id file)))
 281         (setq id (replace-regexp-in-string "[ \t]" "_" id))
 282         (with-current-buffer (find-file-noselect sigfile)
 283           (goto-char (point-min))
 284           (while (and (search-forward id nil 'move)
 285                       (save-excursion
 286                         (goto-char (- (match-beginning 0) 2))
 287                         ;; For `names', the lines start with `?./foo/bar'.
 288                         ;; For others there's 2 chars before the ./foo/bar.
 289                         (or (not (or (bolp) (looking-at "\n?")))
 290                             ;; Ignore E_ entries used for foo.id files.
 291                             (looking-at "E_")))))
 292           (if (eobp)
 293               ;; ID not found.
 294               (if (equal (file-name-nondirectory sigfile)
 295                          (subst-char-in-string
 296                           ?/ ?% (vc-arch-working-revision file)))
 297                   'added
 298                 ;; Might be `added' or `up-to-date' as well.
 299                 ;; FIXME: Check in the patch logs to find out.
 300                 'edited)
 301             ;; Found the ID, let's check the inode.
 302             (if (not (re-search-forward
 303                       "\t.*mtime=\\([0-9]+\\):size=\\([0-9]+\\)"
 304                       (line-end-position) t))
 305                 ;; Buh?  Unexpected format.
 306                 'edited
 307               (let ((ats (file-attributes file)))
 308                 (if (and (eq (nth 7 ats) (string-to-number (match-string 2)))
 309                          (equal (format-time-string "%s" (nth 5 ats))
 310                                 (match-string 1)))
 311                     'up-to-date
 312                   'edited)))))))))
 313
 314 (defun vc-arch-dir-status (dir callback)
 315   "Run 'tla inventory' for DIR and pass results to CALLBACK.
 316 CALLBACK expects (ENTRIES &optional MORE-TO-COME); see
 317 `vc-dir-refresh'."
 318   (let ((default-directory dir))
 319     (vc-arch-command t 'async nil "changes"))
 320   ;; The updating could be done asynchronously.
 321   (vc-exec-after
 322    `(vc-arch-after-dir-status ',callback)))
 323
 324 (defun vc-arch-after-dir-status (callback)
 325   (let* ((state-map '(("M " . edited)
 326                       ("Mb" . edited)   ;binary
 327                       ("D " . removed)
 328                       ("D/" . removed)  ;directory
 329                       ("A " . added)
 330                       ("A/" . added)    ;directory
 331                       ("=>" . renamed)
 332                       ("/>" . renamed)  ;directory
 333                       ("lf" . symlink-to-file)
 334                       ("fl" . file-to-symlink)
 335                       ("--" . permissions-changed)
 336                       ("-/" . permissions-changed) ;directory
 337                       ))
 338          (state-map-regexp (regexp-opt (mapcar 'car state-map) t))
 339          (entry-regexp (concat "^" state-map-regexp " \\(.*\\)$"))
 340          result)
 341     (goto-char (point-min))
 342     ;;(message "Got %s" (buffer-string))
 343     (while (re-search-forward entry-regexp nil t)
 344       (let* ((state-string (match-string 1))
 345              (state (cdr (assoc state-string state-map)))
 346              (filename (match-string 2)))
 347         (push (list filename state) result)))
 348
 349     (funcall callback result nil)))
 350
 351 (defun vc-arch-working-revision (file)
 352   (let* ((root (expand-file-name "{arch}" (vc-arch-root file)))
 353          (defbranch (vc-arch-default-version file)))
 354     (when (and defbranch (string-match "\\`\\(.+@[^/\n]+\\)/\\(\\(\\(.*?\\)\\(?:--.*\\)?\\)--.*\\)\\'" defbranch))
 355       (let* ((archive (match-string 1 defbranch))
 356              (category (match-string 4 defbranch))
 357              (branch (match-string 3 defbranch))
 358              (version (match-string 2 defbranch))
 359              (sealed nil) (rev-nb 0)
 360              (rev nil)
 361              logdir tmp)
 362         (setq logdir (expand-file-name category root))
 363         (setq logdir (expand-file-name branch logdir))
 364         (setq logdir (expand-file-name version logdir))
 365         (setq logdir (expand-file-name archive logdir))
 366         (setq logdir (expand-file-name "patch-log" logdir))
 367         (dolist (file (if (file-directory-p logdir) (directory-files logdir)))
 368           ;; Revision names go: base-0, patch-N, version-0, versionfix-M.
 369           (when (and (eq (aref file 0) ?v) (not sealed))
 370             (setq sealed t rev-nb 0))
 371           (if (and (string-match "-\\([0-9]+\\)\\'" file)
 372                    (setq tmp (string-to-number (match-string 1 file)))
 373                    (or (not sealed) (eq (aref file 0) ?v))
 374                    (>= tmp rev-nb))
 375               (setq rev-nb tmp rev file)))
 376         ;; Use "none-000" if the tree hasn't yet been committed on the
 377         ;; default branch.  We'll then get "Arch:000[branch]" on the mode-line.
 378         (concat defbranch "--" (or rev "none-000"))))))
 379
 380
 381 (defcustom vc-arch-mode-line-rewrite
 382   '(("\\`.*--\\(.*--.*\\)--\\(v?\\).*-\\([0-9]+\\)\\'" . "\\2\\3[\\1]"))
 383   "Rewrite rules to shorten Arch's revision names on the mode-line."
 384   :type '(repeat (cons regexp string))
 385   :group 'vc-arch)
 386
 387 (defun vc-arch-mode-line-string (file)
 388   "Return string for placement in modeline by `vc-mode-line' for FILE."
 389   (let ((rev (vc-working-revision file)))
 390     (dolist (rule vc-arch-mode-line-rewrite)
 391       (if (string-match (car rule) rev)
 392           (setq rev (replace-match (cdr rule) t nil rev))))
 393     (format "Arch%c%s"
 394             (case (vc-state file)
 395               ((up-to-date needs-update) ?-)
 396               (added ?@)
 397               (t ?:))
 398             rev)))
 399
 400 (defun vc-arch-diff3-rej-p (rej)
 401   (let ((attrs (file-attributes rej)))
 402     (and attrs (< (nth 7 attrs) 60)
 403          (with-temp-buffer
 404            (insert-file-contents rej)
 405            (goto-char (point-min))
 406            (looking-at "Conflicts occurred, diff3 conflict markers left in file\\.")))))
 407
 408 (defun vc-arch-delete-rej-if-obsolete ()
 409   "For use in `after-save-hook'."
 410   (save-excursion
 411     (let ((rej (concat buffer-file-name ".rej")))
 412       (when (and buffer-file-name (vc-arch-diff3-rej-p rej))
 413         (unless (re-search-forward "^<<<<<<< " nil t)
 414           ;; The .rej file is obsolete.
 415           (condition-case nil (delete-file rej) (error nil))
 416           ;; Remove the hook so that it is not called multiple times.
 417           (remove-hook 'after-save-hook 'vc-arch-delete-rej-if-obsolete t))))))
 418
 419 (defun vc-arch-find-file-hook ()
 420   (let ((rej (concat buffer-file-name ".rej")))
 421     (when (and buffer-file-name (file-exists-p rej))
 422       (if (vc-arch-diff3-rej-p rej)
 423           (save-excursion
 424             (goto-char (point-min))
 425             (if (not (re-search-forward "^<<<<<<< " nil t))
 426                 ;; The .rej file is obsolete.
 427                 (condition-case nil (delete-file rej) (error nil))
 428               (smerge-mode 1)
 429               (add-hook 'after-save-hook
 430                         'vc-arch-delete-rej-if-obsolete nil t)
 431               (message "There are unresolved conflicts in this file")))
 432         (message "There are unresolved conflicts in %s"
 433                  (file-name-nondirectory rej))))))
 434
 435 (defun vc-arch-checkin (files rev comment)
 436   (if rev (error "Committing to a specific revision is unsupported"))
 437   ;; FIXME: This implementation probably only works for singleton filesets
 438   (let ((summary (file-relative-name (car files) (vc-arch-root (car files)))))
 439     ;; Extract a summary from the comment.
 440     (when (or (string-match "\\`Summary:[ \t]*\\(.*[^ \t\n]\\)\\([ \t]*\n\\)*" comment)
 441               (string-match "\\`[ \t]*\\(.*[^ \t\n]\\)[ \t]*\\(\n?\\'\\|\n\\([ \t]*\n\\)+\\)" comment))
 442       (setq summary (match-string 1 comment))
 443       (setq comment (substring comment (match-end 0))))
 444     (vc-arch-command nil 0 files "commit" "-s" summary "-L" comment "--"
 445                      (vc-switches 'Arch 'checkin))))
 446
 447 (defun vc-arch-diff (files &optional oldvers newvers buffer)
 448   "Get a difference report using Arch between two versions of FILES."
 449   ;; FIXME: This implementation only works for singleton filesets.  To make
 450   ;; it work for more cases, we have to either call `file-diffs' manually on
 451   ;; each and every `file' in the fileset, or use `changes --diffs' (and
 452   ;; variants) and maybe filter the output with `filterdiff' to only include
 453   ;; the files in which we're interested.
 454   (let ((file (car files)))
 455     (if (and newvers
 456              (vc-up-to-date-p file)
 457              (equal newvers (vc-working-revision file)))
 458         ;; Newvers is the base revision and the current file is unchanged,
 459         ;; so we can diff with the current file.
 460         (setq newvers nil))
 461     (if newvers
 462         (error "Diffing specific revisions not implemented")
 463       (let* (process-file-side-effects
 464              (async (not vc-disable-async-diff))
 465              ;; Run the command from the root dir.
 466              (default-directory (vc-arch-root file))
 467              (status
 468               (vc-arch-command
 469                (or buffer "*vc-diff*")
 470                (if async 'async 1)
 471                nil "file-diffs"
 472                (vc-switches 'Arch 'diff)
 473                (file-relative-name file)
 474                (if (equal oldvers (vc-working-revision file))
 475                    nil
 476                  oldvers))))
 477         (if async 1 status)))))        ; async diff, pessimistic assumption.
 478
 479 (defun vc-arch-delete-file (file)
 480   (vc-arch-command nil 0 file "rm"))
 481
 482 (defun vc-arch-rename-file (old new)
 483   (vc-arch-command nil 0 new "mv" (file-relative-name old)))
 484
 485 (defalias 'vc-arch-responsible-p 'vc-arch-root)
 486
 487 (defun vc-arch-command (buffer okstatus file &rest flags)
 488   "A wrapper around `vc-do-command' for use in vc-arch.el."
 489   (apply 'vc-do-command (or buffer "*vc*") okstatus vc-arch-program file flags))
 490
 491 (defun vc-arch-init-revision () nil)
 492
 493 ;;; Completion of versions and revisions.
 494
 495 (defun vc-arch--version-completion-table (root string)
 496   (delq nil
 497         (mapcar
 498          (lambda (d)
 499            (when (string-match "/\\([^/]+\\)/\\([^/]+\\)\\'" d)
 500              (concat (match-string 2 d) "/" (match-string 1 d))))
 501          (let ((default-directory root))
 502            (file-expand-wildcards
 503             (concat "*/*/"
 504                     (if (string-match "/" string)
 505                         (concat (substring string (match-end 0))
 506                                 "*/" (substring string 0 (match-beginning 0)))
 507                       (concat "*/" string))
 508                     "*"))))))
 509
 510 (defun vc-arch-revision-completion-table (files)
 511   (lexical-let ((files files))
 512     (lambda (string pred action)
 513       ;; FIXME: complete revision patches as well.
 514       (let* ((root (expand-file-name "{arch}" (vc-arch-root (car files))))
 515              (table (vc-arch--version-completion-table root string)))
 516         (complete-with-action action table string pred)))))
 517
 518 ;;; Trimming revision libraries.
 519
 520 ;; This code is not directly related to VC and there are many variants of
 521 ;; this functionality available as scripts, but I like this version better,
 522 ;; so maybe others will like it too.
 523
 524 (defun vc-arch-trim-find-least-useful-rev (revs)
 525   (let* ((first (pop revs))
 526          (second (pop revs))
 527          (third (pop revs))
 528          ;; We try to give more importance to recent revisions.  The idea is
 529          ;; that it's OK if checking out a revision 1000-patch-old is ten
 530          ;; times slower than checking out a revision 100-patch-old.  But at
 531          ;; the same time a 2-patch-old rev isn't really ten times more
 532          ;; important than a 20-patch-old, so we use an arbitrary constant
 533          ;; "100" to reduce this effect for recent revisions.  Making this
 534          ;; constant a float has the side effect of causing the subsequent
 535          ;; computations to be done as floats as well.
 536          (max (+ 100.0 (car (or (car (last revs)) third))))
 537          (cost (lambda () (/ (- (car third) (car first)) (- max (car second)))))
 538          (minrev second)
 539          (mincost (funcall cost)))
 540     (while revs
 541       (setq first second)
 542       (setq second third)
 543       (setq third (pop revs))
 544       (when (< (funcall cost) mincost)
 545         (setq minrev second)
 546         (setq mincost (funcall cost))))
 547     minrev))
 548
 549 (defun vc-arch-trim-make-sentinel (revs)
 550   (if (null revs) (lambda (proc msg) (message "VC-Arch trimming ... done"))
 551     (lexical-let ((revs revs))
 552       (lambda (proc msg)
 553         (message "VC-Arch trimming %s..." (file-name-nondirectory (car revs)))
 554         (rename-file (car revs) (concat (car revs) "*rm*"))
 555        (setq proc (start-process "vc-arch-trim" nil
 556                                   "rm" "-rf" (concat (car revs) "*rm*")))
 557         (set-process-sentinel proc (vc-arch-trim-make-sentinel (cdr revs)))))))
 558
 559 (defun vc-arch-trim-one-revlib (dir)
 560   "Delete half of the revisions in the revision library."
 561   (interactive "Ddirectory: ")
 562   (let ((garbage (directory-files dir 'full "\\`,," 'nosort)))
 563     (when garbage
 564       (funcall (vc-arch-trim-make-sentinel garbage) nil nil)))
 565   (let ((revs
 566          (sort (delq nil
 567                      (mapcar
 568                       (lambda (f)
 569                         (when (string-match "-\\([0-9]+\\)\\'" f)
 570                           (cons (string-to-number (match-string 1 f)) f)))
 571                       (directory-files dir nil nil 'nosort)))
 572                'car-less-than-car))
 573         (subdirs nil))
 574     (when (cddr revs)
 575       (dotimes (i (/ (length revs) 2))
 576         (let ((minrev (vc-arch-trim-find-least-useful-rev revs)))
 577           (setq revs (delq minrev revs))
 578           (push minrev subdirs)))
 579       (funcall (vc-arch-trim-make-sentinel
 580                 (mapcar (lambda (x) (expand-file-name (cdr x) dir)) subdirs))
 581                nil nil))))
 582
 583 (defun vc-arch-trim-revlib ()
 584   "Delete half of the revisions in the revision library."
 585   (interactive)
 586   (let ((rl-dir (with-output-to-string
 587                   (call-process vc-arch-program nil standard-output nil
 588                                 "my-revision-library"))))
 589     (while (string-match "\\(.*\\)\n" rl-dir)
 590       (let ((dir (match-string 1 rl-dir)))
 591         (setq rl-dir
 592               (if (and (file-directory-p dir) (file-writable-p dir))
 593                   dir
 594                 (substring rl-dir (match-end 0))))))
 595     (unless (file-writable-p rl-dir)
 596       (error "No writable revlib directory found"))
 597     (message "Revlib at %s" rl-dir)
 598     (let* ((archives (directory-files rl-dir 'full "[^.]\\|..."))
 599            (categories
 600             (apply 'append
 601                    (mapcar (lambda (dir)
 602                              (when (file-directory-p dir)
 603                                (directory-files dir 'full "[^.]\\|...")))
 604                            archives)))
 605            (branches
 606             (apply 'append
 607                    (mapcar (lambda (dir)
 608                              (when (file-directory-p dir)
 609                                (directory-files dir 'full "[^.]\\|...")))
 610                            categories)))
 611            (versions
 612             (apply 'append
 613                    (mapcar (lambda (dir)
 614                              (when (file-directory-p dir)
 615                                (directory-files dir 'full "--.*--")))
 616                            branches))))
 617       (mapc 'vc-arch-trim-one-revlib versions))
 618     ))
 619
 620 (defvar vc-arch-extra-menu-map
 621   (let ((map (make-sparse-keymap)))
 622     (define-key map [add-tagline]
 623       '(menu-item "Add tagline" vc-arch-add-tagline))
 624     map))
 625
 626 (defun vc-arch-extra-menu () vc-arch-extra-menu-map)
 627
 628
 629 ;;; Less obvious implementations.
 630
 631 (defun vc-arch-find-revision (file rev buffer)
 632   (let ((out (make-temp-file "vc-out")))
 633     (unwind-protect
 634         (progn
 635           (with-temp-buffer
 636             (vc-arch-command (current-buffer) 1 nil "file-diffs" file rev)
 637             (call-process-region (point-min) (point-max)
 638                                  "patch" nil nil nil "-R" "-o" out file))
 639           (with-current-buffer buffer
 640             (insert-file-contents out)))
 641       (delete-file out))))
 642
 643 (provide 'vc-arch)
 644
 645 ;;; vc-arch.el ends here