lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
   6 ;; Keywords: faces files
   7 ;; Version: 3.07
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Purpose:
  28 ;;
  29 ;; To make visiting a file in `font-lock-mode' faster by restoring its face
  30 ;; text properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55
  56 ;; Feedback:
  57 ;;
  58 ;; Feedback is welcome.
  59 ;; To submit a bug report (or make comments) please use the mechanism provided:
  60 ;;
  61 ;; M-x fast-lock-submit-bug-report RET
  62 \f
  63 ;; History:
  64 ;;
  65 ;; 0.02--1.00:
  66 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only.
  67 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode.
  68 ;; 1.00--1.01:
  69 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'.
  70 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil.
  71 ;; - Moved save-all conditions to `fast-lock-save-cache'.
  72 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'.
  73 ;; 1.01--2.00: complete rewrite---not worth the space to document.
  74 ;; - Changed structure of text properties cache and threw out file mod checks.
  75 ;; 2.00--2.01:
  76 ;; - Made `condition-case' forms understand `quit'.
  77 ;; - Made `fast-lock' require `font-lock'.
  78 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit).
  79 ;; 2.01--3.00:
  80 ;; - Changed structure of cache to include `font-lock-keywords' (from rms).
  81 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'.
  82 ;; - Removed `fast-lock-read-others'.
  83 ;; - Made `fast-lock-read-cache' ignore cache owner.
  84 ;; - Made `fast-lock-save-cache-external' create cache directory.
  85 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'.
  86 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'.
  87 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw.
  88 ;; - Package now provides itself.
  89 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'.
  90 ;; - Lucid: Use `list-faces' for `face-list'.
  91 ;; - Lucid: Added `set-text-properties'.
  92 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'.
  93 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'.
  94 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'.
  95 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw.
  96 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera).
  97 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw).
  98 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'.
  99 ;; 3.02--3.03:
 100 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'.
 101 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'.
 102 ;; 3.03--3.04:
 103 ;; - Corrected `subrp' test of Lucid code.
 104 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'.
 105 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents.
 106 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty).
 107 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory.
 108 ;; 3.04--3.05:
 109 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'.
 110 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'.
 111 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation.
 112 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey).
 113 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey).
 114 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig).
 115 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'.
 116 ;; - XEmacs: Removed `list-faces' `defalias'.
 117 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies.
 118 ;; - Added `lazy-lock-submit-bug-report'.
 119 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'.
 120 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted.
 121 ;; - Made `fast-lock-save-cache-data' output a message if save attempted.
 122 ;; - Made `fast-lock-cache-data' output a message if load attempted.
 123 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'.
 124 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing.
 125 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig).
 126 ;; - Added `fast-lock-save-events'.
 127 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig).
 128 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'.
 129 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'.
 130 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'.
 131 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig).
 132 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig).
 133 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it.
 134 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name.
 135 ;; - Added `fast-lock-after-fontify-buffer'.
 136 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor).
 137 ;; - Made `fast-lock-get-face-properties' functions use it.
 138 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way.
 139 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped).
 140 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on.
 141 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster).
 142 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster).
 143 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym).
 144 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'.
 145 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary.
 146 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'.
 147 ;; 3.06--3.07:
 148 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook.
 149 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'.
 150 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'.
 151 \f
 152 (require 'font-lock)
 153
 154 (eval-when-compile
 155   ;; Shut Emacs' byte-compiler up (cf. stop me getting mail from users).
 156   (setq byte-compile-warnings '(free-vars callargs redefine)))
 157
 158 (defun fast-lock-submit-bug-report ()
 159   "Submit via mail a bug report on fast-lock.el."
 160   (interactive)
 161   (let ((reporter-prompt-for-summary-p t))
 162     (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.07"
 163      '(fast-lock-cache-directories fast-lock-minimum-size
 164        fast-lock-save-others fast-lock-save-events fast-lock-save-faces)
 165      nil nil
 166      (concat "Hi Si.,
 167
 168 I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 169 know how to make a clear and unambiguous report.  To reproduce the bug:
 170
 171 Start a fresh Emacs via `" invocation-name " -no-init-file -no-site-file'.
 172 In the `*scratch*' buffer, evaluate:"))))
 173
 174 ;;;###autoload
 175 (defvar fast-lock-mode nil)             ; for modeline
 176 (defvar fast-lock-cache-timestamp nil)  ; for saving/reading
 177 (defvar fast-lock-cache-filename nil)   ; for deleting
 178 \f
 179 ;; User Variables:
 180
 181 (defvar fast-lock-cache-directories '("." "~/.emacs-flc")
 182 ; - `internal', keep each file's Font Lock cache file in the same file.
 183 ; - `external', keep each file's Font Lock cache file in the same directory.
 184   "Directories in which Font Lock cache files are saved and read.
 185 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 186 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 187
 188 An attempt will be made to save or read Font Lock cache files using these items
 189 until one succeeds (i.e., until a readable or writable one is found).  If an
 190 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 191 For example:
 192
 193  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 194    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 195     =>
 196  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 197
 198 would cause a file's current directory to be used if the file is under your
 199 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'.")
 200
 201 (defvar fast-lock-minimum-size (* 25 1024)
 202   "If non-nil, the minimum size for buffers.
 203 Only buffers more than this can have associated Font Lock cache files saved.
 204 If nil, means size is irrelevant.")
 205
 206 (defvar fast-lock-save-events '(kill-buffer kill-emacs)
 207   "A list of events under which caches will be saved.
 208 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 209 If concurrent editing sessions use the same associated cache file for a file's
 210 buffer, then you should add `save-buffer' to this list.")
 211
 212 (defvar fast-lock-save-others t
 213   "If non-nil, save Font Lock cache files irrespective of file owner.
 214 If nil, means only buffer files known to be owned by you can have associated
 215 Font Lock cache files saved.  Ownership may be unknown for networked files.")
 216
 217 (defvar fast-lock-save-faces
 218   ;; Since XEmacs uses extents for everything, we have to pick the right ones.
 219   ;; In XEmacs 19.13 we can't identify which text properties are Font Lock's.
 220   (if (save-match-data (string-match "XEmacs" (emacs-version)))
 221       '(font-lock-string-face font-lock-doc-string-face font-lock-type-face
 222         font-lock-function-name-face font-lock-comment-face
 223         font-lock-keyword-face font-lock-preprocessor-face)
 224     ;; For Emacs 19.30 I don't think this is generally necessary.
 225     nil)
 226   "A list of faces that will be saved in a Font Lock cache file.
 227 If nil, means information for all faces will be saved.")
 228 \f
 229 ;; User Functions:
 230
 231 ;;;###autoload
 232 (defun fast-lock-mode (&optional arg)
 233   "Toggle Fast Lock mode.
 234 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 235 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 236
 237  (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 238
 239 If Fast Lock mode is enabled, and the current buffer does not contain any text
 240 properties, any associated Font Lock cache is used if its timestamp matches the
 241 buffer's file, and its `font-lock-keywords' match those that you are using.
 242
 243 Font Lock caches may be saved:
 244  - When you save the file's buffer.
 245  - When you kill an unmodified file's buffer.
 246  - When you exit Emacs, for all unmodified or saved buffers.
 247 Depending on the value of `fast-lock-save-events'.
 248 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 249
 250 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 251
 252 Various methods of control are provided for the Font Lock cache.  In general,
 253 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 254 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 255 `fast-lock-save-others' and `fast-lock-save-faces'.
 256
 257 Use \\[fast-lock-submit-bug-report] to send bug reports or feedback."
 258   (interactive "P")
 259   (set (make-local-variable 'fast-lock-mode)
 260        (and buffer-file-truename
 261             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 262   (if (and fast-lock-mode (not font-lock-mode))
 263       ;; Turned on `fast-lock-mode' rather than using `font-lock-mode-hook'.
 264       (progn
 265         (add-hook 'font-lock-mode-hook 'turn-on-fast-lock)
 266         (font-lock-mode t))
 267     ;; Let's get down to business.
 268     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 269     (set (make-local-variable 'fast-lock-cache-filename) nil)
 270     (if (and fast-lock-mode (not font-lock-fontified))
 271         (fast-lock-read-cache))))
 272
 273 (defun fast-lock-read-cache ()
 274   "Read the Font Lock cache for the current buffer.
 275
 276 The following criteria must be met for a Font Lock cache file to be read:
 277  - Fast Lock mode must be turned on in the buffer.
 278  - The buffer must not be modified.
 279  - The buffer's `font-lock-keywords' must match the cache's.
 280  - The buffer file's timestamp must match the cache's.
 281  - Criteria imposed by `fast-lock-cache-directories'.
 282
 283 See `fast-lock-mode'."
 284   (interactive)
 285   (let ((directories fast-lock-cache-directories)
 286         (modified (buffer-modified-p)) (inhibit-read-only t)
 287         (fontified font-lock-fontified))
 288     (setq fast-lock-cache-filename nil)
 289     (set (make-local-variable 'font-lock-fontified) nil)
 290     ;; Keep trying directories until fontification is turned off.
 291     (while (and directories (not font-lock-fontified))
 292       (let* ((directory (fast-lock-cache-directory (car directories) nil))
 293              (file (and directory (fast-lock-cache-name directory))))
 294         (condition-case nil
 295             (and file (file-readable-p file) (load file t t t))
 296           (error nil) (quit nil))
 297         (setq directories (cdr directories))))
 298     (set-buffer-modified-p modified)
 299     (or font-lock-fontified (setq font-lock-fontified fontified))))
 300
 301 (defun fast-lock-save-cache (&optional buffer)
 302   "Save the Font Lock cache of BUFFER or the current buffer.
 303
 304 The following criteria must be met for a Font Lock cache file to be saved:
 305  - Fast Lock mode must be turned on in the buffer.
 306  - The event must be one of `fast-lock-save-events'.
 307  - The buffer must be at least `fast-lock-minimum-size' bytes long.
 308  - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 309  - The buffer must contain at least one `face' text property.
 310  - The buffer must not be modified.
 311  - The buffer file's timestamp must be the same as the file's on disk.
 312  - The on disk file's timestamp must be different than the buffer's cache.
 313  - Criteria imposed by `fast-lock-cache-directories'.
 314
 315 See `fast-lock-mode'."
 316   (interactive)
 317   (save-excursion
 318     (and buffer (set-buffer buffer))
 319     (let ((file-timestamp (visited-file-modtime)) (saved nil))
 320       (if (and fast-lock-mode
 321                ;;
 322                ;; "Only save if the buffer matches the file, the file has
 323                ;; changed, and it was changed by the current emacs session."
 324                ;;
 325                ;; Only save if the buffer is not modified,
 326                ;; (i.e., so we don't save for something not on disk)
 327                (not (buffer-modified-p))
 328                ;; and the file's timestamp is the same as the buffer's,
 329                ;; (i.e., someone else hasn't written the file in the meantime)
 330                (verify-visited-file-modtime (current-buffer))
 331                ;; and the file's timestamp is different from the cache's.
 332                ;; (i.e., a save has occurred since the cache was read)
 333                (not (equal fast-lock-cache-timestamp file-timestamp))
 334                ;;
 335                ;; Only save if user's restrictions are satisfied.
 336                (or (not fast-lock-minimum-size)
 337                    (<= fast-lock-minimum-size (buffer-size)))
 338                (or fast-lock-save-others
 339                    (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 340                ;;
 341                ;; Only save if there are `face' properties to save.
 342                (text-property-not-all (point-min) (point-max) 'face nil))
 343           ;; Try each directory until we manage to save or the user quits.
 344           (let ((directories fast-lock-cache-directories))
 345             (while (and directories (memq saved '(nil error)))
 346               (let* ((dir (fast-lock-cache-directory (car directories) t))
 347                      (file (and dir (fast-lock-cache-name dir))))
 348                 (if (and file (file-writable-p file))
 349                     (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 350                 (setq directories (cdr directories)))))))))
 351
 352 ;;;###autoload
 353 (defun turn-on-fast-lock ()
 354   "Unconditionally turn on Fast Lock mode."
 355   (fast-lock-mode t))
 356 \f
 357 ;;; API Functions:
 358
 359 (defun fast-lock-after-fontify-buffer ()
 360   ;; Delete the Font Lock cache file used to restore fontification, if any.
 361   (if fast-lock-cache-filename
 362       (if (file-writable-p fast-lock-cache-filename)
 363           (delete-file fast-lock-cache-filename)
 364         (message "File %s font lock cache cannot be deleted" (buffer-name))))
 365   ;; Flag so that a cache will be saved later even if the file is never saved.
 366   (setq fast-lock-cache-timestamp nil))
 367 \f
 368 ;; Miscellaneous Functions:
 369
 370 (defun fast-lock-after-save-hook ()
 371   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 372   (if (memq 'save-buffer fast-lock-save-events)
 373       (fast-lock-save-cache)))
 374
 375 (defun fast-lock-kill-buffer-hook ()
 376   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 377   (if (memq 'kill-buffer fast-lock-save-events)
 378       (fast-lock-save-cache)))
 379
 380 (defun fast-lock-kill-emacs-hook ()
 381   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 382   (if (memq 'kill-emacs fast-lock-save-events)
 383       (mapcar 'fast-lock-save-cache (buffer-list))))
 384
 385 (defun fast-lock-cache-directory (directory create)
 386   "Return usable directory based on DIRECTORY.
 387 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 388 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 389 See `fast-lock-cache-directories'."
 390   (let ((dir
 391          (cond ((not buffer-file-name)
 392                 ;; Should never be nil, but `crypt++' screws it up.
 393                 nil)
 394                ((stringp directory)
 395                 ;; Just a directory.
 396                 directory)
 397                (t
 398                 ;; A directory iff the file name matches the regexp.
 399                 (let ((bufile (expand-file-name buffer-file-truename))
 400                       (case-fold-search nil))
 401                   (if (save-match-data (string-match (car directory) bufile))
 402                       (cdr directory)))))))
 403     (cond ((not dir)
 404            nil)
 405           ((file-accessible-directory-p dir)
 406            dir)
 407           (create
 408            (condition-case nil
 409                (progn (make-directory dir t) dir)
 410              (error nil))))))
 411
 412 ;; If you are wondering why we only hash if the directory is not ".", rather
 413 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 414 ;; relative cache directories (that are not ".") then it is possible that more
 415 ;; than one file would have the same cache name in that directory, if the luser
 416 ;; made a link from one relative cache directory to another.  (Phew!)
 417 (defun fast-lock-cache-name (directory)
 418   "Return full cache path name using caching DIRECTORY.
 419 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 420 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 421 abbreviated file name, with all `/' characters in the name replaced with `#'
 422 characters, and appended with `.flc'.
 423
 424 If the same file has different cache path names when edited on different
 425 machines, e.g., on one machine the cache file name has the prefix `#home',
 426 perhaps due to automount, try putting in your `~/.emacs' something like:
 427
 428  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 429
 430 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 431
 432 See `fast-lock-cache-directory'."
 433   (if (string-equal directory ".")
 434       (concat buffer-file-name ".flc")
 435     (let* ((bufile (expand-file-name buffer-file-truename))
 436            (chars-alist
 437             (if (eq system-type 'emx)
 438                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 439               '((?/ . (?#)) (?# . (?# ?#)))))
 440            (mapchars
 441             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 442       (concat
 443        (file-name-as-directory (expand-file-name directory))
 444        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 445        ".flc"))))
 446 \f
 447 ;; Font Lock Cache Processing Functions:
 448
 449 (defun fast-lock-save-cache-1 (file timestamp)
 450   ;; Save the FILE with the TIMESTAMP as:
 451   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
 452   ;; Returns non-nil if a save was attempted to a writable cache file.
 453   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 454         (buname (buffer-name)) (saved t))
 455     (message "Saving %s font lock cache..." buname)
 456     (condition-case nil
 457         (save-excursion
 458           (print (list 'fast-lock-cache-data 2
 459                        (list 'quote timestamp)
 460                        (list 'quote font-lock-keywords)
 461                        (list 'quote (fast-lock-get-face-properties)))
 462                  tpbuf)
 463           (set-buffer tpbuf)
 464           (write-region (point-min) (point-max) file nil 'quietly)
 465           (setq fast-lock-cache-timestamp timestamp
 466                 fast-lock-cache-filename file))
 467       (error (setq saved 'error)) (quit (setq saved 'quit)))
 468     (kill-buffer tpbuf)
 469     (message "Saving %s font lock cache... %s." buname
 470              (cond ((eq saved 'error) "failed")
 471                    ((eq saved 'quit) "aborted")
 472                    (t "done")))
 473     ;; We return non-nil regardless of whether a failure occurred.
 474     saved))
 475
 476 (defun fast-lock-cache-data (version timestamp keywords properties
 477                              &rest ignored)
 478   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
 479   (if (consp (cdr-safe timestamp)) (setcdr timestamp (nth 1 timestamp)))
 480   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
 481   (let ((current font-lock-keywords))
 482     (setq keywords (font-lock-compile-keywords keywords)
 483           font-lock-keywords (font-lock-compile-keywords current)))
 484   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
 485   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
 486   ;; buffer's font-lock-keywords are the same as KEYWORDS.
 487   (let ((buf-timestamp (visited-file-modtime))
 488         (buname (buffer-name)) (loaded t))
 489     (if (or (/= version 2)
 490             (buffer-modified-p)
 491             (not (equal timestamp buf-timestamp))
 492             (not (equal keywords font-lock-keywords)))
 493         (setq loaded nil)
 494       (message "Loading %s font lock cache..." buname)
 495       (condition-case nil
 496           (fast-lock-set-face-properties properties)
 497         (error (setq loaded 'error)) (quit (setq loaded 'quit)))
 498       (message "Loading %s font lock cache... %s." buname
 499                (cond ((eq loaded 'error) "failed")
 500                      ((eq loaded 'quit) "aborted")
 501                      (t "done"))))
 502     ;; If we used the text properties, stop fontification and keep timestamp.
 503     ;; Kludge warning: `file' comes from sole caller `fast-lock-read-cache'.
 504     (setq font-lock-fontified (eq loaded t)
 505           fast-lock-cache-timestamp (and (eq loaded t) timestamp)
 506           fast-lock-cache-filename (and (eq loaded t) file))))
 507 \f
 508 ;; Text Properties Processing Functions:
 509
 510 ;; This is faster, but fails if adjacent characters have different `face' text
 511 ;; properties.  Maybe that's why I dropped it in the first place?
 512 ;(defun fast-lock-get-face-properties ()
 513 ;  "Return a list of all `face' text properties in the current buffer.
 514 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 515 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 516 ;  (save-restriction
 517 ;    (widen)
 518 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 519 ;         (limit (point-max)) end properties value cell)
 520 ;      (while start
 521 ;       (setq end (next-single-property-change start 'face nil limit)
 522 ;             value (get-text-property start 'face))
 523 ;       ;; Make, or add to existing, list of regions with same `face'.
 524 ;       (if (setq cell (assq value properties))
 525 ;           (setcdr cell (cons start (cons end (cdr cell))))
 526 ;         (setq properties (cons (list value start end) properties)))
 527 ;       (setq start (next-single-property-change end 'face)))
 528 ;      properties)))
 529
 530 (defun fast-lock-get-face-properties ()
 531   "Return a list of all `face' text properties in the current buffer.
 532 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 533 where VALUE is a `face' property value and STARTx and ENDx are positions.
 534 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 535   (save-restriction
 536     (widen)
 537     (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 538           properties regions face start end)
 539       (while faces
 540         (setq face (car faces) faces (cdr faces) regions () end (point-min))
 541         ;; Make a list of start/end regions with `face' property face.
 542         (while (setq start (text-property-any end limit 'face face))
 543           (setq end (or (text-property-not-all start limit 'face face) limit)
 544                 regions (cons start (cons end regions))))
 545         ;; Add `face' face's regions, if any, to properties.
 546         (if regions (setq properties (cons (cons face regions) properties))))
 547       properties)))
 548
 549 (defun fast-lock-set-face-properties (properties)
 550   "Set all `face' text properties to PROPERTIES in the current buffer.
 551 Any existing `face' text properties are removed first.  Leaves buffer modified.
 552 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 553   (save-restriction
 554     (widen)
 555     (font-lock-unfontify-region (point-min) (point-max))
 556     (while properties
 557       (let ((plist (list 'face (car (car properties))))
 558             (regions (cdr (car properties))))
 559         ;; Set the `face' property for each start/end region.
 560         (while regions
 561           (set-text-properties (nth 0 regions) (nth 1 regions) plist)
 562           (setq regions (nthcdr 2 regions)))
 563         (setq properties (cdr properties))))))
 564 \f
 565 ;; Functions for XEmacs:
 566
 567 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 568     ;; It would be better to use XEmacs 19.12's `map-extents' over extents with
 569     ;; `font-lock' property, but `face' properties are on different extents.
 570     (defun fast-lock-get-face-properties ()
 571       "Return a list of all `face' text properties in the current buffer.
 572 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 573 where VALUE is a `face' property value and STARTx and ENDx are positions.
 574 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 575       (save-restriction
 576         (widen)
 577         (let ((properties ()) cell)
 578           (map-extents
 579            (function
 580             (lambda (extent ignore)
 581               (let ((value (extent-face extent)))
 582                 ;; We're only interested if it's one of `fast-lock-save-faces'.
 583                 (if (and value (or (null fast-lock-save-faces)
 584                                    (memq value fast-lock-save-faces)))
 585                     (let ((start (extent-start-position extent))
 586                           (end (extent-end-position extent)))
 587                       ;; Make or add to existing list of regions with the same
 588                       ;; `face' property value.
 589                       (if (setq cell (assq value properties))
 590                           (setcdr cell (cons start (cons end (cdr cell))))
 591                         (setq properties (cons (list value start end)
 592                                                properties)))))
 593                 ;; Return nil to keep `map-extents' going.
 594                 nil))))
 595           properties))))
 596
 597 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 598     ;; Make extents just like XEmacs's font-lock.el does.
 599     (defun fast-lock-set-face-properties (properties)
 600       "Set all `face' text properties to PROPERTIES in the current buffer.
 601 Any existing `face' text properties are removed first.
 602 See `fast-lock-get-face-properties' for the format of PROPERTIES."
 603       (save-restriction
 604         (widen)
 605         (font-lock-unfontify-region (point-min) (point-max))
 606         (while properties
 607           (let ((face (car (car properties)))
 608                 (regions (cdr (car properties))))
 609             ;; Set the `face' property, etc., for each start/end region.
 610             (while regions
 611               (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 612               (setq regions (nthcdr 2 regions)))
 613             (setq properties (cdr properties)))))))
 614
 615 (if (save-match-data (string-match "XEmacs" (emacs-version)))
 616     ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 617     (add-hook 'font-lock-after-fontify-buffer-hook
 618               'fast-lock-after-fontify-buffer))
 619
 620 (or (fboundp 'font-lock-compile-keywords)
 621     (defalias 'font-lock-compile-keywords 'identity))
 622 \f
 623 ;; Install ourselves:
 624
 625 ;; We don't install ourselves on `font-lock-mode-hook' as packages with similar
 626 ;; functionality exist, and fast-lock.el should be dumpable without forcing
 627 ;; people to use caches or making it difficult for people to use alternatives.
 628 (add-hook 'after-save-hook 'fast-lock-after-save-hook)
 629 (add-hook 'kill-buffer-hook 'fast-lock-kill-buffer-hook)
 630 (add-hook 'kill-emacs-hook 'fast-lock-kill-emacs-hook)
 631
 632 ;; Maybe save on the modeline?
 633 ;;(setcdr (assq 'font-lock-mode minor-mode-alist) '(" Fast"))
 634
 635 (or (assq 'fast-lock-mode minor-mode-alist)
 636     (setq minor-mode-alist (cons '(fast-lock-mode " Fast") minor-mode-alist)))
 637
 638 ;; Provide ourselves:
 639
 640 (provide 'fast-lock)
 641
 642 ;;; fast-lock.el ends here