lisp/url/url-cookie.el

   1 ;;; url-cookie.el --- URL cookie support
   2
   3 ;; Copyright (C) 1996-1999, 2004-2011  Free Software Foundation, Inc.
   4
   5 ;; Keywords: comm, data, processes, hypermedia
   6
   7 ;; This file is part of GNU Emacs.
   8 ;;
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;;; Code:
  25
  26 (require 'url-util)
  27 (require 'url-parse)
  28
  29 (eval-when-compile (require 'cl))       ; defstruct
  30
  31 (defgroup url-cookie nil
  32   "URL cookies."
  33   :prefix "url-"
  34   :prefix "url-cookie-"
  35   :group 'url)
  36
  37 ;; A cookie is stored internally as a vector of 7 slots
  38 ;; [ url-cookie NAME VALUE EXPIRES LOCALPART DOMAIN SECURE ]
  39
  40 (defstruct (url-cookie
  41             (:constructor url-cookie-create)
  42             (:copier nil)
  43             (:type vector)
  44             :named)
  45   name value expires localpart domain secure)
  46
  47 (defvar url-cookie-storage nil         "Where cookies are stored.")
  48 (defvar url-cookie-secure-storage nil  "Where secure cookies are stored.")
  49 (defcustom url-cookie-file nil
  50   "File where cookies are stored on disk."
  51   :type '(choice (const :tag "Default" :value nil) file)
  52   :group 'url-file
  53   :group 'url-cookie)
  54
  55 (defcustom url-cookie-confirmation nil
  56   "If non-nil, confirmation by the user is required to accept HTTP cookies."
  57   :type 'boolean
  58   :group 'url-cookie)
  59
  60 (defcustom url-cookie-multiple-line nil
  61   "If nil, HTTP requests put all cookies for the server on one line.
  62 Some web servers, such as http://www.hotmail.com/, only accept cookies
  63 when they are on one line.  This is broken behavior, but just try
  64 telling Microsoft that."
  65   :type 'boolean
  66   :group 'url-cookie)
  67
  68 (defvar url-cookies-changed-since-last-save nil
  69   "Whether the cookies list has changed since the last save operation.")
  70
  71 (defun url-cookie-parse-file (&optional fname)
  72   "Load FNAME, default `url-cookie-file'."
  73   ;; It's completely normal for the cookies file not to exist yet.
  74   (load (or fname url-cookie-file) t t))
  75
  76 (defun url-cookie-clean-up (&optional secure)
  77   (let ((var (if secure 'url-cookie-secure-storage 'url-cookie-storage))
  78         new new-cookies)
  79     (dolist (cur (symbol-value var))
  80       (setq new-cookies nil)
  81       (dolist (cur-cookie (cdr cur))
  82         (or (not (url-cookie-p cur-cookie))
  83             (url-cookie-expired-p cur-cookie)
  84             (null (url-cookie-expires cur-cookie))
  85             (setq new-cookies (cons cur-cookie new-cookies))))
  86       (when new-cookies
  87         (setcdr cur new-cookies)
  88         (setq new (cons cur new))))
  89     (set var new)))
  90
  91 (defun url-cookie-write-file (&optional fname)
  92   (when url-cookies-changed-since-last-save
  93     (or fname (setq fname (expand-file-name url-cookie-file)))
  94     (if (condition-case nil
  95             (progn
  96               (url-make-private-file fname)
  97               nil)
  98           (error t))
  99         (message "Error accessing cookie file `%s'" fname)
 100     (url-cookie-clean-up)
 101     (url-cookie-clean-up t)
 102     (with-temp-buffer
 103       (insert ";; Emacs-W3 HTTP cookies file\n"
 104               ";; Automatically generated file!!! DO NOT EDIT!!!\n\n"
 105               "(setq url-cookie-storage\n '")
 106       (pp url-cookie-storage (current-buffer))
 107       (insert ")\n(setq url-cookie-secure-storage\n '")
 108       (pp url-cookie-secure-storage (current-buffer))
 109       (insert ")\n")
 110       (insert "\f\n;; Local Variables:\n"
 111               ";; version-control: never\n"
 112               ";; no-byte-compile: t\n"
 113               ";; End:\n")
 114       (set (make-local-variable 'version-control) 'never)
 115       (write-file fname))
 116     (setq url-cookies-changed-since-last-save nil))))
 117
 118 (defun url-cookie-store (name value &optional expires domain localpart secure)
 119   "Store a cookie."
 120   (let ((storage (if secure url-cookie-secure-storage url-cookie-storage))
 121         tmp found-domain)
 122     ;; First, look for a matching domain.
 123     (if (setq found-domain (assoc domain storage))
 124         ;; Need to either stick the new cookie in existing domain storage
 125         ;; or possibly replace an existing cookie if the names match.
 126         (unless (dolist (cur (setq storage (cdr found-domain)) tmp)
 127                   (and (equal localpart (url-cookie-localpart cur))
 128                        (equal name (url-cookie-name cur))
 129                        (progn
 130                          (setf (url-cookie-expires cur) expires)
 131                          (setf (url-cookie-value cur) value)
 132                          (setq tmp t))))
 133           ;; New cookie.
 134           (setcdr found-domain (cons
 135                                 (url-cookie-create :name name
 136                                                    :value value
 137                                                    :expires expires
 138                                                    :domain domain
 139                                                    :localpart localpart
 140                                                    :secure secure)
 141                                 (cdr found-domain))))
 142       ;; Need to add a new top-level domain.
 143       (setq tmp (url-cookie-create :name name
 144                                    :value value
 145                                    :expires expires
 146                                    :domain domain
 147                                    :localpart localpart
 148                                    :secure secure))
 149       (cond (storage
 150              (setcdr storage (cons (list domain tmp) (cdr storage))))
 151             (secure
 152              (setq url-cookie-secure-storage (list (list domain tmp))))
 153             (t
 154              (setq url-cookie-storage (list (list domain tmp))))))))
 155
 156 (defun url-cookie-expired-p (cookie)
 157   "Return non-nil if COOKIE is expired."
 158   (let ((exp (url-cookie-expires cookie)))
 159     (and exp (> (float-time) (float-time (date-to-time exp))))))
 160
 161 (defun url-cookie-retrieve (host &optional localpart secure)
 162   "Retrieve all cookies for a specified HOST and LOCALPART."
 163   (let ((storage (if secure
 164                      (append url-cookie-secure-storage url-cookie-storage)
 165                    url-cookie-storage))
 166         (case-fold-search t)
 167         cookies retval localpart-match)
 168     (dolist (cur storage)
 169       (setq cookies (cdr cur))
 170       (if (and (car cur)
 171                (string-match
 172                 (concat "^.*"
 173                         (regexp-quote
 174                          ;; Remove the dot from wildcard domains
 175                          ;; before matching.
 176                          (if (eq ?. (aref (car cur) 0))
 177                              (substring (car cur) 1)
 178                            (car cur)))
 179                         "$") host))
 180           ;; The domains match - a possible hit!
 181           (dolist (cur cookies)
 182             (and (if (and (stringp
 183                            (setq localpart-match (url-cookie-localpart cur)))
 184                           (stringp localpart))
 185                      (string-match (concat "^" (regexp-quote localpart-match))
 186                                    localpart)
 187                    (equal localpart localpart-match))
 188                  (not (url-cookie-expired-p cur))
 189                  (setq retval (cons cur retval))))))
 190     retval))
 191
 192 (defun url-cookie-generate-header-lines (host localpart secure)
 193   (let ((cookies (url-cookie-retrieve host localpart secure))
 194         retval chunk)
 195     ;; Have to sort this for sending most specific cookies first.
 196     (setq cookies (and cookies
 197                        (sort cookies
 198                              (lambda (x y)
 199                                (> (length (url-cookie-localpart x))
 200                                   (length (url-cookie-localpart y)))))))
 201     (dolist (cur cookies)
 202       (setq chunk (format "%s=%s" (url-cookie-name cur) (url-cookie-value cur))
 203             retval (if (and url-cookie-multiple-line
 204                             (< 80 (+ (length retval) (length chunk) 4)))
 205                        (concat retval "\r\nCookie: " chunk)
 206                      (if retval
 207                          (concat retval "; " chunk)
 208                        (concat "Cookie: " chunk)))))
 209     (if retval
 210         (concat retval "\r\n")
 211       "")))
 212
 213 (defvar url-cookie-two-dot-domains
 214   (concat "\\.\\("
 215    (mapconcat 'identity (list "com" "edu" "net" "org" "gov" "mil" "int")
 216               "\\|")
 217    "\\)$")
 218   "A regexp of top level domains that only require two matching
 219 '.'s in the domain name in order to set a cookie.")
 220
 221 (defcustom url-cookie-trusted-urls nil
 222   "A list of regular expressions matching URLs to always accept cookies from."
 223   :type '(repeat regexp)
 224   :group 'url-cookie)
 225
 226 (defcustom url-cookie-untrusted-urls nil
 227   "A list of regular expressions matching URLs to never accept cookies from."
 228   :type '(repeat regexp)
 229   :group 'url-cookie)
 230
 231 (defun url-cookie-host-can-set-p (host domain)
 232   (let ((numdots 0)
 233         (last nil)
 234         (case-fold-search t)
 235         (mindots 3))
 236     (while (setq last (string-match "\\." domain last))
 237       (setq numdots (1+ numdots)
 238             last (1+ last)))
 239     (if (string-match url-cookie-two-dot-domains domain)
 240         (setq mindots 2))
 241     (cond
 242      ((string= host domain)             ; Apparently netscape lets you do this
 243       t)
 244      ((>= numdots mindots)              ; We have enough dots in domain name
 245       ;; Need to check and make sure the host is actually _in_ the
 246       ;; domain it wants to set a cookie for though.
 247       (string-match (concat (regexp-quote
 248                              ;; Remove the dot from wildcard domains
 249                              ;; before matching.
 250                              (if (eq ?. (aref domain 0))
 251                                  (substring domain 1)
 252                                domain))
 253                             "$") host))
 254      (t
 255       nil))))
 256
 257 (defun url-cookie-handle-set-cookie (str)
 258   (setq url-cookies-changed-since-last-save t)
 259   (let* ((args (url-parse-args str t))
 260          (case-fold-search t)
 261          (secure (and (assoc-string "secure" args t) t))
 262          (domain (or (cdr-safe (assoc-string "domain" args t))
 263                      (url-host url-current-object)))
 264          (current-url (url-view-url t))
 265          (trusted url-cookie-trusted-urls)
 266          (untrusted url-cookie-untrusted-urls)
 267          (expires (cdr-safe (assoc-string "expires" args t)))
 268          (localpart (or (cdr-safe (assoc-string "path" args t))
 269                         (file-name-directory
 270                          (url-filename url-current-object))))
 271          (rest nil))
 272     (dolist (this args)
 273       (or (member (downcase (car this)) '("secure" "domain" "expires" "path"))
 274           (setq rest (cons this rest))))
 275
 276     ;; Sometimes we get dates that the timezone package cannot handle very
 277     ;; gracefully - take care of this here, instead of in url-cookie-expired-p
 278     ;; to speed things up.
 279     (and expires
 280          (string-match
 281           (concat "^[^,]+, +\\(..\\)-\\(...\\)-\\(..\\) +"
 282                   "\\(..:..:..\\) +\\[*\\([^\]]+\\)\\]*$")
 283           expires)
 284          (setq expires (concat (match-string 1 expires) " "
 285                                (match-string 2 expires) " "
 286                                (match-string 3 expires) " "
 287                                (match-string 4 expires) " ["
 288                                (match-string 5 expires) "]")))
 289
 290     ;; This one is for older Emacs/XEmacs variants that don't
 291     ;; understand this format without tenths of a second in it.
 292     ;; Wednesday, 30-Dec-2037 16:00:00 GMT
 293     ;;       - vs -
 294     ;; Wednesday, 30-Dec-2037 16:00:00.00 GMT
 295     (and expires
 296          (string-match
 297           "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\(\\.[0-9]+\\)*[ \t]+\\([-+a-zA-Z0-9]+\\)"
 298           expires)
 299          (setq expires (concat (match-string 1 expires) "-"     ; day
 300                                (match-string 2 expires) "-"     ; month
 301                                (match-string 3 expires) " "     ; year
 302                                (match-string 4 expires) ".00 " ; hour:minutes:seconds
 303                                (match-string 6 expires)))) ":" ; timezone
 304
 305     (while (consp trusted)
 306       (if (string-match (car trusted) current-url)
 307           (setq trusted (- (match-end 0) (match-beginning 0)))
 308         (pop trusted)))
 309     (while (consp untrusted)
 310       (if (string-match (car untrusted) current-url)
 311           (setq untrusted (- (match-end 0) (match-beginning 0)))
 312         (pop untrusted)))
 313     (and trusted untrusted
 314          ;; Choose the more specific match.
 315          (set (if (> trusted untrusted) 'untrusted 'trusted) nil))
 316     (cond
 317      (untrusted
 318       ;; The site was explicity marked as untrusted by the user.
 319       nil)
 320      ((or (eq url-privacy-level 'paranoid)
 321           (and (listp url-privacy-level) (memq 'cookies url-privacy-level)))
 322       ;; User never wants cookies.
 323       nil)
 324      ((and url-cookie-confirmation
 325            (not trusted)
 326            (save-window-excursion
 327              (with-output-to-temp-buffer "*Cookie Warning*"
 328                (dolist (x rest)
 329                  (princ (format "%s - %s" (car x) (cdr x)))))
 330              (prog1
 331                  (not (funcall url-confirmation-func
 332                                (format "Allow %s to set these cookies? "
 333                                        (url-host url-current-object))))
 334                (if (get-buffer "*Cookie Warning*")
 335                    (kill-buffer "*Cookie Warning*")))))
 336       ;; User wants to be asked, and declined.
 337       nil)
 338      ((url-cookie-host-can-set-p (url-host url-current-object) domain)
 339       ;; Cookie is accepted by the user, and passes our security checks.
 340       (dolist (cur rest)
 341         (url-cookie-store (car cur) (cdr cur) expires domain localpart secure)))
 342      (t
 343       (url-lazy-message "%s tried to set a cookie for domain %s - rejected."
 344                         (url-host url-current-object) domain)))))
 345
 346 (defvar url-cookie-timer nil)
 347
 348 (defcustom url-cookie-save-interval 3600
 349   "The number of seconds between automatic saves of cookies.
 350 Default is 1 hour.  Note that if you change this variable outside of
 351 the `customize' interface after `url-do-setup' has been run, you need
 352 to run the `url-cookie-setup-save-timer' function manually."
 353   :set #'(lambda (var val)
 354            (set-default var val)
 355            (if (bound-and-true-p url-setup-done)
 356                (url-cookie-setup-save-timer)))
 357   :type 'integer
 358   :group 'url-cookie)
 359
 360 (defun url-cookie-setup-save-timer ()
 361   "Reset the cookie saver timer."
 362   (interactive)
 363   (ignore-errors (cancel-timer url-cookie-timer))
 364   (setq url-cookie-timer nil)
 365   (if url-cookie-save-interval
 366       (setq url-cookie-timer (run-at-time url-cookie-save-interval
 367                                           url-cookie-save-interval
 368                                           #'url-cookie-write-file))))
 369
 370 (provide 'url-cookie)
 371
 372 ;;; url-cookie.el ends here