lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: mouse, terminals
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Enable mouse support when running inside an xterm.
  26
  27 ;; This is actually useful when you are running X11 locally, but is
  28 ;; working on remote machine over a modem line or through a gateway.
  29
  30 ;; It works by translating xterm escape codes into generic emacs mouse
  31 ;; events so it should work with any package that uses the mouse.
  32
  33 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  34 ;; functionality, it is still available by holding down the SHIFT key
  35 ;; when you press the mouse button.
  36
  37 ;;; Todo:
  38
  39 ;; Support multi-click -- somehow.
  40
  41 ;;; Code:
  42
  43 (defvar xterm-mouse-debug-buffer nil)
  44
  45 (defvar xterm-mouse-last)
  46
  47 ;; Mouse events symbols must have an 'event-kind property with
  48 ;; the value 'mouse-click.
  49 (dolist (event-type '(mouse-1 mouse-2 mouse-3
  50                               M-down-mouse-1 M-down-mouse-2 M-down-mouse-3))
  51   (put event-type 'event-kind 'mouse-click))
  52
  53 (defun xterm-mouse-translate (_event)
  54   "Read a click and release event from XTerm."
  55   (save-excursion
  56     (save-window-excursion
  57       (deactivate-mark)
  58       (let* ((xterm-mouse-last)
  59              (down (xterm-mouse-event))
  60              (down-command (nth 0 down))
  61              (down-data (nth 1 down))
  62              (down-where (nth 1 down-data))
  63              (down-binding (key-binding (if (symbolp down-where)
  64                                             (vector down-where down-command)
  65                                           (vector down-command))))
  66              (is-click (string-match "^mouse" (symbol-name (car down)))))
  67
  68         (unless is-click
  69           (unless (and (eq (read-char) ?\e)
  70                        (eq (read-char) ?\[)
  71                        (eq (read-char) ?M))
  72             (error "Unexpected escape sequence from XTerm")))
  73
  74         (let* ((click (if is-click down (xterm-mouse-event)))
  75                ;; (click-command (nth 0 click))
  76                (click-data (nth 1 click))
  77                (click-where (nth 1 click-data)))
  78           (if (memq down-binding '(nil ignore))
  79               (if (and (symbolp click-where)
  80                        (consp click-where))
  81                   (vector (list click-where click-data) click)
  82                 (vector click))
  83             (setq unread-command-events
  84                   (if (eq down-where click-where)
  85                       (list click)
  86                     (list
  87                      ;; Cheat `mouse-drag-region' with move event.
  88                      (list 'mouse-movement click-data)
  89                      ;; Generate a drag event.
  90                      (if (symbolp down-where)
  91                          0
  92                        (list (intern (format "drag-mouse-%d"
  93                                              (+ 1 xterm-mouse-last)))
  94                              down-data click-data)))))
  95             (if xterm-mouse-debug-buffer
  96                 (print unread-command-events xterm-mouse-debug-buffer))
  97             (if (and (symbolp down-where)
  98                      (consp down-where))
  99                 (vector (list down-where down-data) down)
 100               (vector down))))))))
 101
 102 ;; These two variables have been converted to terminal parameters.
 103 ;;
 104 ;;(defvar xterm-mouse-x 0
 105 ;;  "Position of last xterm mouse event relative to the frame.")
 106 ;;
 107 ;;(defvar xterm-mouse-y 0
 108 ;;  "Position of last xterm mouse event relative to the frame.")
 109
 110 (defvar xt-mouse-epoch nil)
 111
 112 ;; Indicator for the xterm-mouse mode.
 113
 114 (defun xterm-mouse-position-function (pos)
 115   "Bound to `mouse-position-function' in XTerm mouse mode."
 116   (when (terminal-parameter nil 'xterm-mouse-x)
 117     (setcdr pos (cons (terminal-parameter nil 'xterm-mouse-x)
 118                       (terminal-parameter nil 'xterm-mouse-y))))
 119   pos)
 120
 121 ;; read xterm sequences above ascii 127 (#x7f)
 122 (defun xterm-mouse-event-read ()
 123   ;; We get the characters decoded by the keyboard coding system.  Try
 124   ;; to recover the raw character.
 125   (let ((c (read-char)))
 126     (cond ;; If meta-flag is t we get a meta character
 127           ((>= c ?\M-\^@)
 128            (- c (- ?\M-\^@ 128)))
 129           ;; Reencode the character in the keyboard coding system, if
 130           ;; this is a non-ASCII character.
 131           ((>= c #x80)
 132            (aref (encode-coding-string (string c) (keyboard-coding-system)) 0))
 133           (t c))))
 134
 135 (defun xterm-mouse-truncate-wrap (f)
 136   "Truncate with wrap-around."
 137   (condition-case nil
 138       ;; First try the built-in truncate, in case there's no overflow.
 139       (truncate f)
 140     ;; In case of overflow, do wraparound by hand.
 141     (range-error
 142      ;; In our case, we wrap around every 3 days or so, so if we assume
 143      ;; a maximum of 65536 wraparounds, we're safe for a couple years.
 144      ;; Using a power of 2 makes rounding errors less likely.
 145      (let* ((maxwrap (* 65536 2048))
 146             (dbig (truncate (/ f maxwrap)))
 147             (fdiff (- f (* 1.0 maxwrap dbig))))
 148        (+ (truncate fdiff) (* maxwrap dbig))))))
 149
 150 (defun xterm-mouse-event ()
 151   "Convert XTerm mouse event to Emacs mouse event."
 152   (let* ((type (- (xterm-mouse-event-read) #o40))
 153          (x (- (xterm-mouse-event-read) #o40 1))
 154          (y (- (xterm-mouse-event-read) #o40 1))
 155          ;; Emulate timestamp information.  This is accurate enough
 156          ;; for default value of mouse-1-click-follows-link (450msec).
 157          (timestamp (xterm-mouse-truncate-wrap
 158                      (* 1000
 159                         (- (float-time)
 160                            (or xt-mouse-epoch
 161                                (setq xt-mouse-epoch (float-time)))))))
 162          (mouse (intern
 163                  ;; For buttons > 3, the release-event looks
 164                  ;; differently (see xc/programs/xterm/button.c,
 165                  ;; function EditorButton), and there seems to come in
 166                  ;; a release-event only, no down-event.
 167                  (cond ((>= type 64)
 168                         (format "mouse-%d" (- type 60)))
 169                        ((memq type '(8 9 10))
 170                         (setq xterm-mouse-last type)
 171                         (format "M-down-mouse-%d" (- type 7)))
 172                        ((= type 11)
 173                         (format "mouse-%d" (- xterm-mouse-last 7)))
 174                        ((= type 3)
 175                         ;; For buttons > 5 xterm only reports a
 176                         ;; button-release event.  Avoid error by mapping
 177                         ;; them all to mouse-1.
 178                         (format "mouse-%d" (+ 1 (or xterm-mouse-last 0))))
 179                        (t
 180                         (setq xterm-mouse-last type)
 181                         (format "down-mouse-%d" (+ 1 type))))))
 182          (w (window-at x y))
 183          (ltrb (window-edges w))
 184          (left (nth 0 ltrb))
 185          (top (nth 1 ltrb)))
 186
 187     (set-terminal-parameter nil 'xterm-mouse-x x)
 188     (set-terminal-parameter nil 'xterm-mouse-y y)
 189     (setq
 190      last-input-event
 191      (list mouse
 192            (let ((event (if w
 193                             (posn-at-x-y (- x left) (- y top) w t)
 194                           (append (list nil 'menu-bar)
 195                                   (nthcdr 2 (posn-at-x-y x y))))))
 196              (setcar (nthcdr 3 event) timestamp)
 197              event)))))
 198
 199 ;;;###autoload
 200 (define-minor-mode xterm-mouse-mode
 201   "Toggle XTerm mouse mode.
 202 With a prefix argument ARG, enable XTerm mouse mode if ARG is
 203 positive, and disable it otherwise.  If called from Lisp, enable
 204 the mode if ARG is omitted or nil.
 205
 206 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 207 This works in terminal emulators compatible with xterm.  It only
 208 works for simple uses of the mouse.  Basically, only non-modified
 209 single clicks are supported.  When turned on, the normal xterm
 210 mouse functionality for such clicks is still available by holding
 211 down the SHIFT key while pressing the mouse button."
 212   :global t :group 'mouse
 213   (let ((do-hook (if xterm-mouse-mode 'add-hook 'remove-hook)))
 214     (funcall do-hook 'terminal-init-xterm-hook
 215              'turn-on-xterm-mouse-tracking-on-terminal)
 216     (funcall do-hook 'delete-terminal-functions
 217              'turn-off-xterm-mouse-tracking-on-terminal)
 218     (funcall do-hook 'suspend-tty-functions
 219              'turn-off-xterm-mouse-tracking-on-terminal)
 220     (funcall do-hook 'resume-tty-functions
 221              'turn-on-xterm-mouse-tracking-on-terminal)
 222     (funcall do-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 223     (funcall do-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 224     (funcall do-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking))
 225   (if xterm-mouse-mode
 226       ;; Turn it on
 227       (progn
 228         (setq mouse-position-function #'xterm-mouse-position-function)
 229         (turn-on-xterm-mouse-tracking))
 230     ;; Turn it off
 231     (turn-off-xterm-mouse-tracking 'force)
 232     (setq mouse-position-function nil)))
 233
 234 (defun turn-on-xterm-mouse-tracking ()
 235   "Enable Emacs mouse tracking in xterm."
 236   (dolist (terminal (terminal-list))
 237     (turn-on-xterm-mouse-tracking-on-terminal terminal)))
 238
 239 (defun turn-off-xterm-mouse-tracking (&optional _force)
 240   "Disable Emacs mouse tracking in xterm."
 241   (dolist (terminal (terminal-list))
 242     (turn-off-xterm-mouse-tracking-on-terminal terminal)))
 243
 244 (defun turn-on-xterm-mouse-tracking-on-terminal (&optional terminal)
 245   "Enable xterm mouse tracking on TERMINAL."
 246   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal))
 247              ;; Avoid the initial terminal which is not a termcap device.
 248              ;; FIXME: is there more elegant way to detect the initial terminal?
 249              (not (string= (terminal-name terminal) "initial_terminal")))
 250     (unless (terminal-parameter terminal 'xterm-mouse-mode)
 251       ;; Simulate selecting a terminal by selecting one of its frames ;-(
 252       (with-selected-frame (car (frames-on-display-list terminal))
 253         (define-key input-decode-map "\e[M" 'xterm-mouse-translate))
 254       (set-terminal-parameter terminal 'xterm-mouse-mode t))
 255     (send-string-to-terminal "\e[?1000h" terminal)))
 256
 257 (defun turn-off-xterm-mouse-tracking-on-terminal (terminal)
 258   "Disable xterm mouse tracking on TERMINAL."
 259   ;; Only send the disable command to those terminals to which we've already
 260   ;; sent the enable command.
 261   (when (and (terminal-parameter terminal 'xterm-mouse-mode)
 262              (eq t (terminal-live-p terminal))
 263              ;; Avoid the initial terminal which is not a termcap device.
 264              ;; FIXME: is there more elegant way to detect the initial terminal?
 265              (not (string= (terminal-name terminal) "initial_terminal")))
 266     ;; We could remove the key-binding and unset the `xterm-mouse-mode'
 267     ;; terminal parameter, but it seems less harmful to send this escape
 268     ;; command too many times (or to catch an unintended key sequence), than
 269     ;; to send it too few times (or to fail to let xterm-mouse events
 270     ;; pass by untranslated).
 271     (send-string-to-terminal "\e[?1000l" terminal)))
 272
 273 (provide 'xt-mouse)
 274
 275 ;;; xt-mouse.el ends here