lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2003
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "*Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "*A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "*A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "*If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'."
 207   :global t :group 'partial-completion
 208   ;; Deal with key bindings...
 209   (PC-bindings partial-completion-mode)
 210   ;; Deal with include file feature...
 211   (cond ((not partial-completion-mode)
 212          (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 213         ((not PC-disable-includes)
 214          (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 215   ;; ... with some underhand redefining.
 216   (cond ((and (not partial-completion-mode)
 217               (functionp PC-old-read-file-name-internal))
 218          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 219         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 220          (setq PC-old-read-file-name-internal
 221                (symbol-function 'read-file-name-internal))
 222          (fset 'read-file-name-internal
 223                'PC-read-include-file-name-internal)))
 224     (when (and partial-completion-mode (null PC-env-vars-alist))
 225       (setq PC-env-vars-alist
 226             (mapcar (lambda (string)
 227                       (let ((d (string-match "=" string)))
 228                         (cons (concat "$" (substring string 0 d))
 229                               (and d (substring string (1+ d))))))
 230                     process-environment))))
 231
 232 \f
 233 (defun PC-complete ()
 234   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 235 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 236 name which consists of three or more words, the first beginning with \"b\"
 237 and the third beginning with \"di\".
 238
 239 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 240 `beginning-of-defun', so this would produce a list of completions
 241 just like when normal Emacs completions are ambiguous.
 242
 243 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 244 \".\", and SPC."
 245   (interactive)
 246   (if (PC-was-meta-key)
 247       (minibuffer-complete)
 248     ;; If the previous command was not this one,
 249     ;; never scroll, always retry completion.
 250     (or (eq last-command this-command)
 251         (setq minibuffer-scroll-window nil))
 252     (let ((window minibuffer-scroll-window))
 253       ;; If there's a fresh completion window with a live buffer,
 254       ;; and this command is repeated, scroll that window.
 255       (if (and window (window-buffer window)
 256                (buffer-name (window-buffer window)))
 257           (save-excursion
 258             (set-buffer (window-buffer window))
 259             (if (pos-visible-in-window-p (point-max) window)
 260                 (set-window-start window (point-min) nil)
 261               (scroll-other-window)))
 262         (PC-do-completion nil)))))
 263
 264
 265 (defun PC-complete-word ()
 266   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 267 See `PC-complete' for details.
 268 This can be bound to other keys, like `-' and `.', if you wish."
 269   (interactive)
 270   (if (eq (PC-was-meta-key) PC-meta-flag)
 271       (if (eq last-command-char ? )
 272           (minibuffer-complete-word)
 273         (self-insert-command 1))
 274     (self-insert-command 1)
 275     (if (eobp)
 276         (PC-do-completion 'word))))
 277
 278
 279 (defun PC-complete-space ()
 280   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 281 See `PC-complete' for details.
 282 This is suitable for binding to other keys which should act just like SPC."
 283   (interactive)
 284   (if (eq (PC-was-meta-key) PC-meta-flag)
 285       (minibuffer-complete-word)
 286     (insert " ")
 287     (if (eobp)
 288         (PC-do-completion 'word))))
 289
 290
 291 (defun PC-complete-and-exit ()
 292   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 293 See `PC-complete' for details."
 294   (interactive)
 295   (if (eq (PC-was-meta-key) PC-meta-flag)
 296       (minibuffer-complete-and-exit)
 297     (PC-do-complete-and-exit)))
 298
 299 (defun PC-force-complete-and-exit ()
 300   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 301 See `PC-complete' for details."
 302   (interactive)
 303   (let ((minibuffer-completion-confirm nil))
 304     (PC-do-complete-and-exit)))
 305
 306 (defun PC-do-complete-and-exit ()
 307   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 308       (exit-minibuffer)
 309     (let ((flag (PC-do-completion 'exit)))
 310       (and flag
 311            (if (or (eq flag 'complete)
 312                    (not minibuffer-completion-confirm))
 313                (exit-minibuffer)
 314              (PC-temp-minibuffer-message " [Confirm]"))))))
 315
 316
 317 (defun PC-completion-help ()
 318   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 319 See `PC-complete' for details."
 320   (interactive)
 321   (if (eq (PC-was-meta-key) PC-meta-flag)
 322       (minibuffer-completion-help)
 323     (PC-do-completion 'help)))
 324
 325 (defun PC-was-meta-key ()
 326   (or (/= (length (this-command-keys)) 1)
 327       (let ((key (aref (this-command-keys) 0)))
 328         (if (integerp key)
 329             (>= key 128)
 330           (not (null (memq 'meta (event-modifiers key))))))))
 331
 332
 333 (defvar PC-ignored-extensions 'empty-cache)
 334 (defvar PC-delims 'empty-cache)
 335 (defvar PC-ignored-regexp nil)
 336 (defvar PC-word-failed-flag nil)
 337 (defvar PC-delim-regex nil)
 338 (defvar PC-ndelims-regex nil)
 339 (defvar PC-delims-list nil)
 340
 341 (defvar PC-completion-as-file-name-predicate
 342   (function
 343    (lambda ()
 344      (memq minibuffer-completion-table
 345            '(read-file-name-internal read-directory-name-internal))))
 346    "A function testing whether a minibuffer completion now will work filename-style.
 347 The function takes no arguments, and typically looks at the value
 348 of `minibuffer-completion-table' and the minibuffer contents.")
 349
 350 (defun PC-do-completion (&optional mode beg end)
 351   (or beg (setq beg (minibuffer-prompt-end)))
 352   (or end (setq end (point-max)))
 353   (let* ((table minibuffer-completion-table)
 354          (pred minibuffer-completion-predicate)
 355          (filename (funcall PC-completion-as-file-name-predicate))
 356          (dirname nil)
 357          (dirlength 0)
 358          (str (buffer-substring beg end))
 359          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 360          (ambig nil)
 361          basestr
 362          env-on
 363          regex
 364          p offset
 365          (poss nil)
 366          helpposs
 367          (case-fold-search completion-ignore-case))
 368
 369     ;; Check if buffer contents can already be considered complete
 370     (if (and (eq mode 'exit)
 371              (PC-is-complete-p str table pred))
 372         'complete
 373
 374       ;; Do substitutions in directory names
 375       (and filename
 376            (setq basestr (or (file-name-directory str) ""))
 377            (setq dirlength (length basestr))
 378            ;; Do substitutions in directory names
 379            (setq p (substitute-in-file-name basestr))
 380            (not (string-equal basestr p))
 381            (setq str (concat p (file-name-nondirectory str)))
 382            (progn
 383              (delete-region beg end)
 384              (insert str)
 385              (setq end (+ beg (length str)))))
 386
 387       ;; Prepare various delimiter strings
 388       (or (equal PC-word-delimiters PC-delims)
 389           (setq PC-delims PC-word-delimiters
 390                 PC-delim-regex (concat "[" PC-delims "]")
 391                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 392                 PC-delims-list (append PC-delims nil)))
 393
 394       ;; Add wildcards if necessary
 395       (and filename
 396            (let ((dir (file-name-directory str))
 397                  (file (file-name-nondirectory str))
 398                  ;; The base dir for file-completion is passed in `predicate'.
 399                  (default-directory (expand-file-name pred)))
 400              (while (and (stringp dir) (not (file-directory-p dir)))
 401                (setq dir (directory-file-name dir))
 402                (setq file (concat (replace-regexp-in-string
 403                                    PC-delim-regex "*\\&"
 404                                    (file-name-nondirectory dir))
 405                                   "*/" file))
 406                (setq dir (file-name-directory dir)))
 407              (setq str (concat dir file))))
 408
 409       ;; Look for wildcard expansions in directory name
 410       (and filename
 411            (string-match "\\*.*/" str)
 412            (let ((pat str)
 413                  ;; The base dir for file-completion is passed in `predicate'.
 414                  (default-directory (expand-file-name pred))
 415                  files)
 416              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 417              (while (setq p (string-match PC-delim-regex pat p))
 418                (setq pat (concat (substring pat 0 p)
 419                                  "*"
 420                                  (substring pat p))
 421                      p (+ p 2)))
 422              (setq files (PC-expand-many-files (concat pat "*")))
 423              (if files
 424                  (let ((dir (file-name-directory (car files)))
 425                        (p files))
 426                    (while (and (setq p (cdr p))
 427                                (equal dir (file-name-directory (car p)))))
 428                    (if p
 429                        (setq filename nil table nil pred nil
 430                              ambig t)
 431                      (delete-region beg end)
 432                      (setq str (concat dir (file-name-nondirectory str)))
 433                      (insert str)
 434                      (setq end (+ beg (length str)))))
 435                (setq filename nil table nil pred nil))))
 436
 437       ;; Strip directory name if appropriate
 438       (if filename
 439           (if incname
 440               (setq basestr (substring str incname)
 441                     dirname (substring str 0 incname))
 442             (setq basestr (file-name-nondirectory str)
 443                   dirname (file-name-directory str))
 444             ;; Make sure str is consistent with its directory and basename
 445             ;; parts.  This is important on DOZe'NT systems when str only
 446             ;; includes a drive letter, like in "d:".
 447             (setq str (concat dirname basestr)))
 448         (setq basestr str))
 449
 450       ;; Convert search pattern to a standard regular expression
 451       (setq regex (regexp-quote basestr)
 452             offset (if (and (> (length regex) 0)
 453                             (not (eq (aref basestr 0) ?\*))
 454                             (or (eq PC-first-char t)
 455                                 (and PC-first-char filename))) 1 0)
 456             p offset)
 457       (while (setq p (string-match PC-delim-regex regex p))
 458         (if (eq (aref regex p) ? )
 459             (setq regex (concat (substring regex 0 p)
 460                                 PC-ndelims-regex
 461                                 PC-delim-regex
 462                                 (substring regex (1+ p)))
 463                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 464           (let ((bump (if (memq (aref regex p)
 465                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 466                           -1 0)))
 467             (setq regex (concat (substring regex 0 (+ p bump))
 468                                 PC-ndelims-regex
 469                                 (substring regex (+ p bump)))
 470                   p (+ p (length PC-ndelims-regex) 1)))))
 471       (setq p 0)
 472       (if filename
 473           (while (setq p (string-match "\\\\\\*" regex p))
 474             (setq regex (concat (substring regex 0 p)
 475                                 "[^/]*"
 476                                 (substring regex (+ p 2))))))
 477       ;;(setq the-regex regex)
 478       (setq regex (concat "\\`" regex))
 479
 480       (and (> (length basestr) 0)
 481            (= (aref basestr 0) ?$)
 482            (setq env-on t
 483                  table PC-env-vars-alist
 484                  pred nil))
 485
 486       ;; Find an initial list of possible completions
 487       (if (not (setq p (string-match (concat PC-delim-regex
 488                                              (if filename "\\|\\*" ""))
 489                                      str
 490                                      (+ (length dirname) offset))))
 491
 492           ;; Minibuffer contains no hyphens -- simple case!
 493           (setq poss (all-completions (if env-on
 494                                           basestr str)
 495                                       table
 496                                       pred))
 497
 498         ;; Use all-completions to do an initial cull.  This is a big win,
 499         ;; since all-completions is written in C!
 500         (let ((compl (all-completions (if env-on
 501                                           (file-name-nondirectory (substring str 0 p))
 502                                         (substring str 0 p))
 503                                         table
 504                                         pred)))
 505           (setq p compl)
 506           (while p
 507             (and (string-match regex (car p))
 508                  (progn
 509                    (set-text-properties 0 (length (car p)) '() (car p))
 510                    (setq poss (cons (car p) poss))))
 511             (setq p (cdr p)))))
 512
 513       ;; Now we have a list of possible completions
 514       (cond
 515
 516        ;; No valid completions found
 517        ((null poss)
 518         (if (and (eq mode 'word)
 519                  (not PC-word-failed-flag))
 520             (let ((PC-word-failed-flag t))
 521               (delete-backward-char 1)
 522               (PC-do-completion 'word))
 523           (beep)
 524           (PC-temp-minibuffer-message (if ambig
 525                                           " [Ambiguous dir name]"
 526                                         (if (eq mode 'help)
 527                                             " [No completions]"
 528                                           " [No match]")))
 529           nil))
 530
 531        ;; More than one valid completion found
 532        ((or (cdr (setq helpposs poss))
 533             (memq mode '(help word)))
 534
 535         ;; Handle completion-ignored-extensions
 536         (and filename
 537              (not (eq mode 'help))
 538              (let ((p2 poss))
 539
 540                ;; Build a regular expression representing the extensions list
 541                (or (equal completion-ignored-extensions PC-ignored-extensions)
 542                    (setq PC-ignored-regexp
 543                          (concat "\\("
 544                                  (mapconcat
 545                                   'regexp-quote
 546                                   (setq PC-ignored-extensions
 547                                         completion-ignored-extensions)
 548                                   "\\|")
 549                                  "\\)\\'")))
 550
 551                ;; Check if there are any without an ignored extension.
 552                ;; Also ignore `.' and `..'.
 553                (setq p nil)
 554                (while p2
 555                  (or (string-match PC-ignored-regexp (car p2))
 556                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 557                      (setq p (cons (car p2) p)))
 558                  (setq p2 (cdr p2)))
 559
 560                ;; If there are "good" names, use them
 561                (and p (setq poss p))))
 562
 563         ;; Is the actual string one of the possible completions?
 564         (setq p (and (not (eq mode 'help)) poss))
 565         (while (and p
 566                     (not (string-equal (car p) basestr)))
 567           (setq p (cdr p)))
 568         (and p (null mode)
 569              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 570         (if (and p
 571                  (not (and (null mode)
 572                            (eq this-command last-command))))
 573             t
 574
 575           ;; If ambiguous, try for a partial completion
 576           (let ((improved nil)
 577                 prefix
 578                 (pt nil)
 579                 (skip "\\`"))
 580
 581             ;; Check if next few letters are the same in all cases
 582             (if (and (not (eq mode 'help))
 583                      (setq prefix (try-completion "" (mapcar 'list poss))))
 584                 (let ((first t) i)
 585                   (if (eq mode 'word)
 586                       (setq prefix (PC-chop-word prefix basestr)))
 587                   (goto-char (+ beg (length dirname)))
 588                   (while (and (progn
 589                                 (setq i 0)
 590                                 (while (< i (length prefix))
 591                                   (if (and (< (point) end)
 592                                            (eq (aref prefix i)
 593                                                (following-char)))
 594                                       (forward-char 1)
 595                                     (if (and (< (point) end)
 596                                              (or (and (looking-at " ")
 597                                                       (memq (aref prefix i)
 598                                                             PC-delims-list))
 599                                                  (eq (downcase (aref prefix i))
 600                                                      (downcase
 601                                                       (following-char)))))
 602                                         (progn
 603                                           (delete-char 1)
 604                                           (setq end (1- end)))
 605                                       (and filename (looking-at "\\*")
 606                                            (progn
 607                                              (delete-char 1)
 608                                              (setq end (1- end))))
 609                                       (setq improved t))
 610                                     (insert (substring prefix i (1+ i)))
 611                                     (setq end (1+ end)))
 612                                   (setq i (1+ i)))
 613                                 (or pt (equal (point) beg)
 614                                     (setq pt (point)))
 615                                 (looking-at PC-delim-regex))
 616                               (setq skip (concat skip
 617                                                  (regexp-quote prefix)
 618                                                  PC-ndelims-regex)
 619                                     prefix (try-completion
 620                                             ""
 621                                             (mapcar
 622                                              (function
 623                                               (lambda (x)
 624                                                 (list
 625                                                  (and (string-match skip x)
 626                                                       (substring
 627                                                        x
 628                                                        (match-end 0))))))
 629                                              poss)))
 630                               (or (> i 0) (> (length prefix) 0))
 631                               (or (not (eq mode 'word))
 632                                   (and first (> (length prefix) 0)
 633                                        (setq first nil
 634                                              prefix (substring prefix 0 1))))))
 635                   (goto-char (if (eq mode 'word) end
 636                                (or pt beg)))))
 637
 638             (if (and (eq mode 'word)
 639                      (not PC-word-failed-flag))
 640
 641                 (if improved
 642
 643                     ;; We changed it... would it be complete without the space?
 644                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 645                                           table pred)
 646                         (delete-region (1- end) end)))
 647
 648               (if improved
 649
 650                   ;; We changed it... enough to be complete?
 651                   (and (eq mode 'exit)
 652                        (PC-is-complete-p (field-string) table pred))
 653
 654                 ;; If totally ambiguous, display a list of completions
 655                 (if (or (eq completion-auto-help t)
 656                         (and completion-auto-help
 657                              (eq last-command this-command))
 658                         (eq mode 'help))
 659                     (with-output-to-temp-buffer "*Completions*"
 660                       (display-completion-list (sort helpposs 'string-lessp))
 661                       (save-excursion
 662                         (set-buffer standard-output)
 663                         ;; Record which part of the buffer we are completing
 664                         ;; so that choosing a completion from the list
 665                         ;; knows how much old text to replace.
 666                         (setq completion-base-size dirlength)))
 667                   (PC-temp-minibuffer-message " [Next char not unique]"))
 668                 nil)))))
 669
 670        ;; Only one possible completion
 671        (t
 672         (if (and (equal basestr (car poss))
 673                  (not (and env-on filename)))
 674             (if (null mode)
 675                 (PC-temp-minibuffer-message " [Sole completion]"))
 676           (delete-region beg end)
 677           (insert (format "%s"
 678                           (if filename
 679                               (substitute-in-file-name (concat dirname (car poss)))
 680                             (car poss)))))
 681         t)))))
 682
 683
 684 (defun PC-is-complete-p (str table pred)
 685   (let ((res (if (listp table)
 686                  (assoc str table)
 687                (if (vectorp table)
 688                    (or (equal str "nil")   ; heh, heh, heh
 689                        (intern-soft str table))
 690                  (funcall table str pred 'lambda)))))
 691     (and res
 692          (or (not pred)
 693              (and (not (listp table)) (not (vectorp table)))
 694              (funcall pred res))
 695          res)))
 696
 697 (defun PC-chop-word (new old)
 698   (let ((i -1)
 699         (j -1))
 700     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 701                 (setq j (string-match PC-delim-regex new (1+ j)))))
 702     (if (and j
 703              (or (not PC-word-failed-flag)
 704                  (setq j (string-match PC-delim-regex new (1+ j)))))
 705         (substring new 0 (1+ j))
 706       new)))
 707
 708 (defvar PC-not-minibuffer nil)
 709
 710 (defun PC-temp-minibuffer-message (message)
 711   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 712   (cond (PC-not-minibuffer
 713          (message message)
 714          (sit-for 2)
 715          (message ""))
 716         ((fboundp 'temp-minibuffer-message)
 717          (temp-minibuffer-message message))
 718         (t
 719          (let ((point-max (point-max)))
 720            (save-excursion
 721              (goto-char point-max)
 722              (insert message))
 723            (let ((inhibit-quit t))
 724              (sit-for 2)
 725              (delete-region point-max (point-max))
 726              (when quit-flag
 727                (setq quit-flag nil
 728                      unread-command-events '(7))))))))
 729
 730
 731 (defun PC-lisp-complete-symbol ()
 732   "Perform completion on Lisp symbol preceding point.
 733 That symbol is compared against the symbols that exist
 734 and any additional characters determined by what is there
 735 are inserted.
 736 If the symbol starts just after an open-parenthesis,
 737 only symbols with function definitions are considered.
 738 Otherwise, all symbols with function definitions, values
 739 or properties are considered."
 740   (interactive)
 741   (let* ((end (point))
 742          (buffer-syntax (syntax-table))
 743          (beg (unwind-protect
 744                   (save-excursion
 745                     (if lisp-mode-syntax-table
 746                         (set-syntax-table lisp-mode-syntax-table))
 747                     (backward-sexp 1)
 748                     (while (= (char-syntax (following-char)) ?\')
 749                       (forward-char 1))
 750                     (point))
 751                 (set-syntax-table buffer-syntax)))
 752          (minibuffer-completion-table obarray)
 753          (minibuffer-completion-predicate
 754           (if (eq (char-after (1- beg)) ?\()
 755               'fboundp
 756             (function (lambda (sym)
 757                         (or (boundp sym) (fboundp sym)
 758                             (symbol-plist sym))))))
 759          (PC-not-minibuffer t))
 760     (PC-do-completion nil beg end)))
 761
 762 (defun PC-complete-as-file-name ()
 763    "Perform completion on file names preceding point.
 764  Environment vars are converted to their values."
 765    (interactive)
 766    (let* ((end (point))
 767           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 768                                        (point-min) t)
 769                    (+ (point) 2)
 770                    (point-min)))
 771           (minibuffer-completion-table 'read-file-name-internal)
 772           (minibuffer-completion-predicate "")
 773           (PC-not-minibuffer t))
 774      (goto-char end)
 775      (PC-do-completion nil beg end)))
 776
 777 ;;; Use the shell to do globbing.
 778 ;;; This could now use file-expand-wildcards instead.
 779
 780 (defun PC-expand-many-files (name)
 781   (save-excursion
 782     (set-buffer (generate-new-buffer " *Glob Output*"))
 783     (erase-buffer)
 784     (shell-command (concat "echo " name) t)
 785     (goto-char (point-min))
 786     (if (looking-at ".*No match")
 787         nil
 788       (insert "(\"")
 789       (while (search-forward " " nil t)
 790         (delete-backward-char 1)
 791         (insert "\" \""))
 792       (goto-char (point-max))
 793       (delete-backward-char 1)
 794       (insert "\")")
 795       (goto-char (point-min))
 796       (let ((files (read (current-buffer))) (p nil))
 797         (kill-buffer (current-buffer))
 798         (or (equal completion-ignored-extensions PC-ignored-extensions)
 799             (setq PC-ignored-regexp
 800                   (concat "\\("
 801                           (mapconcat
 802                            'regexp-quote
 803                            (setq PC-ignored-extensions
 804                                  completion-ignored-extensions)
 805                            "\\|")
 806                           "\\)\\'")))
 807         (setq p nil)
 808         (while files
 809           (or (string-match PC-ignored-regexp (car files))
 810               (setq p (cons (car files) p)))
 811           (setq files (cdr files)))
 812         p))))
 813
 814 ;;; Facilities for loading C header files.  This is independent from the
 815 ;;; main completion code.  See also the variable `PC-include-file-path'
 816 ;;; at top of this file.
 817
 818 (defun PC-look-for-include-file ()
 819   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 820       (let ((name (substring (buffer-file-name)
 821                              (match-beginning 1) (match-end 1)))
 822             (punc (aref (buffer-file-name) (match-beginning 0)))
 823             (path nil)
 824             new-buf)
 825         (kill-buffer (current-buffer))
 826         (if (equal name "")
 827             (save-excursion
 828               (set-buffer (car (buffer-list)))
 829               (save-excursion
 830                 (beginning-of-line)
 831                 (if (looking-at
 832                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 833                     (setq name (buffer-substring (match-beginning 1)
 834                                                  (match-end 1))
 835                           punc (char-after (1- (match-beginning 1))))
 836                   ;; Suggested by Frank Siebenlist:
 837                   (if (or (looking-at
 838                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 839                           (looking-at
 840                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 841                           (looking-at
 842                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 843                       (progn
 844                         (setq name (buffer-substring (match-beginning 1)
 845                                                      (match-end 1))
 846                               punc ?\<
 847                               path load-path)
 848                         (if (string-match "\\.elc$" name)
 849                             (setq name (substring name 0 -1))
 850                           (or (string-match "\\.el$" name)
 851                               (setq name (concat name ".el")))))
 852                     (error "Not on an #include line"))))))
 853         (or (string-match "\\.[[:alnum:]]+$" name)
 854             (setq name (concat name ".h")))
 855         (if (eq punc ?\<)
 856             (let ((path (or path (PC-include-file-path))))
 857               (while (and path
 858                           (not (file-exists-p
 859                                 (concat (file-name-as-directory (car path))
 860                                         name))))
 861                 (setq path (cdr path)))
 862               (if path
 863                   (setq name (concat (file-name-as-directory (car path)) name))
 864                 (error "No such include file: <%s>" name)))
 865           (let ((dir (save-excursion
 866                        (set-buffer (car (buffer-list)))
 867                        default-directory)))
 868             (if (file-exists-p (concat dir name))
 869                 (setq name (concat dir name))
 870               (error "No such include file: `%s'" name))))
 871         (setq new-buf (get-file-buffer name))
 872         (if new-buf
 873             ;; no need to verify last-modified time for this!
 874             (set-buffer new-buf)
 875           (setq new-buf (create-file-buffer name))
 876           (set-buffer new-buf)
 877           (erase-buffer)
 878           (insert-file-contents name t))
 879         ;; Returning non-nil with the new buffer current
 880         ;; is sufficient to tell find-file to use it.
 881         t)
 882     nil))
 883
 884 (defun PC-include-file-path ()
 885   (or PC-include-file-path
 886       (let ((env (getenv "INCPATH"))
 887             (path nil)
 888             pos)
 889         (or env (error "No include file path specified"))
 890         (while (setq pos (string-match ":[^:]+$" env))
 891           (setq path (cons (substring env (1+ pos)) path)
 892                 env (substring env 0 pos)))
 893         path)))
 894
 895 ;;; This is adapted from lib-complete.el, by Mike Williams.
 896 (defun PC-include-file-all-completions (file search-path &optional full)
 897   "Return all completions for FILE in any directory on SEARCH-PATH.
 898 If optional third argument FULL is non-nil, returned pathnames should be
 899 absolute rather than relative to some directory on the SEARCH-PATH."
 900   (setq search-path
 901         (mapcar (lambda (dir)
 902                   (if dir (file-name-as-directory dir) default-directory))
 903                 search-path))
 904   (if (file-name-absolute-p file)
 905       ;; It's an absolute file name, so don't need search-path
 906       (progn
 907         (setq file (expand-file-name file))
 908         (file-name-all-completions
 909          (file-name-nondirectory file) (file-name-directory file)))
 910     (let ((subdir (file-name-directory file))
 911           (ndfile (file-name-nondirectory file))
 912           file-lists)
 913       ;; Append subdirectory part to each element of search-path
 914       (if subdir
 915           (setq search-path
 916                 (mapcar (lambda (dir) (concat dir subdir))
 917                         search-path)
 918                 file ))
 919       ;; Make list of completions in each directory on search-path
 920       (while search-path
 921         (let* ((dir (car search-path))
 922                (subdir (if full dir subdir)))
 923           (if (file-directory-p dir)
 924               (progn
 925                 (setq file-lists
 926                       (cons
 927                        (mapcar (lambda (file) (concat subdir file))
 928                                (file-name-all-completions ndfile
 929                                                           (car search-path)))
 930                        file-lists))))
 931           (setq search-path (cdr search-path))))
 932       ;; Compress out duplicates while building complete list (slloooow!)
 933       (let ((sorted (sort (apply 'nconc file-lists)
 934                           (lambda (x y) (not (string-lessp x y)))))
 935             compressed)
 936         (while sorted
 937           (if (equal (car sorted) (car compressed)) nil
 938             (setq compressed (cons (car sorted) compressed)))
 939           (setq sorted (cdr sorted)))
 940         compressed))))
 941
 942 (defun PC-read-include-file-name-internal (string dir action)
 943   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 944       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 945              (str2 (substring string (match-beginning 0)))
 946              (completion-table
 947               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 948                       (PC-include-file-all-completions
 949                        name (PC-include-file-path)))))
 950         (cond
 951          ((not completion-table) nil)
 952          ((eq action nil) (try-completion str2 completion-table nil))
 953          ((eq action t) (all-completions str2 completion-table nil))
 954          ((eq action 'lambda)
 955           (eq (try-completion str2 completion-table nil) t))))
 956     (funcall PC-old-read-file-name-internal string dir action)))
 957 \f
 958
 959 (provide 'complete)
 960
 961 ;;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 962 ;;; complete.el ends here