lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer
   2
   3 ;; Copyright (C) 1986, 1987, 1994, 1995, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package provides the sorting facilities documented in the Emacs
  29 ;; user's manual.
  30
  31 ;;; Code:
  32
  33 (defgroup sort nil
  34   "Commands to sort text in an Emacs buffer."
  35   :group 'data)
  36
  37 (defcustom sort-fold-case nil
  38   "*Non-nil if the buffer sort functions should ignore case."
  39   :group 'sort
  40   :type 'boolean)
  41
  42 ;;;###autoload
  43 (defun sort-subr (reverse nextrecfun endrecfun
  44                           &optional startkeyfun endkeyfun predicate)
  45   "General text sorting routine to divide buffer into records and sort them.
  46
  47 We divide the accessible portion of the buffer into disjoint pieces
  48 called sort records.  A portion of each sort record (perhaps all of
  49 it) is designated as the sort key.  The records are rearranged in the
  50 buffer in order by their sort keys.  The records may or may not be
  51 contiguous.
  52
  53 Usually the records are rearranged in order of ascending sort key.
  54 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  55 The variable `sort-fold-case' determines whether alphabetic case affects
  56 the sort order.
  57
  58 The next four arguments are functions to be called to move point
  59 across a sort record.  They will be called many times from within sort-subr.
  60
  61 NEXTRECFUN is called with point at the end of the previous record.
  62 It moves point to the start of the next record.
  63 It should move point to the end of the buffer if there are no more records.
  64 The first record is assumed to start at the position of point when sort-subr
  65 is called.
  66
  67 ENDRECFUN is called with point within the record.
  68 It should move point to the end of the record.
  69
  70 STARTKEYFUN moves from the start of the record to the start of the key.
  71 It may return either a non-nil value to be used as the key, or
  72 else the key is the substring between the values of point after
  73 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  74 starts at the beginning of the record.
  75
  76 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  77 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  78 same as ENDRECFUN.
  79
  80 PREDICATE is the function to use to compare keys.  If keys are numbers,
  81 it defaults to `<', otherwise it defaults to `string<'."
  82   ;; Heuristically try to avoid messages if sorting a small amt of text.
  83   (let ((messages (> (- (point-max) (point-min)) 50000)))
  84     (save-excursion
  85       (if messages (message "Finding sort keys..."))
  86       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  87                                            startkeyfun endkeyfun))
  88              (old (reverse sort-lists))
  89              (case-fold-search sort-fold-case))
  90         (if (null sort-lists)
  91             ()
  92           (or reverse (setq sort-lists (nreverse sort-lists)))
  93           (if messages (message "Sorting records..."))
  94           (setq sort-lists
  95                 (sort sort-lists
  96                       (cond (predicate
  97                              `(lambda (a b) (,predicate (car a) (car b))))
  98                             ((numberp (car (car sort-lists)))
  99                              'car-less-than-car)
 100                             ((consp (car (car sort-lists)))
 101                              (lambda (a b)
 102                                (> 0 (compare-buffer-substrings
 103                                      nil (car (car a)) (cdr (car a))
 104                                      nil (car (car b)) (cdr (car b))))))
 105                             (t
 106                              (lambda (a b) (string< (car a) (car b)))))))
 107           (if reverse (setq sort-lists (nreverse sort-lists)))
 108           (if messages (message "Reordering buffer..."))
 109           (sort-reorder-buffer sort-lists old)))
 110       (if messages (message "Reordering buffer... Done"))))
 111   nil)
 112
 113 ;; Parse buffer into records using the arguments as Lisp expressions;
 114 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 115 ;; where KEY is the sort key (a number or string),
 116 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 117
 118 ;; The records appear in the list lastmost first!
 119
 120 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 121   (let ((sort-lists ())
 122         (start-rec nil)
 123         done key)
 124     ;; Loop over sort records.
 125     ;(goto-char (point-min)) -- it is the caller's responsibility to
 126     ;arrange this if necessary
 127     (while (not (eobp))
 128       (setq start-rec (point))          ;save record start
 129       (setq done nil)
 130       ;; Get key value, or move to start of key.
 131       (setq key (catch 'key
 132                   (or (and startkeyfun (funcall startkeyfun))
 133                       ;; If key was not returned as value,
 134                       ;; move to end of key and get key from the buffer.
 135                       (let ((start (point)))
 136                         (funcall (or endkeyfun
 137                                      (prog1 endrecfun (setq done t))))
 138                         (cons start (point))))))
 139       ;; Move to end of this record (start of next one, or end of buffer).
 140       (cond ((prog1 done (setq done nil)))
 141             (endrecfun (funcall endrecfun))
 142             (nextrecfun (funcall nextrecfun) (setq done t)))
 143       (if key (push
 144                ;; consing optimization in case in which key is same as record.
 145                (if (and (consp key)
 146                         (equal (car key) start-rec)
 147                         (equal (cdr key) (point)))
 148                    (cons key key)
 149                  (cons key (cons start-rec (point))))
 150                sort-lists))
 151       (and (not done) nextrecfun (funcall nextrecfun)))
 152     sort-lists))
 153
 154 (defun sort-reorder-buffer (sort-lists old)
 155   (let ((last (point-min))
 156         (min (point-min)) (max (point-max))
 157         (old-buffer (current-buffer))
 158         temp-buffer)
 159     (with-temp-buffer
 160       ;; Record the temporary buffer.
 161       (setq temp-buffer (current-buffer))
 162
 163       ;; Copy the sorted text into the temporary buffer.
 164       (while sort-lists
 165         (goto-char (point-max))
 166         (insert-buffer-substring old-buffer
 167                                  last
 168                                  (nth 1 (car old)))
 169         (goto-char (point-max))
 170         (insert-buffer-substring old-buffer
 171                                  (nth 1 (car sort-lists))
 172                                  (cdr (cdr (car sort-lists))))
 173         (setq last (cdr (cdr (car old)))
 174               sort-lists (cdr sort-lists)
 175               old (cdr old)))
 176       (goto-char (point-max))
 177       (insert-buffer-substring old-buffer last max)
 178
 179       ;; Copy the reordered text from the temporary buffer
 180       ;; to the buffer we sorted (OLD-BUFFER).
 181       (set-buffer old-buffer)
 182       (let ((inhibit-quit t))
 183         ;; Make sure insertions done for reordering
 184         ;; saves any markers at the end of the sorted region,
 185         ;; by leaving the last character of the region.
 186         (delete-region min (1- max))
 187         ;; Now replace the one remaining old character with the sorted text.
 188         (goto-char (point-min))
 189         (insert-buffer-substring temp-buffer)
 190         (delete-region max (1+ max))))))
 191
 192 ;;;###autoload
 193 (defun sort-lines (reverse beg end)
 194   "Sort lines in region alphabetically; argument means descending order.
 195 Called from a program, there are three arguments:
 196 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 197 The variable `sort-fold-case' determines whether alphabetic case affects
 198 the sort order."
 199   (interactive "P\nr")
 200   (save-excursion
 201     (save-restriction
 202       (narrow-to-region beg end)
 203       (goto-char (point-min))
 204       (sort-subr reverse 'forward-line 'end-of-line))))
 205
 206 ;;;###autoload
 207 (defun sort-paragraphs (reverse beg end)
 208   "Sort paragraphs in region alphabetically; argument means descending order.
 209 Called from a program, there are three arguments:
 210 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 211 The variable `sort-fold-case' determines whether alphabetic case affects
 212 the sort order."
 213   (interactive "P\nr")
 214   (save-excursion
 215     (save-restriction
 216       (narrow-to-region beg end)
 217       (goto-char (point-min))
 218       (sort-subr reverse
 219                  (function
 220                   (lambda ()
 221                     (while (and (not (eobp)) (looking-at paragraph-separate))
 222                       (forward-line 1))))
 223                  'forward-paragraph))))
 224
 225 ;;;###autoload
 226 (defun sort-pages (reverse beg end)
 227   "Sort pages in region alphabetically; argument means descending order.
 228 Called from a program, there are three arguments:
 229 REVERSE (non-nil means reverse order), BEG and END (region to sort).
 230 The variable `sort-fold-case' determines whether alphabetic case affects
 231 the sort order."
 232   (interactive "P\nr")
 233   (save-excursion
 234     (save-restriction
 235       (narrow-to-region beg end)
 236       (goto-char (point-min))
 237       (sort-subr reverse
 238                  (function (lambda () (skip-chars-forward "\n")))
 239                  'forward-page))))
 240 \f
 241 (defvar sort-fields-syntax-table nil)
 242 (if sort-fields-syntax-table nil
 243   (let ((table (make-syntax-table))
 244         (i 0))
 245     (while (< i 256)
 246       (modify-syntax-entry i "w" table)
 247       (setq i (1+ i)))
 248     (modify-syntax-entry ?\  " " table)
 249     (modify-syntax-entry ?\t " " table)
 250     (modify-syntax-entry ?\n " " table)
 251     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 252     (setq sort-fields-syntax-table table)))
 253
 254 (defcustom sort-numeric-base 10
 255   "*The default base used by `sort-numeric-fields'."
 256   :group 'sort
 257   :type 'integer)
 258
 259 ;;;###autoload
 260 (defun sort-numeric-fields (field beg end)
 261   "Sort lines in region numerically by the ARGth field of each line.
 262 Fields are separated by whitespace and numbered from 1 up.
 263 Specified field must contain a number in each line of the region,
 264 which may begin with \"0x\" or \"0\" for hexadecimal and octal values.
 265 Otherwise, the number is interpreted according to sort-numeric-base.
 266 With a negative arg, sorts by the ARGth field counted from the right.
 267 Called from a program, there are three arguments:
 268 FIELD, BEG and END.  BEG and END specify region to sort."
 269   (interactive "p\nr")
 270   (sort-fields-1 field beg end
 271                  (lambda ()
 272                    (sort-skip-fields field)
 273                    (let* ((case-fold-search t)
 274                           (base
 275                            (if (looking-at "\\(0x\\)[0-9a-f]\\|\\(0\\)[0-7]")
 276                                (cond ((match-beginning 1)
 277                                       (goto-char (match-end 1))
 278                                       16)
 279                                      ((match-beginning 2)
 280                                       (goto-char (match-end 2))
 281                                       8)
 282                                      (t nil)))))
 283                      (string-to-number (buffer-substring (point)
 284                                                          (save-excursion
 285                                                            (forward-sexp 1)
 286                                                            (point)))
 287                                        (or base sort-numeric-base))))
 288                  nil))
 289
 290 ;;;;;###autoload
 291 ;;(defun sort-float-fields (field beg end)
 292 ;;  "Sort lines in region numerically by the ARGth field of each line.
 293 ;;Fields are separated by whitespace and numbered from 1 up.  Specified field
 294 ;;must contain a floating point number in each line of the region.  With a
 295 ;;negative arg, sorts by the ARGth field counted from the right.  Called from a
 296 ;;program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 297 ;;region to sort."
 298 ;;  (interactive "p\nr")
 299 ;;  (sort-fields-1 field beg end
 300 ;;               (function (lambda ()
 301 ;;                           (sort-skip-fields field)
 302 ;;                           (string-to-number
 303 ;;                            (buffer-substring
 304 ;;                             (point)
 305 ;;                             (save-excursion
 306 ;;                               (re-search-forward
 307 ;;                                "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 308 ;;                               (point))))))
 309 ;;               nil))
 310
 311 ;;;###autoload
 312 (defun sort-fields (field beg end)
 313   "Sort lines in region lexicographically by the ARGth field of each line.
 314 Fields are separated by whitespace and numbered from 1 up.
 315 With a negative arg, sorts by the ARGth field counted from the right.
 316 Called from a program, there are three arguments:
 317 FIELD, BEG and END.  BEG and END specify region to sort.
 318 The variable `sort-fold-case' determines whether alphabetic case affects
 319 the sort order."
 320   (interactive "p\nr")
 321   (sort-fields-1 field beg end
 322                  (function (lambda ()
 323                              (sort-skip-fields field)
 324                              nil))
 325                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 326
 327 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 328   (let ((tbl (syntax-table)))
 329     (if (zerop field) (setq field 1))
 330     (unwind-protect
 331         (save-excursion
 332           (save-restriction
 333             (narrow-to-region beg end)
 334             (goto-char (point-min))
 335             (set-syntax-table sort-fields-syntax-table)
 336             (sort-subr nil
 337                        'forward-line 'end-of-line
 338                        startkeyfun endkeyfun)))
 339       (set-syntax-table tbl))))
 340
 341 ;; Position at the beginning of field N on the current line,
 342 ;; assuming point is initially at the beginning of the line.
 343 (defun sort-skip-fields (n)
 344   (if (> n 0)
 345       ;; Skip across N - 1 fields.
 346       (let ((i (1- n)))
 347         (while (> i 0)
 348           (skip-chars-forward " \t")
 349           (skip-chars-forward "^ \t\n")
 350           (setq i (1- i)))
 351         (skip-chars-forward " \t")
 352         (if (eolp)
 353             (error "Line has too few fields: %s"
 354                    (buffer-substring
 355                     (save-excursion (beginning-of-line) (point))
 356                     (save-excursion (end-of-line) (point))))))
 357     (end-of-line)
 358     ;; Skip back across - N - 1 fields.
 359     (let ((i (1- (- n))))
 360       (while (> i 0)
 361         (skip-chars-backward " \t")
 362         (skip-chars-backward "^ \t\n")
 363         (setq i (1- i)))
 364       (skip-chars-backward " \t"))
 365     (if (bolp)
 366         (error "Line has too few fields: %s"
 367                (buffer-substring
 368                 (save-excursion (beginning-of-line) (point))
 369                 (save-excursion (end-of-line) (point)))))
 370     ;; Position at the front of the field
 371     ;; even if moving backwards.
 372     (skip-chars-backward "^ \t\n")))
 373 \f
 374 (defvar sort-regexp-fields-regexp)
 375 (defvar sort-regexp-record-end)
 376
 377 ;; Move to the beginning of the next match for record-regexp,
 378 ;; and set sort-regexp-record-end to the end of that match.
 379 ;; If the next match is empty and does not advance point,
 380 ;; skip one character and try again.
 381 (defun sort-regexp-fields-next-record ()
 382   (let ((oldpos (point)))
 383     (and (re-search-forward sort-regexp-fields-regexp nil 'move)
 384          (setq sort-regexp-record-end (match-end 0))
 385          (if (= sort-regexp-record-end oldpos)
 386              (progn
 387                (forward-char 1)
 388                (re-search-forward sort-regexp-fields-regexp nil 'move)
 389                (setq sort-regexp-record-end (match-end 0)))
 390            t)
 391          (goto-char (match-beginning 0)))))
 392
 393 ;;;###autoload
 394 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 395   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 396 RECORD-REGEXP specifies the textual units which should be sorted.
 397   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 398 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 399   is to be used for sorting.
 400   If it is \"\\\\digit\" then the digit'th \"\\\\(...\\\\)\" match field from
 401   RECORD-REGEXP is used.
 402   If it is \"\\\\&\" then the whole record is used.
 403   Otherwise, it is a regular-expression for which to search within the record.
 404 If a match for KEY is not found within a record then that record is ignored.
 405
 406 With a negative prefix arg sorts in reverse order.
 407
 408 The variable `sort-fold-case' determines whether alphabetic case affects
 409 the sort order.
 410
 411 For example: to sort lines in the region by the first word on each line
 412  starting with the letter \"f\",
 413  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\\\=\\<f\\\\w*\\\\>\""
 414   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 415   ;; other sort-.*fields functions but then again this was before, since it
 416   ;; didn't use the magnitude of the arg to specify anything.
 417   (interactive "P\nsRegexp specifying records to sort:
 418 sRegexp specifying key within record: \nr")
 419   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 420          (setq key-regexp 0))
 421         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 422          (setq key-regexp (- (aref key-regexp 1) ?0))))
 423   (save-excursion
 424     (save-restriction
 425       (narrow-to-region beg end)
 426       (goto-char (point-min))
 427       (let (sort-regexp-record-end
 428             (sort-regexp-fields-regexp record-regexp))
 429         (re-search-forward sort-regexp-fields-regexp nil t)
 430         (setq sort-regexp-record-end (point))
 431         (goto-char (match-beginning 0))
 432         (sort-subr reverse
 433                    'sort-regexp-fields-next-record
 434                    (function (lambda ()
 435                                (goto-char sort-regexp-record-end)))
 436                    (function (lambda ()
 437                                (let ((n 0))
 438                                  (cond ((numberp key-regexp)
 439                                         (setq n key-regexp))
 440                                        ((re-search-forward
 441                                           key-regexp sort-regexp-record-end t)
 442                                         (setq n 0))
 443                                        (t (throw 'key nil)))
 444                                  (condition-case ()
 445                                      (cons (match-beginning n)
 446                                            (match-end n))
 447                                    ;; if there was no such register
 448                                    (error (throw 'key nil)))))))))))
 449
 450 \f
 451 (defvar sort-columns-subprocess t)
 452
 453 ;;;###autoload
 454 (defun sort-columns (reverse &optional beg end)
 455   "Sort lines in region alphabetically by a certain range of columns.
 456 For the purpose of this command, the region BEG...END includes
 457 the entire line that point is in and the entire line the mark is in.
 458 The column positions of point and mark bound the range of columns to sort on.
 459 A prefix argument means sort into REVERSE order.
 460 The variable `sort-fold-case' determines whether alphabetic case affects
 461 the sort order.
 462
 463 Note that `sort-columns' rejects text that contains tabs,
 464 because tabs could be split across the specified columns
 465 and it doesn't know how to handle that.  Also, when possible,
 466 it uses the `sort' utility program, which doesn't understand tabs.
 467 Use \\[untabify] to convert tabs to spaces before sorting."
 468   (interactive "P\nr")
 469   (save-excursion
 470     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 471       (goto-char (min beg end))
 472       (setq col-beg1 (current-column))
 473       (beginning-of-line)
 474       (setq beg1 (point))
 475       (goto-char (max beg end))
 476       (setq col-end1 (current-column))
 477       (forward-line)
 478       (setq end1 (point))
 479       (setq col-start (min col-beg1 col-end1))
 480       (setq col-end (max col-beg1 col-end1))
 481       (if (search-backward "\t" beg1 t)
 482           (error "sort-columns does not work with tabs -- use M-x untabify"))
 483       (if (not (or (memq system-type '(vax-vms windows-nt))
 484                    (let ((pos beg1) plist fontified)
 485                      (catch 'found
 486                        (while (< pos end1)
 487                          (setq plist (text-properties-at pos))
 488                          (setq fontified (plist-get plist 'fontified))
 489                          (while (consp plist)
 490                            (unless (or (eq (car plist) 'fontified)
 491                                        (and (eq (car plist) 'face)
 492                                             fontified))
 493                              (throw 'found t))
 494                            (setq plist (cddr plist)))
 495                          (setq pos (next-property-change pos nil end1)))))))
 496           ;; Use the sort utility if we can; it is 4 times as fast.
 497           ;; Do not use it if there are any non-font-lock properties
 498           ;; in the region, since the sort utility would lose the
 499           ;; properties.
 500           (let ((sort-args (list (if reverse "-rt\n" "-t\n")
 501                                  (concat "+0." (int-to-string col-start))
 502                                  (concat "-0." (int-to-string col-end)))))
 503             (when sort-fold-case
 504               (push "-f" sort-args))
 505             (apply #'call-process-region beg1 end1 "sort" t t nil sort-args))
 506         ;; On VMS and ms-windows, use Emacs's own facilities.
 507         (save-excursion
 508           (save-restriction
 509             (narrow-to-region beg1 end1)
 510             (goto-char beg1)
 511             (sort-subr reverse 'forward-line 'end-of-line
 512                        #'(lambda () (move-to-column col-start) nil)
 513                        #'(lambda () (move-to-column col-end) nil))))))))
 514
 515 ;;;###autoload
 516 (defun reverse-region (beg end)
 517   "Reverse the order of lines in a region.
 518 From a program takes two point or marker arguments, BEG and END."
 519   (interactive "r")
 520   (if (> beg end)
 521       (let (mid) (setq mid end end beg beg mid)))
 522   (save-excursion
 523     ;; put beg at the start of a line and end and the end of one --
 524     ;; the largest possible region which fits this criteria
 525     (goto-char beg)
 526     (or (bolp) (forward-line 1))
 527     (setq beg (point))
 528     (goto-char end)
 529     ;; the test for bolp is for those times when end is on an empty line;
 530     ;; it is probably not the case that the line should be included in the
 531     ;; reversal; it isn't difficult to add it afterward.
 532     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 533     (setq end (point-marker))
 534     ;; the real work.  this thing cranks through memory on large regions.
 535     (let (ll (do t))
 536       (while do
 537         (goto-char beg)
 538         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 539                        ll))
 540         (setq do (/= (point) end))
 541         (delete-region beg (if do (1+ (point)) (point))))
 542       (while (cdr ll)
 543         (insert (car ll) "\n")
 544         (setq ll (cdr ll)))
 545       (insert (car ll)))))
 546
 547 (provide 'sort)
 548
 549 ;;; arch-tag: fbac12be-2a7b-4c8a-9665-264d61f70bd9
 550 ;;; sort.el ends here