lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: mouse, terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Enable mouse support when running inside an xterm.
  29
  30 ;; This is actually useful when you are running X11 locally, but is
  31 ;; working on remote machine over a modem line or through a gateway.
  32
  33 ;; It works by translating xterm escape codes into generic emacs mouse
  34 ;; events so it should work with any package that uses the mouse.
  35
  36 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  37 ;; functionality, it is still available by holding down the SHIFT key
  38 ;; when you press the mouse button.
  39
  40 ;;; Todo:
  41
  42 ;; Support multi-click -- somehow.
  43
  44 ;;; Code:
  45
  46 (defvar xterm-mouse-debug-buffer nil)
  47
  48 ;; XXX Perhaps this should be terminal-local instead. --lorentey
  49 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  50
  51 (defvar xterm-mouse-last)
  52
  53 ;; Mouse events symbols must have an 'event-kind property with
  54 ;; the value 'mouse-click.
  55 (dolist (event-type '(mouse-1 mouse-2 mouse-3
  56                               M-down-mouse-1 M-down-mouse-2 M-down-mouse-3))
  57   (put event-type 'event-kind 'mouse-click))
  58
  59 (defun xterm-mouse-translate (event)
  60   "Read a click and release event from XTerm."
  61   (save-excursion
  62     (save-window-excursion
  63       (deactivate-mark)
  64       (let* ((xterm-mouse-last)
  65              (down (xterm-mouse-event))
  66              (down-command (nth 0 down))
  67              (down-data (nth 1 down))
  68              (down-where (nth 1 down-data))
  69              (down-binding (key-binding (if (symbolp down-where)
  70                                             (vector down-where down-command)
  71                                           (vector down-command))))
  72              (is-click (string-match "^mouse" (symbol-name (car down)))))
  73
  74         (unless is-click
  75           (unless (and (eq (read-char) ?\e)
  76                        (eq (read-char) ?\[)
  77                        (eq (read-char) ?M))
  78             (error "Unexpected escape sequence from XTerm")))
  79
  80         (let* ((click (if is-click down (xterm-mouse-event)))
  81                (click-command (nth 0 click))
  82                (click-data (nth 1 click))
  83                (click-where (nth 1 click-data)))
  84           (if (memq down-binding '(nil ignore))
  85               (if (and (symbolp click-where)
  86                        (consp click-where))
  87                   (vector (list click-where click-data) click)
  88                 (vector click))
  89             (setq unread-command-events
  90                   (if (eq down-where click-where)
  91                       (list click)
  92                     (list
  93                      ;; Cheat `mouse-drag-region' with move event.
  94                      (list 'mouse-movement click-data)
  95                      ;; Generate a drag event.
  96                      (if (symbolp down-where)
  97                          0
  98                        (list (intern (format "drag-mouse-%d"
  99                                              (+ 1 xterm-mouse-last)))
 100                              down-data click-data)))))
 101             (if xterm-mouse-debug-buffer
 102                 (print unread-command-events xterm-mouse-debug-buffer))
 103             (if (and (symbolp down-where)
 104                      (consp down-where))
 105                 (vector (list down-where down-data) down)
 106               (vector down))))))))
 107
 108 ;; These two variables have been converted to terminal parameters.
 109 ;;
 110 ;;(defvar xterm-mouse-x 0
 111 ;;  "Position of last xterm mouse event relative to the frame.")
 112 ;;
 113 ;;(defvar xterm-mouse-y 0
 114 ;;  "Position of last xterm mouse event relative to the frame.")
 115
 116 (defvar xt-mouse-epoch nil)
 117
 118 ;; Indicator for the xterm-mouse mode.
 119
 120 (defun xterm-mouse-position-function (pos)
 121   "Bound to `mouse-position-function' in XTerm mouse mode."
 122   (when (terminal-parameter nil 'xterm-mouse-x)
 123     (setcdr pos (cons (terminal-parameter nil 'xterm-mouse-x)
 124                       (terminal-parameter nil 'xterm-mouse-y))))
 125   pos)
 126
 127 ;; read xterm sequences above ascii 127 (#x7f)
 128 (defun xterm-mouse-event-read ()
 129   (let ((c (read-char)))
 130     (if (< c 0)
 131         (+ c #x8000000 128)
 132       c)))
 133
 134 (defun xterm-mouse-truncate-wrap (f)
 135   "Truncate with wrap-around."
 136   (condition-case nil
 137       ;; First try the built-in truncate, in case there's no overflow.
 138       (truncate f)
 139     ;; In case of overflow, do wraparound by hand.
 140     (range-error
 141      ;; In our case, we wrap around every 3 days or so, so if we assume
 142      ;; a maximum of 65536 wraparounds, we're safe for a couple years.
 143      ;; Using a power of 2 makes rounding errors less likely.
 144      (let* ((maxwrap (* 65536 2048))
 145             (dbig (truncate (/ f maxwrap)))
 146             (fdiff (- f (* 1.0 maxwrap dbig))))
 147        (+ (truncate fdiff) (* maxwrap dbig))))))
 148
 149 (defun xterm-mouse-event ()
 150   "Convert XTerm mouse event to Emacs mouse event."
 151   (let* ((type (- (xterm-mouse-event-read) #o40))
 152          (x (- (xterm-mouse-event-read) #o40 1))
 153          (y (- (xterm-mouse-event-read) #o40 1))
 154          ;; Emulate timestamp information.  This is accurate enough
 155          ;; for default value of mouse-1-click-follows-link (450msec).
 156          (timestamp (xterm-mouse-truncate-wrap
 157                      (* 1000
 158                         (- (float-time)
 159                            (or xt-mouse-epoch
 160                                (setq xt-mouse-epoch (float-time)))))))
 161          (mouse (intern
 162                  ;; For buttons > 3, the release-event looks
 163                  ;; differently (see xc/programs/xterm/button.c,
 164                  ;; function EditorButton), and there seems to come in
 165                  ;; a release-event only, no down-event.
 166                  (cond ((>= type 64)
 167                         (format "mouse-%d" (- type 60)))
 168                        ((memq type '(8 9 10))
 169                         (setq xterm-mouse-last type)
 170                         (format "M-down-mouse-%d" (- type 7)))
 171                        ((= type 11)
 172                         (format "mouse-%d" (- xterm-mouse-last 7)))
 173                        ((= type 3)
 174                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 175                        (t
 176                         (setq xterm-mouse-last type)
 177                         (format "down-mouse-%d" (+ 1 type))))))
 178          (w (window-at x y))
 179          (ltrb (window-edges w))
 180          (left (nth 0 ltrb))
 181          (top (nth 1 ltrb)))
 182
 183     (set-terminal-parameter nil 'xterm-mouse-x x)
 184     (set-terminal-parameter nil 'xterm-mouse-y y)
 185     (setq
 186      last-input-event
 187      (list mouse
 188            (let ((event (if w
 189                             (posn-at-x-y (- x left) (- y top) w t)
 190                           (append (list nil 'menu-bar)
 191                                   (nthcdr 2 (posn-at-x-y x y))))))
 192              (setcar (nthcdr 3 event) timestamp)
 193              event)))))
 194
 195 ;;;###autoload
 196 (define-minor-mode xterm-mouse-mode
 197   "Toggle XTerm mouse mode.
 198 With prefix arg, turn XTerm mouse mode on if arg is positive, otherwise turn
 199 it off.
 200
 201 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 202 This works in terminal emulators compatible with xterm.  It only
 203 works for simple uses of the mouse.  Basically, only non-modified
 204 single clicks are supported.  When turned on, the normal xterm
 205 mouse functionality for such clicks is still available by holding
 206 down the SHIFT key while pressing the mouse button."
 207   :global t :group 'mouse
 208   (if xterm-mouse-mode
 209       ;; Turn it on
 210       (progn
 211         ;; Frame creation and deletion.
 212         (add-hook 'after-make-frame-functions
 213                   'turn-on-xterm-mouse-tracking-on-terminal)
 214         (add-hook 'delete-frame-functions 'xterm-mouse-handle-delete-frame)
 215
 216         ;; Restore normal mouse behaviour outside Emacs.
 217         (add-hook 'suspend-tty-functions
 218                   'turn-off-xterm-mouse-tracking-on-terminal)
 219         (add-hook 'resume-tty-functions
 220                   'turn-on-xterm-mouse-tracking-on-terminal)
 221         (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 222         (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 223         (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 224         (setq mouse-position-function #'xterm-mouse-position-function)
 225         (turn-on-xterm-mouse-tracking))
 226     ;; Turn it off
 227     (remove-hook 'after-make-frame-functions
 228                  'turn-on-xterm-mouse-tracking-on-terminal)
 229     (remove-hook 'delete-frame-functions 'xterm-mouse-handle-delete-frame)
 230     (remove-hook 'suspend-tty-functions
 231                  'turn-off-xterm-mouse-tracking-on-terminal)
 232     (remove-hook 'resume-tty-functions
 233                  'turn-on-xterm-mouse-tracking-on-terminal)
 234     (remove-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 235     (remove-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 236     (remove-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 237     (turn-off-xterm-mouse-tracking 'force)
 238     (setq mouse-position-function nil)))
 239
 240 (defun turn-on-xterm-mouse-tracking ()
 241   "Enable Emacs mouse tracking in xterm."
 242   (dolist (f (frame-list))
 243     (when (eq t (frame-live-p f))
 244       (with-selected-frame f
 245         (when xterm-mouse-mode
 246           (send-string-to-terminal "\e[?1000h"))))))
 247
 248 (defun turn-off-xterm-mouse-tracking (&optional force)
 249   "Disable Emacs mouse tracking in xterm."
 250   (dolist (f (frame-list))
 251     (when (eq t (frame-live-p f))
 252       (with-selected-frame f
 253         (when (or force xterm-mouse-mode)
 254           (send-string-to-terminal "\e[?1000l"))))))
 255
 256 (defun turn-on-xterm-mouse-tracking-on-terminal (terminal)
 257   "Enable xterm mouse tracking on TERMINAL."
 258   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal)))
 259     (send-string-to-terminal "\e[?1000h" terminal)))
 260
 261 (defun turn-off-xterm-mouse-tracking-on-terminal (terminal)
 262   "Disable xterm mouse tracking on TERMINAL."
 263   (when (and xterm-mouse-mode (eq t (terminal-live-p terminal)))
 264     (send-string-to-terminal "\e[?1000l" terminal)))
 265
 266 (defun xterm-mouse-handle-delete-frame (frame)
 267   "Turn off xterm mouse tracking if FRAME is the last frame on its device."
 268   (when (and (eq t (frame-live-p frame))
 269              (<= 1 (length (frames-on-display-list (frame-terminal frame)))))
 270     (turn-off-xterm-mouse-tracking-on-terminal frame)))
 271
 272 (provide 'xt-mouse)
 273
 274 ;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 275 ;;; xt-mouse.el ends here