lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 221 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 222 positive, and disable it otherwise.  If called from Lisp, enable
 223 the mode if ARG is omitted or nil."
 224   nil nil nil
 225   (unless (derived-mode-p 'ibuffer-mode)
 226     (error "This buffer is not in Ibuffer mode"))
 227   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 228   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 229
 230 (defun ibuffer-auto-update-changed ()
 231   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 232     (dolist (buf (buffer-list))
 233       (ignore-errors
 234         (with-current-buffer buf
 235           (when (and ibuffer-auto-mode
 236                      (derived-mode-p 'ibuffer-mode))
 237             (ibuffer-update nil t)))))))
 238
 239 ;;;###autoload
 240 (defun ibuffer-mouse-filter-by-mode (event)
 241   "Enable or disable filtering by the major mode chosen via mouse."
 242   (interactive "e")
 243   (ibuffer-interactive-filter-by-mode event))
 244
 245 ;;;###autoload
 246 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 247   "Enable or disable filtering by the major mode at point."
 248   (interactive "d")
 249   (if (eventp event-or-point)
 250       (posn-set-point (event-end event-or-point))
 251     (goto-char event-or-point))
 252   (let ((buf (ibuffer-current-buffer)))
 253     (if (assq 'mode ibuffer-filtering-qualifiers)
 254         (setq ibuffer-filtering-qualifiers
 255               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 256       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 257   (ibuffer-update nil t))
 258
 259 ;;;###autoload
 260 (defun ibuffer-mouse-toggle-filter-group (event)
 261   "Toggle the display status of the filter group chosen with the mouse."
 262   (interactive "e")
 263   (ibuffer-toggle-filter-group-1 (save-excursion
 264                                    (mouse-set-point event)
 265                                    (point))))
 266
 267 ;;;###autoload
 268 (defun ibuffer-toggle-filter-group ()
 269   "Toggle the display status of the filter group on this line."
 270   (interactive)
 271   (ibuffer-toggle-filter-group-1 (point)))
 272
 273 (defun ibuffer-toggle-filter-group-1 (posn)
 274   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 275     (unless (stringp name)
 276       (error "No filtering group name present"))
 277     (if (member name ibuffer-hidden-filter-groups)
 278         (setq ibuffer-hidden-filter-groups
 279               (delete name ibuffer-hidden-filter-groups))
 280       (push name ibuffer-hidden-filter-groups))
 281     (ibuffer-update nil t)))
 282
 283 ;;;###autoload
 284 (defun ibuffer-forward-filter-group (&optional count)
 285   "Move point forwards by COUNT filtering groups."
 286   (interactive "P")
 287   (unless count
 288     (setq count 1))
 289   (when (> count 0)
 290     (when (get-text-property (point) 'ibuffer-filter-group-name)
 291       (goto-char (next-single-property-change
 292                   (point) 'ibuffer-filter-group-name
 293                   nil (point-max))))
 294     (goto-char (next-single-property-change
 295                 (point) 'ibuffer-filter-group-name
 296                 nil (point-max)))
 297     (ibuffer-forward-filter-group (1- count)))
 298   (ibuffer-forward-line 0))
 299
 300 ;;;###autoload
 301 (defun ibuffer-backward-filter-group (&optional count)
 302   "Move point backwards by COUNT filtering groups."
 303   (interactive "P")
 304   (unless count
 305     (setq count 1))
 306   (when (> count 0)
 307     (when (get-text-property (point) 'ibuffer-filter-group-name)
 308       (goto-char (previous-single-property-change
 309                   (point) 'ibuffer-filter-group-name
 310                   nil (point-min))))
 311     (goto-char (previous-single-property-change
 312                 (point) 'ibuffer-filter-group-name
 313                 nil (point-min)))
 314     (ibuffer-backward-filter-group (1- count)))
 315   (when (= (point) (point-min))
 316     (goto-char (point-max))
 317     (ibuffer-backward-filter-group 1))
 318   (ibuffer-forward-line 0))
 319
 320 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 321 (define-ibuffer-op shell-command-pipe (command)
 322   "Pipe the contents of each marked buffer to shell command COMMAND."
 323   (:interactive "sPipe to shell command: "
 324    :opstring "Shell command executed on"
 325    :modifier-p nil)
 326   (shell-command-on-region
 327    (point-min) (point-max) command
 328    (get-buffer-create "* ibuffer-shell-output*")))
 329
 330 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 331 (define-ibuffer-op shell-command-pipe-replace (command)
 332   "Replace the contents of marked buffers with output of pipe to COMMAND."
 333   (:interactive "sPipe to shell command (replace): "
 334    :opstring "Buffer contents replaced in"
 335    :active-opstring "replace buffer contents in"
 336    :dangerous t
 337    :modifier-p t)
 338   (with-current-buffer buf
 339     (shell-command-on-region (point-min) (point-max)
 340                              command nil t)))
 341
 342 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 343 (define-ibuffer-op shell-command-file (command)
 344   "Run shell command COMMAND separately on files of marked buffers."
 345   (:interactive "sShell command on buffer's file: "
 346    :opstring "Shell command executed on"
 347    :modifier-p nil)
 348   (shell-command (concat command " "
 349                          (shell-quote-argument
 350                           (if buffer-file-name
 351                               buffer-file-name
 352                             (make-temp-file
 353                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 356 (define-ibuffer-op eval (form)
 357   "Evaluate FORM in each of the buffers.
 358 Does not display the buffer during evaluation. See
 359 `ibuffer-do-view-and-eval' for that."
 360   (:interactive
 361    (list
 362     (read-from-minibuffer
 363      "Eval in buffers (form): "
 364      nil read-expression-map t 'read-expression-history))
 365    :opstring "evaluated in"
 366    :modifier-p :maybe)
 367   (eval form))
 368
 369 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 370 (define-ibuffer-op view-and-eval (form)
 371   "Evaluate FORM while displaying each of the marked buffers.
 372 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 373   (:interactive
 374    (list
 375     (read-from-minibuffer
 376      "Eval viewing in buffers (form): "
 377      nil read-expression-map t 'read-expression-history))
 378    :opstring "evaluated in"
 379    :complex t
 380    :modifier-p :maybe)
 381   (let ((ibuffer-buf (current-buffer)))
 382     (unwind-protect
 383         (progn
 384           (switch-to-buffer buf)
 385           (eval form))
 386       (switch-to-buffer ibuffer-buf))))
 387
 388 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 389 (define-ibuffer-op rename-uniquely ()
 390   "Rename marked buffers as with `rename-uniquely'."
 391   (:opstring "renamed"
 392    :modifier-p t)
 393   (rename-uniquely))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 396 (define-ibuffer-op revert ()
 397   "Revert marked buffers as with `revert-buffer'."
 398   (:dangerous t
 399    :opstring "reverted"
 400    :active-opstring "revert"
 401    :modifier-p :maybe)
 402   (revert-buffer t t))
 403
 404 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 405 (define-ibuffer-op ibuffer-do-isearch ()
 406   "Perform a `isearch-forward' in marked buffers."
 407   (:interactive ()
 408    :opstring "searched in"
 409    :complex t
 410    :modifier-p :maybe)
 411   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 412
 413 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 414 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 415   "Perform a `isearch-forward-regexp' in marked buffers."
 416   (:interactive ()
 417    :opstring "searched regexp in"
 418    :complex t
 419    :modifier-p :maybe)
 420   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 421
 422 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 423 (define-ibuffer-op replace-regexp (from-str to-str)
 424   "Perform a `replace-regexp' in marked buffers."
 425   (:interactive
 426    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 427           (to-str (read-from-minibuffer (concat "Replace " from-str
 428                                                 " with: "))))
 429      (list from-str to-str))
 430    :opstring "replaced in"
 431    :complex t
 432    :modifier-p :maybe)
 433   (save-window-excursion
 434     (switch-to-buffer buf)
 435     (save-excursion
 436       (goto-char (point-min))
 437       (let ((case-fold-search ibuffer-case-fold-search))
 438         (while (re-search-forward from-str nil t)
 439           (replace-match to-str))))
 440     t))
 441
 442 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 443 (define-ibuffer-op query-replace (&rest args)
 444   "Perform a `query-replace' in marked buffers."
 445   (:interactive
 446    (query-replace-read-args "Query replace" t t)
 447    :opstring "replaced in"
 448    :complex t
 449    :modifier-p :maybe)
 450   (save-window-excursion
 451     (switch-to-buffer buf)
 452     (save-excursion
 453       (let ((case-fold-search ibuffer-case-fold-search))
 454         (goto-char (point-min))
 455         (apply #'query-replace args)))
 456     t))
 457
 458 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 459 (define-ibuffer-op query-replace-regexp (&rest args)
 460   "Perform a `query-replace-regexp' in marked buffers."
 461   (:interactive
 462    (query-replace-read-args "Query replace regexp" t t)
 463    :opstring "replaced in"
 464    :complex t
 465    :modifier-p :maybe)
 466   (save-window-excursion
 467     (switch-to-buffer buf)
 468     (save-excursion
 469       (let ((case-fold-search ibuffer-case-fold-search))
 470         (goto-char (point-min))
 471         (apply #'query-replace-regexp args)))
 472     t))
 473
 474 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 475 (define-ibuffer-op print ()
 476   "Print marked buffers as with `print-buffer'."
 477   (:opstring "printed"
 478    :modifier-p nil)
 479   (print-buffer))
 480
 481 ;;;###autoload
 482 (defun ibuffer-included-in-filters-p (buf filters)
 483   (not
 484    (memq nil ;; a filter will return nil if it failed
 485          (mapcar
 486           ;; filter should be like (TYPE . QUALIFIER), or
 487           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 488           #'(lambda (qual)
 489               (ibuffer-included-in-filter-p buf qual))
 490           filters))))
 491
 492 (defun ibuffer-included-in-filter-p (buf filter)
 493   (if (eq (car filter) 'not)
 494       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 495     (ibuffer-included-in-filter-p-1 buf filter)))
 496
 497 (defun ibuffer-included-in-filter-p-1 (buf filter)
 498   (not
 499    (not
 500     (case (car filter)
 501       (or
 502        (memq t (mapcar #'(lambda (x)
 503                            (ibuffer-included-in-filter-p buf x))
 504                        (cdr filter))))
 505       (saved
 506        (let ((data
 507               (assoc (cdr filter)
 508                      ibuffer-saved-filters)))
 509          (unless data
 510            (ibuffer-filter-disable t)
 511            (error "Unknown saved filter %s" (cdr filter)))
 512          (ibuffer-included-in-filters-p buf (cadr data))))
 513       (t
 514        (let ((filterdat (assq (car filter)
 515                               ibuffer-filtering-alist)))
 516          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 517          ;; just a sanity check
 518         (unless filterdat
 519           (ibuffer-filter-disable t)
 520           (error "Undefined filter %s" (car filter)))
 521         (not
 522          (not
 523           (funcall (caddr filterdat)
 524                    buf
 525                    (cdr filter))))))))))
 526
 527 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 528   (let ((filter-group-alist (if nodefault
 529                                 ibuffer-filter-groups
 530                               (append ibuffer-filter-groups
 531                                       (list (cons "Default" nil))))))
 532 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 533 ;;       (setq filter-group-alist (ibuffer-delete-alist
 534 ;;                                 hidden filter-group-alist)))
 535     (let ((vec (make-vector (length filter-group-alist) nil))
 536           (i 0))
 537       (dolist (filtergroup filter-group-alist)
 538         (let ((filterset (cdr filtergroup)))
 539           (multiple-value-bind (hip-crowd lamers)
 540               (values-list
 541                (ibuffer-split-list (lambda (bufmark)
 542                                      (ibuffer-included-in-filters-p (car bufmark)
 543                                                                     filterset))
 544                                    bmarklist))
 545             (aset vec i hip-crowd)
 546             (incf i)
 547             (setq bmarklist lamers))))
 548       (let (ret)
 549         (dotimes (j i ret)
 550           (let ((bufs (aref vec j)))
 551             (unless (and noempty (null bufs))
 552               (push (cons (car (nth j filter-group-alist))
 553                           bufs)
 554                     ret))))))))
 555
 556 ;;;###autoload
 557 (defun ibuffer-filters-to-filter-group (name)
 558   "Make the current filters into a filtering group."
 559   (interactive "sName for filtering group: ")
 560   (when (null ibuffer-filtering-qualifiers)
 561     (error "No filters in effect"))
 562   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 563   (ibuffer-filter-disable))
 564
 565 ;;;###autoload
 566 (defun ibuffer-set-filter-groups-by-mode ()
 567   "Set the current filter groups to filter by mode."
 568   (interactive)
 569   (setq ibuffer-filter-groups
 570         (mapcar (lambda (mode)
 571                   (cons (format "%s" mode) `((mode . ,mode))))
 572                 (let ((modes
 573                        (ibuffer-remove-duplicates
 574                         (mapcar (lambda (buf)
 575                                   (buffer-local-value 'major-mode buf))
 576                                 (buffer-list)))))
 577                   (if ibuffer-view-ibuffer
 578                       modes
 579                     (delq 'ibuffer-mode modes)))))
 580   (ibuffer-update nil t))
 581
 582 ;;;###autoload
 583 (defun ibuffer-pop-filter-group ()
 584   "Remove the first filter group."
 585   (interactive)
 586   (when (null ibuffer-filter-groups)
 587     (error "No filter groups active"))
 588   (setq ibuffer-hidden-filter-groups
 589         (delete (pop ibuffer-filter-groups)
 590                 ibuffer-hidden-filter-groups))
 591   (ibuffer-update nil t))
 592
 593 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 594   (when (and (not noerror) (null ibuffer-filter-groups))
 595     (error "No filter groups active"))
 596   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 597   ;; groups, possibly excluding empty groups or Default.
 598   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 599   ;; Default if necessary.
 600   (completing-read msg (nconc
 601                         (ibuffer-generate-filter-groups
 602                          (ibuffer-current-state-list)
 603                          (not ibuffer-show-empty-filter-groups)
 604                          nodefault)
 605                         (if nodefault
 606                             (remove "Default" ibuffer-hidden-filter-groups)
 607                           ibuffer-hidden-filter-groups))
 608                    nil t))
 609
 610 ;;;###autoload
 611 (defun ibuffer-decompose-filter-group (group)
 612   "Decompose the filter group GROUP into active filters."
 613   (interactive
 614    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 615   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 616     (setq ibuffer-filter-groups (ibuffer-delete-alist
 617                                  group ibuffer-filter-groups)
 618           ibuffer-filtering-qualifiers data))
 619   (ibuffer-update nil t))
 620
 621 ;;;###autoload
 622 (defun ibuffer-clear-filter-groups ()
 623   "Remove all filter groups."
 624   (interactive)
 625   (setq ibuffer-filter-groups nil
 626         ibuffer-hidden-filter-groups nil)
 627   (ibuffer-update nil t))
 628
 629 (defun ibuffer-current-filter-groups-with-position ()
 630   (save-excursion
 631     (goto-char (point-min))
 632     (let ((pos nil)
 633           (result nil))
 634       (while (and (not (eobp))
 635                   (setq pos (next-single-property-change
 636                              (point) 'ibuffer-filter-group-name)))
 637         (goto-char pos)
 638         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 639                     pos)
 640               result)
 641         (goto-char (next-single-property-change
 642                     pos 'ibuffer-filter-group-name)))
 643       (nreverse result))))
 644
 645 ;;;###autoload
 646 (defun ibuffer-jump-to-filter-group (name)
 647   "Move point to the filter group whose name is NAME."
 648   (interactive
 649    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 650   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 651       (goto-char (cdr it))
 652     (error "No filter group with name %s" name)))
 653
 654 ;;;###autoload
 655 (defun ibuffer-kill-filter-group (name)
 656   "Kill the filter group named NAME.
 657 The group will be added to `ibuffer-filter-group-kill-ring'."
 658   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 659   (when (equal name "Default")
 660     (error "Can't kill default filter group"))
 661   (ibuffer-aif (assoc name ibuffer-filter-groups)
 662       (progn
 663         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 664         (setq ibuffer-filter-groups (ibuffer-delete-alist
 665                                      name ibuffer-filter-groups))
 666         (setq ibuffer-hidden-filter-groups
 667               (delete name ibuffer-hidden-filter-groups)))
 668     (error "No filter group with name \"%s\"" name))
 669   (ibuffer-update nil t))
 670
 671 ;;;###autoload
 672 (defun ibuffer-kill-line (&optional arg interactive-p)
 673   "Kill the filter group at point.
 674 See also `ibuffer-kill-filter-group'."
 675   (interactive "P\np")
 676   (ibuffer-aif (save-excursion
 677                  (ibuffer-forward-line 0)
 678                  (get-text-property (point) 'ibuffer-filter-group-name))
 679       (progn
 680         (ibuffer-kill-filter-group it))
 681       (funcall (if interactive-p #'call-interactively #'funcall)
 682                #'kill-line arg)))
 683
 684 (defun ibuffer-insert-filter-group-before (newgroup group)
 685   (let* ((found nil)
 686          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 687                     (res 0))
 688                 (while groups
 689                   (if (equal (car groups) group)
 690                       (setq found t
 691                             groups nil)
 692                     (incf res)
 693                     (setq groups (cdr groups))))
 694                 res)))
 695     (cond ((not found)
 696            (setq ibuffer-filter-groups
 697                  (nconc ibuffer-filter-groups (list newgroup))))
 698           ((zerop pos)
 699            (push newgroup ibuffer-filter-groups))
 700           (t
 701            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 702              (setf (cdr cell) (cons (car cell) (cdr cell)))
 703              (setf (car cell) newgroup))))))
 704
 705 ;;;###autoload
 706 (defun ibuffer-yank ()
 707   "Yank the last killed filter group before group at point."
 708   (interactive)
 709   (ibuffer-yank-filter-group
 710    (or (get-text-property (point) 'ibuffer-filter-group-name)
 711        (get-text-property (point) 'ibuffer-filter-group)
 712        (error "No filter group at point"))))
 713
 714 ;;;###autoload
 715 (defun ibuffer-yank-filter-group (name)
 716   "Yank the last killed filter group before group named NAME."
 717   (interactive (list (ibuffer-read-filter-group-name
 718                         "Yank filter group before group: ")))
 719   (unless ibuffer-filter-group-kill-ring
 720     (error "The Ibuffer filter group kill-ring is empty"))
 721   (save-excursion
 722     (ibuffer-forward-line 0)
 723     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 724                                         name))
 725   (ibuffer-update nil t))
 726
 727 ;;;###autoload
 728 (defun ibuffer-save-filter-groups (name groups)
 729   "Save all active filter groups GROUPS as NAME.
 730 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 731 prompt for NAME, and use the current filters."
 732   (interactive
 733    (if (null ibuffer-filter-groups)
 734        (error "No filter groups active")
 735      (list
 736       (read-from-minibuffer "Save current filter groups as: ")
 737       ibuffer-filter-groups)))
 738   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 739       (setcdr it groups)
 740     (push (cons name groups) ibuffer-saved-filter-groups))
 741   (ibuffer-maybe-save-stuff))
 742
 743 ;;;###autoload
 744 (defun ibuffer-delete-saved-filter-groups (name)
 745   "Delete saved filter groups with NAME.
 746 They are removed from `ibuffer-saved-filter-groups'."
 747   (interactive
 748    (list
 749     (if (null ibuffer-saved-filter-groups)
 750         (error "No saved filter groups")
 751       (completing-read "Delete saved filter group: "
 752                        ibuffer-saved-filter-groups nil t))))
 753   (setq ibuffer-saved-filter-groups
 754         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 755   (ibuffer-maybe-save-stuff)
 756   (ibuffer-update nil t))
 757
 758 ;;;###autoload
 759 (defun ibuffer-switch-to-saved-filter-groups (name)
 760   "Set this buffer's filter groups to saved version with NAME.
 761 The value from `ibuffer-saved-filter-groups' is used."
 762   (interactive
 763    (list
 764     (if (null ibuffer-saved-filter-groups)
 765         (error "No saved filters")
 766       (completing-read "Switch to saved filter group: "
 767                        ibuffer-saved-filter-groups nil t))))
 768   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 769         ibuffer-hidden-filter-groups nil)
 770   (ibuffer-update nil t))
 771
 772 ;;;###autoload
 773 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 774   "Disable all filters currently in effect in this buffer.
 775 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 776 group definitions by setting `ibuffer-filter-groups' to nil."
 777   (interactive)
 778   (setq ibuffer-filtering-qualifiers nil)
 779   (if delete-filter-groups
 780       (setq ibuffer-filter-groups nil))
 781   (let ((buf (ibuffer-current-buffer)))
 782     (ibuffer-update nil t)
 783     (when buf
 784       (ibuffer-jump-to-buffer (buffer-name buf)))))
 785
 786 ;;;###autoload
 787 (defun ibuffer-pop-filter ()
 788   "Remove the top filter in this buffer."
 789   (interactive)
 790   (when (null ibuffer-filtering-qualifiers)
 791     (error "No filters in effect"))
 792   (pop ibuffer-filtering-qualifiers)
 793   (let ((buf (ibuffer-current-buffer)))
 794     (ibuffer-update nil t)
 795     (when buf
 796       (ibuffer-jump-to-buffer (buffer-name buf)))))
 797
 798 (defun ibuffer-push-filter (qualifier)
 799   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 800   (push qualifier ibuffer-filtering-qualifiers))
 801
 802 ;;;###autoload
 803 (defun ibuffer-decompose-filter ()
 804   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 805
 806 This means that the topmost filter on the filtering stack, which must
 807 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 808 turned into two separate filters [name: foo] and [mode: bar-mode]."
 809   (interactive)
 810   (when (null ibuffer-filtering-qualifiers)
 811     (error "No filters in effect"))
 812   (let ((lim (pop ibuffer-filtering-qualifiers)))
 813     (case (car lim)
 814       (or
 815        (setq ibuffer-filtering-qualifiers (append
 816                                           (cdr lim)
 817                                           ibuffer-filtering-qualifiers)))
 818       (saved
 819        (let ((data
 820               (assoc (cdr lim)
 821                      ibuffer-saved-filters)))
 822          (unless data
 823            (ibuffer-filter-disable)
 824            (error "Unknown saved filter %s" (cdr lim)))
 825          (setq ibuffer-filtering-qualifiers (append
 826                                             (cadr data)
 827                                             ibuffer-filtering-qualifiers))))
 828       (not
 829        (push (cdr lim)
 830              ibuffer-filtering-qualifiers))
 831       (t
 832        (error "Filter type %s is not compound" (car lim)))))
 833   (ibuffer-update nil t))
 834
 835 ;;;###autoload
 836 (defun ibuffer-exchange-filters ()
 837   "Exchange the top two filters on the stack in this buffer."
 838   (interactive)
 839   (when (< (length ibuffer-filtering-qualifiers)
 840            2)
 841     (error "Need two filters to exchange"))
 842   (let ((first (pop ibuffer-filtering-qualifiers))
 843         (second (pop ibuffer-filtering-qualifiers)))
 844     (push first ibuffer-filtering-qualifiers)
 845     (push second ibuffer-filtering-qualifiers))
 846   (ibuffer-update nil t))
 847
 848 ;;;###autoload
 849 (defun ibuffer-negate-filter ()
 850   "Negate the sense of the top filter in the current buffer."
 851   (interactive)
 852   (when (null ibuffer-filtering-qualifiers)
 853     (error "No filters in effect"))
 854   (let ((lim (pop ibuffer-filtering-qualifiers)))
 855     (push (if (eq (car lim) 'not)
 856               (cdr lim)
 857             (cons 'not lim))
 858           ibuffer-filtering-qualifiers))
 859   (ibuffer-update nil t))
 860
 861 ;;;###autoload
 862 (defun ibuffer-or-filter (&optional reverse)
 863   "Replace the top two filters in this buffer with their logical OR.
 864 If optional argument REVERSE is non-nil, instead break the top OR
 865 filter into parts."
 866   (interactive "P")
 867   (if reverse
 868       (progn
 869         (when (or (null ibuffer-filtering-qualifiers)
 870                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 871           (error "Top filter is not an OR"))
 872         (let ((lim (pop ibuffer-filtering-qualifiers)))
 873           (setq ibuffer-filtering-qualifiers
 874                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 875     (when (< (length ibuffer-filtering-qualifiers) 2)
 876       (error "Need two filters to OR"))
 877     ;; If the second filter is an OR, just add to it.
 878     (let ((first (pop ibuffer-filtering-qualifiers))
 879           (second (pop ibuffer-filtering-qualifiers)))
 880       (if (eq 'or (car second))
 881           (push (nconc (list 'or first) (cdr second))
 882                 ibuffer-filtering-qualifiers)
 883         (push (list 'or first second)
 884               ibuffer-filtering-qualifiers))))
 885   (ibuffer-update nil t))
 886
 887 (defun ibuffer-maybe-save-stuff ()
 888   (when ibuffer-save-with-custom
 889     (if (fboundp 'customize-save-variable)
 890         (progn
 891           (customize-save-variable 'ibuffer-saved-filters
 892                                    ibuffer-saved-filters)
 893           (customize-save-variable 'ibuffer-saved-filter-groups
 894                                    ibuffer-saved-filter-groups))
 895       (message "Not saved permanently: Customize not available"))))
 896
 897 ;;;###autoload
 898 (defun ibuffer-save-filters (name filters)
 899   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 900 Interactively, prompt for NAME, and use the current filters."
 901   (interactive
 902    (if (null ibuffer-filtering-qualifiers)
 903        (error "No filters currently in effect")
 904      (list
 905       (read-from-minibuffer "Save current filters as: ")
 906       ibuffer-filtering-qualifiers)))
 907   (ibuffer-aif (assoc name ibuffer-saved-filters)
 908       (setcdr it filters)
 909     (push (list name filters) ibuffer-saved-filters))
 910   (ibuffer-maybe-save-stuff))
 911
 912 ;;;###autoload
 913 (defun ibuffer-delete-saved-filters (name)
 914   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 915   (interactive
 916    (list
 917     (if (null ibuffer-saved-filters)
 918         (error "No saved filters")
 919       (completing-read "Delete saved filters: "
 920                        ibuffer-saved-filters nil t))))
 921   (setq ibuffer-saved-filters
 922         (ibuffer-delete-alist name ibuffer-saved-filters))
 923   (ibuffer-maybe-save-stuff)
 924   (ibuffer-update nil t))
 925
 926 ;;;###autoload
 927 (defun ibuffer-add-saved-filters (name)
 928   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 929   (interactive
 930    (list
 931     (if (null ibuffer-saved-filters)
 932         (error "No saved filters")
 933       (completing-read "Add saved filters: "
 934                        ibuffer-saved-filters nil t))))
 935   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 936   (ibuffer-update nil t))
 937
 938 ;;;###autoload
 939 (defun ibuffer-switch-to-saved-filters (name)
 940   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 941   (interactive
 942    (list
 943     (if (null ibuffer-saved-filters)
 944         (error "No saved filters")
 945       (completing-read "Switch to saved filters: "
 946                        ibuffer-saved-filters nil t))))
 947   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 948   (ibuffer-update nil t))
 949
 950 (defun ibuffer-format-filter-group-data (filter)
 951   (if (equal filter "Default")
 952       ""
 953     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 954                                  (cdr (assq filter ibuffer-filter-groups))
 955                                  " "))))
 956
 957 (defun ibuffer-format-qualifier (qualifier)
 958   (if (eq (car-safe qualifier) 'not)
 959       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 960     (ibuffer-format-qualifier-1 qualifier)))
 961
 962 (defun ibuffer-format-qualifier-1 (qualifier)
 963   (case (car qualifier)
 964     (saved
 965      (concat " [filter: " (cdr qualifier) "]"))
 966     (or
 967      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 968                                (cdr qualifier) "") "]"))
 969     (t
 970      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 971        (unless qualifier
 972          (error "Ibuffer: bad qualifier %s" qualifier))
 973        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 974
 975
 976 (defun ibuffer-list-buffer-modes ()
 977   "Create an alist of buffer modes currently in use.
 978 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 979   (let ((bufs (buffer-list))
 980         (modes)
 981         (this-mode))
 982     (while bufs
 983       (setq this-mode (buffer-local-value 'major-mode (car bufs))
 984             bufs (cdr bufs))
 985       (add-to-list
 986        'modes
 987        `(,(symbol-name this-mode) .
 988          ,this-mode)))
 989     modes))
 990
 991
 992 ;;; Extra operation definitions
 993
 994 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 995 (define-ibuffer-filter mode
 996   "Toggle current view to buffers with major mode QUALIFIER."
 997   (:description "major mode"
 998    :reader
 999    (intern
1000     (completing-read "Filter by major mode: " obarray
1001                      #'(lambda (e)
1002                          (string-match "-mode$"
1003                                        (symbol-name e)))
1004                      t
1005                      (let ((buf (ibuffer-current-buffer)))
1006                        (if (and buf (buffer-live-p buf))
1007                            (symbol-name (buffer-local-value 'major-mode buf))
1008                          "")))))
1009   (eq qualifier (buffer-local-value 'major-mode buf)))
1010
1011 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1012 (define-ibuffer-filter used-mode
1013   "Toggle current view to buffers with major mode QUALIFIER.
1014 Called interactively, this function allows selection of modes
1015 currently used by buffers."
1016   (:description "major mode in use"
1017                 :reader
1018                 (intern
1019                  (completing-read "Filter by major mode: "
1020                                   (ibuffer-list-buffer-modes)
1021                                   nil
1022                                   t
1023                                   (let ((buf (ibuffer-current-buffer)))
1024                                     (if (and buf (buffer-live-p buf))
1025                                         (symbol-name (buffer-local-value
1026                                                       'major-mode buf))
1027                                       "")))))
1028   (eq qualifier (buffer-local-value 'major-mode buf)))
1029
1030 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1031 (define-ibuffer-filter name
1032   "Toggle current view to buffers with name matching QUALIFIER."
1033   (:description "buffer name"
1034    :reader (read-from-minibuffer "Filter by name (regexp): "))
1035   (string-match qualifier (buffer-name buf)))
1036
1037 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1038 (define-ibuffer-filter filename
1039   "Toggle current view to buffers with filename matching QUALIFIER."
1040   (:description "filename"
1041    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1042   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1043     (string-match qualifier it)))
1044
1045 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1046 (define-ibuffer-filter size-gt
1047   "Toggle current view to buffers with size greater than QUALIFIER."
1048   (:description "size greater than"
1049    :reader
1050    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1051   (> (with-current-buffer buf (buffer-size))
1052      qualifier))
1053
1054 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1055 (define-ibuffer-filter size-lt
1056    "Toggle current view to buffers with size less than QUALIFIER."
1057   (:description "size less than"
1058    :reader
1059    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1060   (< (with-current-buffer buf (buffer-size))
1061      qualifier))
1062
1063 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1064 (define-ibuffer-filter content
1065    "Toggle current view to buffers whose contents match QUALIFIER."
1066   (:description "content"
1067    :reader (read-from-minibuffer "Filter by content (regexp): "))
1068   (with-current-buffer buf
1069     (save-excursion
1070       (goto-char (point-min))
1071       (re-search-forward qualifier nil t))))
1072
1073 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1074 (define-ibuffer-filter predicate
1075    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1076   (:description "predicate"
1077    :reader (read-minibuffer "Filter by predicate (form): "))
1078   (with-current-buffer buf
1079     (eval qualifier)))
1080
1081 ;;; Sorting
1082
1083 ;;;###autoload
1084 (defun ibuffer-toggle-sorting-mode ()
1085   "Toggle the current sorting mode.
1086 Default sorting modes are:
1087  Recency - the last time the buffer was viewed
1088  Name - the name of the buffer
1089  Major Mode - the name of the major mode of the buffer
1090  Size - the size of the buffer"
1091   (interactive)
1092   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1093     (add-to-list 'modes 'recency)
1094     (setq modes (sort modes 'string-lessp))
1095     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1096                     (car modes))))
1097       (setq ibuffer-sorting-mode next)
1098       (message "Sorting by %s" next)))
1099   (ibuffer-redisplay t))
1100
1101 ;;;###autoload
1102 (defun ibuffer-invert-sorting ()
1103   "Toggle whether or not sorting is in reverse order."
1104   (interactive)
1105   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1106   (message "Sorting order %s"
1107            (if ibuffer-sorting-reversep
1108                "reversed"
1109              "normal"))
1110   (ibuffer-redisplay t))
1111
1112 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1113 (define-ibuffer-sorter major-mode
1114   "Sort the buffers by major modes.
1115 Ordering is lexicographic."
1116   (:description "major mode")
1117   (string-lessp (downcase
1118                  (symbol-name (buffer-local-value 'major-mode (car a))))
1119                 (downcase
1120                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1121
1122 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1123 (define-ibuffer-sorter mode-name
1124   "Sort the buffers by their mode name.
1125 Ordering is lexicographic."
1126   (:description "major mode name")
1127   (string-lessp (downcase
1128                  (with-current-buffer
1129                      (car a)
1130                    (format-mode-line mode-name)))
1131                 (downcase
1132                  (with-current-buffer
1133                      (car b)
1134                    (format-mode-line mode-name)))))
1135
1136 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1137 (define-ibuffer-sorter alphabetic
1138   "Sort the buffers by their names.
1139 Ordering is lexicographic."
1140   (:description "buffer name")
1141   (string-lessp
1142    (buffer-name (car a))
1143    (buffer-name (car b))))
1144
1145 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1146 (define-ibuffer-sorter size
1147  "Sort the buffers by their size."
1148   (:description "size")
1149   (< (with-current-buffer (car a)
1150        (buffer-size))
1151      (with-current-buffer (car b)
1152        (buffer-size))))
1153
1154 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1155 (define-ibuffer-sorter filename/process
1156  "Sort the buffers by their file name/process name."
1157   (:description "file name")
1158   (string-lessp
1159    ;; FIXME: For now just compare the file name and the process name
1160    ;; (if it exists).  Is there a better way to do this?
1161    (or (buffer-file-name (car a))
1162        (let ((pr-a (get-buffer-process (car a))))
1163          (and (processp pr-a) (process-name pr-a))))
1164    (or (buffer-file-name (car b))
1165        (let ((pr-b (get-buffer-process (car b))))
1166          (and (processp pr-b) (process-name pr-b))))))
1167
1168 ;;; Functions to emulate bs.el
1169
1170 ;;;###autoload
1171 (defun ibuffer-bs-show ()
1172   "Emulate `bs-show' from the bs.el package."
1173   (interactive)
1174   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1175   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1176
1177 (defun ibuffer-bs-toggle-all ()
1178   "Emulate `bs-toggle-show-all' from the bs.el package."
1179   (interactive)
1180   (if ibuffer-filtering-qualifiers
1181       (ibuffer-pop-filter)
1182     (progn (ibuffer-push-filter '(filename . ".*"))
1183            (ibuffer-update nil t))))
1184
1185 ;;; Handy functions
1186
1187 ;;;###autoload
1188 (defun ibuffer-add-to-tmp-hide (regexp)
1189   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1190 This means that buffers whose name matches REGEXP will not be shown
1191 for this Ibuffer session."
1192   (interactive
1193    (list
1194     (read-from-minibuffer "Never show buffers matching: "
1195                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1196   (push regexp ibuffer-tmp-hide-regexps))
1197
1198 ;;;###autoload
1199 (defun ibuffer-add-to-tmp-show (regexp)
1200   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1201 This means that buffers whose name matches REGEXP will always be shown
1202 for this Ibuffer session."
1203   (interactive
1204    (list
1205     (read-from-minibuffer "Always show buffers matching: "
1206                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1207   (push regexp ibuffer-tmp-show-regexps))
1208
1209 ;;;###autoload
1210 (defun ibuffer-forward-next-marked (&optional count mark direction)
1211   "Move forward by COUNT marked buffers (default 1).
1212
1213 If MARK is non-nil, it should be a character denoting the type of mark
1214 to move by.  The default is `ibuffer-marked-char'.
1215
1216 If DIRECTION is non-nil, it should be an integer; negative integers
1217 mean move backwards, non-negative integers mean move forwards."
1218   (interactive "P")
1219   (unless count
1220     (setq count 1))
1221   (unless mark
1222     (setq mark ibuffer-marked-char))
1223   (unless direction
1224     (setq direction 1))
1225   ;; Skip the title
1226   (ibuffer-forward-line 0)
1227   (let ((opos (point)))
1228     (ibuffer-forward-line direction)
1229     (while (not (or (= (point) opos)
1230                     (eq (ibuffer-current-mark) mark)))
1231       (ibuffer-forward-line direction))
1232     (when (and (= (point) opos)
1233                (not (eq (ibuffer-current-mark) mark)))
1234       (error "No buffers with mark %c" mark))))
1235
1236 ;;;###autoload
1237 (defun ibuffer-backwards-next-marked (&optional count mark)
1238    "Move backwards by COUNT marked buffers (default 1).
1239
1240 If MARK is non-nil, it should be a character denoting the type of mark
1241 to move by.  The default is `ibuffer-marked-char'."
1242    (interactive "P")
1243    (ibuffer-forward-next-marked count mark -1))
1244
1245 ;;;###autoload
1246 (defun ibuffer-do-kill-lines ()
1247   "Hide all of the currently marked lines."
1248   (interactive)
1249   (if (= (ibuffer-count-marked-lines) 0)
1250       (message "No buffers marked; use 'm' to mark a buffer")
1251     (let ((count
1252            (ibuffer-map-marked-lines
1253             #'(lambda (_buf _mark)
1254                 'kill))))
1255       (message "Killed %s lines" count))))
1256
1257 ;;;###autoload
1258 (defun ibuffer-jump-to-buffer (name)
1259   "Move point to the buffer whose name is NAME.
1260
1261 If called interactively, prompt for a buffer name and go to the
1262 corresponding line in the Ibuffer buffer.  If said buffer is in a
1263 hidden group filter, open it.
1264
1265 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1266 visible buffers in the completion list.  Calling the command with
1267 a prefix argument reverses the meaning of that variable."
1268   (interactive (list
1269                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1270                   (when current-prefix-arg
1271                     (setq only-visible (not only-visible)))
1272                   (if only-visible
1273                       (let ((table (mapcar #'(lambda (x)
1274                                                (buffer-name (car x)))
1275                                            (ibuffer-current-state-list))))
1276                         (when (null table)
1277                           (error "No buffers!"))
1278                         (completing-read "Jump to buffer: "
1279                                          table nil t))
1280                     (read-buffer "Jump to buffer: " nil t)))))
1281   (when (not (string= "" name))
1282     (let (buf-point)
1283       ;; Blindly search for our buffer: it is very likely that it is
1284       ;; not in a hidden filter group.
1285       (ibuffer-map-lines #'(lambda (buf _marks)
1286                              (when (string= (buffer-name buf) name)
1287                                (setq buf-point (point))
1288                                nil))
1289                          t nil)
1290       (when (and
1291              (null buf-point)
1292              (not (null ibuffer-hidden-filter-groups)))
1293         ;; We did not find our buffer.  It must be in a hidden filter
1294         ;; group, so go through all hidden filter groups to find it.
1295         (catch 'found
1296           (dolist (group ibuffer-hidden-filter-groups)
1297             (ibuffer-jump-to-filter-group group)
1298             (ibuffer-toggle-filter-group)
1299             (ibuffer-map-lines #'(lambda (buf _marks)
1300                                    (when (string= (buffer-name buf) name)
1301                                      (setq buf-point (point))
1302                                      nil))
1303                                t group)
1304             (if buf-point
1305                 (throw 'found nil)
1306               (ibuffer-toggle-filter-group)))))
1307       (if (null buf-point)
1308           ;; Still not found even though we expanded all hidden filter
1309           ;; groups: that must be because it's hidden by predicate:
1310           ;; we won't bother trying to display it.
1311           (error "No buffer with name %s" name)
1312         (goto-char buf-point)))))
1313
1314 (declare-function diff-sentinel "diff"
1315                   (code &optional old-temp-file new-temp-file))
1316
1317 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1318   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1319         (tempfile (make-temp-file "buffer-content-")))
1320     (when bufferfile
1321       (unwind-protect
1322           (progn
1323             (with-current-buffer buffer
1324               (write-region nil nil tempfile nil 'nomessage))
1325             (let* ((old (expand-file-name bufferfile))
1326                    (new (expand-file-name tempfile))
1327                    (oldtmp (file-local-copy old))
1328                    (newtmp (file-local-copy new))
1329                    (switches diff-switches)
1330                    (command
1331                     (mapconcat
1332                      'identity
1333                      `(,diff-command
1334                        ;; Use explicitly specified switches
1335                        ,@(if (listp switches) switches (list switches))
1336                        ,@(if (or old new)
1337                              (list "-L" (shell-quote-argument old)
1338                                    "-L" (shell-quote-argument
1339                                          (format "Buffer %s" (buffer-name buffer)))))
1340                        ,(shell-quote-argument (or oldtmp old))
1341                        ,(shell-quote-argument (or newtmp new)))
1342                      " ")))
1343               (let ((inhibit-read-only t))
1344                 (insert command "\n")
1345                 (diff-sentinel
1346                  (call-process shell-file-name nil
1347                                (current-buffer) nil
1348                                shell-command-switch command)))
1349               (insert "\n"))))
1350       (sit-for 0)
1351       (when (file-exists-p tempfile)
1352         (delete-file tempfile)))))
1353
1354 ;;;###autoload
1355 (defun ibuffer-diff-with-file ()
1356   "View the differences between marked buffers and their associated files.
1357 If no buffers are marked, use buffer at point.
1358 This requires the external program \"diff\" to be in your `exec-path'."
1359   (interactive)
1360   (require 'diff)
1361   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1362     (when (null marked-bufs)
1363       (setq marked-bufs (list (ibuffer-current-buffer t))))
1364     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1365       (setq buffer-read-only nil)
1366       (buffer-disable-undo (current-buffer))
1367       (erase-buffer)
1368       (buffer-enable-undo (current-buffer))
1369       (diff-mode)
1370       (dolist (buf marked-bufs)
1371         (unless (buffer-live-p buf)
1372           (error "Buffer %s has been killed" buf))
1373         (ibuffer-diff-buffer-with-file-1 buf))
1374       (setq buffer-read-only t)))
1375   (switch-to-buffer "*Ibuffer Diff*"))
1376
1377 ;;;###autoload
1378 (defun ibuffer-copy-filename-as-kill (&optional arg)
1379   "Copy filenames of marked buffers into the kill ring.
1380
1381 The names are separated by a space.
1382 If a buffer has no filename, it is ignored.
1383
1384 With no prefix arg, use the filename sans its directory of each marked file.
1385 With a zero prefix arg, use the complete filename of each marked file.
1386 With \\[universal-argument], use the filename of each marked file relative
1387 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1388
1389 You can then feed the file name(s) to other commands with \\[yank]."
1390   (interactive "p")
1391   (if (zerop (ibuffer-count-marked-lines))
1392       (message "No buffers marked; use 'm' to mark a buffer")
1393     (let ((ibuffer-copy-filename-as-kill-result "")
1394           (type (cond ((zerop arg)
1395                        'full)
1396                       ((= arg 4)
1397                        'relative)
1398                       (t
1399                        'name))))
1400       (ibuffer-map-marked-lines
1401        #'(lambda (buf _mark)
1402            (setq ibuffer-copy-filename-as-kill-result
1403                  (concat ibuffer-copy-filename-as-kill-result
1404                          (let ((name (buffer-file-name buf)))
1405                            (if name
1406                                (case type
1407                                  (full
1408                                   name)
1409                                  (relative
1410                                   (file-relative-name
1411                                    name (or ibuffer-default-directory
1412                                             default-directory)))
1413                                  (t
1414                                   (file-name-nondirectory name)))
1415                              ""))
1416                          " "))))
1417       (kill-new ibuffer-copy-filename-as-kill-result))))
1418
1419 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1420   (let ((count
1421          (ibuffer-map-lines
1422           #'(lambda (buf _mark)
1423               (when (funcall func buf)
1424                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1425                                         ibuffer-marked-char))
1426                 t))
1427           nil
1428           group)))
1429     (ibuffer-redisplay t)
1430     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1431       (message "Marked %s buffers" count))))
1432
1433 ;;;###autoload
1434 (defun ibuffer-mark-by-name-regexp (regexp)
1435   "Mark all buffers whose name matches REGEXP."
1436   (interactive "sMark by name (regexp): ")
1437   (ibuffer-mark-on-buffer
1438    #'(lambda (buf)
1439        (string-match regexp (buffer-name buf)))))
1440
1441 ;;;###autoload
1442 (defun ibuffer-mark-by-mode-regexp (regexp)
1443   "Mark all buffers whose major mode matches REGEXP."
1444   (interactive "sMark by major mode (regexp): ")
1445   (ibuffer-mark-on-buffer
1446    #'(lambda (buf)
1447        (with-current-buffer buf
1448          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1449
1450 ;;;###autoload
1451 (defun ibuffer-mark-by-file-name-regexp (regexp)
1452   "Mark all buffers whose file name matches REGEXP."
1453   (interactive "sMark by file name (regexp): ")
1454   (ibuffer-mark-on-buffer
1455    #'(lambda (buf)
1456        (let ((name (or (buffer-file-name buf)
1457                        (with-current-buffer buf
1458                          (and
1459                           (boundp 'dired-directory)
1460                           (stringp dired-directory)
1461                           dired-directory)))))
1462          (when name
1463            (string-match regexp name))))))
1464
1465 ;;;###autoload
1466 (defun ibuffer-mark-by-mode (mode)
1467   "Mark all buffers whose major mode equals MODE."
1468   (interactive
1469    (list (intern (completing-read "Mark by major mode: " obarray
1470                                   #'(lambda (e)
1471                                       ;; kind of a hack...
1472                                       (and (fboundp e)
1473                                            (string-match "-mode$"
1474                                                          (symbol-name e))))
1475                                   t
1476                                   (let ((buf (ibuffer-current-buffer)))
1477                                     (if (and buf (buffer-live-p buf))
1478                                         (with-current-buffer buf
1479                                           (cons (symbol-name major-mode)
1480                                                 0))
1481                                       ""))))))
1482   (ibuffer-mark-on-buffer
1483    #'(lambda (buf)
1484        (eq (buffer-local-value 'major-mode buf) mode))))
1485
1486 ;;;###autoload
1487 (defun ibuffer-mark-modified-buffers ()
1488   "Mark all modified buffers."
1489   (interactive)
1490   (ibuffer-mark-on-buffer
1491    #'(lambda (buf) (buffer-modified-p buf))))
1492
1493 ;;;###autoload
1494 (defun ibuffer-mark-unsaved-buffers ()
1495   "Mark all modified buffers that have an associated file."
1496   (interactive)
1497   (ibuffer-mark-on-buffer
1498    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1499                         (buffer-modified-p buf)))))
1500
1501 ;;;###autoload
1502 (defun ibuffer-mark-dissociated-buffers ()
1503   "Mark all buffers whose associated file does not exist."
1504   (interactive)
1505   (ibuffer-mark-on-buffer
1506    #'(lambda (buf)
1507        (with-current-buffer buf
1508          (or
1509           (and buffer-file-name
1510                (not (file-exists-p buffer-file-name)))
1511           (and (eq major-mode 'dired-mode)
1512                (boundp 'dired-directory)
1513                (stringp dired-directory)
1514                (not (file-exists-p (file-name-directory dired-directory)))))))))
1515
1516 ;;;###autoload
1517 (defun ibuffer-mark-help-buffers ()
1518   "Mark buffers like *Help*, *Apropos*, *Info*."
1519   (interactive)
1520   (ibuffer-mark-on-buffer
1521    #'(lambda (buf)
1522        (with-current-buffer buf
1523          (memq major-mode ibuffer-help-buffer-modes)))))
1524
1525 ;;;###autoload
1526 (defun ibuffer-mark-compressed-file-buffers ()
1527   "Mark buffers whose associated file is compressed."
1528   (interactive)
1529   (ibuffer-mark-on-buffer
1530    #'(lambda (buf)
1531        (with-current-buffer buf
1532          (and buffer-file-name
1533               (string-match ibuffer-compressed-file-name-regexp
1534                            buffer-file-name))))))
1535
1536 ;;;###autoload
1537 (defun ibuffer-mark-old-buffers ()
1538   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1539   (interactive)
1540   (ibuffer-mark-on-buffer
1541    #'(lambda (buf)
1542        (with-current-buffer buf
1543          ;; hacked from midnight.el
1544          (when buffer-display-time
1545            (let* ((tm (current-time))
1546                   (now (+ (* (float (ash 1 16)) (car tm))
1547                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1548                   (then (+ (* (float (ash 1 16))
1549                               (car buffer-display-time))
1550                            (float (cadr buffer-display-time))
1551                            (* 0.0000001 (caddr buffer-display-time)))))
1552              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1553
1554 ;;;###autoload
1555 (defun ibuffer-mark-special-buffers ()
1556   "Mark all buffers whose name begins and ends with '*'."
1557   (interactive)
1558   (ibuffer-mark-on-buffer
1559    #'(lambda (buf) (string-match "^\\*.+\\*$"
1560                                  (buffer-name buf)))))
1561
1562 ;;;###autoload
1563 (defun ibuffer-mark-read-only-buffers ()
1564   "Mark all read-only buffers."
1565   (interactive)
1566   (ibuffer-mark-on-buffer
1567    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1568
1569 ;;;###autoload
1570 (defun ibuffer-mark-dired-buffers ()
1571   "Mark all `dired' buffers."
1572   (interactive)
1573   (ibuffer-mark-on-buffer
1574    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1575
1576 ;;;###autoload
1577 (defun ibuffer-do-occur (regexp &optional nlines)
1578   "View lines which match REGEXP in all marked buffers.
1579 Optional argument NLINES says how many lines of context to display: it
1580 defaults to one."
1581   (interactive (occur-read-primary-args))
1582   (if (or (not (integerp nlines))
1583           (< nlines 0))
1584       (setq nlines 0))
1585   (when (zerop (ibuffer-count-marked-lines))
1586     (ibuffer-set-mark ibuffer-marked-char))
1587   (let ((ibuffer-do-occur-bufs nil))
1588     ;; Accumulate a list of marked buffers
1589     (ibuffer-map-marked-lines
1590      #'(lambda (buf _mark)
1591          (push buf ibuffer-do-occur-bufs)))
1592     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1593
1594 (provide 'ibuf-ext)
1595
1596 ;; Local Variables:
1597 ;; generated-autoload-file: "ibuffer.el"
1598 ;; End:
1599
1600 ;;; ibuf-ext.el ends here