lisp/tabify.el

   1 ;;; tabify.el --- tab conversion commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Commands to optimize spaces to tabs or expand tabs to spaces in a region
  26 ;; (`tabify' and `untabify').  The variable tab-width does the obvious.
  27
  28 ;;; Code:
  29
  30 ;;;###autoload
  31 (defun untabify (start end)
  32   "Convert all tabs in region to multiple spaces, preserving columns.
  33 Called non-interactively, the region is specified by arguments
  34 START and END, rather than by the position of point and mark.
  35 The variable `tab-width' controls the spacing of tab stops."
  36   (interactive "r")
  37   (save-excursion
  38     (save-restriction
  39       (narrow-to-region (point-min) end)
  40       (goto-char start)
  41       (while (search-forward "\t" nil t)        ; faster than re-search
  42         (let ((tab-beg (point))
  43               (column (current-column))
  44               (indent-tabs-mode nil))
  45           (skip-chars-backward "\t" start)
  46           (delete-region tab-beg (point))
  47           (indent-to column))))))
  48
  49 ;;;###autoload
  50 (defun tabify (start end)
  51   "Convert multiple spaces in region to tabs when possible.
  52 A group of spaces is partially replaced by tabs
  53 when this can be done without changing the column they end at.
  54 Called non-interactively, the region is specified by arguments
  55 START and END, rather than by the position of point and mark.
  56 The variable `tab-width' controls the spacing of tab stops."
  57   (interactive "r")
  58   (save-excursion
  59     (save-restriction
  60       (narrow-to-region start end)
  61       (goto-char start)
  62       (while (re-search-forward "[ \t][ \t][ \t]*" nil t)
  63         (let ((column (current-column))
  64               (indent-tabs-mode t))
  65           (delete-region (match-beginning 0) (point))
  66           (indent-to column))))))
  67
  68 (provide 'tabify)
  69
  70 ;;; tabify.el ends here