lisp/add-log.el

   1 ;;; add-log.el --- change log maintenance commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1988, 1993, 1994, 1997, 1998, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This facility is documented in the Emacs Manual.
  29
  30 ;; Todo:
  31
  32 ;; - Find/use/create _MTN/log if there's a _MTN directory.
  33 ;; - Find/use/create ++log.* if there's an {arch} directory.
  34 ;; - Use an open *VC-Log* or *cvs-commit* buffer if it's related to the
  35 ;;   source file.
  36 ;; - Don't add TAB indents (and username?) if inserting entries in those
  37 ;;   special places.
  38
  39 ;;; Code:
  40
  41 (eval-when-compile
  42   (require 'timezone))
  43
  44 (defgroup change-log nil
  45   "Change log maintenance."
  46   :group 'tools
  47   :link '(custom-manual "(emacs)Change Log")
  48   :prefix "change-log-"
  49   :prefix "add-log-")
  50
  51
  52 (defcustom change-log-default-name nil
  53   "Name of a change log file for \\[add-change-log-entry]."
  54   :type '(choice (const :tag "default" nil)
  55                  string)
  56   :group 'change-log)
  57 (put 'change-log-default-name 'safe-local-variable 'string-or-null-p)
  58
  59 (defcustom change-log-mode-hook nil
  60   "Normal hook run by `change-log-mode'."
  61   :type 'hook
  62   :group 'change-log)
  63
  64 ;; Many modes set this variable, so avoid warnings.
  65 ;;;###autoload
  66 (defcustom add-log-current-defun-function nil
  67   "If non-nil, function to guess name of surrounding function.
  68 It is used by `add-log-current-defun' in preference to built-in rules.
  69 Returns function's name as a string, or nil if outside a function."
  70   :type '(choice (const nil) function)
  71   :group 'change-log)
  72
  73 ;;;###autoload
  74 (defcustom add-log-full-name nil
  75   "Full name of user, for inclusion in ChangeLog daily headers.
  76 This defaults to the value returned by the function `user-full-name'."
  77   :type '(choice (const :tag "Default" nil)
  78                  string)
  79   :group 'change-log)
  80
  81 ;;;###autoload
  82 (defcustom add-log-mailing-address nil
  83   "Email addresses of user, for inclusion in ChangeLog headers.
  84 This defaults to the value of `user-mail-address'.  In addition to
  85 being a simple string, this value can also be a list.  All elements
  86 will be recognized as referring to the same user; when creating a new
  87 ChangeLog entry, one element will be chosen at random."
  88   :type '(choice (const :tag "Default" nil)
  89                  (string :tag "String")
  90                  (repeat :tag "List of Strings" string))
  91   :group 'change-log)
  92
  93 (defcustom add-log-time-format 'add-log-iso8601-time-string
  94   "Function that defines the time format.
  95 For example, `add-log-iso8601-time-string', which gives the
  96 date in international ISO 8601 format,
  97 and `current-time-string' are two valid values."
  98   :type '(radio (const :tag "International ISO 8601 format"
  99                        add-log-iso8601-time-string)
 100                 (const :tag "Old format, as returned by `current-time-string'"
 101                        current-time-string)
 102                 (function :tag "Other"))
 103   :group 'change-log)
 104
 105 (defcustom add-log-keep-changes-together nil
 106   "If non-nil, normally keep day's log entries for one file together.
 107
 108 Log entries for a given file made with \\[add-change-log-entry] or
 109 \\[add-change-log-entry-other-window] will only be added to others \
 110 for that file made
 111 today if this variable is non-nil or that file comes first in today's
 112 entries.  Otherwise another entry for that file will be started.  An
 113 original log:
 114
 115         * foo (...): ...
 116         * bar (...): change 1
 117
 118 in the latter case, \\[add-change-log-entry-other-window] in a \
 119 buffer visiting `bar', yields:
 120
 121         * bar (...): -!-
 122         * foo (...): ...
 123         * bar (...): change 1
 124
 125 and in the former:
 126
 127         * foo (...): ...
 128         * bar (...): change 1
 129         (...): -!-
 130
 131 The NEW-ENTRY arg to `add-change-log-entry' can override the effect of
 132 this variable."
 133   :version "20.3"
 134   :type 'boolean
 135   :group 'change-log)
 136
 137 (defcustom add-log-always-start-new-record nil
 138   "If non-nil, `add-change-log-entry' will always start a new record."
 139   :version "22.1"
 140   :type 'boolean
 141   :group 'change-log)
 142
 143 (defcustom add-log-buffer-file-name-function nil
 144   "If non-nil, function to call to identify the full filename of a buffer.
 145 This function is called with no argument.  If this is nil, the default is to
 146 use `buffer-file-name'."
 147   :type '(choice (const nil) function)
 148   :group 'change-log)
 149
 150 (defcustom add-log-file-name-function nil
 151   "If non-nil, function to call to identify the filename for a ChangeLog entry.
 152 This function is called with one argument, the value of variable
 153 `buffer-file-name' in that buffer.  If this is nil, the default is to
 154 use the file's name relative to the directory of the change log file."
 155   :type '(choice (const nil) function)
 156   :group 'change-log)
 157
 158
 159 (defcustom change-log-version-info-enabled nil
 160   "If non-nil, enable recording version numbers with the changes."
 161   :version "21.1"
 162   :type 'boolean
 163   :group 'change-log)
 164
 165 (defcustom change-log-version-number-regexp-list
 166   (let ((re    "\\([0-9]+\.[0-9.]+\\)"))
 167     (list
 168      ;;  (defconst ad-version "2.15"
 169      (concat "^(def[^ \t\n]+[ \t]+[^ \t\n][ \t]\"" re)
 170      ;; Revision: pcl-cvs.el,v 1.72 1999/09/05 20:21:54 monnier Exp
 171      (concat "^;+ *Revision: +[^ \t\n]+[ \t]+" re)))
 172   "List of regexps to search for version number.
 173 The version number must be in group 1.
 174 Note: The search is conducted only within 10%, at the beginning of the file."
 175   :version "21.1"
 176   :type '(repeat regexp)
 177   :group 'change-log)
 178
 179 (defface change-log-date
 180   '((t (:inherit font-lock-string-face)))
 181   "Face used to highlight dates in date lines."
 182   :version "21.1"
 183   :group 'change-log)
 184 ;; backward-compatibility alias
 185 (put 'change-log-date-face 'face-alias 'change-log-date)
 186
 187 (defface change-log-name
 188   '((t (:inherit font-lock-constant-face)))
 189   "Face for highlighting author names."
 190   :version "21.1"
 191   :group 'change-log)
 192 ;; backward-compatibility alias
 193 (put 'change-log-name-face 'face-alias 'change-log-name)
 194
 195 (defface change-log-email
 196   '((t (:inherit font-lock-variable-name-face)))
 197   "Face for highlighting author email addresses."
 198   :version "21.1"
 199   :group 'change-log)
 200 ;; backward-compatibility alias
 201 (put 'change-log-email-face 'face-alias 'change-log-email)
 202
 203 (defface change-log-file
 204   '((t (:inherit font-lock-function-name-face)))
 205   "Face for highlighting file names."
 206   :version "21.1"
 207   :group 'change-log)
 208 ;; backward-compatibility alias
 209 (put 'change-log-file-face 'face-alias 'change-log-file)
 210
 211 (defface change-log-list
 212   '((t (:inherit font-lock-keyword-face)))
 213   "Face for highlighting parenthesized lists of functions or variables."
 214   :version "21.1"
 215   :group 'change-log)
 216 ;; backward-compatibility alias
 217 (put 'change-log-list-face 'face-alias 'change-log-list)
 218
 219 (defface change-log-conditionals
 220   '((t (:inherit font-lock-variable-name-face)))
 221   "Face for highlighting conditionals of the form `[...]'."
 222   :version "21.1"
 223   :group 'change-log)
 224 ;; backward-compatibility alias
 225 (put 'change-log-conditionals-face 'face-alias 'change-log-conditionals)
 226
 227 (defface change-log-function
 228   '((t (:inherit font-lock-variable-name-face)))
 229   "Face for highlighting items of the form `<....>'."
 230   :version "21.1"
 231   :group 'change-log)
 232 ;; backward-compatibility alias
 233 (put 'change-log-function-face 'face-alias 'change-log-function)
 234
 235 (defface change-log-acknowledgement
 236   '((t (:inherit font-lock-comment-face)))
 237   "Face for highlighting acknowledgments."
 238   :version "21.1"
 239   :group 'change-log)
 240 ;; backward-compatibility alias
 241 (put 'change-log-acknowledgement-face 'face-alias 'change-log-acknowledgement)
 242
 243 (defvar change-log-font-lock-keywords
 244   '(;;
 245     ;; Date lines, new (2000-01-01) and old (Sat Jan  1 00:00:00 2000) styles.
 246     ;; Fixme: this regepx is just an approximate one and may match
 247     ;; wrongly with a non-date line existing as a random note.  In
 248     ;; addition, using any kind of fixed setting like this doesn't
 249     ;; work if a user customizes add-log-time-format.
 250     ("^[0-9-]+ +\\|^\\(Sun\\|Mon\\|Tue\\|Wed\\|Thu\\|Fri\\|Sat\\) [A-z][a-z][a-z] [0-9:+ ]+"
 251      (0 'change-log-date-face)
 252      ;; Name and e-mail; some people put e-mail in parens, not angles.
 253      ("\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]" nil nil
 254       (1 'change-log-name)
 255       (2 'change-log-email)))
 256     ;;
 257     ;; File names.
 258     ("^\\( +\\|\t\\)\\* \\([^ ,:([\n]+\\)"
 259      (2 'change-log-file)
 260      ;; Possibly further names in a list:
 261      ("\\=, \\([^ ,:([\n]+\\)" nil nil (1 'change-log-file))
 262      ;; Possibly a parenthesized list of names:
 263      ("\\= (\\([^(),\n]+\\|(\\(setf\\|SETF\\) [^() ,\n]+)\\)"
 264       nil nil (1 'change-log-list))
 265      ("\\=, *\\([^(),\n]+\\|(\\(setf\\|SETF\\) [^() ,\n]+)\\)"
 266       nil nil (1 'change-log-list)))
 267     ;;
 268     ;; Function or variable names.
 269     ("^\\( +\\|\t\\)(\\([^(),\n]+\\|(\\(setf\\|SETF\\) [^() ,\n]+)\\)"
 270      (2 'change-log-list)
 271      ("\\=, *\\([^(),\n]+\\|(\\(setf\\|SETF\\) [^() ,\n]+)\\)" nil nil
 272       (1 'change-log-list)))
 273     ;;
 274     ;; Conditionals.
 275     ("\\[!?\\([^]\n]+\\)\\]\\(:\\| (\\)" (1 'change-log-conditionals))
 276     ;;
 277     ;; Function of change.
 278     ("<\\([^>\n]+\\)>\\(:\\| (\\)" (1 'change-log-function))
 279     ;;
 280     ;; Acknowledgements.
 281     ;; Don't include plain "From" because that is vague;
 282     ;; we want to encourage people to say something more specific.
 283     ;; Note that the FSF does not use "Patches by"; our convention
 284     ;; is to put the name of the author of the changes at the top
 285     ;; of the change log entry.
 286     ("\\(^\\( +\\|\t\\)\\|  \\)\\(Patch\\(es\\)? by\\|Report\\(ed by\\| from\\)\\|Suggest\\(ed by\\|ion from\\)\\)"
 287      3 'change-log-acknowledgement))
 288   "Additional expressions to highlight in Change Log mode.")
 289
 290 (defvar change-log-mode-map
 291   (let ((map (make-sparse-keymap)))
 292     (define-key map [?\C-c ?\C-p] 'add-log-edit-prev-comment)
 293     (define-key map [?\C-c ?\C-n] 'add-log-edit-next-comment)
 294     map)
 295   "Keymap for Change Log major mode.")
 296
 297 ;; It used to be called change-log-time-zone-rule but really should be
 298 ;; called add-log-time-zone-rule since it's only used from add-log-* code.
 299 (defvaralias 'change-log-time-zone-rule 'add-log-time-zone-rule)
 300 (defvar add-log-time-zone-rule nil
 301   "Time zone used for calculating change log time stamps.
 302 It takes the same format as the TZ argument of `set-time-zone-rule'.
 303 If nil, use local time.
 304 If t, use universal time.")
 305 (put 'add-log-time-zone-rule 'safe-local-variable
 306      '(lambda (x) (or (booleanp x) (stringp x))))
 307
 308 (defun add-log-iso8601-time-zone (&optional time)
 309   (let* ((utc-offset (or (car (current-time-zone time)) 0))
 310          (sign (if (< utc-offset 0) ?- ?+))
 311          (sec (abs utc-offset))
 312          (ss (% sec 60))
 313          (min (/ sec 60))
 314          (mm (% min 60))
 315          (hh (/ min 60)))
 316     (format (cond ((not (zerop ss)) "%c%02d:%02d:%02d")
 317                   ((not (zerop mm)) "%c%02d:%02d")
 318                   (t "%c%02d"))
 319             sign hh mm ss)))
 320
 321 (defvar add-log-iso8601-with-time-zone nil)
 322
 323 (defun add-log-iso8601-time-string ()
 324   (let ((time (format-time-string "%Y-%m-%d"
 325                                   nil (eq t add-log-time-zone-rule))))
 326     (if add-log-iso8601-with-time-zone
 327         (concat time " " (add-log-iso8601-time-zone))
 328       time)))
 329
 330 (defun change-log-name ()
 331   "Return (system-dependent) default name for a change log file."
 332   (or change-log-default-name
 333       (if (eq system-type 'vax-vms)
 334           "$CHANGE_LOG$.TXT"
 335         "ChangeLog")))
 336
 337 (defun add-log-edit-prev-comment (arg)
 338   "Cycle backward through Log-Edit mode comment history.
 339 With a numeric prefix ARG, go back ARG comments."
 340   (interactive "*p")
 341   (save-restriction
 342     (narrow-to-region (point)
 343                       (if (memq last-command '(add-log-edit-prev-comment
 344                                                add-log-edit-next-comment))
 345                           (mark) (point)))
 346     (when (fboundp 'log-edit-previous-comment)
 347       (log-edit-previous-comment arg)
 348       (indent-region (point-min) (point-max))
 349       (goto-char (point-min))
 350       (unless (save-restriction (widen) (bolp))
 351         (delete-region (point) (progn (skip-chars-forward " \t\n") (point))))
 352       (set-mark (point-min))
 353       (goto-char (point-max))
 354       (delete-region (point) (progn (skip-chars-backward " \t\n") (point))))))
 355
 356 (defun add-log-edit-next-comment (arg)
 357   "Cycle forward through Log-Edit mode comment history.
 358 With a numeric prefix ARG, go back ARG comments."
 359   (interactive "*p")
 360   (add-log-edit-prev-comment (- arg)))
 361
 362 ;;;###autoload
 363 (defun prompt-for-change-log-name ()
 364   "Prompt for a change log name."
 365   (let* ((default (change-log-name))
 366          (name (expand-file-name
 367                 (read-file-name (format "Log file (default %s): " default)
 368                                 nil default))))
 369     ;; Handle something that is syntactically a directory name.
 370     ;; Look for ChangeLog or whatever in that directory.
 371     (if (string= (file-name-nondirectory name) "")
 372         (expand-file-name (file-name-nondirectory default)
 373                           name)
 374       ;; Handle specifying a file that is a directory.
 375       (if (file-directory-p name)
 376           (expand-file-name (file-name-nondirectory default)
 377                             (file-name-as-directory name))
 378         name))))
 379
 380 (defun change-log-version-number-search ()
 381   "Return version number of current buffer's file.
 382 This is the value returned by `vc-workfile-version' or, if that is
 383 nil, by matching `change-log-version-number-regexp-list'."
 384   (let* ((size (buffer-size))
 385          (limit
 386           ;; The version number can be anywhere in the file, but
 387           ;; restrict search to the file beginning: 10% should be
 388           ;; enough to prevent some mishits.
 389           ;;
 390           ;; Apply percentage only if buffer size is bigger than
 391           ;; approx 100 lines.
 392           (if (> size (* 100 80)) (+ (point) (/ size 10)))))
 393     (or (and buffer-file-name (vc-workfile-version buffer-file-name))
 394         (save-restriction
 395           (widen)
 396           (let ((regexps change-log-version-number-regexp-list)
 397                 version)
 398             (while regexps
 399               (save-excursion
 400                 (goto-char (point-min))
 401                 (when (re-search-forward (pop regexps) limit t)
 402                   (setq version (match-string 1)
 403                         regexps nil))))
 404             version)))))
 405
 406
 407 ;;;###autoload
 408 (defun find-change-log (&optional file-name buffer-file)
 409   "Find a change log file for \\[add-change-log-entry] and return the name.
 410
 411 Optional arg FILE-NAME specifies the file to use.
 412 If FILE-NAME is nil, use the value of `change-log-default-name'.
 413 If `change-log-default-name' is nil, behave as though it were 'ChangeLog'
 414 \(or whatever we use on this operating system).
 415
 416 If `change-log-default-name' contains a leading directory component, then
 417 simply find it in the current directory.  Otherwise, search in the current
 418 directory and its successive parents for a file so named.
 419
 420 Once a file is found, `change-log-default-name' is set locally in the
 421 current buffer to the complete file name.
 422 Optional arg BUFFER-FILE overrides `buffer-file-name'."
 423   ;; If user specified a file name or if this buffer knows which one to use,
 424   ;; just use that.
 425   (or file-name
 426       (setq file-name (and change-log-default-name
 427                            (file-name-directory change-log-default-name)
 428                            change-log-default-name))
 429       (progn
 430         ;; Chase links in the source file
 431         ;; and use the change log in the dir where it points.
 432         (setq file-name (or (and (or buffer-file buffer-file-name)
 433                                  (file-name-directory
 434                                   (file-chase-links
 435                                    (or buffer-file buffer-file-name))))
 436                             default-directory))
 437         (if (file-directory-p file-name)
 438             (setq file-name (expand-file-name (change-log-name) file-name)))
 439         ;; Chase links before visiting the file.
 440         ;; This makes it easier to use a single change log file
 441         ;; for several related directories.
 442         (setq file-name (file-chase-links file-name))
 443         (setq file-name (expand-file-name file-name))
 444         ;; Move up in the dir hierarchy till we find a change log file.
 445         (let ((file1 file-name)
 446               parent-dir)
 447           (while (and (not (or (get-file-buffer file1) (file-exists-p file1)))
 448                       (progn (setq parent-dir
 449                                    (file-name-directory
 450                                     (directory-file-name
 451                                      (file-name-directory file1))))
 452                              ;; Give up if we are already at the root dir.
 453                              (not (string= (file-name-directory file1)
 454                                            parent-dir))))
 455             ;; Move up to the parent dir and try again.
 456             (setq file1 (expand-file-name
 457                          (file-name-nondirectory (change-log-name))
 458                          parent-dir)))
 459           ;; If we found a change log in a parent, use that.
 460           (if (or (get-file-buffer file1) (file-exists-p file1))
 461               (setq file-name file1)))))
 462   ;; Make a local variable in this buffer so we needn't search again.
 463   (set (make-local-variable 'change-log-default-name) file-name)
 464   file-name)
 465
 466 (defun add-log-file-name (buffer-file log-file)
 467   ;; Never want to add a change log entry for the ChangeLog file itself.
 468   (unless (or (null buffer-file) (string= buffer-file log-file))
 469     (if add-log-file-name-function
 470         (funcall add-log-file-name-function buffer-file)
 471       (setq buffer-file
 472             (file-relative-name buffer-file (file-name-directory log-file)))
 473       ;; If we have a backup file, it's presumably because we're
 474       ;; comparing old and new versions (e.g. for deleted
 475       ;; functions) and we'll want to use the original name.
 476       (if (backup-file-name-p buffer-file)
 477           (file-name-sans-versions buffer-file)
 478         buffer-file))))
 479
 480 ;;;###autoload
 481 (defun add-change-log-entry (&optional whoami file-name other-window new-entry)
 482   "Find change log file, and add an entry for today and an item for this file.
 483 Optional arg WHOAMI (interactive prefix) non-nil means prompt for user
 484 name and email (stored in `add-log-full-name' and `add-log-mailing-address').
 485
 486 Second arg FILE-NAME is file name of the change log.
 487 If nil, use the value of `change-log-default-name'.
 488
 489 Third arg OTHER-WINDOW non-nil means visit in other window.
 490
 491 Fourth arg NEW-ENTRY non-nil means always create a new entry at the front;
 492 never append to an existing entry.  Option `add-log-keep-changes-together'
 493 otherwise affects whether a new entry is created.
 494
 495 Option `add-log-always-start-new-record' non-nil means always create a
 496 new record, even when the last record was made on the same date and by
 497 the same person.
 498
 499 The change log file can start with a copyright notice and a copying
 500 permission notice.  The first blank line indicates the end of these
 501 notices.
 502
 503 Today's date is calculated according to `add-log-time-zone-rule' if
 504 non-nil, otherwise in local time."
 505   (interactive (list current-prefix-arg
 506                      (prompt-for-change-log-name)))
 507   (let* ((defun (add-log-current-defun))
 508          (version (and change-log-version-info-enabled
 509                        (change-log-version-number-search)))
 510          (buf-file-name (if add-log-buffer-file-name-function
 511                             (funcall add-log-buffer-file-name-function)
 512                           buffer-file-name))
 513          (buffer-file (if buf-file-name (expand-file-name buf-file-name)))
 514          (file-name (expand-file-name (find-change-log file-name buffer-file)))
 515          ;; Set ITEM to the file name to use in the new item.
 516          (item (add-log-file-name buffer-file file-name)))
 517
 518     (unless (equal file-name buffer-file-name)
 519       (if (or other-window (window-dedicated-p (selected-window)))
 520           (find-file-other-window file-name)
 521         (find-file file-name)))
 522     (or (derived-mode-p 'change-log-mode)
 523         (change-log-mode))
 524     (undo-boundary)
 525     (goto-char (point-min))
 526
 527     (let ((full-name (or add-log-full-name (user-full-name)))
 528           (mailing-address (or add-log-mailing-address user-mail-address)))
 529
 530       (when whoami
 531         (setq full-name (read-string "Full name: " full-name))
 532         ;; Note that some sites have room and phone number fields in
 533         ;; full name which look silly when inserted.  Rather than do
 534         ;; anything about that here, let user give prefix argument so that
 535         ;; s/he can edit the full name field in prompter if s/he wants.
 536         (setq mailing-address
 537               (read-string "Mailing address: " mailing-address)))
 538
 539       ;; If file starts with a copyright and permission notice, skip them.
 540       ;; Assume they end at first blank line.
 541       (when (looking-at "Copyright")
 542         (search-forward "\n\n")
 543         (skip-chars-forward "\n"))
 544
 545       ;; Advance into first entry if it is usable; else make new one.
 546       (let ((new-entries
 547              (mapcar (lambda (addr)
 548                        (concat
 549                         (if (stringp add-log-time-zone-rule)
 550                             (let ((tz (getenv "TZ")))
 551                               (unwind-protect
 552                                   (progn
 553                                     (set-time-zone-rule add-log-time-zone-rule)
 554                                     (funcall add-log-time-format))
 555                                 (set-time-zone-rule tz)))
 556                           (funcall add-log-time-format))
 557                         "  " full-name
 558                         "  <" addr ">"))
 559                      (if (consp mailing-address)
 560                          mailing-address
 561                        (list mailing-address)))))
 562         (if (and (not add-log-always-start-new-record)
 563                  (let ((hit nil))
 564                    (dolist (entry new-entries hit)
 565                      (when (looking-at (regexp-quote entry))
 566                        (setq hit t)))))
 567             (forward-line 1)
 568           (insert (nth (random (length new-entries))
 569                        new-entries)
 570                   (if use-hard-newlines hard-newline "\n")
 571                   (if use-hard-newlines hard-newline "\n"))
 572           (forward-line -1))))
 573
 574     ;; Determine where we should stop searching for a usable
 575     ;; item to add to, within this entry.
 576     (let ((bound
 577            (save-excursion
 578              (if (looking-at "\n*[^\n* \t]")
 579                  (skip-chars-forward "\n")
 580                (if add-log-keep-changes-together
 581                    (forward-page)      ; page delimits entries for date
 582                  (forward-paragraph))) ; paragraph delimits entries for file
 583              (point))))
 584
 585       ;; Now insert the new line for this item.
 586       (cond ((re-search-forward "^\\s *\\*\\s *$" bound t)
 587              ;; Put this file name into the existing empty item.
 588              (if item
 589                  (insert item)))
 590             ((and (not new-entry)
 591                   (let (case-fold-search)
 592                     (re-search-forward
 593                      (concat (regexp-quote (concat "* " item))
 594                              ;; Don't accept `foo.bar' when
 595                              ;; looking for `foo':
 596                              "\\(\\s \\|[(),:]\\)")
 597                      bound t)))
 598              ;; Add to the existing item for the same file.
 599              (re-search-forward "^\\s *$\\|^\\s \\*")
 600              (goto-char (match-beginning 0))
 601              ;; Delete excess empty lines; make just 2.
 602              (while (and (not (eobp)) (looking-at "^\\s *$"))
 603                (delete-region (point) (line-beginning-position 2)))
 604              (insert (if use-hard-newlines hard-newline "\n")
 605                      (if use-hard-newlines hard-newline "\n"))
 606              (forward-line -2)
 607              (indent-relative-maybe))
 608             (t
 609              ;; Make a new item.
 610              (while (looking-at "\\sW")
 611                (forward-line 1))
 612              (while (and (not (eobp)) (looking-at "^\\s *$"))
 613                (delete-region (point) (line-beginning-position 2)))
 614              (insert (if use-hard-newlines hard-newline "\n")
 615                      (if use-hard-newlines hard-newline "\n")
 616                      (if use-hard-newlines hard-newline "\n"))
 617              (forward-line -2)
 618              (indent-to left-margin)
 619              (insert "* ")
 620              (if item (insert item)))))
 621     ;; Now insert the function name, if we have one.
 622     ;; Point is at the item for this file,
 623     ;; either at the end of the line or at the first blank line.
 624     (if (not defun)
 625         ;; No function name, so put in a colon unless we have just a star.
 626         (unless (save-excursion
 627                   (beginning-of-line 1)
 628                   (looking-at "\\s *\\(\\*\\s *\\)?$"))
 629           (insert ": ")
 630           (if version (insert version ?\s)))
 631       ;; Make it easy to get rid of the function name.
 632       (undo-boundary)
 633       (unless (save-excursion
 634                 (beginning-of-line 1)
 635                 (looking-at "\\s *$"))
 636         (insert ?\s))
 637       ;; See if the prev function name has a message yet or not.
 638       ;; If not, merge the two items.
 639       (let ((pos (point-marker)))
 640         (skip-syntax-backward " ")
 641         (skip-chars-backward "):")
 642         (if (and (looking-at "):")
 643                  (let ((pos (save-excursion (backward-sexp 1) (point))))
 644                    (when (equal (buffer-substring pos (point)) defun)
 645                      (delete-region pos (point)))
 646                    (> fill-column (+ (current-column) (length defun) 4))))
 647             (progn (skip-chars-backward ", ")
 648                    (delete-region (point) pos)
 649                    (unless (memq (char-before) '(?\()) (insert ", ")))
 650           (if (looking-at "):")
 651               (delete-region (+ 1 (point)) (line-end-position)))
 652           (goto-char pos)
 653           (insert "("))
 654         (set-marker pos nil))
 655       (insert defun "): ")
 656       (if version (insert version ?\s)))))
 657
 658 ;;;###autoload
 659 (defun add-change-log-entry-other-window (&optional whoami file-name)
 660   "Find change log file in other window and add entry and item.
 661 This is just like `add-change-log-entry' except that it displays
 662 the change log file in another window."
 663   (interactive (if current-prefix-arg
 664                    (list current-prefix-arg
 665                          (prompt-for-change-log-name))))
 666   (add-change-log-entry whoami file-name t))
 667 ;;;###autoload (define-key ctl-x-4-map "a" 'add-change-log-entry-other-window)
 668
 669
 670 (defvar change-log-indent-text 0)
 671
 672 (defun change-log-fill-parenthesized-list ()
 673   ;; Fill parenthesized lists of names according to GNU standards.
 674   ;; * file-name.ext (very-long-foo, very-long-bar, very-long-foobar):
 675   ;; should be filled as
 676   ;; * file-name.ext (very-long-foo, very-long-bar)
 677   ;; (very-long-foobar):
 678   (save-excursion
 679     (end-of-line 0)
 680     (skip-chars-backward " \t")
 681     (when (and (equal (char-before) ?\,)
 682                (> (point) (1+ (point-min))))
 683       (condition-case nil
 684           (when (save-excursion
 685                   (and (prog2
 686                            (up-list -1)
 687                            (equal (char-after) ?\()
 688                          (skip-chars-backward " \t"))
 689                        (or (bolp)
 690                            ;; Skip everything but a whitespace or asterisk.
 691                            (and (not (zerop (skip-chars-backward "^ \t\n*")))
 692                                 (skip-chars-backward " \t")
 693                                 ;; We want one asterisk here.
 694                                 (= (skip-chars-backward "*") -1)
 695                                 (skip-chars-backward " \t")
 696                                 (bolp)))))
 697             ;; Delete the comma.
 698             (delete-char -1)
 699             ;; Close list on previous line.
 700             (insert ")")
 701             (skip-chars-forward " \t\n")
 702             ;; Start list on new line.
 703             (insert-before-markers "("))
 704         (error nil)))))
 705
 706 (defun change-log-indent ()
 707   (change-log-fill-parenthesized-list)
 708   (let* ((indent
 709           (save-excursion
 710             (beginning-of-line)
 711             (skip-chars-forward " \t")
 712             (cond
 713              ((and (looking-at "\\(.*\\)  [^ \n].*[^ \n]  <.*>\\(?: +(.*)\\)? *$")
 714                    ;; Matching the output of add-log-time-format is difficult,
 715                    ;; but I'll get it has at least two adjacent digits.
 716                    (string-match "[[:digit:]][[:digit:]]" (match-string 1)))
 717               0)
 718              ((looking-at "[^*(]")
 719               (+ (current-left-margin) change-log-indent-text))
 720              (t (current-left-margin)))))
 721          (pos (save-excursion (indent-line-to indent) (point))))
 722     (if (> pos (point)) (goto-char pos))))
 723
 724
 725 (defvar smerge-resolve-function)
 726
 727 ;;;###autoload
 728 (define-derived-mode change-log-mode text-mode "Change Log"
 729   "Major mode for editing change logs; like Indented Text Mode.
 730 Prevents numeric backups and sets `left-margin' to 8 and `fill-column' to 74.
 731 New log entries are usually made with \\[add-change-log-entry] or \\[add-change-log-entry-other-window].
 732 Each entry behaves as a paragraph, and the entries for one day as a page.
 733 Runs `change-log-mode-hook'.
 734 \\{change-log-mode-map}"
 735   (setq left-margin 8
 736         fill-column 74
 737         indent-tabs-mode t
 738         tab-width 8
 739         show-trailing-whitespace t)
 740   (set (make-local-variable 'fill-paragraph-function)
 741        'change-log-fill-paragraph)
 742   ;; Avoid that filling leaves behind a single "*" on a line.
 743   (add-hook 'fill-nobreak-predicate
 744             '(lambda ()
 745                (looking-back "^\\s *\\*\\s *" (line-beginning-position)))
 746             nil t)
 747   (set (make-local-variable 'indent-line-function) 'change-log-indent)
 748   (set (make-local-variable 'tab-always-indent) nil)
 749   ;; We really do want "^" in paragraph-start below: it is only the
 750   ;; lines that begin at column 0 (despite the left-margin of 8) that
 751   ;; we are looking for.  Adding `* ' allows eliding the blank line
 752   ;; between entries for different files.
 753   (set (make-local-variable 'paragraph-start) "\\s *$\\|\f\\|^\\<")
 754   (set (make-local-variable 'paragraph-separate) paragraph-start)
 755   ;; Match null string on the date-line so that the date-line
 756   ;; is grouped with what follows.
 757   (set (make-local-variable 'page-delimiter) "^\\<\\|^\f")
 758   (set (make-local-variable 'version-control) 'never)
 759   (set (make-local-variable 'smerge-resolve-function)
 760        'change-log-resolve-conflict)
 761   (set (make-local-variable 'adaptive-fill-regexp) "\\s *")
 762   (set (make-local-variable 'font-lock-defaults)
 763        '(change-log-font-lock-keywords t nil nil backward-paragraph)))
 764
 765 ;; It might be nice to have a general feature to replace this.  The idea I
 766 ;; have is a variable giving a regexp matching text which should not be
 767 ;; moved from bol by filling.  change-log-mode would set this to "^\\s *\\s(".
 768 ;; But I don't feel up to implementing that today.
 769 (defun change-log-fill-paragraph (&optional justify)
 770   "Fill the paragraph, but preserve open parentheses at beginning of lines.
 771 Prefix arg means justify as well."
 772   (interactive "P")
 773   (let ((end (progn (forward-paragraph) (point)))
 774         (beg (progn (backward-paragraph) (point)))
 775         ;; Add lines starting with whitespace followed by a left paren or an
 776         ;; asterisk.
 777         (paragraph-start (concat paragraph-start "\\|\\s *\\(?:\\s(\\|\\*\\)"))
 778         ;; Make sure we call `change-log-indent'.
 779         (fill-indent-according-to-mode t))
 780     (fill-region beg end justify)
 781     t))
 782 \f
 783 (defcustom add-log-current-defun-header-regexp
 784   "^\\([[:upper:]][[:upper:]_ ]*[[:upper:]_]\\|[-_[:alpha:]]+\\)[ \t]*[:=]"
 785   "Heuristic regexp used by `add-log-current-defun' for unknown major modes."
 786   :type 'regexp
 787   :group 'change-log)
 788
 789 ;;;###autoload
 790 (defvar add-log-lisp-like-modes
 791   '(emacs-lisp-mode lisp-mode scheme-mode dsssl-mode lisp-interaction-mode)
 792   "*Modes that look like Lisp to `add-log-current-defun'.")
 793
 794 ;;;###autoload
 795 (defvar add-log-c-like-modes
 796   '(c-mode c++-mode c++-c-mode objc-mode)
 797   "*Modes that look like C to `add-log-current-defun'.")
 798
 799 ;;;###autoload
 800 (defvar add-log-tex-like-modes
 801   '(TeX-mode plain-TeX-mode LaTeX-mode tex-mode)
 802   "*Modes that look like TeX to `add-log-current-defun'.")
 803
 804 ;;;###autoload
 805 (defun add-log-current-defun ()
 806   "Return name of function definition point is in, or nil.
 807
 808 Understands C, Lisp, LaTeX (\"functions\" are chapters, sections, ...),
 809 Texinfo (@node titles) and Perl.
 810
 811 Other modes are handled by a heuristic that looks in the 10K before
 812 point for uppercase headings starting in the first column or
 813 identifiers followed by `:' or `='.  See variables
 814 `add-log-current-defun-header-regexp' and
 815 `add-log-current-defun-function'.
 816
 817 Has a preference of looking backwards."
 818   (condition-case nil
 819       (save-excursion
 820         (let ((location (point)))
 821           (cond (add-log-current-defun-function
 822                  (funcall add-log-current-defun-function))
 823                 ((apply 'derived-mode-p add-log-lisp-like-modes)
 824                  ;; If we are now precisely at the beginning of a defun,
 825                  ;; make sure beginning-of-defun finds that one
 826                  ;; rather than the previous one.
 827                  (or (eobp) (forward-char 1))
 828                  (beginning-of-defun)
 829                  ;; Make sure we are really inside the defun found,
 830                  ;; not after it.
 831                  (when (and (looking-at "\\s(")
 832                             (progn (end-of-defun)
 833                                    (< location (point)))
 834                             (progn (forward-sexp -1)
 835                                    (>= location (point))))
 836                    (if (looking-at "\\s(")
 837                        (forward-char 1))
 838                    ;; Skip the defining construct name, typically "defun"
 839                    ;; or "defvar".
 840                    (forward-sexp 1)
 841                    ;; The second element is usually a symbol being defined.
 842                    ;; If it is not, use the first symbol in it.
 843                    (skip-chars-forward " \t\n'(")
 844                    (buffer-substring-no-properties (point)
 845                                                    (progn (forward-sexp 1)
 846                                                           (point)))))
 847                 ((and (apply 'derived-mode-p add-log-c-like-modes)
 848                       (save-excursion
 849                         (beginning-of-line)
 850                         ;; Use eq instead of = here to avoid
 851                         ;; error when at bob and char-after
 852                         ;; returns nil.
 853                         (while (eq (char-after (- (point) 2)) ?\\)
 854                           (forward-line -1))
 855                         (looking-at "[ \t]*#[ \t]*define[ \t]")))
 856                  ;; Handle a C macro definition.
 857                  (beginning-of-line)
 858                  (while (eq (char-after (- (point) 2)) ?\\) ;not =; note above
 859                    (forward-line -1))
 860                  (search-forward "define")
 861                  (skip-chars-forward " \t")
 862                  (buffer-substring-no-properties (point)
 863                                                  (progn (forward-sexp 1)
 864                                                         (point))))
 865                 ((apply 'derived-mode-p add-log-c-like-modes)
 866                  ;; See whether the point is inside a defun.
 867                  (let (having-previous-defun
 868                        having-next-defun
 869                        previous-defun-end
 870                        next-defun-beginning)
 871
 872                    (save-excursion
 873                      (setq having-previous-defun
 874                            (c-beginning-of-defun))
 875                      (c-end-of-defun)
 876                      ;; `c-end-of-defun' moves point to the line after
 877                      ;; the function close, but the position we prefer
 878                      ;; here is the position after the final }.
 879                      (backward-sexp 1)
 880                      (forward-sexp 1)
 881                      ;; Skip the semicolon ``;'' for
 882                      ;; enum/union/struct/class definition.
 883                      (if (= (char-after (point)) ?\;)
 884                          (forward-char 1))
 885                      (setq previous-defun-end (point)))
 886
 887                    (save-excursion
 888                      (setq having-next-defun
 889                            (c-end-of-defun))
 890                      (c-beginning-of-defun)
 891                      (setq next-defun-beginning (point)))
 892
 893                    (if (and having-next-defun
 894                             (< location next-defun-beginning))
 895                        (skip-syntax-forward " "))
 896                    (if (and having-previous-defun
 897                             (> location previous-defun-end))
 898                        (skip-syntax-backward " "))
 899                    (unless (or
 900                             ;; When there is no previous defun, the
 901                             ;; point is not in a defun if it is not at
 902                             ;; the beginning of the next defun.
 903                             (and (not having-previous-defun)
 904                                  (not (= (point)
 905                                          next-defun-beginning)))
 906                             ;; When there is no next defun, the point
 907                             ;; is not in a defun if it is not at the
 908                             ;; end of the previous defun.
 909                             (and (not having-next-defun)
 910                                  (not (= (point)
 911                                          previous-defun-end)))
 912                             ;; If the point is between two defuns, it
 913                             ;; is not in a defun.
 914                             (and (> (point) previous-defun-end)
 915                                  (< (point) next-defun-beginning)))
 916                      ;; If the point is already at the beginning of a
 917                      ;; defun, there is no need to move point again.
 918                      (if (not (= (point) next-defun-beginning))
 919                          (c-beginning-of-defun))
 920                      ;; Is this a DEFUN construct?  And is LOCATION in it?
 921                      (if (and (looking-at "DEFUN\\b")
 922                               (>= location (point)))
 923                          ;; DEFUN ("file-name-directory", Ffile_name_directory, Sfile_name_directory, ...) ==> Ffile_name_directory
 924                          ;; DEFUN(POSIX::STREAM-LOCK, stream lockp &key BLOCK SHARED START LENGTH) ==> POSIX::STREAM-LOCK
 925                          (progn
 926                            (down-list 1)
 927                            (when (= (char-after (point)) ?\")
 928                              (forward-sexp 1)
 929                              (search-forward ","))
 930                            (skip-syntax-forward " ")
 931                            (buffer-substring-no-properties
 932                             (point)
 933                             (progn (search-forward ",")
 934                                    (forward-char -1)
 935                                    (skip-syntax-backward " ")
 936                                    (point))))
 937                        (if (looking-at "^[+-]")
 938                            ;; Objective-C
 939                            (change-log-get-method-definition)
 940                          ;; Ordinary C function syntax.
 941                          (let ((beg (point)))
 942                            (if (and
 943                                 ;; Protect against "Unbalanced parens" error.
 944                                 (condition-case nil
 945                                     (progn
 946                                       (down-list 1) ; into arglist
 947                                       (backward-up-list 1)
 948                                       (skip-chars-backward " \t")
 949                                       t)
 950                                   (error nil))
 951                                 ;; Verify initial pos was after
 952                                 ;; real start of function.
 953                                 (save-excursion
 954                                   (goto-char beg)
 955                                   ;; For this purpose, include the line
 956                                   ;; that has the decl keywords.  This
 957                                   ;; may also include some of the
 958                                   ;; comments before the function.
 959                                   (while (and (not (bobp))
 960                                               (save-excursion
 961                                                 (forward-line -1)
 962                                                 (looking-at "[^\n\f]")))
 963                                     (forward-line -1))
 964                                   (>= location (point)))
 965                                 ;; Consistency check: going down and up
 966                                 ;; shouldn't take us back before BEG.
 967                                 (> (point) beg))
 968                                (let (end middle)
 969                                  ;; Don't include any final whitespace
 970                                  ;; in the name we use.
 971                                  (skip-chars-backward " \t\n")
 972                                  (setq end (point))
 973                                  (backward-sexp 1)
 974                                  ;; Now find the right beginning of the name.
 975                                  ;; Include certain keywords if they
 976                                  ;; precede the name.
 977                                  (setq middle (point))
 978                                  ;; We tried calling `forward-sexp' in a loop
 979                                  ;; but it causes inconsistency for C names.
 980                                  (forward-sexp -1)
 981                                  ;; Is this C++ method?
 982                                  (when (and (< 2 middle)
 983                                             (string= (buffer-substring (- middle 2)
 984                                                                        middle)
 985                                                      "::"))
 986                                    ;; Include "classname::".
 987                                    (setq middle (point)))
 988                                  ;; Ignore these subparts of a class decl
 989                                  ;; and move back to the class name itself.
 990                                  (while (looking-at "public \\|private ")
 991                                    (skip-chars-backward " \t:")
 992                                    (setq end (point))
 993                                    (backward-sexp 1)
 994                                    (setq middle (point))
 995                                    (forward-word -1))
 996                                  (and (bolp)
 997                                       (looking-at
 998                                        "enum \\|struct \\|union \\|class ")
 999                                       (setq middle (point)))
1000                                  (goto-char end)
1001                                  (when (eq (preceding-char) ?=)
1002                                    (forward-char -1)
1003                                    (skip-chars-backward " \t")
1004                                    (setq end (point)))
1005                                  (buffer-substring-no-properties
1006                                   middle end)))))))))
1007                 ((apply 'derived-mode-p add-log-tex-like-modes)
1008                  (if (re-search-backward
1009                       "\\\\\\(sub\\)*\\(section\\|paragraph\\|chapter\\)"
1010                       nil t)
1011                      (progn
1012                        (goto-char (match-beginning 0))
1013                        (buffer-substring-no-properties
1014                         (1+ (point))    ; without initial backslash
1015                         (line-end-position)))))
1016                 ((derived-mode-p 'texinfo-mode)
1017                  (if (re-search-backward "^@node[ \t]+\\([^,\n]+\\)" nil t)
1018                      (match-string-no-properties 1)))
1019                 ((derived-mode-p 'perl-mode 'cperl-mode)
1020                  (if (re-search-backward "^sub[ \t]+\\([^({ \t\n]+\\)" nil t)
1021                      (match-string-no-properties 1)))
1022                 ;; Emacs's autoconf-mode installs its own
1023                 ;; `add-log-current-defun-function'.  This applies to
1024                 ;; a different mode apparently for editing .m4
1025                 ;; autoconf source.
1026                 ((derived-mode-p 'autoconf-mode)
1027                  (if (re-search-backward
1028                       "^\\(\\(m4_\\)?define\\|A._DEFUN\\)(\\[?\\([A-Za-z0-9_]+\\)" nil t)
1029                      (match-string-no-properties 3)))
1030                 (t
1031                  ;; If all else fails, try heuristics
1032                  (let (case-fold-search
1033                        result)
1034                    (end-of-line)
1035                    (when (re-search-backward
1036                           add-log-current-defun-header-regexp
1037                           (- (point) 10000)
1038                           t)
1039                      (setq result (or (match-string-no-properties 1)
1040                                       (match-string-no-properties 0)))
1041                      ;; Strip whitespace away
1042                      (when (string-match "\\([^ \t\n\r\f].*[^ \t\n\r\f]\\)"
1043                                          result)
1044                        (setq result (match-string-no-properties 1 result)))
1045                      result))))))
1046     (error nil)))
1047
1048 (defvar change-log-get-method-definition-md)
1049
1050 ;; Subroutine used within change-log-get-method-definition.
1051 ;; Add the last match in the buffer to the end of `md',
1052 ;; followed by the string END; move to the end of that match.
1053 (defun change-log-get-method-definition-1 (end)
1054   (setq change-log-get-method-definition-md
1055         (concat change-log-get-method-definition-md
1056                 (match-string 1)
1057                 end))
1058   (goto-char (match-end 0)))
1059
1060 (defun change-log-get-method-definition ()
1061 "For Objective C, return the method name if we are in a method."
1062   (let ((change-log-get-method-definition-md "["))
1063     (save-excursion
1064       (if (re-search-backward "^@implementation\\s-*\\([A-Za-z_]*\\)" nil t)
1065           (change-log-get-method-definition-1 " ")))
1066     (save-excursion
1067       (cond
1068        ((re-search-forward "^\\([-+]\\)[ \t\n\f\r]*\\(([^)]*)\\)?\\s-*" nil t)
1069         (change-log-get-method-definition-1 "")
1070         (while (not (looking-at "[{;]"))
1071           (looking-at
1072            "\\([A-Za-z_]*:?\\)\\s-*\\(([^)]*)\\)?[A-Za-z_]*[ \t\n\f\r]*")
1073           (change-log-get-method-definition-1 ""))
1074         (concat change-log-get-method-definition-md "]"))))))
1075 \f
1076 (defun change-log-sortable-date-at ()
1077   "Return date of log entry in a consistent form for sorting.
1078 Point is assumed to be at the start of the entry."
1079   (require 'timezone)
1080   (if (looking-at "^\\sw.........[0-9:+ ]*")
1081       (let ((date (match-string-no-properties 0)))
1082         (if date
1083             (if (string-match "\\(....\\)-\\(..\\)-\\(..\\)\\s-+" date)
1084                 (concat (match-string 1 date) (match-string 2 date)
1085                         (match-string 3 date))
1086               (condition-case nil
1087                   (timezone-make-date-sortable date)
1088                 (error nil)))))
1089     (error "Bad date")))
1090
1091 (defun change-log-resolve-conflict ()
1092   "Function to be used in `smerge-resolve-function'."
1093   (save-excursion
1094     (save-restriction
1095       (narrow-to-region (match-beginning 0) (match-end 0))
1096       (let ((mb1 (match-beginning 1))
1097             (me1 (match-end 1))
1098             (mb3 (match-beginning 3))
1099             (me3 (match-end 3))
1100             (tmp1 (generate-new-buffer " *changelog-resolve-1*"))
1101             (tmp2 (generate-new-buffer " *changelog-resolve-2*")))
1102         (unwind-protect
1103             (let ((buf (current-buffer)))
1104               (with-current-buffer tmp1
1105                 (change-log-mode)
1106                 (insert-buffer-substring buf mb1 me1))
1107               (with-current-buffer tmp2
1108                 (change-log-mode)
1109                 (insert-buffer-substring buf mb3 me3)
1110                 ;; Do the merge here instead of inside `buf' so as to be
1111                 ;; more robust in case change-log-merge fails.
1112                 (change-log-merge tmp1))
1113               (goto-char (point-max))
1114               (delete-region (point-min)
1115                              (prog1 (point)
1116                                (insert-buffer-substring tmp2))))
1117           (kill-buffer tmp1)
1118           (kill-buffer tmp2))))))
1119
1120 ;;;###autoload
1121 (defun change-log-merge (other-log)
1122   "Merge the contents of change log file OTHER-LOG with this buffer.
1123 Both must be found in Change Log mode (since the merging depends on
1124 the appropriate motion commands).  OTHER-LOG can be either a file name
1125 or a buffer.
1126
1127 Entries are inserted in chronological order.  Both the current and
1128 old-style time formats for entries are supported."
1129   (interactive "*fLog file name to merge: ")
1130   (if (not (derived-mode-p 'change-log-mode))
1131       (error "Not in Change Log mode"))
1132   (let ((other-buf (if (bufferp other-log) other-log
1133                      (find-file-noselect other-log)))
1134         (buf (current-buffer))
1135         date1 start end)
1136     (save-excursion
1137       (goto-char (point-min))
1138       (set-buffer other-buf)
1139       (goto-char (point-min))
1140       (if (not (derived-mode-p 'change-log-mode))
1141           (error "%s not found in Change Log mode" other-log))
1142       ;; Loop through all the entries in OTHER-LOG.
1143       (while (not (eobp))
1144         (setq date1 (change-log-sortable-date-at))
1145         (setq start (point)
1146               end (progn (forward-page) (point)))
1147         ;; Look for an entry in original buffer that isn't later.
1148         (with-current-buffer buf
1149           (while (and (not (eobp))
1150                       (string< date1 (change-log-sortable-date-at)))
1151             (forward-page))
1152           (if (not (eobp))
1153               (insert-buffer-substring other-buf start end)
1154             ;; At the end of the original buffer, insert a newline to
1155             ;; separate entries and then the rest of the file being
1156             ;; merged.
1157             (unless (or (bobp)
1158                         (and (= ?\n (char-before))
1159                              (or (<= (1- (point)) (point-min))
1160                                  (= ?\n (char-before (1- (point)))))))
1161               (insert (if use-hard-newlines hard-newline "\n")))
1162             ;; Move to the end of it to terminate outer loop.
1163             (with-current-buffer other-buf
1164               (goto-char (point-max)))
1165             (insert-buffer-substring other-buf start)))))))
1166
1167 (provide 'add-log)
1168
1169 ;; arch-tag: 81eee6fc-088f-4372-a37f-80ad9620e762
1170 ;;; add-log.el ends here