lisp/mail/mailpost.el

   1 ;;; mailpost.el --- RMAIL coupler to /usr/uci/post mailer
   2
   3 ;; This is in the public domain
   4 ;; since Delp distributed it without a copyright notice in 1986.
   5
   6 ;; Author: Gary Delp <delp@huey.Udel.Edu>
   7 ;; Maintainer: FSF
   8 ;; Created: 13 Jan 1986
   9 ;; Keywords: mail
  10
  11 ;;; Commentary:
  12
  13 ;; Yet another mail interface.  this for the rmail system to provide
  14 ;;  the missing sendmail interface on systems without /usr/lib/sendmail,
  15 ;;   but with /usr/uci/post.
  16
  17 ;;; Code:
  18
  19 (require 'mailalias)
  20 (require 'sendmail)
  21
  22 ;; (setq send-mail-function 'post-mail-send-it)
  23
  24 (defun post-mail-send-it ()
  25   "The MH -post interface for `rmail-mail' to call.
  26 To use it, include \"(setq send-mail-function 'post-mail-send-it)\" in
  27 site-init."
  28   (let ((errbuf (if mail-interactive
  29                     (generate-new-buffer " post-mail errors")
  30                   0))
  31         temfile
  32         (tembuf (generate-new-buffer " post-mail temp"))
  33         (case-fold-search nil)
  34         delimline
  35         (mailbuf (current-buffer)))
  36     (unwind-protect
  37         (save-excursion
  38           (set-buffer tembuf)
  39           (erase-buffer)
  40           (insert-buffer-substring mailbuf)
  41           (goto-char (point-max))
  42           ;; require one newline at the end.
  43           (or (= (preceding-char) ?\n)
  44               (insert ?\n))
  45           ;; Change header-delimiter to be what post-mail expects.
  46           (mail-sendmail-undelimit-header)
  47           (setq delimline (point-marker))
  48           (if mail-aliases
  49               (expand-mail-aliases (point-min) delimline))
  50           (goto-char (point-min))
  51           ;; ignore any blank lines in the header
  52           (while (and (re-search-forward "\n\n\n*" delimline t)
  53                       (< (point) delimline))
  54             (replace-match "\n"))
  55           ;; Find and handle any FCC fields.
  56           (let ((case-fold-search t))
  57             (goto-char (point-min))
  58             (if (re-search-forward "^FCC:" delimline t)
  59                 (mail-do-fcc delimline))
  60             ;; If there is a From and no Sender, put it a Sender.
  61             (goto-char (point-min))
  62             (and (re-search-forward "^From:"  delimline t)
  63                  (not (save-excursion
  64                         (goto-char (point-min))
  65                         (re-search-forward "^Sender:" delimline t)))
  66                  (progn
  67                    (forward-line 1)
  68                    (insert "Sender: " (user-login-name) "\n")))
  69             ;; don't send out a blank subject line
  70             (goto-char (point-min))
  71             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
  72                 (replace-match ""))
  73             (if mail-interactive
  74                 (save-excursion
  75                   (set-buffer errbuf)
  76                   (erase-buffer))))
  77           (let ((m (default-file-modes)))
  78             (unwind-protect
  79                 (progn
  80                   (set-default-file-modes 384)
  81                   (setq temfile  (make-temp-file ",rpost")))
  82               (set-default-file-modes m)))
  83           (apply 'call-process
  84                  (append (list (if (boundp 'post-mail-program)
  85                                    post-mail-program
  86                                  "/usr/uci/lib/mh/post")
  87                                nil errbuf nil
  88                                "-nofilter" "-msgid")
  89                          (if mail-interactive '("-watch") '("-nowatch"))
  90                          (list temfile)))
  91           (if mail-interactive
  92               (save-excursion
  93                 (set-buffer errbuf)
  94                 (goto-char (point-min))
  95                 (while (re-search-forward "\n\n* *" nil t)
  96                   (replace-match "; "))
  97                 (if (not (zerop (buffer-size)))
  98                     (error "Sending...failed to %s"
  99                            (buffer-substring (point-min) (point-max)))))))
 100       (kill-buffer tembuf)
 101       (if (bufferp errbuf)
 102           (switch-to-buffer errbuf)))))
 103
 104 (provide 'mailpost)
 105
 106 ;;; mailpost.el ends here